MacFormat 2000 July/macformat-092.iso/MacFormat 92 CD/Shareware Plus/Utilities/FolderSynchronizer 1.8.9/FoldersSynchronizer/FoldersSynchronizer.9/AllScripts_10_ScriptRegister.ls

Text File | 2000-05-10 | 4.2 KB | 114 lines

on RegistrazioneSoftware____________
end

on LookRegistration
  global gRegisteredCopy, gMaxUnreg, gSep, gLocalSep, gOriginalProgramName, gOriginalKeySoftware
  put " " into field "VersionField"
  set gOriginalProgramName to "FoldersSynchronizer 1.3"
  set gOriginalKeySoftware to "0011"
  if MAC() then
    set gLocalSep to ":"
  else
    set gLocalSep to "/"
  end if
  set gMaxUnreg to (22 + 8 - 10) * 2
  set gRegisteredCopy to LeggiRegisterFile()
  FillVersionField()
  set the visible of the stage to 1
end

on FillVersionField
  global gRegisteredCopy, gNero, gBlu, gThisVersion, gRegisterName, gKeyCode
  set the visible of sprite 11 to 0
  if gRegisteredCopy then
    set gVersionField to "v." && gThisVersion && "- Registered to" & RETURN & gRegisterName & RETURN & "SerialNumber: " & gKeyCode
    put gVersionField into field "VersionField"
  else
    set gVersionField to "v." && gThisVersion && "- This is an unregistered shareware copy." & RETURN & "Register your copy on-line to http://order.kagi.com/?U3S" & RETURN & " or off-line using the" && QUOTE & "Register" & QUOTE && "application."
    set mySelStart to offset("http", gVersionField)
    set mySelEnd to offset("?U3S", gVersionField) + 3
    set the foreColor of field "VersionField" to gNero
    set the textStyle of field "VersionField" to "plain"
    put gVersionField into field "VersionField"
    set the foreColor of char mySelStart to mySelEnd of field "VersionField" to gBlu
    set the textStyle of char mySelStart to mySelEnd of field "VersionField" to "underline"
  end if
  set gRegisterName to VOID
  set gKeyCode to VOID
  set the visible of sprite 11 to 1
end

on LeggiRegisterFile
  global gSep, gLocalSep, gOriginalProgramName, gOriginalKeySoftware, gVersionField, gRegisterName, gKeyCode, gDirXTRAs
  set myFileInfo to gDirXTRAs & "RegistrationFile.txt"
  set myDBFile to DecriptaRegisterFile(myFileInfo)
  if myDBFile <> 0 then
    set oldDelimiter to the itemDelimiter
    set the itemDelimiter to RETURN
    set ProgramName to item 1 of myDBFile
    if ProgramName = gOriginalProgramName then
      set gRegisterName to item 2 of myDBFile
      set gKeyCode to item 3 of myDBFile
      set the itemDelimiter to "-"
      set KeySoftware to item 2 of gKeyCode
      if KeySoftware = gOriginalKeySoftware then
        set KeyBase to item 1 of gKeyCode & the itemDelimiter & item 2 of gKeyCode & the itemDelimiter
        set KeyNumber to value(item 3 of gKeyCode)
        set TestoBase to ProgramName & RETURN & gRegisterName & RETURN & KeyBase
        set the itemDelimiter to oldDelimiter
        set CodeNum to 0
        repeat with i = 1 to length(myDBFile) - length(string(KeyNumber))
          set CodeNum to CodeNum + charToNum(char i of TestoBase)
        end repeat
        return CodeNum = KeyNumber
      end if
    end if
  end if
  return 0
end

on DecriptaRegisterFile nomefile
  set TestoResult to 0
  set file to new(xtra("fileio"))
  if objectp(file) then
    set err to openFile(file, nomefile, 1)
    if err = 0 then
      set LunghezzaFile to getLength(file)
      set Chiave to ">»í•èçóòk»«"
      set LunChiave to length(Chiave)
      set TestoResult to EMPTY
      repeat with i = 1 to LunghezzaFile
        set myChar to numToChar(charToNum(readChar(file)) - charToNum(char ((i - 1) mod LunChiave) + 1 of Chiave))
        put myChar after TestoResult
      end repeat
      closeFile(file)
    end if
    set file to 0
    return TestoResult
  end if
  set file to 0
  return 0
end

on StoppaUnregistered
  global gFolderList, gMaxUnreg, gMultiAll, gOneDirection, gIterMulti
  if gOneDirection then
    set myTask to "backup"
    set myVerbo to "backup"
  else
    set myTask to "synchronization"
    set myVerbo to "synchronize"
  end if
  if (gIterMulti - 1) > 1 then
    put "s" after myTask
  end if
  if not gMultiAll then
    AlertBox("Sorry. The unregistered copy can " & myVerbo & " MAX" && gMaxUnreg && "files." & RETURN & RETURN & "No task done.")
  else
    AlertBox("Sorry. The unregistered copy can " & myVerbo & " MAX" && gMaxUnreg && "files." & RETURN & RETURN & string(gIterMulti - 1) && myTask && "done.")
  end if
  updateStage()
  set gFolderList to []
  AbortSync("Interrupted for unregistered copy." & MsgTimer())
end