home *** CD-ROM | disk | FTP | other *** search
/ PC World 2007 March / PCWorld_2007-03_cd.bin / audio-video / reaper / reaper174-install.exe / Effects / SStillwell / majortom < prev    next >
Text File  |  2007-01-25  |  5KB  |  161 lines
  1. // Copyright 2006, Thomas Scott Stillwell
  2. // All rights reserved.
  3. //
  4. //Redistribution and use in source and binary forms, with or without modification, are permitted 
  5. //provided that the following conditions are met:
  6. //
  7. //Redistributions of source code must retain the above copyright notice, this list of conditions 
  8. //and the following disclaimer. 
  9. //
  10. //Redistributions in binary form must reproduce the above copyright notice, this list of conditions 
  11. //and the following disclaimer in the documentation and/or other materials provided with the distribution. 
  12. //
  13. //The name of Thomas Scott Stillwell may not be used to endorse or 
  14. //promote products derived from this software without specific prior written permission. 
  15. //
  16.  
  17.  
  18. //THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS OR 
  19. //IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND 
  20. //FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS 
  21. //BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES 
  22. //(INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR 
  23. //PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, 
  24. //STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF 
  25. //THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  26. desc:program dependent compressor
  27.  
  28. slider1:0<-60,0,0.1>Threshold (dB)
  29. slider2:1<1,20,0.1>Ratio
  30. slider3:0<-20,20,0.1>Gain
  31. slider4:0<0,1,1{No,Yes}>Soft knee?
  32. slider5:0<0,1,1{Normal,Sidechain}>Detector input
  33. slider6:0<0,1,1{No,Yes}>Auto-makeup?
  34. slider7:0<0,1,1{Peak,RMS}>Detection
  35. slider8:0<0,1,1{Feedforward,Feedback}>Detection source
  36.  
  37. @init
  38.   denorm = 10^-30;
  39.   log2db = 8.6858896380650365530225783783321; // 20 / ln(10)
  40.   db2log = 0.11512925464970228420089957273422; // ln(10) / 20 
  41.   dcoffset = 0.0000000000000000000000001;
  42.   i=0;
  43.   loop(
  44.     120,
  45.     attimes[i] = ((0.08924 / i) + (0.60755 / (i ^ 2)) - 0.00006)+dcoffset;
  46.     i+=1;
  47.   );
  48.   attime=0.010;
  49.   reltime=0.100;
  50.   maxover=0;
  51.   ratio=0;
  52.   cratio=0;
  53.   rundb=0;
  54.   overdb=0;
  55.   maxover=0;
  56.   atcoef=exp(-1/(attime * srate));
  57.   relcoef=exp(-1/(reltime * srate));
  58.   fbacoef=exp(-1000/(2 * srate)); // 2 msec. opto attack for feedback detection
  59.   fbrcoef=exp(-1000/(200 * srate)); // 200 msec. opto release for feedback detection
  60.   sidechain = 0;
  61.   automakeup = 0;
  62.  
  63. @slider
  64.   thresh = slider1;
  65.   threshv = exp(thresh * db2log);
  66.   ratio = slider2;
  67.   softknee = slider4;
  68.   cthresh = (softknee ? (thresh -3) : thresh);
  69.   cthreshv = exp(cthresh * db2log);
  70.   sidechain = slider5;
  71.   automakeup = slider6;
  72.   automakeup ? (
  73.     autogain = (abs(thresh) - (abs(thresh)/max(1,ratio-1)))/2;
  74.   ) : (
  75.     autogain = 0;
  76.   );
  77.   makeup = slider3;
  78.   makeupv = exp((makeup+autogain) * db2log);
  79.   RMSdet = slider7;
  80.   RMSdet ? (
  81.     rmscoef=exp(-1000/(10 * srate));       // 10 ms RMS window
  82.   ) : (
  83.     rmscoef=exp(-1000/(0.0025 * srate));  // 2.5 us Peak detector
  84.   );
  85.   opto = slider8;
  86.  
  87. @sample
  88.   spl0 += denorm;
  89.   spl1 += denorm;
  90.   sidechain ? (
  91.     spl2 += denorm;
  92.     spl3 += denorm;
  93.     aspl0 = abs(spl2);
  94.     aspl1 = abs(spl3);
  95.   ) : (
  96.     opto ? (
  97.       ospl = ospl0 * ospl0 + ospl1 * ospl1;
  98.       ospl > runospl ? (
  99.         runospl = ospl + atcoef * (runospl - ospl);
  100.       ) : (
  101.         runospl = ospl + relcoef * (runospl - ospl);
  102.       );
  103.       ospl = sqrt(max(0,runospl));
  104.  
  105. //      ospl = 2.08136898 * log(ospl)*log2db;
  106. //      ospl = ospl - 6;            // reduce feedback to -6 dB
  107. //      ospl = exp(ospl * db2log);
  108.       ospl *= 0.5;
  109.  
  110.       aspl0 = abs(ospl);
  111.       aspl1 = abs(ospl);
  112.     ) : (
  113.       aspl0 = abs(spl0);
  114.       aspl1 = abs(spl1);
  115.     );
  116.   );
  117.  
  118.   RMSDet ? (  
  119.     ave = (aspl0 * aspl0) + (aspl1 * aspl1);
  120.     runave = ave + rmscoef * (runave - ave);
  121.     det = sqrt(max(0,runave));
  122.   ) : (
  123.     maxspl = max(aspl0, aspl1);
  124.     maxspl = maxspl * maxspl;
  125.     runave = maxspl + rmscoef * (runave - maxspl);
  126.     det = sqrt(max(0,runave));
  127.   );
  128.   overdb = 2.08136898 * log(det/cthreshv) * log2db;
  129.   overdb > maxover ? (
  130.     maxover = overdb;
  131.     attime = attimes[max(0,floor(abs(overdb)))];   // attack time per formula
  132.     atcoef = exp(-1/(attime * srate));
  133.     reltime = overdb / 125;                        // release at constant 125 dB/sec.
  134.     relcoef = exp(-1/(reltime * srate));
  135.   );
  136.   overdb = max(0,overdb);
  137.  
  138.   overdb > rundb ? (
  139.     rundb = overdb + atcoef * (rundb - overdb);
  140.   ) : (
  141.     rundb = overdb + relcoef * (rundb - overdb);
  142.   );
  143.   overdb = rundb;
  144.  
  145.   cratio = (softknee ? (1 + (ratio-1) * min(overdb, 6) / 6) : ratio);
  146.   
  147.   gr = -overdb * (cratio-1)/cratio;
  148.   grv = exp(gr * db2log);
  149.   
  150.   runmax = maxover + relcoef * (runmax - maxover);  // highest peak for setting att/rel decays in reltime
  151.   maxover = runmax;
  152.  
  153.   spl0 -= denorm;
  154.   spl1 -= denorm;
  155.  
  156.   spl0 *= grv * makeupv;
  157.   spl1 *= grv * makeupv;  
  158.  
  159.   ospl0 = spl0;
  160.   ospl1 = spl1;
  161.