home *** CD-ROM | disk | FTP | other *** search
/ START Magazine / START VOL 3 NO 6.st / XREF.ARC / PARSEGET.S next >
Encoding:
Text File  |  1988-09-12  |  3.6 KB  |  88 lines
  1. ******************************************************************************
  2. *          main loop for parse_line & get_whatever in gfa_xref.bas.
  3. *                            Copyright (c) 1987
  4. *                            by David Archibald
  5. ******************************************************************************
  6. *
  7. * calling syntax:  call addr%(starting_pos%,len(string$)+1,string$,addr%)
  8. *
  9. ******************************************************************************
  10. *
  11. *
  12.              .text
  13.  
  14.              move.l     6(sp),a1               *ptr to parameters.
  15.              move.l     (a1)+,d0               *position in the string.
  16.              move.l     (a1)+,d3               *the string's length.
  17.              move.l     (a1)+,a0               *and the addr of the string.
  18.              move.l     (a1),a1                *this program's address.
  19.              clr.b      start(a1)              *init the data area.
  20.              clr.b      end(a1)
  21.              clr.b      char(a1)
  22.  
  23. get_start:
  24.              cmp.w      d0,d3
  25.              bls        EOL_exit               *end of string yet?
  26.              move.b     -1(a0,d0.w),d1
  27.              cmp.b      #$22,d1                *check for an opening quote.
  28.              beq        quote
  29.              cmp.b      #'!',d1                *rest of line is a remark-exit.
  30.              beq        EOL_exit
  31.              cmp.b      #'a',d1                *if it's not lower case, then
  32.              blt        cont                    it's not a var/proc/label.
  33.              cmp.b      #'z',d1                *it's between a-z, so it's the
  34.              ble        find_end                beginning of a var/proc/label.
  35.  
  36. cont:
  37.              addq.w     #1,d0
  38.              bra        get_start
  39.  
  40. EOL_exit:
  41.              move.b     #-1,start(a1)          *flag: end of the line reached.
  42.              rts
  43.  
  44. find_end:
  45.              move.b     d0,start(a1)           *save where the var/proc/label
  46. *                                               starts.
  47. get_end:
  48.              addq.w     #1,d0
  49.              move.b     -1(a0,d0.w),d1
  50.              cmp.b      #'!',d1                *part of the var--keep looking.
  51.              beq        get_end
  52.              cmp.b      #'$',d1                *part of the var--keep looking.
  53.              beq        get_end
  54.              cmp.b      #'%',d1                *part of the var--keep looking.
  55.              beq        get_end
  56.              cmp.b      #'_',d1                *part of the var--keep looking.
  57.              beq        get_end
  58.              cmp.b      #'0',d1                *not part of the var/proc/label
  59.              blt        exit                    so git!
  60.              cmp.b      #'9',d1                *between 0 and 9, that's ok.
  61.              ble        get_end
  62.              cmp.b      #'a',d1                *if it's not between a-z, exit.
  63.              blt        exit
  64.              cmp.b      #'z',d1
  65.              bgt        exit
  66.              cmp.w      d0,d3
  67.              bhi        get_end                *loop until the end of the str.
  68.  
  69. exit:
  70.              move.b     d0,end(a1)             *where the var/proc/label ends.
  71.              move.b     d1,char(a1)            *save the last char checked.
  72.              rts
  73.  
  74. quote:
  75.              addq.w     #1,d0                  *loop until the closing quote
  76.              move.b     -1(a0,d0.w),d1          is found.
  77.              cmp.b      #$22,d1
  78.              bne        quote
  79.              bra        cont
  80.  
  81. start:
  82.              dc.b       0
  83. end:
  84.              dc.b       0
  85. char:
  86.              dc.b       0
  87.              .end
  88.