Media Gallery 1995 June/MG6.ISO/mg.dig/00039.ls

Text File | 1995-04-20 | 2.1 KB | 68 lines

on mouseDown
  set fertig to 0
  set orisprite to the clickOn
  set clipcast to the castNum of sprite 37
  set cliph to the locH of sprite 37
  set clipv to the locV of sprite 37
  set the castNum of sprite 37 to the castNum of sprite the clickOn
  posfreien(the locH of sprite the clickOn, the locV of sprite the clickOn)
  set the locH of sprite 37 to the locH of sprite the clickOn
  set the locV of sprite 37 to the locV of sprite the clickOn
  set the locV of sprite the clickOn to 1000
  set oldv to the mouseV
  set oldh to the mouseH
  repeat while the mouseDown
    set newv to the mouseV
    set newh to the mouseH
    set newlocv to the locV of sprite 37 + (newv - oldv)
    set newloch to the locH of sprite 37 + (newh - oldh)
    if newloch < 280 then
      set newloch to 280
    else
      if newloch > 600 then
        set newloch to 600
      else
        set oldh to newh
      end if
    end if
    if newlocv < 90 then
      set newlocv to 90
    else
      if newlocv > 390 then
        set newlocv to 390
      else
        set oldv to newv
      end if
    end if
    set the locH of sprite 37 to newloch
    set the locV of sprite 37 to newlocv
    updateStage()
  end repeat
  if (the locH of sprite 37 > 320) and (the locH of sprite 37 < 560) and (the locV of sprite 37 > 120) and (the locV of sprite 37 < 360) then
    set puzh to (the locH of sprite 37 / 80 * 80) + 40
    set puzv to (the locV of sprite 37 / 60 * 60) + 30
    if platzfrei(puzh, puzv) then
      set the locH of sprite orisprite to puzh
      set the locV of sprite orisprite to puzv
      besetzen(puzh, puzv, orisprite)
      nachhin(orisprite)
      set fertig to loesung()
    else
      set the locH of sprite orisprite to the locH of sprite 37
      set the locV of sprite orisprite to the locV of sprite 37
      nachvorn(orisprite)
    end if
  else
    set the locH of sprite orisprite to the locH of sprite 37
    set the locV of sprite orisprite to the locV of sprite 37
    nachvorn(orisprite)
  end if
  set the castNum of sprite 37 to clipcast
  set the locH of sprite 37 to cliph
  set the locV of sprite 37 to clipv
  updateStage()
  if fertig then
    go(the frame + 2)
  end if
end