PC World 2007 July & August/PCWorld_2007-07-08_cd.bin/audio-video/reaper/reaper1861-install.exe/Effects/IX/MIDI_CCRider

Text File | 2007-03-30 | 5.7 KB | 157 lines

/*
Copyright 2007, Philip S. Considine
All rights reserved.

Redistribution and use in source and binary forms, with or without modification, are permitted
provided that the following conditions are met:

Redistributions of source code must retain the above copyright notice, this list of conditions
and the following disclaimer.

Redistributions in binary form must reproduce the above copyright notice, this list of conditions
and the following disclaimer in the documentation and/or other materials provided with the distribution.

The name of Philip S. Considine may not be used to endorse or promote products derived from this
software without specific prior written permission.

THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS OR
IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND
FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS
BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
(INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*/

////////////////////////////////////////////////////////////////////////////////////////////
desc: LFO Controlled MIDI CC Generator

////////////////////////////////////////////////////////////////////////////////////////////
slider1:0<0,15,1{1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16}>MIDI Channel
slider2:1<0,127,1{0 Bank Sel M,1 Mod Wheel M,2 Breath M,3,4 Foot P M,5 Porta M,6 Data Entry M,7 Vol M,8 Balance M,9,10 Pan M,11 Expression M,12 Ctrl 1 M,13 Ctrl 2 M,14,15,16 GP Slider 1,17 GP Slider 2,18 GP Slider 3,19 GP Slider 4,20,21,22,23,24,25,26,27,28,29,30,31,32 Bank Sel L,33 Mod Wheel L,34 Breath L,35,36 Foot P L,37 Porta L,38 Data Entry L,39 Vol L,40 Balance L,41,42 Pan L,43 Expression L,44 Ctrl 1 L,45 Ctrl 2 L,46,47,48,49,50,51,52,53,54,55,56,57,58,59,60,61,62,63,64 Hold P sw,65 Porta sw,66 Sustenuto sw,67 Soft P sw,68 Legato P sw,69 Hold 2 P sw,70 S.Variation,71 S.Timbre,72 S.Release,73 S.Attack,74 S.Brightness,75 S.Ctrl 6,76 S.Ctrl 7,77 S.Ctrl 8,78 S.Ctrl 9,79 S.Ctrl 10,80 GP B.1 sw,81 GP B.2 sw,82 GP B.3 sw,83 GP B.4 sw,84,85,86,87,88,89,90,91 Effects Lv,92 Trem Lv,93 Chorus Lv,94 Celeste Lv,95 Phaser Lv,96 Data B. Inc,97 Data B. Dec,98 NRP L,99 NRP M,100 RP L,101 RP M,102,103,104,105,106,107,108,109,110,111,112,113,114,115,116,117,118,119,120,121,122,123,124,125,126,127}>Controller
slider3:0<0,127,1>Centre
slider4:0<0,127,1>Range (+/-)
slider5:0<0,127,1>Off Value
slider6:0<0,0,1{Sine}>LFO Shape
slider7:1<0,32,0.1>LFO Frequency
slider8:0<0,1,1{Hertz,Beats}>LFO Units
slider9:6<0,9,1{1,2,4,8,16,32,64,128,256,512}>Updates Per Beat
slider10:1<0,1,1{Off,On}>On/Off
slider16:0,Debug

////////////////////////////////////////////////////////////////////////////////////////////
@init
statController    = 11*16;
updateCounter = 0;
t = 0;

divs[0] = 1;
divs[1] = 2;
divs[2] = 4;
divs[3] = 8;
divs[4] = 16;
divs[5] = 32;
divs[6] = 64;
divs[7] = 128;
divs[8] = 256;
divs[9] = 512;

////////////////////////////////////////////////////////////////////////////////////////////
@slider

slider3 < 0 ? slider3 = 0; slider3 > 127 ? slider3 = 127; slider3= floor(slider3);
slider4 < 0 ? slider4 = 0; slider4 > 127 ? slider4 = 127; slider4= floor(slider4);
slider5 < 0 ? slider5 = 0; slider5 > 127 ? slider5 = 127; slider5= floor(slider5);
slider7 < 0 ? slider7 = 0; slider7 > 50 ? slider7 = 256;

channel = slider1;
target = slider2;
centre = slider3;
range = slider4;
offValue = slider5;
shape = slider6;
freq = slider7;
units = slider8;
updateFreq = divs[slider9];

slider10 != on ?
(
    on = slider10;
    t = 0;
    updateCounter = 0;
);

////////////////////////////////////////////////////////////////////////////////////////////
@block
updateSamples = ((srate * 60) / tempo) / updateFreq;

units == 0 ? oscTemp = 2*$pi*freq; //Hz
units == 1 ? oscTemp = 2*$pi*((tempo/60)/freq); //Beats

on == 1 ?
(
    active = 1;

    updateCounter + samplesblock >= updateSamples ?
    (
        updateSamples <= samplesblock ?
        (
            //Possibly more than one update in the block
            samplesLeft = samplesblock;
            offset = 0;
            while
            (
                offset += updateSamples - updateCounter;

                t += (updateSamples - updateCounter)/srate;

                //Sine
                shape == 0 ? value = centre + floor(range * sin(oscTemp*t));

                value < 0 ? value = 0;
                value > 127 ? value = 127;

                midisend(offset,statController+channel,target|(value*256));
                samplesLeft -= updateSamples - updateCounter;
                updateCounter = 0;
                samplesLeft >= updateSamples;
            );
            updateCounter = samplesLeft;
            t += updateCounter/srate;

        )
        :
        (
            //Block is smaller than updateSamples, just one update
            offset = updateCounter + samplesblock - updateSamples;

            t += offset/srate;

            //Sine
            shape == 0 ? value = centre + floor(range * sin(oscTemp*t));

            value < 0 ? value = 0;
            value > 127 ? value = 127;

            midisend(offset,statController+channel,target|(value*256));
            updateCounter = samplesblock - offset;
            t += updateCounter/srate;
        );
    )
    :
    (
        //Just update counters
        updateCounter += samplesblock;
        t += samplesblock /srate;
    );
)
:
(
    //send off value only if not already sent
    active == 1 ?
    (
        midisend(offset,statController+channel,target|(offValue*256));
        active = 0;
    );
);