Cardinal Internet Access Solutions/Cardinal_Internet_Access_Solutions(1996-08-19).iso/files/internet/fibs/unixc.scc

Text File | 1994-05-31 | 3KB | 95 lines

@echo 0 ;%%Generic UNIX host with csh command shell.
@rem ****************************************************************************
@rem ****                                                                   *****
@rem ****     UNIX csh login Script                                         *****
@rem ****        Assumes that csh is the default command shell              *****
@rem ****                                                                   *****
@rem ****************************************************************************

@echo "\r\n** Connecting to FIBS via UNIX Host (command shell: csh) **\r\n"
@board 0

@rem *****************************************************
@rem ***  Dial the Telephone Number                     **
@rem *****************************************************


@rem Execute dial.scr file to dial the telephone number.
<dial.scr


@rem *****************************************************
@rem ***  Execute the login procedure                   **
@rem *****************************************************

@if "%HostLoginName%" != ""
@:RetryLogin
@   if "%NetworkScript%" == "manual.scn" ; No prompts or timeouts during manual network connect
@      wait "ogin:"
@   else
@      echo "\r\n** Logging in...\r\n"
@      if not @wait "ogin:" 10     ; e.g. "login:", or "Login:" &c.
@          echo "\r\n** Error(unixc.scc): error - Host Login Prompt not received\r\n"
@          send "\r"
@          goto RetryLogin
@      endif
@   endif
@   send "%HostLoginName%\r"
@   if not @wait "\n" 10
@      echo "\r\n** Error(unixc.scc): No response to Host Login Name\r\n"
<
@   endif
@   if "%HostPassword%" != ""
@       if not @wait "assword:" 30  ; e.g. "Password:" or "password:"
@           echo "\r\n** Error(unixc.scc): Host Password prompt not received\r\n"
<
@       endif
@       send "%HostPassword%\r"
@       if not @wait "\n" 10
@           echo "\r\n** Error(unixc.scc): No response to Host Password\r\n"
<
@       endif
@   else
@       rem ** We need to synchronize around the password **
@       echo "\r\n** Automated login script will resume after you enter your password\r\n"
@       if not @wait "assword:" 30
@          echo "\r\n** Error(unixc.scc): Host password prompt not received\r\n"
<
@       endif
@       passwordEntry 1
@       wait "\n"
@       passwordEntry 0
@   endif ; HostPassword
@else
@   if "%NetworkScript%" != "manual.scn" ; no prompts during manual network connect
@       echo "\r\n** Automated login script will resume after login is complete\r\n"
@   endif
@   wait "ogin:"
@   wait "assword:"
@   passwordEntry 1
@   wait "\n"
@   passwordEntry 0
@endif ; HostLoginName

@rem *****************************************************
@rem *** Wait for the command shell prompt             ***
@rem *****************************************************

@rem This section assumes that (1) login shell is csh, not sh (2) '%' does not occur in the motd (heaven forbid@)
@rem Change '\%' to '$' if your login shell is sh

@echo "\r\n*** Waiting for shell command prompt...\r\n"
@if not @wait "\%"  ; Wait indefinitely
@   echo "\r\n*** Error(unixc.scc): Command shell prompt not found\r\n"
<
@endif


@rem *****************************************************
@rem *** Connect via telnet                            ***
@rem *****************************************************

<telnet.scr