Shocking The Web CD-ROM/SHOCK_CD.ISO/pc/tutorial/devglry/elementl/source/main.dir/00034.ls

Text File | 1996-11-11 | 5.8 KB | 175 lines

on startMovie
  global gQuestionLock
  set gQuestionLock to 0
end

on spritesOn
  repeat with x = 10 to 13
    puppetSprite(x, 1)
  end repeat
end

on selectInterviewee castMemberNumber, castMemberName
  global gWhichName
  puppetSprite(3, 1)
  set currentCast to word 2 of castMemberName + 0
  set whatItIs to word 2 of the name of cast the castNum of sprite 3
  if whatItIs < currentCast then
    puppetSound("Cube Snap.aiff")
    repeat with y = whatItIs to currentCast
      set the castNum of sprite 3 to the number of member ("Cube" && y)
      set castMemberNumber to the castNum of sprite 3
      set castMemberName to the name of cast castMemberNumber
      updateStage()
    end repeat
  else
    if whatItIs > currentCast then
      puppetSound("Cube Snap.aiff")
      repeat with y = whatItIs down to currentCast
        set the castNum of sprite 3 to the number of member ("Cube" && y)
        set castMemberNumber to the castNum of sprite 3
        set castMemberName to the name of cast castMemberNumber
        updateStage()
      end repeat
    else
      nothing()
    end if
  end if
  goToPage()
end

on buttonDown
  puppetSound("Chip.aiff")
  set selectedSprite to the clickOn
  set castMemberName to the name of cast the castNum of sprite selectedSprite
  set the foreColor of sprite selectedSprite to 255
  set the backColor of sprite selectedSprite to 23
  updateStage()
  repeat while the mouseDown
    if rollOver(selectedSprite) = 0 then
      set the foreColor of sprite selectedSprite to 255
      set the backColor of sprite selectedSprite to 0
      updateStage()
      next repeat
    end if
    set the foreColor of sprite selectedSprite to 255
    set the backColor of sprite selectedSprite to 23
    updateStage()
  end repeat
end

on spinCube
  global gSpinDirection
  if the doubleClick then
    goToPage()
  end if
  cursor(200)
  puppetSprite(3, 1)
  set selectedSprite to the clickOn
  set castMemberNumber to the castNum of sprite selectedSprite
  set castMemberName to the name of cast castMemberNumber
  set firstCast to 1.0
  set lastCast to 20.0
  set initialMouseH to the mouseH
  repeat while the mouseDown
    if the mouseH < initialMouseH then
      if word 2 of the name of cast castMemberNumber = lastCast then
        set the castNum of sprite selectedSprite to the number of member "Cube 1.0"
        set castMemberNumber to the castNum of sprite selectedSprite
        updateStage()
      end if
      set the castNum of sprite selectedSprite to the number of member ("Cube" && word 2 of the name of cast castMemberNumber + 1)
      set castMemberNumber to the castNum of sprite selectedSprite
      set castMemberName to the name of cast castMemberNumber
      set gSpinDirection to "LEFT"
    end if
    if the mouseH > initialMouseH then
      if word 2 of the name of cast castMemberNumber = firstCast then
        set the castNum of sprite selectedSprite to the number of member "Cube 20.0"
        set castMemberNumber to the castNum of sprite selectedSprite
        updateStage()
      end if
      set the castNum of sprite selectedSprite to the number of member ("Cube" && word 2 of the name of cast castMemberNumber - 1)
      set castMemberNumber to the castNum of sprite selectedSprite
      set castMemberName to the name of cast castMemberNumber
      set gSpinDirection to "RIGHT"
    end if
    set initialMouseH to the mouseH
    updateStage()
  end repeat
end

on snapTo
  global gSpinDirection
  cursor(-1)
  set selectedSprite to the clickOn
  set castMemberNumber to the castNum of sprite selectedSprite
  set castMemberName to the name of cast castMemberNumber
  set firstCast to 1.0
  set lastCast to 20.0
  set howManyPositions to 4
  set mainPositions to []
  repeat with x = 0 to 3
    set listItem to (x * (lastCast / howManyPositions)) + firstCast
    append(mainPositions, listItem)
  end repeat
  if gSpinDirection = "LEFT" then
    set currentCast to word 2 of the name of cast castMemberNumber + 0
    add(mainPositions, currentCast)
    sort(mainPositions)
    add(mainPositions, 20)
    set listPosition to findPos(mainPositions, currentCast) + 1
    set targetCast to getAt(mainPositions, listPosition + 1)
    if (currentCast - targetCast) <> 0 then
      puppetSound("Cube Snap.aiff")
    end if
    repeat with y = currentCast to targetCast
      set the castNum of sprite selectedSprite to the number of member ("Cube" && y)
      set castMemberNumber to the castNum of sprite selectedSprite
      set castMemberName to the name of cast castMemberNumber
      updateStage()
      if y = 20 then
        set the castNum of sprite selectedSprite to the number of member "Cube 1.0"
        updateStage()
      end if
    end repeat
  end if
  if gSpinDirection = "RIGHT" then
    set currentCast to word 2 of the name of cast castMemberNumber + 0
    add(mainPositions, currentCast)
    sort(mainPositions)
    set listPosition to findPos(mainPositions, currentCast) + 1
    append(mainPositions, 1)
    if currentCast = getAt(mainPositions, listPosition + 1) then
      nothing()
    else
      puppetSound("Cube Snap.aiff")
      repeat with y = currentCast down to getAt(mainPositions, listPosition - 1)
        set the castNum of sprite selectedSprite to the number of member ("Cube" && y)
        set castMemberNumber to the castNum of sprite selectedSprite
        set castMemberName to the name of cast castMemberNumber
        updateStage()
      end repeat
    end if
  end if
end

on goToPage
  set currentPosition to word 2 of the name of cast the castNum of sprite 3
  if currentPosition = 1 then
    goToNetPage("../fun.html")
  else
    if currentPosition = 6 then
      goToNetPage("../art.html")
    else
      if currentPosition = 11 then
        goToNetPage("../who.html")
      else
        if currentPosition = 16 then
          goToNetPage("../svc.html")
        end if
      end if
    end if
  end if
end