home *** CD-ROM | disk | FTP | other *** search
/ PC Gamer (Italian) 48 / PC Gamer IT CD 48 2-2.iso / Starsiege / tribesdemo.exe / Disk1 / data1.cab / Tribes_Demo / base / scripts.vol / server.cs < prev    next >
Encoding:
Text File  |  1999-09-14  |  10.4 KB  |  390 lines
  1. // putting a global variable in the argument list means:
  2. // if an argument is passed for that parameter it gets
  3. // assigned to the global scope, not the scope of the function
  4.  
  5. function createTrainingServer()
  6. {
  7.    $SinglePlayer = true;
  8.    createServer($pref::lastTrainingMission, false);
  9. }
  10.  
  11. function remoteSetCLInfo(%clientId, %skin, %name, %email, %tribe, %url, %info, %autowp, %enterInv, %msgMask)
  12. {
  13.    $Client::info[%clientId, 0] = %skin;
  14.    $Client::info[%clientId, 1] = %name;
  15.    $Client::info[%clientId, 2] = %email;
  16.    $Client::info[%clientId, 3] = %tribe;
  17.    $Client::info[%clientId, 4] = %url;
  18.    $Client::info[%clientId, 5] = %info;
  19.    if(%autowp)
  20.       %clientId.autoWaypoint = true;
  21.    if(%enterInv)
  22.       %clientId.noEnterInventory = true;
  23.    if(%msgMask != "")
  24.       %clientId.messageFilter = %msgMask;
  25. }
  26.  
  27. function Server::storeData()
  28. {
  29.    $ServerDataFile = "serverTempData" @ $Server::Port @ ".cs";
  30.  
  31.    export("Server::*", "temp\\" @ $ServerDataFile, False);
  32.    export("pref::lastMission", "temp\\" @ $ServerDataFile, true);
  33.    EvalSearchPath();
  34. }
  35.  
  36. function Server::refreshData()
  37. {
  38.    exec($ServerDataFile);  // reload prefs.
  39.    checkMasterTranslation();
  40.    Server::nextMission(false);
  41. }
  42.  
  43. function Server::onClientDisconnect(%clientId)
  44. {
  45.     // Need to kill the player off here to make everything
  46.     // is cleaned up properly.
  47.    %player = Client::getOwnedObject(%clientId);
  48.    if(%player != -1 && getObjectType(%player) == "Player" && !Player::isDead(%player)) {
  49.         playNextAnim(%player);
  50.        Player::kill(%player);
  51.     }
  52.  
  53.    Client::setControlObject(%clientId, -1);
  54.    Client::leaveGame(%clientId);
  55.    Game::CheckTourneyMatchStart();
  56.    if(getNumClients() == 1) // this is the last client.
  57.       Server::refreshData();
  58. }
  59.  
  60. function KickDaJackal(%clientId)
  61. {
  62.    Net::kick(%clientId, "The FBI has been notified.  You better buy a legit copy before they get to your house.");
  63. }
  64.  
  65. function Server::onClientConnect(%clientId)
  66. {
  67.    if(!String::NCompare(Client::getTransportAddress(%clientId), "LOOPBACK", 8))
  68.    {
  69.       // force admin the loopback dude
  70.       %clientId.isAdmin = true;
  71.       %clientId.isSuperAdmin = true;
  72.    }
  73.    echo("CONNECT: " @ %clientId @ " \"" @ 
  74.       escapeString(Client::getName(%clientId)) @ 
  75.       "\" " @ Client::getTransportAddress(%clientId));
  76.  
  77.    if(Client::getName(%clientId) == "DaJackal")
  78.       schedule("KickDaJackal(" @ %clientId @ ");", 20, %clientId);
  79.  
  80.    %clientId.noghost = true;
  81.    %clientId.messageFilter = -1; // all messages
  82.    remoteEval(%clientId, SVInfo, version(), $Server::Hostname, $modList, $Server::Info, $ItemFavoritesKey);
  83.    remoteEval(%clientId, MODInfo, $MODInfo);
  84.    remoteEval(%clientId, FileURL, $Server::FileURL);
  85.  
  86.    // clear out any client info:
  87.    for(%i = 0; %i < 10; %i++)
  88.       $Client::info[%clientId, %i] = "";
  89.  
  90.    Game::onPlayerConnected(%clientId);
  91. }
  92.  
  93. function createServer(%mission, %dedicated)
  94. {
  95.    $loadingMission = false;
  96.    $ME::Loaded = false;
  97.    if(%mission == "")
  98.       %mission = $pref::lastMission;
  99.  
  100.    if(%mission == "")
  101.    {
  102.       echo("Error: no mission provided.");
  103.       return "False";
  104.    }
  105.  
  106.    if(!$SinglePlayer)
  107.       $pref::lastMission = %mission;
  108.  
  109.     //display the "loading" screen
  110.     cursorOn(MainWindow);
  111.     GuiLoadContentCtrl(MainWindow, "gui\\Loading.gui");
  112.     renderCanvas(MainWindow);
  113.  
  114.    if(!%dedicated)
  115.    {
  116.       deleteServer();
  117.       purgeResources();
  118.       newServer();
  119.       focusServer();
  120.    }
  121.    if($SinglePlayer)
  122.       newObject(serverDelegate, FearCSDelegate, true, "LOOPBACK", $Server::Port);
  123.    else
  124.       newObject(serverDelegate, FearCSDelegate, true, "IP", $Server::Port, "IPX", $Server::Port, "LOOPBACK", $Server::Port);
  125.    
  126.    exec(admin);
  127.    exec(Marker);
  128.    exec(Trigger);
  129.    exec(NSound);
  130.    exec(BaseExpData);
  131.    exec(BaseDebrisData);
  132.     exec(BaseProjData);
  133.    exec(ArmorData);
  134.    exec(Mission);
  135.     exec(Item);
  136.     exec(Player);
  137.     exec(Vehicle);
  138.     exec(Turret);
  139.     exec(Beacon);
  140.     exec(StaticShape);
  141.     exec(Station);
  142.     exec(Moveable);
  143.     exec(Sensor);
  144.     exec(Mine);
  145.     exec(InteriorLight);
  146.    
  147.    Server::storeData();
  148.  
  149.    // NOTE!! You must have declared all data blocks BEFORE you call
  150.    // preloadServerDataBlocks.
  151.  
  152.    preloadServerDataBlocks();
  153.  
  154.    Server::loadMission( ($missionName = %mission), true );
  155.  
  156.    if(!%dedicated)
  157.    {
  158.       focusClient();
  159.  
  160.         if ($IRC::DisconnectInSim == "")
  161.         {
  162.             $IRC::DisconnectInSim = true;
  163.         }
  164.         if ($IRC::DisconnectInSim == true)
  165.         {
  166.             ircDisconnect();
  167.             $IRCConnected = FALSE;
  168.             $IRCJoinedRoom = FALSE;
  169.         }
  170.       // join up to the server
  171.       $Server::Address = "LOOPBACK:" @ $Server::Port;
  172.         $Server::JoinPassword = $Server::Password;
  173.       connect($Server::Address);
  174.    }
  175.    return "True";
  176. }
  177.  
  178. function Server::nextMission(%replay)
  179. {
  180.    if(%replay || $Server::TourneyMode)
  181.       %nextMission = $missionName;
  182.    else
  183.       %nextMission = $nextMission[$missionName];
  184.    echo("Changing to mission ", %nextMission, ".");
  185.    // give the clients enough time to load up the victory screen
  186.    Server::loadMission(%nextMission);
  187. }
  188.  
  189. function remoteCycleMission(%clientId)
  190. {
  191.    if(%clientId.isAdmin)
  192.    {
  193.       messageAll(0, Client::getName(%playerId) @ " cycled the mission.");
  194.       Server::nextMission();
  195.    }
  196. }
  197.  
  198. function remoteDataFinished(%clientId)
  199. {
  200.    if(%clientId.dataFinished)
  201.       return;
  202.    %clientId.dataFinished = true;
  203.    Client::setDataFinished(%clientId);
  204.    %clientId.svNoGhost = ""; // clear the data flag
  205.    if($ghosting)
  206.    {
  207.       %clientId.ghostDoneFlag = true; // allow a CGA done from this dude
  208.       startGhosting(%clientId);  // let the ghosting begin!
  209.    }
  210. }
  211.  
  212. function remoteCGADone(%playerId)
  213. {
  214.    if(!%playerId.ghostDoneFlag || !$ghosting)
  215.       return;
  216.    %playerId.ghostDoneFlag = "";
  217.  
  218.    Game::initialMissionDrop(%playerid);
  219.  
  220.     if ($cdTrack != "")
  221.         remoteEval (%playerId, setMusic, $cdTrack, $cdPlayMode);
  222.    remoteEval(%playerId, MInfo, $missionName);
  223. }
  224.  
  225. function Server::loadMission(%missionName, %immed)
  226. {
  227.    if($loadingMission)
  228.       return;
  229.  
  230.    %missionFile = "missions\\" $+ %missionName $+ ".mis";
  231.    if(File::FindFirst(%missionFile) == "")
  232.    {
  233.       %missionName = $firstMission;
  234.       %missionFile = "missions\\" $+ %missionName $+ ".mis";
  235.       if(File::FindFirst(%missionFile) == "")
  236.       {
  237.          echo("invalid nextMission and firstMission...");
  238.          echo("aborting mission load.");
  239.          return;
  240.       }
  241.    }
  242.    echo("Notfifying players of mission change: ", getNumClients(), " in game");
  243.    for(%cl = Client::getFirst(); %cl != -1; %cl = Client::getNext(%cl))
  244.    {
  245.       Client::setGuiMode(%cl, $GuiModeVictory);
  246.       %cl.guiLock = true;
  247.       %cl.nospawn = true;
  248.       remoteEval(%cl, missionChangeNotify, %missionName);
  249.    }
  250.  
  251.    $loadingMission = true;
  252.    $missionName = %missionName;
  253.    $missionFile = %missionFile;
  254.    $prevNumTeams = getNumTeams();
  255.  
  256.    deleteObject("MissionGroup");
  257.    deleteObject("MissionCleanup");
  258.    deleteObject("ConsoleScheduler");
  259.    resetPlayerManager();
  260.    resetGhostManagers();
  261.    $matchStarted = false;
  262.    $countdownStarted = false;
  263.    $ghosting = false;
  264.  
  265.    resetSimTime(); // deal with time imprecision
  266.  
  267.    newObject(ConsoleScheduler, SimConsoleScheduler);
  268.    if(!%immed)
  269.       schedule("Server::finishMissionLoad();", 18);
  270.    else
  271.       Server::finishMissionLoad();      
  272. }
  273.  
  274. function Server::finishMissionLoad()
  275. {
  276.    $loadingMission = false;
  277.     $TestMissionType = "";
  278.    // instant off of the manager
  279.    setInstantGroup(0);
  280.    newObject(MissionCleanup, SimGroup);
  281.  
  282.    exec($missionFile);
  283.    Mission::init();
  284.     Mission::reinitData();
  285.    if($prevNumTeams != getNumTeams())
  286.    {
  287.       // loop thru clients and setTeam to -1;
  288.       messageAll(0, "New teamcount - resetting teams.");
  289.       for(%cl = Client::getFirst(); %cl != -1; %cl = Client::getNext(%cl))
  290.          GameBase::setTeam(%cl, -1);
  291.    }
  292.  
  293.    $ghosting = true;
  294.    for(%cl = Client::getFirst(); %cl != -1; %cl = Client::getNext(%cl))
  295.    {
  296.       if(!%cl.svNoGhost)
  297.       {
  298.          %cl.ghostDoneFlag = true;
  299.          startGhosting(%cl);
  300.       }
  301.    }
  302.    if($SinglePlayer)
  303.       Game::startMatch();
  304.    else if($Server::warmupTime && !$Server::TourneyMode)
  305.       Server::Countdown($Server::warmupTime);
  306.    else if(!$Server::TourneyMode)
  307.       Game::startMatch();
  308.  
  309.    $teamplay = (getNumTeams() != 1);
  310.    purgeResources(true);
  311.  
  312.    // make sure the match happens within 5-10 hours.
  313.    schedule("Server::CheckMatchStarted();", 3600);
  314.    schedule("Server::nextMission();", 18000);
  315.    
  316.    return "True";
  317. }
  318.  
  319. function Server::CheckMatchStarted()
  320. {
  321.    // if the match hasn't started yet, just reset the map
  322.    // timing issue.
  323.    if(!$matchStarted)
  324.       Server::nextMission(true);
  325. }
  326.  
  327. function Server::Countdown(%time)
  328. {
  329.    $countdownStarted = true;
  330.    schedule("Game::startMatch();", %time);
  331.    Game::notifyMatchStart(%time);
  332.    if(%time > 30)
  333.       schedule("Game::notifyMatchStart(30);", %time - 30);
  334.    if(%time > 15)
  335.       schedule("Game::notifyMatchStart(15);", %time - 15);
  336.    if(%time > 10)
  337.       schedule("Game::notifyMatchStart(10);", %time - 10);
  338.    if(%time > 5)
  339.       schedule("Game::notifyMatchStart(5);", %time - 5);
  340. }
  341.  
  342. function Client::setInventoryText(%clientId, %txt)
  343. {
  344.    remoteEval(%clientId, "ITXT", %txt);
  345. }
  346.  
  347. function centerprint(%clientId, %msg, %timeout)
  348. {
  349.    if(%timeout == "")
  350.       %timeout = 5;
  351.    remoteEval(%clientId, "CP", %msg, %timeout);
  352. }
  353.  
  354. function bottomprint(%clientId, %msg, %timeout)
  355. {
  356.    if(%timeout == "")
  357.       %timeout = 5;
  358.    remoteEval(%clientId, "BP", %msg, %timeout);
  359. }
  360.  
  361. function topprint(%clientId, %msg, %timeout)
  362. {
  363.    if(%timeout == "")
  364.       %timeout = 5;
  365.    remoteEval(%clientId, "TP", %msg, %timeout);
  366. }
  367.  
  368. function centerprintall(%msg, %timeout)
  369. {
  370.    if(%timeout == "")
  371.       %timeout = 5;
  372.    for(%clientId = Client::getFirst(); %clientId != -1; %clientId = Client::getNext(%clientId))
  373.       remoteEval(%clientId, "CP", %msg, %timeout);
  374. }
  375.  
  376. function bottomprintall(%msg, %timeout)
  377. {
  378.    if(%timeout == "")
  379.       %timeout = 5;
  380.    for(%clientId = Client::getFirst(); %clientId != -1; %clientId = Client::getNext(%clientId))
  381.       remoteEval(%clientId, "BP", %msg, %timeout);
  382. }
  383.  
  384. function topprintall(%msg, %timeout)
  385. {
  386.    if(%timeout == "")
  387.       %timeout = 5;
  388.    for(%clientId = Client::getFirst(); %clientId != -1; %clientId = Client::getNext(%clientId))
  389.       remoteEval(%clientId, "TP", %msg, %timeout);
  390. }