ProfitPress Mega CDROM2 …eeware (MSDOS)(1992)(Eng)/ProfitPress-MegaCDROM2.B6I/DESQVIEW/MISC/DV2VIEW.ZIP/QUICKDV.BAT

DOS Batch File | 1990-02-18 | 8.7 KB | 299 lines

@echo off
   rem JACOB'S WELL  1:382/50 Fidonet
   rem QUICKDV.BAT  Updated: 02-16-1990 v2.62   DesqView MODE
   rem ---------------------------------------------------------------
   rem  Set-up DOS environment

set BINKLEY=C:\QBBS\
set SYSOP=Rs Zabbage
set GADS=YES
set TEARLINE=r (386)
c:
rem d:\tools\mark
c:\dos33\bin\dvansi
cd\qbbs

   rem ***************************************************************
:Start

   rem  Set the Clock (XT Only)
   rem timer/s

capture

   rem  Execute Binkley, leaving the Fossil 'hot' upon Exit
BT Share
   rem  On Exit from Binkley...
if errorlevel 192 goto 19200_baud
if errorlevel 96  goto 9600_baud
if errorlevel 80  goto Net_only
if errorlevel 60  goto Net&echo
if errorlevel 50  goto Poll_George
if errorlevel 40  goto Undial
if errorlevel 31  goto Out
if errorlevel 30  goto Clean
if errorlevel 24  goto 2400_Baud
if errorlevel 20  goto Localbbs
if errorlevel 12  goto 1200_Baud
if errorlevel 10  goto Unpackmail
if errorlevel  3  goto 300_baud
if errorlevel  1  goto Out
goto Start

:Poll_George
PLEASE POLL 382/8 CRASH
goto Net&echo

:19200_baud
QuickBBS -b19200 -E0
goto After_quick

:9600_baud
QuickBBS -b9600 -E0
goto After_quick

:2400_baud
QuickBBS -b2400 -E0
goto After_quick

:1200_baud
QuickBBS -b1200 -E0
goto After_quick

:300_baud
QuickBBS -b300 -E0
goto After_quick

:Localbbs
QuickBBS -L -E0
goto After_Quick

:Restart_Quick
c:
cd\qbbs
   rem  Restart Quickbbs by logging in the last user and exiting with an
   rem  error level of 0 when the user logs off.
QuickBBS -R -E0
   rem  Fall through to After_Quick after leaving QBBS

:After_Quick
   rem  Check for error levels that require servicing on QBBS exit
   rem  Error level six is set from a menu that shells to the outside
   rem  Error levels 3, 4, and 5 must be enabled in the QCONFIG program.
if errorlevel 100 goto Twedit
if errorlevel 90 goto Tw
if errorlevel 6 goto Outside
if errorlevel 5 goto Net&echo
if errorlevel 4 goto Echo_only
if errorlevel 3 goto Net_only
   rem  Restart BBS
goto Start

:twedit
cd c:\QBBS\tw
twedit c:\QBBS\dorinfo1.def
goto Restart_Quick

:tw
cd \qbbs\tw
echo INTERGALACTIC EMERGENCY CHANNEL TRANSMISSION FOLLOWS: > com1:
echo MAYDAY!  ______   MAYDAY!  ______   MAYDAY! >com1:
echo CABAL 'DOOMSDAY' MECHANISM HAS BEEN ENABLED > com1:
echo UNABLE TO CYPHER 'DISABLE' PASSWORD > com1:
echo EXTINCTION OF ALL CARBON-BASED SPECIES IMENENT... > com1:
copy c:\qbbs\dorinfo1.def c:\qbbs\tw
tw2.exe c:\QBBS\dorinfo1.def
REM copy /b clearscr.asc + twmesg.dat c:\qbbs\txtfiles\twmesg.asc
REM copy /b clearscr.asc + tw-day.dat c:\qbbs\txtfiles\tw-day.asc
goto Restart_Quick

:Outside
   rem  errorlevel 6 jump from After_Quick
   rem  Turn on the carrier detect program
WATCHCD COM1 ON
   rem  Change the Console I/O to Com1
ctty GATE1
   rem <Run outside program here>
COMMAND.COM
   rem  Change the I/O back to the console
Ctty CON:
   rem  Turn the carrier detect program off
WATCHCD COM1 OFF
   rem  Reload the qbbs program
