PC World 2008 February/PCWorld_2008-02_cd.bin/audio-video/reaper/reaper2028-install.exe/Effects/IX/MIDI_Router

Text File | 2007-12-03 | 4.9 KB | 126 lines

/*
Copyright 2007, Philip S. Considine
All rights reserved.

Redistribution and use in source and binary forms, with or without modification, are permitted
provided that the following conditions are met:

Redistributions of source code must retain the above copyright notice, this list of conditions
and the following disclaimer.

Redistributions in binary form must reproduce the above copyright notice, this list of conditions
and the following disclaimer in the documentation and/or other materials provided with the distribution.

The name of Philip S. Considine may not be used to endorse or promote products derived from this
software without specific prior written permission.

THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS OR
IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND
FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS
BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
(INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*/

////////////////////////////////////////////////////////////////////////////////////////////
desc: MIDI Router. Click edit for more info.

////////////////////////////////////////////////////////////////////////////////////////////

//I/O Channels
slider1:0<0,15,1{1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16}>Input Channel
slider2:0<0,15,1{1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16}>Output Channel
slider3:3<0,3,1{Off, Notes, Non-Notes, Both}>Mode

/*----------- NOTE MIN/MAX You can change these if you want! --------------*/
//Sliders
slider4:0<0,127,1>Note Min
slider5:127<0,127,1>Note Max

//Drop-downs with note names (disabled)
//slider4:0<0,127,1{C0,C#0,D0,D#0,E0,F0,F#0,G0,G#0,A0,A#0,B0,C1,C#1,D1,D#1,E1,F1,F#1,G1,G#1,A1,A#1,B1,C2,C#2,D2,D#2,E2,F2,F#2,G2,G#2,A2,A#2,B2,C3,C#3,D3,D#3,E3,F3,F#3,G3,G#3,A3,A#3,B3,C4,C#4,D4,D#4,E4,F4,F#4,G4,G#4,A4,A#4,B4,C5,C#5,D5,D#5,E5,F5,F#5,G5,G#5,A5,A#5,B5,C6,C#6,D6,D#6,E6,F6,F#6,G6,G#6,A6,A#6,B6,C7,C#7,D7,D#7,E7,F7,F#7,G7,G#7,A7,A#7,B7,C8,C#8,D8,D#8,E8,F8,F#8,G8,G#8,A8,A#8,B8,C9,C#9,D9,D#9,E9,F9,F#9,G9,G#9,A9,A#9,B9,C10,C#10,D10,D#10,E10,F10,F#10,G10}>Note Min
//slider5:127<0,127,1{C0,C#0,D0,D#0,E0,F0,F#0,G0,G#0,A0,A#0,B0,C1,C#1,D1,D#1,E1,F1,F#1,G1,G#1,A1,A#1,B1,C2,C#2,D2,D#2,E2,F2,F#2,G2,G#2,A2,A#2,B2,C3,C#3,D3,D#3,E3,F3,F#3,G3,G#3,A3,A#3,B3,C4,C#4,D4,D#4,E4,F4,F#4,G4,G#4,A4,A#4,B4,C5,C#5,D5,D#5,E5,F5,F#5,G5,G#5,A5,A#5,B5,C6,C#6,D6,D#6,E6,F6,F#6,G6,G#6,A6,A#6,B6,C7,C#7,D7,D#7,E7,F7,F#7,G7,G#7,A7,A#7,B7,C8,C#8,D8,D#8,E8,F8,F#8,G8,G#8,A8,A#8,B8,C9,C#9,D9,D#9,E9,F9,F#9,G9,G#9,A9,A#9,B9,C10,C#10,D10,D#10,E10,F10,F#10,G10}>Note Max
/*-------------------------------------------------------------------------*/

//Transpose
slider6:0<-60,60,1>Transpose

////////////////////////////////////////////////////////////////////////////////////////////
@init

statNoteOn = 9 * 16;
statNoteOff = 8 * 16;
status = channel = note = velocity = 0;

////////////////////////////////////////////////////////////////////////////////////////////
@slider

slider4 = floor(slider4);
slider4 < 0 ? slider4 = 0;
slider4 > 127 ? slider4 = 127;

slider5 = floor(slider5);
slider5 < 0 ? slider5 = 0;
slider5 > 127 ? slider5 = 127;

slider6 = floor(slider6);
slider6 < -60 ? slider6 = -60;
slider6 > 60 ? slider6 = 60;

inChannel = slider1;
outChannel = slider2;
mode = slider3;
noteMin = slider4;
noteMax = slider5;
transpose = slider6;

////////////////////////////////////////////////////////////////////////////////////////////
@block
while
(
    midirecv(offset,msg1,msg23) ?
    (
        //Check status byte
        status = msg1 & 240;    //High four bits is message type (240 == 11110000)
        channel = msg1 & 15;    //Low four bits is channel number (15 == 00001111)

        //Is it on our channel?
        channel == inChannel ?
        (
            //Route note events
            (status == statNoteOn || status == statNoteOff) ?
            (
                //get note number
                note = msg23 & 127;

                //Is it within our note range?
                mode & 1 ?
                (
                    note >= noteMin && note <= noteMax ?
                    (
                        //Transpose and clamp
                        note += transpose;
                        note < 0 ? note = 0; note > 127 ? note = 127;

                        //Get velocity
                        velocity = ((msg23/256) & 127);

                        //Set up messages
                        msg1 = status + outChannel;
                        msg23 = note|(velocity*256);
                    );
                );
            )
            :
            (
                //Route non-note events
                mode & 2 ? msg1 = status + outChannel;
            );
        );
        //Send messages
        midisend(offset,msg1,msg23);
    );
);