home *** CD-ROM | disk | FTP | other *** search
/ Play and Learn 2 / 19941.ZIP / 19941 / EDUCLING / SPELLBEE / SPELLBEE.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1994-02-04  |  3.9 KB  |  166 lines
  1. 10  REM        SPELLING BEE
  2. 20  REM
  3. 25  REM    By  Keith Barber  KCMO
  4. 30  REM
  5. 40  REM  Variables
  6. 50  REM     a$(I)  Spelling List
  7. 60  REM     N     No. of words to spell
  8. 70  REM     S     Selection; Speed
  9. 80  REM     B$    User Spelling
  10. 90  REM     T     Error Counter
  11. 100  REM     W     No. Wrong
  12. 110  REM     C     No. Correct
  13. 120  REM     TD    Time Delay
  14. 130  REM    X,Y,R  Location & Radius
  15. 140  REM           of face
  16. 150  REM
  17. 160  REM
  18. 170  REM
  19. 180  KEY OFF :CLS
  20. 190  SCREEN 1
  21. 200  KDB=VAL(RIGHT$(TIME$,2))*VAL(MID$(TIME$,4,2))
  22. 210  RANDOMIZE KDB
  23. 220  DIM A$(700),A(2,2)
  24. 230  SB$="SPELLING BEE"
  25. 240  PRINT :PRINT TAB(14);SB$
  26. 250  PRINT :PRINT :PRINT
  27. 260  PRINT "   Skill Levels:"
  28. 270  PRINT "      1) Beginning"
  29. 280  PRINT "      2) Intermediate"
  30. 290  PRINT "      3) Average"
  31. 300  PRINT "      4) Advanced"
  32. 310  PRINT "      5) Speed Reader"
  33. 320  PRINT
  34. 330  INPUT "What is your selection";S
  35. 340  PRINT
  36. 350  FOR CK=1 TO 5
  37. 360  IF CK = S THEN 400
  38. 370  NEXT CK
  39. 380  CLS : PRINT
  40. 390  CLS: PRINT "The number you selected was not offered,":PRINT "please reenter your selection.":PRINT :GOTO 230
  41. 400  INPUT "How many words would you like to spell";N
  42. 410  IF N>10 THEN PRINT "That's too many words to work with at":PRINT "one time. I'll let you spell 10 words":PRINT "during this exercise.": N=10 ELSE 430
  43. 420  FOR TD=1 TO 2000 : NEXT TD
  44. 430  ON S GOTO 440,470,500,530,560
  45. 440  T = -1
  46. 450  OPEN "I",1,"spell1.dat"
  47. 460  GOTO 580
  48. 470  T = 0
  49. 480  OPEN "I",1,"spell2.dat"
  50. 490  GOTO 580
  51. 500  T = 1
  52. 510  OPEN "I",1,"spell3.dat"
  53. 520  GOTO 580
  54. 530  T = 2
  55. 540  OPEN "I",1,"spell4.dat"
  56. 550  GOTO 580
  57. 560  T = 2
  58. 570  OPEN "I",1,"spell4.dat"
  59. 580  IF EOF(1) THEN 630
  60. 590  INPUT #1,A$
  61. 600  WORDS = WORDS + 1
  62. 610  A$(WORDS)=A$
  63. 620  GOTO 580
  64. 630  CLOSE 1
  65. 640  N1=N
  66. 650  SKIP = INT(4*RND(1))+1
  67. 660  KB = INT(WORDS*RND(1))
  68. 670  IF KB > (WORDS - N1*SKIP) THEN 250
  69. 680  CLS
  70. 690  LOCATE 10,15 :PRINT "Get Ready!"
  71. 700  FOR TD=1 TO 800 : NEXT TD
  72. 710  FOR I=KB TO KB + N1*SKIP -SKIP STEP SKIP
  73. 712  IF S=1 THEN T=-1 :GOTO 720
  74. 714  IF S=2 THEN T=0 : GOTO 720
  75. 716  IF S=3 THEN T=1 ELSE T=2
  76. 720  CLS
  77. 730  FOR TD=1 TO 500 : NEXT TD
  78. 740  PLAY"MBL20gggc"
  79. 750  LOCATE 10,15 :PRINT A$(I)
  80. 760  FOR TD=1 TO 1500/S^1.25 :NEXT TD
  81. 770  CLS
  82. 780  LOCATE 11,6 : LINE INPUT "Spell it: ";B$
  83. 790  IF B$=A$(I) THEN 910
  84. 800  BEEP : BEEP
  85. 810  IF T=2 THEN W=W+1 :GOTO 860
  86. 820  LOCATE 13,1 : PRINT "I'm sorry that was not correct. Please  try again."
  87. 830  FOR TD=1 TO 2000 :NEXT TD
  88. 840  T=T+1
  89. 850  GOTO 720
  90. 860  CLS
  91. 870  LOCATE 20,1 :PRINT "The correct spelling is... ";A$(I)
  92. 880  GOSUB 1360
  93. 890  FOR TD=1 TO 3000 : NEXT TD
  94. 900  GOTO 960
  95. 910  LOCATE 13,16: PRINT "CORRECT"
  96. 920  PLAY "MBl4abcdc"
  97. 930  GOSUB 1230
  98. 940  C=C+1
  99. 950  FOR TD=1 TO 2000 :NEXT TD
  100. 960  NEXT I
  101. 970  CLS
  102. 980  PRINT
  103. 990  PRINT "***************************************"
  104. 1000  PRINT TAB(15)"SCOREBOARD"
  105. 1010  PRINT "***************************************"
  106. 1020  PRINT
  107. 1030  PRINT "Number of words spelled"TAB(36);N
  108. 1040  PRINT
  109. 1050  PRINT "Number of words spelled correctly"TAB(36);C
  110. 1060  PRINT
  111. 1070  PRINT "Number of words misspelled"TAB(36);W
  112. 1080  PRINT
  113. 1090  PRINT "Percent spelled correctly"TAB(35);CINT(C/N*100)"%"
  114. 1100  PRINT
  115. 1110  PRINT "***************************************"
  116. 1120  PRINT
  117. 1130  R=12 :Y=130
  118. 1140  FOR HP=1 TO CINT(C/N*100/10)
  119. 1150  X=28*HP
  120. 1160  GOSUB 1260
  121. 1170  NEXT HP
  122. 1180  PRINT
  123. 1190  LOCATE 21,1 :INPUT "WOULD YOU LIKE TO SPELL SOME MORE WORDS";A$
  124. 1200  IF LEFT$(A$,1)="y" OR LEFT$(A$,1)="Y" THEN N=N+N1:GOTO 650
  125. 1210  PRINT "Okay, have a nice day."
  126. 1220  END
  127. 1230  X=160  '  Happy Face
  128. 1240  Y=150
  129. 1250  R=40
  130. 1260  CIRCLE(X,Y),R
  131. 1270  CIRCLE(X,Y+R/6),0.4*R,,3.8,5.7
  132. 1280  CIRCLE(X-0.4*R,Y-0.2*R),0.1*R
  133. 1290  CIRCLE(X+0.4*R,Y-0.2*R),0.1*R
  134. 1300  LINE(X,Y-0.1*R)-(X,Y+0.18*R)
  135. 1310  PSET(X-0.4*R,Y-0.2*R)
  136. 1320  PSET(X+0.4*R,Y-0.2*R)
  137. 1330  CIRCLE(X-0.4*R,Y-0.2*R),0.2*R,,0.785,2.356
  138. 1340  CIRCLE(X+0.4*R,Y-0.2*R),0.2*R,,0.785,2.356
  139. 1350  RETURN
  140. 1360  X=162  '  Dunce Face
  141. 1370  Y=100
  142. 1380  R=40
  143. 1390  CIRCLE(X,Y),R
  144. 1400  CIRCLE(X,Y+0.8*R),0.4*R,,0.785,2.36
  145. 1410  CIRCLE(X-0.4*R,Y-0.2*R),0.1*R
  146. 1420  CIRCLE(X+0.4*R,Y-0.2*R),0.1*R
  147. 1430  LINE(X,Y-0.1*R)-(X,Y+0.18*R)
  148. 1440  PSET(X-0.4*R,Y-0.2*R)
  149. 1450  PSET(X+0.4*R,Y-0.2*R)
  150. 1460  CIRCLE(X-0.4*R,Y-0.2*R),0.2*R,,0.5,2
  151. 1470  CIRCLE(X+0.4*R,Y-0.2*R),0.2*R,,1.14,2.64
  152. 1480  LINE(X-R-2,Y)-(X,Y-2.2*R)
  153. 1490  LINE(X+R+2,Y)-(X,Y-2.2*R)
  154. 1500  LOCATE 8,21 :PRINT "D"
  155. 1510  CIRCLE(X-0.39*R,Y-0.2*R),1,,,,2
  156. 1520  GET(X-0.39*R-1,Y-0.2*R-1)-(X-0.39*R+1,Y-0.2*R+1),A
  157. 1530  PUT(X-0.39*R-1,Y-0.2*R-1),A,XOR
  158. 1540  PSET(X-0.4*R,Y-0.2*R)
  159. 1550  FOR TD=1 TO 2
  160. 1560  FOR Y1 =Y-0.2*R TO Y-0.2*R+50 STEP 0.2
  161. 1570  PUT(X-0.39*R,Y1),A,XOR
  162. 1580  PUT(X-0.39*R,Y1),A,XOR
  163. 1590  NEXT Y1
  164. 1600  NEXT TD
  165. 1610  RETURN
  166.