Micromanía 25/CDMM_25.iso/takeru/menu.dxr/00002_bumpuku.ls

Text File | 1996-09-04 | 3.7 KB | 155 lines

on moveSprtDiag whchSprt, newH, newV
  set x1 to the locH of sprite whchSprt
  set y1 to the locV of sprite whchSprt
  set x2 to newH
  set y2 to newV
  set stepSize to 15
  set stepDelay to 5
  if (x1 <> x2) or (y1 <> y2) then
    if x1 > x2 then
      set xVal to -1
    else
      set xVal to 1
    end if
    if y1 > y2 then
      set yVal to -1
    else
      set yVal to 1
    end if
    set xDist to x2 - x1
    set yDist to y2 - y1
    changeCharacter(xDist, yDist)
    set xDistAbs to abs(xDist)
    set yDistAbs to abs(yDist)
    set x to x1 * 1.0
    set y to y1 * 1.0
    if yDistAbs > xDistAbs then
      if yDistAbs = 0 then
        set xFact to 0
      else
        set xFact to 1.0 * xDistAbs / yDistAbs * stepSize
      end if
      set yFact to stepSize
    else
      if xDistAbs = 0 then
        set yFact to 0
      else
        set yFact to 1.0 * yDistAbs / xDistAbs * stepSize
      end if
      set xFact to stepSize
    end if
    repeat while (x <> x2) or (y <> y2)
      set x to x + (xFact * xVal)
      set y to y + (yFact * yVal)
      if abs(x - x2) <= xFact then
        set x to x2
      end if
      if abs(y - y2) <= yFact then
        set y to y2
      end if
      if the castNum of sprite 30 > 100 then
        set the castNum of sprite 30 to the castNum of sprite 30 - 100
      else
        set the castNum of sprite 30 to the castNum of sprite 30 + 100
      end if
      set the locH of sprite whchSprt to integer(x)
      set the locV of sprite whchSprt to integer(y)
      updateStage()
      set curTicks to the ticks
      repeat while the ticks < (curTicks + stepDelay)
        nothing()
      end repeat
      checkMoving()
    end repeat
  else
  end if
end

on followMe offsetH, offsetV
  set newH to the mouseH - offsetH
  set newV to the mouseV - offsetV
  moveSprtDiag(30, newH, newV)
end

on changeCharacter xDist, yDist
  set xDist to xDist * 1.0
  set yDist to yDist * 1.0
  if xDist <> 0 then
    set angle to -atan(yDist / xDist) * (360 / (2 * PI))
    if xDist < 0 then
      set angle to angle + 180
    else
      if (xDist > 0) and (yDist > 0) then
        set angle to angle + 360
      end if
    end if
  else
    if yDist <= 0 then
      set angle to 90
    else
      set angle to 270
    end if
  end if
  set angle to integer(angle)
  turn(angle)
end

on turn angle
  set actualCast to the castNum of sprite 30
  set angleNew to integer(the name of cast actualCast - angle)
  if angleNew < 0 then
    set angleNew to 360 + angleNew
  end if
  if angleNew < 180 then
    set increments to integer((angleNew / 30) + integer(angleNew mod 30 / 15))
    repeat with i = 1 to increments
      if actualCast = 20 then
        set actualCast to 31
      else
        if actualCast = 120 then
          set actualCast to 131
        else
          set actualCast to actualCast - 1
        end if
      end if
      set the castNum of sprite 30 to actualCast
      updateStage()
      myDelay(5)
    end repeat
  else
    set angleNew to 360 - angleNew
    set increments to integer((angleNew / 30) + integer(angleNew mod 30 / 15))
    repeat with i = 1 to increments
      if actualCast = 31 then
        set actualCast to 20
      else
        if actualCast = 131 then
          set actualCast to 120
        else
          set actualCast to actualCast + 1
        end if
      end if
      set the castNum of sprite 30 to actualCast
      updateStage()
      myDelay(5)
    end repeat
  end if
end

on myDelay number
  startTimer()
  repeat while the timer < number
    nothing()
  end repeat
end

on lookAtMe whchSprt, newH, newV
  set x1 to the locH of sprite whchSprt
  set y1 to the locV of sprite whchSprt
  set x2 to newH
  set y2 to newV
  set xDist to x2 - x1
  set yDist to y2 - y1
  changeCharacter(xDist, yDist)
end