home *** CD-ROM | disk | FTP | other *** search
/ Play and Learn 2 / 19941.ZIP / 19941 / EDUCTRIC / PSPICE1 / PSPICE1.ZIP / EXAMPLE1.CIR < prev    next >
Encoding:
Text File  |  1984-01-05  |  1011 b   |  42 lines
  1. EXAMPLE1 - AN ILLUSTRATION OF ALL COMMANDS
  2. *
  3. *  THIS CIRCUIT USES ALL POSSIBLE COMMANDS TO CREATE THE MAXIMUM AMOUNT OF
  4. *  OUTPUT POSSIBLE FROM SUCH A SMALL CIRCUIT.  NORMALLY, ONLY A FEW KINDS OF
  5. *  OUTPUT (SUCH AS TRANSIENT ANALYSIS) WOULD BE RUN.
  6. *
  7. .OPT ACCT LIST NODE OPTS NOPAGE RELTOL=.001
  8. .WIDTH OUT=80
  9. .TEMP 35
  10. .TF V(5) VIN
  11. .DC VIN -0.25 0.25 0.005
  12. .AC DEC 10 1 10GHZ
  13. .TRAN/OP 5NS 500NS
  14. .SENS V(5)
  15. .NOISE V(5) VIN 20
  16. .FOUR 5MEG V(5)
  17. VIN 100 0 AC 1 SIN(0 0.1 5MEG)
  18. VCC 101 0 DC 12
  19. VEE 102 0 -12
  20. Q1 4 2 6 QNL
  21. Q2 5 3 6 QNL
  22. RS1 100 2 1K
  23. RS2 3 0 1K
  24. RC1 4 101 CRES 10K
  25. RC2 5 101 CRES 10K
  26. Q3 6 7 102 QNL
  27. Q4 7 7 102 QNL
  28. RBIAS 7 101 20K
  29. CLOAD 4 5 5PF
  30. .MODEL CRES RES (R=1 TC1=.02 TC2=.0045)
  31. .MODEL QNL NPN (BF=80 RB=100 CCS=2PF TF=0.3NS TR=6NS CJE=3PF CJC=2PF
  32. +   VA=50)
  33. .PRINT DC V(4) V(5)
  34. .PLOT DC IC(Q2)
  35. .PRINT AC VM(5) VP(5)
  36. .PLOT AC VCM(Q2) VCP(Q2)
  37. .PRINT NOISE INOISE ONOISE
  38. .PLOT NOISE INOISE ONOISE
  39. .PRINT TRAN V(4) V(5)
  40. .PLOT TRAN V(4) V(5) I(CLOAD)
  41. .PROBE
  42. .END