home *** CD-ROM | disk | FTP | other *** search
/ PC World 2005 December (Special) / PCWorld_2005-12_Special_cd.bin / Bezpecnost / lsti / lsti.exe / framework-2.5.exe / prove < prev    next >
Text File  |  2005-01-27  |  9KB  |  337 lines
  1. #!/usr/bin/perl
  2.     eval 'exec /usr/bin/perl -S $0 ${1+"$@"}'
  3.     if $running_under_some_shell;
  4. #!/usr/bin/perl -w
  5.  
  6. use strict;
  7.  
  8. use Test::Harness;
  9. use Getopt::Long;
  10. use Pod::Usage 1.12;
  11. use File::Spec;
  12.  
  13. use vars qw( $VERSION );
  14. $VERSION = "1.04";
  15.  
  16. my @ext = ();
  17. my $shuffle = 0;
  18. my $dry = 0;
  19. my $blib = 0;
  20. my $lib = 0;
  21. my $recurse = 0;
  22. my @includes = ();
  23. my @switches = ();
  24.  
  25. # Allow cuddling the paths with the -I
  26. @ARGV = map { /^(-I)(.+)/ ? ($1,$2) : $_ } @ARGV;
  27.  
  28. # Stick any default switches at the beginning, so they can be overridden
  29. # by the command line switches.
  30. unshift @ARGV, split( " ", $ENV{PROVE_SWITCHES} ) if defined $ENV{PROVE_SWITCHES};
  31.  
  32. Getopt::Long::Configure( "no_ignore_case" );
  33. Getopt::Long::Configure( "bundling" );
  34. GetOptions(
  35.     'b|blib'        => \$blib,
  36.     'd|debug'       => \$Test::Harness::debug,
  37.     'D|dry'         => \$dry,
  38.     'h|help|?'      => sub {pod2usage({-verbose => 1, -input => \*DATA}); exit},
  39.     'H|man'         => sub {pod2usage({-verbose => 2, -input => \*DATA}); exit},
  40.     'I=s@'          => \@includes,
  41.     'l|lib'         => \$lib,
  42.     'r|recurse'     => \$recurse,
  43.     's|shuffle'     => \$shuffle,
  44.     't'             => sub { unshift @switches, "-t" }, # Always want -t up front
  45.     'T'             => sub { unshift @switches, "-T" }, # Always want -T up front
  46.     'v|verbose'     => \$Test::Harness::verbose,
  47.     'V|version'     => sub { print_version(); exit; },
  48.     'ext=s@'        => \@ext,
  49. ) or exit 1;
  50.  
  51. $ENV{TEST_VERBOSE} = 1 if $Test::Harness::verbose;
  52.  
  53. # Build up extensions regex
  54. @ext = map { split /,/ } @ext;
  55. s/^\.// foreach @ext;
  56. @ext = ("t") unless @ext;
  57. my $ext_regex = join( "|", map { quotemeta } @ext );
  58. $ext_regex = qr/\.($ext_regex)$/;
  59.  
  60. # Handle blib includes
  61. if ( $blib ) {
  62.     my @blibdirs = blibdirs();
  63.     if ( @blibdirs ) {
  64.         unshift @includes, @blibdirs;
  65.     } else {
  66.         warn "No blib directories found.\n";
  67.     }
  68. }
  69.  
  70. # Handle lib includes
  71. if ( $lib ) {
  72.     unshift @includes, "lib";
  73. }
  74.  
  75. # Build up TH switches
  76. push( @switches, map { /\s/ && !/^".*"$/ ? qq["-I$_"] : "-I$_" } @includes );
  77. $Test::Harness::Switches = join( " ", @switches );
  78. print "# \$Test::Harness::Switches: $Test::Harness::Switches\n" if $Test::Harness::debug;
  79.  
  80. my @tests;
  81. @ARGV = File::Spec->curdir unless @ARGV;
  82. push( @tests, -d $_ ? all_in( $_ ) : $_ ) for map { glob } @ARGV;
  83.  
  84. if ( @tests ) {
  85.     shuffle(@tests) if $shuffle;
  86.     if ( $dry ) {
  87.         print join( "\n", @tests, "" );
  88.     } else {
  89.         print "# ", scalar @tests, " tests to run\n" if $Test::Harness::debug;
  90.         runtests(@tests);
  91.     }
  92. }
  93.  
  94. sub all_in {
  95.     my $start = shift;
  96.  
  97.     my @hits = ();
  98.  
  99.     local *DH;
  100.     if ( opendir( DH, $start ) ) {
  101.         while ( my $file = readdir DH ) {
  102.             next if $file eq File::Spec->updir || $file eq File::Spec->curdir;
  103.             next if $file eq ".svn";
  104.             next if $file eq "CVS";
  105.  
  106.             my $currfile = File::Spec->catfile( $start, $file );
  107.             if ( -d $currfile ) {
  108.                 push( @hits, all_in( $currfile ) ) if $recurse;
  109.             } else {
  110.                 push( @hits, $currfile ) if $currfile =~ $ext_regex;
  111.             }
  112.         }
  113.     } else {
  114.         warn "$start: $!\n";
  115.     }
  116.  
  117.     return @hits;
  118. }
  119.  
  120. sub shuffle {
  121.     # Fisher-Yates shuffle
  122.     my $i = @_;
  123.     while ($i) {
  124.         my $j = rand $i--;
  125.         @_[$i, $j] = @_[$j, $i];
  126.     }
  127. }
  128.  
  129. sub print_version {
  130.     printf( "prove v%s, using Test::Harness v%s and Perl v%vd\n",
  131.         $VERSION, $Test::Harness::VERSION, $^V );
  132. }
  133.  
  134. # Stolen directly from blib.pm
  135. sub blibdirs {
  136.     my $dir = File::Spec->curdir;
  137.     if ($^O eq 'VMS') {
  138.         ($dir = VMS::Filespec::unixify($dir)) =~ s-/\z--;
  139.     }
  140.     my $archdir = "arch";
  141.     if ( $^O eq "MacOS" ) {
  142.         # Double up the MP::A so that it's not used only once.
  143.         $archdir = $MacPerl::Architecture = $MacPerl::Architecture;
  144.     }
  145.  
  146.     my $i = 5;
  147.     while ($i--) {
  148.         my $blib      = File::Spec->catdir( $dir, "blib" );
  149.         my $blib_lib  = File::Spec->catdir( $blib, "lib" );
  150.         my $blib_arch = File::Spec->catdir( $blib, $archdir );
  151.  
  152.         if ( -d $blib && -d $blib_arch && -d $blib_lib ) {
  153.             return ($blib_arch,$blib_lib);
  154.         }
  155.         $dir = File::Spec->catdir($dir, File::Spec->updir);
  156.     }
  157.     warn "$0: Cannot find blib\n";
  158.     return;
  159. }
  160.  
  161. __END__
  162.  
  163. =head1 NAME
  164.  
  165. prove -- A command-line tool for running tests against Test::Harness
  166.  
  167. =head1 SYNOPSIS
  168.  
  169. prove [options] [files/directories]
  170.  
  171. Options:
  172.  
  173.     -b, --blib      Adds blib/lib to the path for your tests, a la "use blib".
  174.     -d, --debug     Includes extra debugging information.
  175.     -D, --dry       Dry run: Show the tests to run, but don't run them.
  176.         --ext=x     Extensions (defaults to .t)
  177.     -h, --help      Display this help
  178.     -H, --man       Longer manpage for prove
  179.     -I              Add libraries to @INC, as Perl's -I
  180.     -l, --lib       Add lib to the path for your tests.
  181.     -r, --recurse   Recursively descend into directories.
  182.     -s, --shuffle   Run the tests in a random order.
  183.     -T              Enable tainting checks
  184.     -t              Enable tainting warnings
  185.     -v, --verbose   Display standard output of test scripts while running them.
  186.     -V, --version   Display version info
  187.  
  188. Single-character options may be stacked.  Default options may be set by
  189. specifying the PROVE_SWITCHES environment variable.
  190.  
  191. =head1 OVERVIEW
  192.  
  193. F<prove> is a command-line interface to the test-running functionality
  194. of C<Test::Harness>.  With no arguments, it will run all tests in the
  195. current directory.
  196.  
  197. Shell metacharacters may be used with command lines options and will be exanded 
  198. via C<glob>.
  199.  
  200. =head1 PROVE VS. "MAKE TEST"
  201.  
  202. F<prove> has a number of advantages over C<make test> when doing development.
  203.  
  204. =over 4
  205.  
  206. =item * F<prove> is designed as a development tool
  207.  
  208. Perl users typically run the test harness through a makefile via
  209. C<make test>.  That's fine for module distributions, but it's
  210. suboptimal for a test/code/debug development cycle.
  211.  
  212. =item * F<prove> is granular 
  213.  
  214. F<prove> lets your run against only the files you want to check.
  215. Running C<prove t/live/ t/master.t> checks every F<*.t> in F<t/live>,
  216. plus F<t/master.t>.
  217.  
  218. =item * F<prove> has an easy verbose mode
  219.  
  220. F<prove> has a C<-v> option to see the raw output from the tests.
  221. To do this with C<make test>, you must set C<HARNESS_VERBOSE=1> in
  222. the environment.
  223.  
  224. =item * F<prove> can run under taint mode
  225.  
  226. F<prove>'s C<-T> runs your tests under C<perl -T>, and C<-t> runs them
  227. under C<perl -t>.
  228.  
  229. =item * F<prove> can shuffle tests
  230.  
  231. You can use F<prove>'s C<--shuffle> option to try to excite problems
  232. that don't show up when tests are run in the same order every time.
  233.  
  234. =item * F<prove> doesn't rely on a make tool
  235.  
  236. Not everyone wants to write a makefile, or use L<ExtUtils::MakeMaker>
  237. to do so.  F<prove> has no external dependencies.
  238.  
  239. =item * Not everything is a module
  240.  
  241. More and more users are using Perl's testing tools outside the
  242. context of a module distribution, and may not even use a makefile
  243. at all.
  244.  
  245. =back
  246.  
  247. =head1 COMMAND LINE OPTIONS
  248.  
  249. =head2 -b, --blib
  250.  
  251. Adds blib/lib to the path for your tests, a la "use blib".
  252.  
  253. =head2 -d, --debug
  254.  
  255. Include debug information about how F<prove> is being run.  This
  256. option doesn't show the output from the test scripts.  That's handled
  257. by -v,--verbose.
  258.  
  259. =head2 -D, --dry
  260.  
  261. Dry run: Show the tests to run, but don't run them.
  262.  
  263. =head2 --ext=extension
  264.  
  265. Specify extensions of the test files to run.  By default, these are .t,
  266. but you may have other non-.t test files, most likely .sh shell scripts.
  267. The --ext is repeatable.
  268.  
  269. =head2 -I
  270.  
  271. Add libraries to @INC, as Perl's -I.
  272.  
  273. =head2 -l, --lib
  274.  
  275. Add C<lib> to @INC.  Equivalent to C<-Ilib>.
  276.  
  277. =head2 -r, --recurse
  278.  
  279. Descends into subdirectories of any directories specified, looking for tests.
  280.  
  281. =head2 -s, --shuffle
  282.  
  283. Sometimes tests are accidentally dependent on tests that have been
  284. run before.  This switch will shuffle the tests to be run prior to
  285. running them, thus ensuring that hidden dependencies in the test
  286. order are likely to be revealed.  The author hopes the run the
  287. algorithm on the preceding sentence to see if he can produce something
  288. slightly less awkward.
  289.  
  290. =head2 -t
  291.  
  292. Runs test programs under perl's -t taint warning mode.
  293.  
  294. =head2 -T
  295.  
  296. Runs test programs under perl's -T taint mode.
  297.  
  298. =head2 -v, --verbose
  299.  
  300. Display standard output of test scripts while running them.  Also sets
  301. TEST_VERBOSE in case your tests rely on them.
  302.  
  303. =head2 -V, --version
  304.  
  305. Display version info.
  306.  
  307. =head1 BUGS
  308.  
  309. Please use the CPAN bug ticketing system at L<http://rt.cpan.org/>.
  310. You can also mail bugs, fixes and enhancements to 
  311. C<< <bug-test-harness@rt.cpan.org> >>.
  312.  
  313. =head1 TODO
  314.  
  315. =over 4
  316.  
  317. =item *
  318.  
  319. Shuffled tests must be recreatable
  320.  
  321. =back
  322.  
  323. =head1 AUTHORS
  324.  
  325. Andy Lester C<< <andy@petdance.com> >>
  326.  
  327. =head1 COPYRIGHT
  328.  
  329. Copyright 2003 by Andy Lester C<< <andy@petdance.com> >>.
  330.  
  331. This program is free software; you can redistribute it and/or 
  332. modify it under the same terms as Perl itself.
  333.  
  334. See L<http://www.perl.com/perl/misc/Artistic.html>.
  335.  
  336. =cut
  337.