home *** CD-ROM | disk | FTP | other *** search
/ ProfitPress Mega CDROM2 …eeware (MSDOS)(1992)(Eng) / ProfitPress-MegaCDROM2.B6I / MISC / EDUCATIO / PROBOTS.ZIP / HOTSHOT.PR < prev    next >
Encoding:
Text File  |  1988-11-05  |  3.9 KB  |  114 lines
  1.   PROCEDURE HotShot;
  2.   {
  3.    Author: David Malmberg
  4.  
  5.    Strategy:  Stay in one place.  Find a foe.  Take a shot.
  6.    Keep improving aim and shooting until foe is lost from sights.
  7.    Then move sights (scanning) to adjacent target area.  If
  8.    hit, then move to another random position on playing field.
  9.    If the Robot scans two complete circles (720 degrees) without
  10.    finding a foe in shooting range, move to another spot on the
  11.    field.  (This will avoid "stand-offs" where opponents stay
  12.    just out of range of one another.)
  13.  
  14.    This Robot should be VERY effective against foes which
  15.    are stopped or are moving slowly.  It will be less effective
  16.    against Robots traveling at high speeds.
  17.   }
  18.  
  19.  
  20.   VAR { HotShot "Global" variables }
  21.  
  22.     Angle, { Scanning angle }
  23.     Last_Damage, { Robot's Last damage value }
  24.     Range, { Range/Distance to foe }
  25.     Sweep, { "Sweep count" -- when = 36, Robot has scanned 720 degrees }
  26.     Delta          : Integer; { Scanning arc }
  27.  
  28.  
  29.     PROCEDURE GOTO(x, y : Integer);
  30.       { Go to location X,Y on playing field. }
  31.     VAR Heading    : Integer;
  32.     BEGIN
  33.       { Find the heading we need to get to the desired spot. }
  34.       Heading := Angle_To(x, y);
  35.  
  36.       { Keep traveling at top speed until we are within 150 meters }
  37.       WHILE (distance(loc_x, loc_y, x, y) > 150) DO drive(Heading, 100);
  38.  
  39.       { Cut speed, and creep the rest of the way. }
  40.       WHILE (distance(loc_x, loc_y, x, y) > 20) DO drive(Heading, 20);
  41.  
  42.       { Stop driving, should coast to a stop. }
  43.       drive(Heading, 0); {I.E., Stop}
  44.     END; {GoTo(X,Y)}
  45.  
  46.  
  47.     FUNCTION Hurt  : Boolean;
  48.       { Checks if Robot has incurred any new damage. }
  49.     VAR Curr_Damage : Integer;
  50.       Answer         : Boolean;
  51.     BEGIN
  52.       Curr_Damage := damage;
  53.       IF Curr_Damage > Last_Damage
  54.       THEN Answer := True
  55.       ELSE Answer := False;
  56.       Last_Damage := Curr_Damage;
  57.       Hurt := Answer;
  58.     END; {Hurt}
  59.  
  60.  
  61.     PROCEDURE Move;
  62.       { Move to a random spot on the playing field. }
  63.     VAR x, y       : Integer;
  64.     BEGIN
  65.       Sweep := 0; { Reset Sweep counter to zero. }
  66.       x := Random(900)+50;
  67.       y := Random(900)+50;
  68.       GOTO(x, y);
  69.     END; {Move}
  70.  
  71.  
  72.     PROCEDURE Aim(VAR Ang : Integer; VAR Arc : Integer);
  73. {
  74.  Improve aim by doing a binary search of the target area.
  75.  I.E., divide the target area in two equal pieces and redefine
  76.  the target area to be the piece where the foe is found.
  77.  If the foe is not found, expand the search area to the
  78.  maximum arc of plus or minus 10 degrees.
  79. }
  80.     BEGIN
  81.       Arc := Arc DIV 2; { Divide search area in two. }
  82.       IF scan(Ang-Arc, Arc) <> 0 { Check piece "below" target angle. }
  83.       THEN Ang := Ang-Arc { If foe found, redefine target angle. }
  84.       ELSE IF scan(Ang+Arc, Arc) <> 0 { Check piece "above" target angle. }
  85.       THEN Ang := Ang+Arc { If foe found, redefine target angle. }
  86.       ELSE Arc := 10;
  87.       { Foe not found in either piece, expand search area to maximum arc. }
  88.     END; {Aim}
  89.  
  90.  
  91.   BEGIN {HotShot Main}
  92.     Angle := Angle_To(500, 500);
  93.     { Start scanning for foes in center of field. }
  94.     Sweep := 0; { Initialize Sweep counter to zero. }
  95.     REPEAT { Until Dead or Winner }
  96.       Delta := 10; { Start with widest scanning arc. }
  97.       Range := scan(Angle, Delta);
  98.       WHILE (Range > 40) AND (Range < 700) DO
  99.         { Must be far enough away to avoid self-damage. }
  100.         BEGIN
  101.           Sweep := 0; { Found foe, so reset Sweep to zero }
  102.           Aim(Angle, Delta); { Improve aim. }
  103.           cannon(Angle, Range); { Fire!! }
  104.           Range := scan(Angle, Delta); { Is foe still in sights? }
  105.         END;
  106.       Angle := Angle+20; { Look in adjacent target area. }
  107.       Sweep := Sweep+1;
  108.       IF Hurt OR (Sweep = 36) THEN Move;
  109.       { If hit or have scanned two full circles, move elsewhere. }
  110.     UNTIL Dead OR Winner;
  111.   END; {HotShot Main}
  112.  
  113.  
  114.