home *** CD-ROM | disk | FTP | other *** search
/ PC World 2007 February / PCWorld_2007-02_cd.bin / temacd / vbuzzer / Vbuzzer_Setup_2.0.282.exe / MessageLog.xsl < prev    next >
Extensible Markup Language  |  2006-05-31  |  12KB  |  187 lines
  1.  ■<?xml version="1.0"?>
  2. <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  4. <!-- localized strings -->
  5. <xsl:variable name='ColumnHeader_Date'>Date</xsl:variable>
  6. <xsl:variable name='ColumnHeader_Time'>Time</xsl:variable>
  7. <xsl:variable name='ColumnHeader_From'>From</xsl:variable>
  8. <xsl:variable name='ColumnHeader_To'>To</xsl:variable>
  9. <xsl:variable name='ColumnHeader_Message'>Message</xsl:variable>
  11. <!-- variables -->
  12. <xsl:variable name='Debug'>0</xsl:variable>
  14. <xsl:variable name='TableStyle'>font-family:Verdana; font-size:67%; text-align:left; vertical-align:top; table-layout:fixed</xsl:variable>
  15. <xsl:variable name='GutterStyle'>width:2ex</xsl:variable>
  16. <xsl:variable name='HeaderStyle'>border-bottom:1 solid black</xsl:variable>
  18. <xsl:variable name='UseZebraStripe'>1</xsl:variable>
  19. <xsl:variable name='ZebraStripeStyle'>background-color:#e0edff</xsl:variable>
  21. <xsl:variable name='MostRecentSessionFirst'>0</xsl:variable>
  24. <xsl:template match="Log">
  26.     <html dir='ltr'>
  27.     <head>
  28.         <title>
  29.             Message Log for <xsl:value-of select="@LogonName"/>
  30.             <xsl:if test="$Debug = 1"> (Debug)</xsl:if>
  31.         </title>
  33.         <xsl:if test="$Debug = 1">
  34.             <span style="font-family:trebuchet ms; font-size:120%">
  35.                 Debug Version
  36.             </span>
  37.             <hr/>
  38.         </xsl:if>
  39.     </head>
  41.     <body style='margin:0'>
  43.         <table id='BodyTable' style="{$TableStyle}" cellspacing='0'>
  45.             <xsl:if test="$Debug = 1">
  46.                 <col style="vertical-align:top; width:5ex;"/>
  47.                 <col style='{$GutterStyle}' />
  48.             </xsl:if>
  50.             <col style="width:16ex;"/>
  51.             <col style='{$GutterStyle}' />
  52.             <col style="width:16ex;"/>
  53.             <col style='{$GutterStyle}' />
  54.             <col style="width:21ex;"/>
  55.             <col style='{$GutterStyle}' />
  56.             <col style="width:21ex;"/>
  57.             <col style='{$GutterStyle}' />
  58.             <col style="width:70ex;"/>
  60.             <thead>
  61.                 <tr>
  62.                     <xsl:if test="$Debug = 1">
  63.                         <th style="{$HeaderStyle}">SID</th>
  64.                         <th/>
  65.                     </xsl:if>
  66.                     <th style="{$HeaderStyle}">
  67.                         <xsl:value-of select="$ColumnHeader_Date"/>
  68.                     </th>
  69.                     <th/>
  70.                     <th style="{$HeaderStyle}">
  71.                         <xsl:value-of select="$ColumnHeader_Time"/>
  72.                     </th>
  73.                     <th/>
  74.                     <th style="{$HeaderStyle}">
  75.                         <xsl:value-of select="$ColumnHeader_From"/>
  76.                     </th>
  77.                     <th/>
  78.                     <th style="{$HeaderStyle}">
  79.                         <xsl:value-of select="$ColumnHeader_To"/>
  80.                     </th>
  81.                     <th/>
  82.                     <th style="{$HeaderStyle}">
  83.                         <xsl:value-of select="$ColumnHeader_Message"/>
  84.                     </th>
  85.                 </tr>
  86.             </thead>
  88.             <tbody style='vertical-align:top'>
  89.                 <xsl:choose>
  91.                     <!-- newest session first -->
  92.                     <xsl:when test="$MostRecentSessionFirst = 1">
  93.                         <xsl:apply-templates>
  94.                             <xsl:sort select='@SessionID' order='descending' data-type='number'/>
  95.                             <xsl:sort select='@DateTime'  order='ascending'/>
  96.                         </xsl:apply-templates>
  97.                     </xsl:when>
  99.                     <!-- oldest session first -->
  100.                     <xsl:otherwise>
  101.                         <xsl:apply-templates>
  102.                             <xsl:sort select='@SessionID' order='ascending' data-type='number'/>
  103.                             <xsl:sort select='@DateTime'  order='ascending'/>
  104.                         </xsl:apply-templates>
  105.                     </xsl:otherwise>
  107.                 </xsl:choose>
  108.             </tbody>
  109.         </table>
  110.     </body>
  111.     </html>
  113. </xsl:template>
  116. <xsl:template match="Message">
  117.     <tr>
  118.         <xsl:call-template name="CommonMessageProcessing" />
  120.         <td> <xsl:apply-templates select="From/User"/> </td>
  121.         <td/>
  122.         <td> <xsl:apply-templates select="To/User"/> </td>
  123.         <td/>
  124.         <td>
  125.             <span>
  126.                 <xsl:attribute name="style">
  127.                     <xsl:value-of select="Text/@Style"/>
  128.                 </xsl:attribute>
  129.                 <xsl:value-of select="Text"/>
  130.             </span>
  131.         </td>
  132.     </tr>
  133. </xsl:template>
  136. <xsl:template match="Invitation|InvitationResponse|Join|Leave">
  137.     <tr>
  138.         <xsl:call-template name="CommonMessageProcessing" />
  140.         <td/>  <!-- From -->
  141.         <td/>
  142.         <td/>  <!-- To -->
  143.         <td/>
  144.         <td>
  145.             <span>
  146.                 <xsl:attribute name="style">
  147.                     <xsl:value-of select="Text/@Style"/>
  148.                 </xsl:attribute>
  149.                 <xsl:value-of select="Text"/>
  150.             </span>
  151.         </td>
  152.     </tr>
  153. </xsl:template>
  156. <xsl:template match="User">
  157.     <!-- add a comma before all but the first user -->
  158.     <xsl:if test="position() != 1">, </xsl:if>
  160.     <xsl:value-of select="@FriendlyName"/>
  161. </xsl:template>
  164. <xsl:template name="CommonMessageProcessing">
  165.     <!-- zebra-stripe the sessions -->
  166.     <xsl:if test="$UseZebraStripe = 1">
  167.         <xsl:if test="(@SessionID mod 2) = 1">
  168.             <xsl:attribute name="style">
  169.                 <xsl:value-of select="$ZebraStripeStyle"/>
  170.             </xsl:attribute>
  171.         </xsl:if>
  172.     </xsl:if>
  174.     <xsl:if test="$Debug = 1">
  175.         <td> <xsl:value-of select="@SessionID"/> </td>
  176.         <td/>
  177.     </xsl:if>
  179.     <td> <xsl:value-of select="@Date"/> </td>
  180.     <td/>
  181.     <td> <xsl:value-of select="@Time"/> </td>
  182.     <td/>
  183. </xsl:template>
  186. </xsl:stylesheet>