home *** CD-ROM | disk | FTP | other *** search
/ Emulator Universe CD / emulatoruniversecd1998.iso / Gameboy / ROMs / SI.ASM < prev    next >
Encoding:
Assembly Source File  |  1997-10-26  |  5.4 KB  |  235 lines
  1.  
  2. ;*****************************
  3. ;*  Space Invaders demo V1.0 *
  4. ;*****************************
  5. ; by Jeff Frohwein
  6.  
  7. ; First edit 24-Oct-97
  8. ; Last edit 26-Oct-97
  9.  
  10. ; All include files not distributed with this file
  11. ; may be found on the Code Libraries web page.
  12. ; http://hiwaay.net/~jfrohwei/gameboy/
  13.  
  14.         INCLUDE "hardware.inc"
  15.  
  16. ;Version 1.5 or later of 'hardware.inc' is required.
  17.         rev_Check_hardware_inc 1.5
  18.  
  19. ;lorambase = $c000
  20. ;hirambase = $80
  21.  
  22. ;Low RAM Assignments
  23.  
  24.         SECTION "Low Ram",BSS
  25.  
  26. XOffsetTable    DS      144
  27. SpriteTable     DS      160
  28. XOffset         DB
  29. VBlankDone      DB
  30.  
  31. ;High RAM Assignments
  32.  
  33. SPR_DMA equ $ff80
  34.  
  35.         SECTION "Org $00",HOME
  36.         ret
  37.  
  38.         SECTION "Org $40",HOME[$40]     ; Vertical Blank Interrupt
  39.         jp      VBlankIntr
  40.  
  41.         SECTION "Org $48",HOME[$48]     ; LCDC Interrupt
  42.         jp      LCDIntr
  43.  
  44.         SECTION "Org $50",HOME[$50]     ; Timer Overflow Interrupt
  45.         reti
  46.  
  47.         DB      "Date 971026"
  48.  
  49.         SECTION "Org $100",HOME[$100]
  50.  
  51. ;*** Beginning of rom execution point ***
  52.  
  53.         nop
  54.         jp      begin
  55.  
  56.         NINTENDO_LOGO
  57.  
  58. ;Rom Header Info
  59. ;    1234567890123456
  60.  db "SPACE INV DEMO",0,0      ; Cart name   16bytes
  61.  db 0,0,0                     ; Not used
  62.  db 3                         ; Cart type   ROM+MBC1+RAM+Battery
  63.  db 0                         ; ROM Size    32k
  64.  db 0                         ; RAM Size     8k
  65.  db 1,1                       ; Maker ID
  66.  db 0                         ; Version     =0
  67.  db $24                       ; Complement check (important)
  68.  dw $0                        ; Checksum (not important on real GB)
  69.  
  70.         INCLUDE "memory1.asm"
  71.         INCLUDE "export.asm"
  72.  
  73. begin:
  74.         di
  75.                   ; The stack initializes to $FFFE
  76.  
  77.         xor     a              ;a = 0
  78.         ldh     [rIF],a        ;clear pending interrupts
  79.         ldh     [rIE],a        ;disable interrupts
  80.  
  81. ; Must be in VBL before turning the screen off.
  82. WaitVBL:
  83.         ldh     a,[rLY]        ; $ff44=LCDC Y-Pos
  84.         cp      $90            ; $90 and bigger = in VBL
  85.         jr      c,WaitVBL      ; Loop until it is $90 or >
  86.  
  87.         ld      a,%00010101    ; LCD Controller = Off [No picture on screen]
  88.                                ; WindowBank = $9800 [Not used]
  89.                                ; Window = OFF
  90.                                ; BG Chr = $8000
  91.                                ; BG Bank= $9800
  92.                                ; OBJ    = 8x16
  93.                                ; OBJ    = Off
  94.                                ; BG     = On
  95.         ldh     [rLCDC],a
  96.  
  97.         ld      hl,TileData+1
  98.         ld      de,$8000
  99.         ld      bc,$1000
  100.         call    mem_Copy       ; Copy tile set to memory
  101.  
  102.         ld      hl,MapData+4
  103.         ld      de,$9800
  104.         ld      bc,$0400
  105.         call    mem_Copy       ; Copy tile map to memory
  106.  
  107.         ld      a,$c0
  108.         ldh     [rBGP],a       ; Set BG default colors
  109.  
  110.         xor     a               ;Initialize interupt vars
  111.         ld      [VBlankDone],a
  112.         ld      [XOffset],a
  113.  
  114.         ld      a,$40           ; Set LCDC Intr to LYC
  115.         ldh     [rSTAT],a
  116.  
  117.         ld      a,3
  118.         ldh     [rIE],a         ;enable LCD interrupt
  119.  
  120.         ld      a,%10010101      ; LCD Controller = On
  121.         ldh     [rLCDC],a
  122.  
  123.         ei
  124.  
  125. ; Clear whole X offset table to 00
  126.         ld      hl,XOffsetTable
  127.         ld      b,144
  128. clroff1:
  129.         xor     a
  130.         ld      [hl+],a
  131.         dec     b
  132.         jr      nz,clroff1
  133.  
  134. ; Position "invaders" to the right side of screen
  135.  
  136.         ld      hl,XOffsetTable + 8
  137.         ld      b,80
  138. clroff2:
  139.         ld      a,$ec
  140.         ld      [hl+],a
  141.         dec     b
  142.         jr      nz,clroff2
  143.  
  144. ;* Main Loop - scroll Invaders 32 pixels to the left *
  145. ;* then 32 pixels to the right & start over. *
  146.  
  147.         ld      d,1
  148. loop1:
  149.         ld      c,32
  150. loop2:
  151.         ld      a,d
  152.         ld      [XOffset],a
  153.  
  154.         call    VBlankWait
  155.  
  156.         xor     a
  157.         ld      [XOffset],a
  158.  
  159.         ld      b,5
  160. loop3:
  161.         call    VBlankWait
  162.         dec     b
  163.         jr      nz,loop3
  164.  
  165.         dec     c
  166.         jr      nz,loop2
  167.  
  168.  ; d = -d
  169.  
  170.         ld      a,d
  171.         cpl
  172.         inc     a
  173.         ld      d,a
  174.  
  175.         jr      loop1
  176.  
  177. ; Wait for VBlank Interrupt to occur
  178.  
  179. VBlankWait:
  180.         xor     a
  181.         ld      [VBlankDone],a
  182. lpp1:   ld      a,[VBlankDone]
  183.         or      a
  184.         jr      z,lpp1
  185.         ret
  186.  
  187. ; LCD Interrupt Routine
  188.  
  189. LCDIntr:
  190.         push    af
  191.         push    hl
  192.  
  193.         ldh     a,[rLYC]
  194.         ld      l,a
  195.         inc     a
  196.         cp      144
  197.         jr      nz,l2947
  198.         ld      a,1
  199. l2947:  ldh     [rLYC],a
  200.  
  201. ; Set scroll X register
  202.         ld      h,XOffsetTable / 256
  203.         ld      a,[hl]
  204.         ldh     [rSCX],a         ; ScrollX = [$c000 + [$45]]
  205.  
  206.         pop     hl
  207.         pop     af
  208.         reti
  209.  
  210. ; VBlank Interrupt Routine
  211.  
  212. VBlankIntr:
  213.         push    af
  214.         push    bc
  215.         push    hl
  216.  
  217.         ld      hl,XOffsetTable + $17
  218.         ld      b,60
  219.         ld      a,[XOffset]
  220.         ld      c,a
  221. Vloop:
  222.         ld      a,[hl]
  223.         add     a,c
  224.         ld      [hl+],a
  225.         dec     b
  226.         jr      nz,Vloop
  227.  
  228.         ld      a,1
  229.         ld      [VBlankDone],a
  230.         pop     hl
  231.         pop     bc
  232.         pop     af
  233.         reti
  234.  
  235.