PC Home 49/PC_Home_Issue_49.iso/winprogs/childenc/oecdemo/shared.dir/00385.ls

Text File | 1996-07-24 | 3.4 KB | 133 lines

on goToMovie moviePath
  set x to the pathName
  delete char the number of chars in x of x
  repeat while the number of chars in x > 0
    set y to char the number of chars in x of x
    if the machineType = 256 then
      if y = "\" then
        exit repeat
      end if
    else
      if y = ":" then
        exit repeat
      end if
    end if
    delete char the number of chars in x of x
  end repeat
  set theMovie to x & moviePath
  go(1, theMovie)
end

on goMovie theMovie, theFrame, type
  if type = "label" then
    go(theFrame, string(theMovie))
  else
    if type = "number" then
      go(value(theFrame), string(theMovie))
    end if
  end if
end

on goFrame theFrame, type
  if type = "label" then
    go(theFrame)
  else
    if value(theFrame) > 209 then
      setUpSprites("16-35", 0, 0)
      go(value(theFrame))
      setUpSprites("16-35", 1, 1)
    else
      go(value(theFrame))
    end if
  end if
end

on goNextLoc theMovie, theFrame, returnFrame
  set type to checkFrameType(theFrame)
  if type = "empty" then
    exit
  end if
  logLocation(returnFrame)
  if (theMovie <> EMPTY) and (string(theFrame) <> EMPTY) then
    if theMovie <> the movie then
      cursor(4)
      goMovie(theMovie, theFrame, type)
    else
      goFrame(theFrame, type)
    end if
  else
    if (theMovie <> EMPTY) and (string(theFrame) = EMPTY) then
      goMovie(theMovie, 1, type)
    else
      if string(theFrame) <> EMPTY then
        goFrame(theFrame, type)
      end if
    end if
  end if
end

on logLocation returnFrame
  global browsetrail, browseNames, browseName, CR
  if stringp(returnFrame) = 0 then
    if integerp(returnFrame) = 0 then
      set temp to marker(0) & "," & the movie
    else
      set temp to returnFrame & "," & the movie
    end if
  else
    set temp to marker(returnFrame) & "," & the movie
  end if
  if (string(browsetrail) = EMPTY) or (string(browsetrail) = "0") then
    set browsetrail to temp
    set browseNames to browseName
  else
    if line the number of lines in browsetrail of browsetrail <> temp then
      if not (browseNames contains browseName) then
        if the number of lines in browsetrail <= 12 then
          set browsetrail to browsetrail & CR & temp
          set browseNames to browseNames & CR & browseName
        else
          delete line 1 of browsetrail
          delete line 1 of browseNames
          set browsetrail to browsetrail & CR & temp
          set browseNames to browseNames & CR & browseName
        end if
      end if
    end if
  end if
end

on goBack offset
  global browsetrail, browseNames, articleList
  if stringp(browsetrail) = 0 then
    set browsetrail to EMPTY
    set browseNames to EMPTY
  end if
  if stringp(offset) = 0 then
    set offset to 0
  end if
  if string(browsetrail) <> EMPTY then
    set theTarget to line the number of lines in browsetrail of browsetrail
    if articleList contains item 2 of theTarget then
      if the number of lines in browsetrail > 1 then
        delete line the number of lines in browsetrail of browsetrail
        delete line the number of lines in browseNames of browseNames
      else
        set browsetrail to EMPTY
        set browseNames to EMPTY
      end if
      set theFrame to item 1 of theTarget
      set theMovie to item 2 of theTarget
      if theMovie <> the movie then
        go(value(theFrame) + offset, theMovie)
      else
        if theFrame <> the frame then
          go(value(theFrame) + offset)
        end if
      end if
    end if
  else
    beep()
  end if
end