home *** CD-ROM | disk | FTP | other *** search
/ ProfitPress Mega CDROM2 …eeware (MSDOS)(1992)(Eng) / ProfitPress-MegaCDROM2.B6I / GRAPHICS / EGAVGA / VGAKIT35.ZIP / MODE13X.ASM < prev    next >
Encoding:
Assembly Source File  |  1991-05-18  |  2.0 KB  |  95 lines
  1.     include    model.h
  2.  
  3. ;
  4. ;    VGAKIT Version 3.5
  5. ;
  6. ;    Copyright 1988,89,90,91 John Bridges
  7. ;    Free for use in commercial, shareware or freeware applications
  8. ;
  9. ;    MODE13X.ASM
  10. ;
  11. ;    Set the VGA 360 by 480 256 color mode.
  12. ;
  13. ;
  14. .data
  15.     extrn    maxx:word,maxy:word,xwidth:word
  16. .code
  17.  
  18. vptbl    dw    06b00h    ; horz total
  19.     dw    05901h    ; horz displayed
  20.     dw    05a02h    ; start horz blanking
  21.     dw    08e03h    ; end horz blanking
  22.     dw    05e04h    ; start h sync
  23.     dw    08a05h    ; end h sync
  24.     dw    00d06h    ; vertical total
  25.     dw    03e07h    ; overflow
  26.     dw    04009h    ; cell height
  27.     dw    0ea10h    ; v sync start
  28.     dw    0ac11h    ; v sync end and protect cr0-cr7
  29.     dw    0df12h    ; vertical displayed
  30.     dw    02d13h    ; offset
  31.     dw    00014h    ; turn off dword mode
  32.     dw    0e715h    ; v blank start
  33.     dw    00616h    ; v blank end
  34.     dw    0e317h    ; turn on byte mode
  35. vpend    label    word
  36.  
  37.  
  38. mode13x    proc
  39.     mov    [maxx],360
  40.     mov    [xwidth],80
  41.     mov    [maxy],480
  42.     push    ds
  43.     mov    ax,cs
  44.     mov    ds,ax
  45.  
  46.     mov    ax,13h        ; start with standard mode 13h
  47.     int    10h        ; let the bios set the mode
  48.  
  49.     mov    dx,3c4h        ; alter sequencer registers
  50.     mov    ax,0604h    ; disable chain 4
  51.     out    dx,ax
  52.  
  53.     mov    ax,0f02h    ; set write plane mask to all bit planes
  54.     out    dx,ax
  55.     push    di
  56.     xor    di,di
  57.     mov    ax,0a000h    ; screen starts at segment A000
  58.     mov    es,ax
  59.     mov    cx,21600    ; ((XSIZE*YSIZE)/(4 planes))/(2 bytes per word)
  60.     xor    ax,ax
  61.     cld
  62.     rep    stosw        ; clear the whole of the screen
  63.     pop    di
  64.  
  65.     mov    ax,0100h    ; synchronous reset
  66.     out    dx,ax        ; asserted
  67.     mov    dx,3c2h        ; misc output
  68.     mov    al,0e7h        ; use 28 mHz dot clock
  69.     out    dx,al        ; select it
  70.     mov    dx,3c4h        ; sequencer again
  71.     mov    ax,0300h    ; restart sequencer
  72.     out    dx,ax        ; running again
  73.  
  74.     mov    dx,3d4h        ; alter crtc registers
  75.  
  76.     mov    al,11h        ; cr11
  77.     out    dx,al        ; current value
  78.     inc    dx        ; point to data
  79.     in    al,dx        ; get cr11 value
  80.     and    al,7fh        ; remove cr0 -> cr7
  81.     out    dx,al        ;    write protect
  82.     dec    dx        ; point to index
  83.     cld
  84.     mov    si,offset vptbl
  85.     mov    cx,((offset vpend)-(offset vptbl)) shr 1
  86. outlp:    lodsw
  87.     out    dx,ax
  88.     loop    outlp
  89.     pop    ds
  90.     ret
  91. mode13x    endp
  92.  
  93.     end
  94.  
  95.