goto Restart_Quick

:Net&echo
   rem  errorlevel 5 jump from After_Quick
   rem  set modem for 'BUSY'
d:\tools\AT M0H1
   rem  scan the qbbs message base for outgoing mail
MAILSCAN 3
   rem  scan the qbbs message base for outgoing echo mail
QECHO -E -F -P -Z
   rem  go to bundle to bundle the generated messages
goto Bundle

:Echo_only
   rem  errorlevel 4 jump from After_Quick
   rem  set modem for 'BUSY'
AT M0H1
   rem  scan the qbbs message base for outgoing echo mail
QECHO -E -F -P -Z
   rem  go to bundle to bundle the generated messages
goto Bundle

:Net_only
   rem  errorlevel 3 jump from After_Quick
   rem  set modem for 'BUSY'
AT M0H1
   rem  scan the qbbs message base for outgoing mail
   rem  go to bundle to bundle the generated messages
MAILSCAN 3
goto Bundle

:Unpackmail
   rem  ECHOGEN unpacks the incoming packets and tosses the echo mail
   rem  MAILTOSS tosses the net mail into board 3 while killing the null
   rem  messages
   rem  set modem for 'BUSY'
   rem run Kill0.exe to kill off any Zero length Files in c:\qbbs before unpacking
d:\tools\AT M0H1
KILL0
   rem  If a new NODEDIFF is not here then go to bundle any outbound messages
   rem  Otherwise, compile the new nodelist, then...
   rem  Fall through to bundle to bundle any messages that were generated
cd\qbbs\netfiles
SPAZ -F -M382/50 -Q c:\qbbs\netfiles
del *.MO?
cd\qbbs
QECHO -LECHOMAIL.BBS -P -U -T -Z
MAILTOSS -F -K
QLINK -LECHOMAIL.BBS
if exist c:\qbbs\ECHOMAIL.BBS del c:\qbbs\ECHOMAIL.BBS
copy c:\qbbs\ECHOMAIL.MIN c:\qbbs\ECHOMAIL.BBS
if exist c:\qbbs\*.KDP del c:\qbbs\*.KDP
if exist c:\netfiles\*.MSG del c:\qbbs\netfiles\*.MSG
   rem  Jump to Bundle if no NODEDIFF
if NOT exist c:\qbbs\netfiles\NODEDIFF.* goto Bundle
copy c:\qbbs\netfiles\NODEDIFF.*
del c:\qbbs\netfiles\NODEDIFF.*
PKXARC NODEDIFF.*
PARSELST
DAYNBR /-7 /d5
del NODEDIFF.*

:Bundle
   rem  Run OMMM to bundle the messages
   rem  Run Fixnulls first to correct any MSG with bad EOF
Rem QBUNFIX C:\QBBS\OUTBOUND -LC:\QBBS\SYSTEM.LOG
Rem FIXNULLS C:\QBBS\Outbound\*.*
OMMM -Cc:\qbbs\ommm.ctl -hc:\qbbs\outbound\ -ic:\qbbs\BINKLEY.PRM -mc:\qbbs\netmail -z1 -0
goto Start

:Clean
   rem  set modem for 'BUSY'
d:\tools\AT M0H1
CD\QBBS\TW
TWMAINT.EXE
CD\QBBS
   rem  Make sure no mail to be processed first....
   rem  If a new NODEDIFF is not here then go to bundle any outbound messages
   rem  Otherwise, compile the new nodelist, then...
   rem  Fall through to bundle2 to bundle any messages that were generated
   rem  Kill off ant Zero lenths files in C:\QBBS to prevent MSG base Crash
Rem Generate New QBEST Activity Reports
QBEST QBEST Jacob's_Well D15 U15 M15 K15 A50 /R /Z /E /C /L /S /Q
Copy QBEST.ASC C:\QBBS\QBEST.LOG
DEL QBEST.ASC
DEL QBEST.ANS
BTREPORT
KILL0
cd\qbbs\netfiles
SPAZ -F -M382/50 -Q c:\qbbs\netfiles
del *.MO?
cd\qbbs
QECHO -LECHOMAIL.BBS -P -U -T -Z
MAILTOSS -F -K
QLINK -LECHOMAIL.BBS
if exist c:\qbbs\ECHOMAIL.BBS del c:\qbbs\ECHOMAIL.BBS
copy c:\qbbs\ECHOMAIL.MIN c:\qbbs\ECHOMAIL.BBS
if exist c:\qbbs\*.KDP del c:\qbbs\*.KDP
if exist c:\netfiles\*.MSG del c:\qbbs\netfiles\*.MSG
   rem  Continue normal cleanup...
