home *** CD-ROM | disk | FTP | other *** search
/ Personal Computing Magazine 1988 September / SEPT_1988 / PDBASIC / VIDEO.BAS < prev   
Encoding:
BASIC Source File  |  1988-01-01  |  3.1 KB  |  148 lines
  1. 10 REM  *****************************
  2. 20 REM  *        PC PROMPTER        *
  3. 30 REM  *       By Ken Hughes       *
  4. 40 REM  * (c) Database Publications *
  5. 50 REM  *****************************
  6. 60 REM
  7. 70 CLS
  8. 80 REM getdrive:
  9. 90 WIDTH 80
  10. 100 COLOR 15,0
  11. 110 drv$=""
  12. 120 WHILE drv$=""
  13. 130 LOCATE 1,1
  14. 140 INPUT "Enter drive letter for textfile: ",drv$
  15. 150 WEND
  16. 160 IF right$(drv$,1)<>":" THEN drv$=drv$+":"
  17. 170 ON ERROR GOTO 1080
  18. 180 FILES drv$
  19. 190 ON ERROR GOTO 0
  20. 200 REM getfile:
  21. 210 PRINT
  22. 220 txtfile$=""
  23. 230 x=POS(i):y=CSRLIN
  24. 240 WHILE txtfile$=""
  25. 250 LOCATE y,x
  26. 260 INPUT "Enter name of text file: ",txtfile$
  27. 270 WEND
  28. 280 ON ERROR GOTO 1160
  29. 290 OPEN "I",1,drv$+txtfile$,1
  30. 300 CLOSE 1
  31. 310 ON ERROR GOTO 0
  32. 320 SCREEN 1
  33. 330 SCREEN 0
  34. 340 COLOR 14,0
  35. 350 CLS
  36. 360 COLOR 0,6
  37. 370 PRINT "Press the button when ready...";
  38. 380 COLOR 14,0
  39. 390 GOSUB 790
  40. 400 tim=INT(TIMER)
  41. 410 CLS
  42. 420 OPEN "I",1,drv$+txtfile$,1
  43. 430 WHILE NOT EOF (1)
  44. 440 LINE INPUT #1,a$
  45. 450 IF a$="" THEN PRINT:GOTO 620
  46. 460 FOR m%=1 TO len(a$)
  47. 470 IF MID$(a$,m%,1)="{" THEN GOSUB 980:GOTO 520
  48. 480 IF MID$(a$,m%,1)="}" THEN GOSUB 1030:GOTO 520
  49. 490 PRINT UCASE$(MID$(a$,m%,1));
  50. 500 GOSUB 1240
  51. 510 REM
  52. 520 REM delayloop:
  53. 530 FOR n%=1 TO 5
  54. 540 q$=INKEY$
  55. 550 IF q$=CHR$(0)+"P" THEN GOSUB 900
  56. 560 NEXT n%
  57. 570 NEXT m%
  58. 580 IF colflag=1 THEN COLOR 14,0
  59. 590 PRINT:PRINT
  60. 600 IF colflag=1 THEN COLOR 15,4
  61. 610 REM
  62. 620 REM bypass:
  63. 630 WEND
  64. 640 CLOSE #1
  65. 650 COLOR 0,6
  66. 660 PRINT "Press the Button...";
  67. 670 COLOR 14,0
  68. 680 PRINT
  69. 690 GOSUB 900
  70. 700 CLS
  71. 710 anymore$=""
  72. 720 WHILE UCASE$(anymore$)<>"Y" AND UCASE$(anymore$)<>"N"
  73. 730 LOCATE 1,1
  74. 740 INPUT "Another speech Y/N? ",anymore$
  75. 750 WEND
  76. 760 IF UCASE$(anymore$)="Y" THEN GOTO 80
  77. 770 END
  78. 780 REM
  79. 790 REM waitone:
  80. 800 q$=""
  81. 810 WHILE q$<>CHR$(0)+"P"
  82. 820 q$=INKEY$
  83. 830 LOCATE 25,1
  84. 840 COLOR 11,0
  85. 850 PRINT "Time "TIME$;
  86. 860 COLOR 14,0
  87. 870 WEND
  88. 880 RETURN
  89. 890 REM
  90. 900 REM waitfor:
  91. 910 q$=""
  92. 920 WHILE q$<>CHR$(0)+"P"
  93. 930 q$=INKEY$
  94. 940 GOSUB 1240
  95. 950 WEND
  96. 960 RETURN
  97. 970 REM
  98. 980 REM red:
  99. 990 colflag=1
  100. 1000 COLOR 15,4
  101. 1010 RETURN
  102. 1020 REM
  103. 1030 REM normal:
  104. 1040 colflag=0
  105. 1050 COLOR 14,0
  106. 1060 RETURN
  107. 1070 REM
  108. 1080 REM driveerror:
  109. 1090 PRINT "Drive ";drv$;" does not exist, press any key to reselect";CHR$(7);
  110. 1100 q$=""
  111. 1110 WHILE q$=""
  112. 1120 q$=INKEY$
  113. 1130 WEND
  114. 1140 RESUME 80
  115. 1150 REM
  116. 1160 REM fileerror:
  117. 1170 PRINT "File ";txtfile$;" does not exist, press any key to reselect";CHR$(7);
  118. 1180 q$=""
  119. 1190 WHILE q$=""
  120. 1200 q$=INKEY$
  121. 1210 WEND
  122. 1220 RESUME 200
  123. 1230 REM
  124. 1240 REM gettime:
  125. 1250 timdel=INT(TIMER)-tim
  126. 1260 m=INT(timdel/60)
  127. 1270 m$=STR$(m)
  128. 1280 h=INT(timdel/3600)
  129. 1290 h$=STR$(h)
  130. 1300 s=INT(timdel-(m*60)-(h*3600))
  131. 1310 s$=STR$(s)
  132. 1320 x=POS(I):y=CSRLIN
  133. 1330 LOCATE 25,1
  134. 1340 COLOR 15,0
  135. 1350 PRINT "Elapsed time: ";
  136. 1360 IF h<10 THEN PRINT "0";
  137. 1370 PRINT MID$(h$,2);":";
  138. 1380 IF m<10 THEN PRINT "0";
  139. 1390 PRINT MID$(m$,2);":";
  140. 1400 IF s<10 THEN PRINT "0";
  141. 1410 PRINT MID$(s$,2);
  142. 1420 m1=m
  143. 1430 IF colflag=0 THEN COLOR 14,0 ELSE COLOR 15,4
  144. 1440 IF y=25 THEN y=y-1
  145. 1450 LOCATE y,x
  146. 1460 RETURN
  147.  
  148.