home *** CD-ROM | disk | FTP | other *** search
/ RISC DISC 1 / RISC_DISC_1.iso / pd_share / code / forthmacs / !Forthmacs / lib / hexify < prev    next >
Encoding:
Text File  |  1994-07-08  |  1.5 KB  |  64 lines
  1. \ This program converts a binary file into a form suitable for downloading
  2. \ to a Data-IO prom programmer.  The format used is Intel Hex Format,
  3. \ which is select code 83 on the Data-IO.
  4. \ 
  5. \ To use:
  6. \ % forth hexify.fth -s "hexify your-binary-file-name" >filename.hex
  7.  
  8. \ TODO: use new record formats to support >64K:
  9. \ : bb AAAA 02 SSSS dd dd dd dd ... cc          Address is (SSSS <  4) + AAAA
  10. \ : bb AAAA 04 HHHH dd dd dd dd ... cc          Address is (HHHH < 16) + AAAA
  11. \ The SSSS and HHHH portions of the address are "sticky", applying to
  12. \ subsequent (type 00) records.
  13.  
  14. hex
  15.  
  16. 10 constant bytes/line
  17. variable out-addr
  18. create line-buf 64 allot
  19. variable outfile
  20. variable checksum
  21. variable end-of-file?
  22.  
  23. : .2  (s u -- )  h# ff and n->l <# # # #> 2dup upper type  ;
  24. : .4  (s u -- )  n->l <# # # # # #> 2dup upper type  ;
  25.  
  26. : get-line
  27.    bytes/line 0 do h# ff line-buf i + c! loop
  28.    bytes/line 0  do
  29.       ifd @  fgetc  dup -1 =  if
  30.          drop  end-of-file? on  leave
  31.       else
  32.          line-buf i + c!
  33.       then
  34.    loop
  35. ;
  36. : put-line
  37.    bytes/line  checksum !
  38.    ." :"  bytes/line .2
  39.    out-addr @ 8 >> h# ff and checksum +!
  40.    out-addr @ h# ff and checksum +!
  41.    out-addr @ .4
  42.    ." 00"
  43.    bytes/line  0  do
  44.       line-buf i + c@
  45.       dup checksum +!
  46.       .2
  47.    loop
  48.    checksum @ ff and
  49.    100 swap -  .2
  50.    cr
  51.    bytes/line out-addr +!
  52. ;
  53. : (hexify ( -- )
  54.    end-of-file? off
  55.    0 out-addr !
  56.    begin
  57.       get-line  put-line
  58.       end-of-file? @
  59.    until
  60.    ." :00000001FF" cr
  61.    ifd @ close
  62. ;
  63. : hexify  ( "input-file-name" -- )  hex reading (hexify  ;
  64.