if exist c:\qbbs\*.KDP del c:\qbbs\*.KDP
if exist c:\qbbs\netfiles\*.MSG del c:\qbbs\netfiles\*.MSG
   rem  Jump to Bundle2 if no NODEDIFF
if NOT exist c:\qbbs\netfiles\NODEDIFF.* goto Bundle2
copy c:\qbbs\netfiles\NODEDIFF.*
del c:\qbbs\netfiles\NODEDIFF.*
PKXARC NODEDIFF.*
PARSELST
DAYNBR /-7 /d5
del NODEDIFF.*

:Bundle2
   rem  Run OMMM to bundle the messages
OMMM -hc:\qbbs\outbound\ -ic:\qbbs\BINKLEY.PRM -mc:\qbbs\netmail -cc:\qbbs\OMMM.CTL

   rem  Kill messages over Max_Count in Areas nn
   rem  MSGUTILS KILLCNT 3 -N25
   rem  Kill messages in Areas nn that are Older than nn days
KILL0.EXE
MSGUTILS KILLOLD 10 11 12 14 13 15 16 17 18 19 20 21 22 23 24 -D3
MSGUTILS KILLOLD 25 -D30
MSGUTILS KILLOLD 26 27 28 29 30 31 32 33 34 35 36 37 38 39 -D3
MSGUTILS KILLOLD 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 -D3
MSGUTILS KILLOLD 55 56 57 58 59 60 -D3
MSGUTILS KILLOLD 63 -D3
   rem  Optimize c: prior to packing message base
   rem First preserve MENUCORE from MENU WORKS
d:\tools\FA C:\MENUCORE.$$$ /CLEAR
d:\tools\FA C:\MENUCORE.$$$ /R+ /HID+
rem OPTUNE C: /OP
d:\tools\FA C:\MENUCORE.$$$ /CLEAR
   rem  Check for any errors in message base
CHKMSG
   rem  Pack message base, Renumber and use 'Write-In-Place' mode
Echokdup.exe
MSGPACK -I
MSGPACK -R -W
   rem  Sort USER files on Access priv
rem USERSORT -B
   rem  Pack and delete anyone who hasn't logged on in the last nn days
USERPACK -B -D180
FIXUSER
   rem  Output ASCII User list for Sysop browsing
if exist c:\qbbs\USERLIST.TXT del c:\qbbs\USERLIST.TXT
USERLIST
   rem  Get rid of any backup files
if exist c:\qbbs\outbound\*.$$? del c:\qbbs\outbound\*.$$?
if exist c:\qbbs\*.BAK del c:\qbbs\*.BAK
if exist c:\qbbs\areas.kdp del c:\qbbs\areas.kdp
   rem  Prepare new list of available PD files
if exist C:\QBBS\F382-050.ZIP del C:\QBBS\F382-050.ZIP
ALIST
PKZIP -M C:\QBBS\F382-050 C:\QBBS\F382-050.TXT
if exist C:\QBBS\F382-050.TXT del C:\QBBS\F382-050.TXT
COPY C:\QBBS\F382-050.ZIP D:\1MISC
   rem  Kill record of last Areas receiving mail
if exist c:\qbbs\ECHOMAIL.BBS del c:\qbbs\ECHOMAIL.BBS
copy c:\qbbs\ECHOMAIL.MIN c:\qbbs\ECHOMAIL.BBS
   rem  Optimize c: after processing clean-up
   rem First preserve MENUCORE from MENU WORKS
d:\tools\FA C:\MENUCORE.$$$ /CLEAR
d:\tools\FA C:\MENUCORE.$$$ /R+ /HID+
rem OPTUNE C: /OP
d:\tools\FA C:\MENUCORE.$$$ /CLEAR

goto Start

:Undial
del \qbbs\outbound\*.$$?
goto Start

:Out - Byebye - Chow
   rem  set modem for 'BUSY'
d:\tools\AT M0H1
rem d:\tools\release