home *** CD-ROM | disk | FTP | other *** search
/ PC World 2005 December (Special) / PCWorld_2005-12_Special_cd.bin / Bezpecnost / lsti / lsti.exe / framework-2.5.exe / find2perl < prev    next >
Text File  |  2005-01-27  |  24KB  |  880 lines
  1. #!/usr/bin/perl
  2.     eval 'exec /usr/bin/perl -S $0 ${1+"$@"}'
  3.       if $running_under_some_shell;
  4. (my $perlpath = <<'/../') =~ s/\s*\z//;
  5. /usr/bin/perl
  6. /../
  7. use strict;
  8. use vars qw/$statdone/;
  9. use File::Spec::Functions 'curdir';
  10. my $startperl = "#! $perlpath -w";
  11.  
  12. #
  13. # Modified September 26, 1993 to provide proper handling of years after 1999
  14. #   Tom Link <tml+@pitt.edu>
  15. #   University of Pittsburgh
  16. #
  17. # Modified April 7, 1998 with nasty hacks to implement the troublesome -follow
  18. #  Billy Constantine <wdconsta@cs.adelaide.edu.au> <billy@smug.adelaide.edu.au>
  19. #  University of Adelaide, Adelaide, South Australia
  20. #
  21. # Modified 1999-06-10, 1999-07-07 to migrate to cleaner perl5 usage
  22. #   Ken Pizzini <ken@halcyon.com>
  23. #
  24. # Modified 2000-01-28 to use the 'follow' option of File::Find
  25.  
  26. sub tab ();
  27. sub n ($$);
  28. sub fileglob_to_re ($);
  29. sub quote ($);
  30.  
  31. my @roots = ();
  32. while ($ARGV[0] =~ /^[^-!(]/) {
  33.     push(@roots, shift);
  34. }
  35. @roots = (curdir()) unless @roots;
  36. for (@roots) { $_ = quote($_) }
  37. my $roots = join(', ', @roots);
  38.  
  39. my $find = "find";
  40. my $indent_depth = 1;
  41. my $stat = 'lstat';
  42. my $decl = '';
  43. my $flushall = '';
  44. my $initfile = '';
  45. my $initnewer = '';
  46. my $out = '';
  47. my $declaresubs = "sub wanted;\n";
  48. my %init = ();
  49. my ($follow_in_effect,$Skip_And) = (0,0);
  50. my $print_needed = 1;
  51.  
  52. while (@ARGV) {
  53.     $_ = shift;
  54.     s/^-// || /^[()!]/ || die "Unrecognized switch: $_\n";
  55.     if ($_ eq '(') {
  56.         $out .= tab . "(\n";
  57.         $indent_depth++;
  58.         next;
  59.     } elsif ($_ eq ')') {
  60.         --$indent_depth;
  61.         $out .= tab . ")";
  62.     } elsif ($_ eq 'follow') {
  63.         $follow_in_effect= 1;
  64.         $stat = 'stat';
  65.         $Skip_And= 1;
  66.     } elsif ($_ eq '!') {
  67.         $out .= tab . "!";
  68.         next;
  69.     } elsif ($_ eq 'name') {
  70.         $out .= tab . '/' . fileglob_to_re(shift) . "/s";
  71.     } elsif ($_ eq 'perm') {
  72.         my $onum = shift;
  73.         $onum =~ /^-?[0-7]+$/
  74.             || die "Malformed -perm argument: $onum\n";
  75.         $out .= tab;
  76.         if ($onum =~ s/^-//) {
  77.             $onum = sprintf("0%o", oct($onum) & 07777);
  78.             $out .= "((\$mode & $onum) == $onum)";
  79.         } else {
  80.             $onum =~ s/^0*/0/;
  81.             $out .= "((\$mode & 0777) == $onum)";
  82.         }
  83.     } elsif ($_ eq 'type') {
  84.         (my $filetest = shift) =~ tr/s/S/;
  85.         $out .= tab . "-$filetest _";
  86.     } elsif ($_ eq 'print') {
  87.         $out .= tab . 'print("$name\n")';
  88.     $print_needed = 0;
  89.     } elsif ($_ eq 'print0') {
  90.         $out .= tab . 'print("$name\0")';
  91.     $print_needed = 0;
  92.     } elsif ($_ eq 'fstype') {
  93.         my $type = shift;
  94.         $out .= tab;
  95.         if ($type eq 'nfs') {
  96.             $out .= '($dev < 0)';
  97.         } else {
  98.             $out .= '($dev >= 0)'; #XXX
  99.         }
  100.     } elsif ($_ eq 'user') {
  101.         my $uname = shift;
  102.         $out .= tab . "(\$uid == \$uid{'$uname'})";
  103.         $init{user} = 1;
  104.     } elsif ($_ eq 'group') {
  105.         my $gname = shift;
  106.         $out .= tab . "(\$gid == \$gid{'$gname'})";
  107.         $init{group} = 1;
  108.     } elsif ($_ eq 'nouser') {
  109.         $out .= tab . '!exists $uid{$uid}';
  110.         $init{user} = 1;
  111.     } elsif ($_ eq 'nogroup') {
  112.         $out .= tab . '!exists $gid{$gid}';
  113.         $init{group} = 1;
  114.     } elsif ($_ eq 'links') {
  115.         $out .= tab . n('$nlink', shift);
  116.     } elsif ($_ eq 'inum') {
  117.         $out .= tab . n('$ino', shift);
  118.     } elsif ($_ eq 'size') {
  119.         $_ = shift;
  120.         my $n = 'int(((-s _) + 511) / 512)';
  121.         if (s/c\z//) {
  122.             $n = 'int(-s _)';
  123.         } elsif (s/k\z//) {
  124.             $n = 'int(((-s _) + 1023) / 1024)';
  125.         }
  126.         $out .= tab . n($n, $_);
  127.     } elsif ($_ eq 'atime') {
  128.         $out .= tab . n('int(-A _)', shift);
  129.     } elsif ($_ eq 'mtime') {
  130.         $out .= tab . n('int(-M _)', shift);
  131.     } elsif ($_ eq 'ctime') {
  132.         $out .= tab . n('int(-C _)', shift);
  133.     } elsif ($_ eq 'exec') {
  134.         my @cmd = ();
  135.         while (@ARGV && $ARGV[0] ne ';')
  136.             { push(@cmd, shift) }
  137.         shift;
  138.         $out .= tab;
  139.         if ($cmd[0] =~m#^(?:(?:/usr)?/bin/)?rm$#
  140.                 && $cmd[$#cmd] eq '{}'
  141.                 && (@cmd == 2 || (@cmd == 3 && $cmd[1] eq '-f'))) {
  142.             if (@cmd == 2) {
  143.                 $out .= '(unlink($_) || warn "$name: $!\n")';
  144.             } elsif (!@ARGV) {
  145.                 $out .= 'unlink($_)';
  146.             } else {
  147.                 $out .= '(unlink($_) || 1)';
  148.             }
  149.         } else {
  150.             for (@cmd)
  151.                 { s/'/\\'/g }
  152.             { local $" = "','"; $out .= "doexec(0, '@cmd')"; }
  153.             $declaresubs .= "sub doexec (\$\@);\n";
  154.             $init{doexec} = 1;
  155.         }
  156.     $print_needed = 0;
  157.     } elsif ($_ eq 'ok') {
  158.         my @cmd = ();
  159.         while (@ARGV && $ARGV[0] ne ';')
  160.             { push(@cmd, shift) }
  161.         shift;
  162.         $out .= tab;
  163.         for (@cmd)
  164.             { s/'/\\'/g }
  165.         { local $" = "','"; $out .= "doexec(1, '@cmd')"; }
  166.         $declaresubs .= "sub doexec (\$\@);\n";
  167.         $init{doexec} = 1;
  168.     $print_needed = 0;
  169.     } elsif ($_ eq 'prune') {
  170.         $out .= tab . '($File::Find::prune = 1)';
  171.     } elsif ($_ eq 'xdev') {
  172.         $out .= tab . '!($File::Find::prune |= ($dev != $File::Find::topdev))'
  173. ;
  174.     } elsif ($_ eq 'newer') {
  175.         my $file = shift;
  176.         my $newername = 'AGE_OF' . $file;
  177.         $newername =~ s/\W/_/g;
  178.         $newername = '$' . $newername;
  179.         $out .= tab . "(-M _ < $newername)";
  180.         $initnewer .= "my $newername = -M " . quote($file) . ";\n";
  181.     } elsif ($_ eq 'eval') {
  182.         my $prog = shift;
  183.         $prog =~ s/'/\\'/g;
  184.         $out .= tab . "eval {$prog}";
  185.     $print_needed = 0;
  186.     } elsif ($_ eq 'depth') {
  187.         $find = 'finddepth';
  188.         next;
  189.     } elsif ($_ eq 'ls') {
  190.         $out .= tab . "ls";
  191.         $declaresubs .= "sub ls ();\n";
  192.         $init{ls} = 1;
  193.     $print_needed = 0;
  194.     } elsif ($_ eq 'tar') {
  195.         die "-tar must have a filename argument\n" unless @ARGV;
  196.         my $file = shift;
  197.         my $fh = 'FH' . $file;
  198.         $fh =~ s/\W/_/g;
  199.         $out .= tab . "tar(*$fh, \$name)";
  200.         $flushall .= "tflushall;\n";
  201.         $declaresubs .= "sub tar;\nsub tflushall ();\n";
  202.         $initfile .= "open($fh, " . quote('> ' . $file) .
  203.                      qq{) || die "Can't open $fh: \$!\\n";\n};
  204.         $init{tar} = 1;
  205.     } elsif (/^(n?)cpio\z/) {
  206.         die "-$_ must have a filename argument\n" unless @ARGV;
  207.         my $file = shift;
  208.         my $fh = 'FH' . $file;
  209.         $fh =~ s/\W/_/g;
  210.         $out .= tab . "cpio(*$fh, \$name, '$1')";
  211.         $find = 'finddepth';
  212.         $flushall .= "cflushall;\n";
  213.         $declaresubs .= "sub cpio;\nsub cflushall ();\n";
  214.         $initfile .= "open($fh, " . quote('> ' . $file) .
  215.                      qq{) || die "Can't open $fh: \$!\\n";\n};
  216.         $init{cpio} = 1;
  217.     } else {
  218.         die "Unrecognized switch: -$_\n";
  219.     }
  220.  
  221.     if (@ARGV) {
  222.         if ($ARGV[0] eq '-o') {
  223.             { local($statdone) = 1; $out .= "\n" . tab . "||\n"; }
  224.             $statdone = 0 if $indent_depth == 1 && exists $init{delayedstat};
  225.             $init{saw_or} = 1;
  226.             shift;
  227.         } else {
  228.             $out .= " &&" unless $Skip_And || $ARGV[0] eq ')';
  229.             $out .= "\n";
  230.             shift if $ARGV[0] eq '-a';
  231.         }
  232.     }
  233. }
  234.  
  235. if ($print_needed) {
  236.     my $t = tab;
  237.     if ($t !~ /&&\s*$/) { $t .= '&& ' }
  238.     $out .= "\n" . $t . 'print("$name\n")';
  239. }
  240.  
  241.  
  242. print <<"END";
  243. $startperl
  244.     eval 'exec $perlpath -S \$0 \${1+"\$@"}'
  245.         if 0; #\$running_under_some_shell
  246.  
  247. use strict;
  248. use File::Find ();
  249.  
  250. # Set the variable \$File::Find::dont_use_nlink if you're using AFS,
  251. # since AFS cheats.
  252.  
  253. # for the convenience of &wanted calls, including -eval statements:
  254. use vars qw/*name *dir *prune/;
  255. *name   = *File::Find::name;
  256. *dir    = *File::Find::dir;
  257. *prune  = *File::Find::prune;
  258.  
  259. $declaresubs
  260.  
  261. END
  262.  
  263. if (exists $init{doexec}) {
  264.     print <<'END';
  265. use Cwd ();
  266. my $cwd = Cwd::cwd();
  267.  
  268. END
  269. }  
  270.  
  271. if (exists $init{ls}) {
  272.     print <<'END';
  273. my @rwx = qw(--- --x -w- -wx r-- r-x rw- rwx);
  274. my @moname = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
  275.  
  276. END
  277. }
  278.  
  279. if (exists $init{user} || exists $init{ls} || exists $init{tar}) {
  280.     print "my (%uid, %user);\n";
  281.     print "while (my (\$name, \$pw, \$uid) = getpwent) {\n";
  282.     print '    $uid{$name} = $uid{$uid} = $uid;', "\n"
  283.         if exists $init{user};
  284.     print '    $user{$uid} = $name unless exists $user{$uid};', "\n"
  285.         if exists $init{ls} || exists $init{tar};
  286.     print "}\n\n";
  287. }
  288.  
  289. if (exists $init{group} || exists $init{ls} || exists $init{tar}) {
  290.     print "my (%gid, %group);\n";
  291.     print "while (my (\$name, \$pw, \$gid) = getgrent) {\n";
  292.     print '    $gid{$name} = $gid{$gid} = $gid;', "\n"
  293.         if exists $init{group};
  294.     print '    $group{$gid} = $name unless exists $group{$gid};', "\n"
  295.         if exists $init{ls} || exists $init{tar};
  296.     print "}\n\n";
  297. }
  298.  
  299. print $initnewer, "\n" if $initnewer ne '';
  300. print $initfile, "\n" if $initfile ne '';
  301. $flushall .= "exit;\n";
  302. if (exists $init{declarestat}) {
  303.     $out = <<'END' . $out;
  304.     my ($dev,$ino,$mode,$nlink,$uid,$gid);
  305.  
  306. END
  307. }
  308.  
  309. if ( $follow_in_effect ) {
  310. $out =~ s/lstat\(\$_\)/lstat(_)/;
  311. print <<"END";
  312. $decl
  313. # Traverse desired filesystems
  314. File::Find::$find( {wanted => \\&wanted, follow => 1}, $roots);
  315. $flushall
  316.  
  317. sub wanted {
  318. $out;
  319. }
  320.  
  321. END
  322. } else {
  323. print <<"END";
  324. $decl
  325. # Traverse desired filesystems
  326. File::Find::$find({wanted => \\&wanted}, $roots);
  327. $flushall
  328.  
  329. sub wanted {
  330. $out;
  331. }
  332.  
  333. END
  334. }
  335.  
  336. if (exists $init{doexec}) {
  337.     print <<'END';
  338.  
  339. sub doexec ($@) {
  340.     my $ok = shift;
  341.     my @command = @_; # copy so we don't try to s/// aliases to constants
  342.     for my $word (@command)
  343.         { $word =~ s#{}#$name#g }
  344.     if ($ok) {
  345.         my $old = select(STDOUT);
  346.         $| = 1;
  347.         print "@command";
  348.         select($old);
  349.         return 0 unless <STDIN> =~ /^y/;
  350.     }
  351.     chdir $cwd; #sigh
  352.     system @command;
  353.     chdir $File::Find::dir;
  354.     return !$?;
  355. }
  356.  
  357. END
  358. }
  359.  
  360. if (exists $init{ls}) {
  361.     print <<'INTRO', <<"SUB", <<'END';
  362.  
  363. sub sizemm {
  364.     my $rdev = shift;
  365.     sprintf("%3d, %3d", ($rdev >> 8) & 0xff, $rdev & 0xff);
  366. }
  367.  
  368. sub ls () {
  369.     my ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
  370. INTRO
  371.         \$atime,\$mtime,\$ctime,\$blksize,\$blocks) = $stat(_);
  372. SUB
  373.     my $pname = $name;
  374.  
  375.     $blocks
  376.         or $blocks = int(($size + 1023) / 1024);
  377.  
  378.     my $perms = $rwx[$mode & 7];
  379.     $mode >>= 3;
  380.     $perms = $rwx[$mode & 7] . $perms;
  381.     $mode >>= 3;
  382.     $perms = $rwx[$mode & 7] . $perms;
  383.     substr($perms, 2, 1) =~ tr/-x/Ss/ if -u _;
  384.     substr($perms, 5, 1) =~ tr/-x/Ss/ if -g _;
  385.     substr($perms, 8, 1) =~ tr/-x/Tt/ if -k _;
  386.     if    (-f _) { $perms = '-' . $perms; }
  387.     elsif (-d _) { $perms = 'd' . $perms; }
  388.     elsif (-l _) { $perms = 'l' . $perms; $pname .= ' -> ' . readlink($_); }
  389.     elsif (-c _) { $perms = 'c' . $perms; $size = sizemm($rdev); }
  390.     elsif (-b _) { $perms = 'b' . $perms; $size = sizemm($rdev); }
  391.     elsif (-p _) { $perms = 'p' . $perms; }
  392.     elsif (-S _) { $perms = 's' . $perms; }
  393.     else         { $perms = '?' . $perms; }
  394.  
  395.     my $user = $user{$uid} || $uid;
  396.     my $group = $group{$gid} || $gid;
  397.  
  398.     my ($sec,$min,$hour,$mday,$mon,$timeyear) = localtime($mtime);
  399.     if (-M _ > 365.25 / 2) {
  400.         $timeyear += 1900;
  401.     } else {
  402.         $timeyear = sprintf("%02d:%02d", $hour, $min);
  403.     }
  404.  
  405.     printf "%5lu %4ld %-10s %3d %-8s %-8s %8s %s %2d %5s %s\n",
  406.             $ino,
  407.                  $blocks,
  408.                       $perms,
  409.                             $nlink,
  410.                                 $user,
  411.                                      $group,
  412.                                           $size,
  413.                                               $moname[$mon],
  414.                                                  $mday,
  415.                                                      $timeyear,
  416.                                                          $pname;
  417.     1;
  418. }
  419.  
  420. END
  421. }
  422.  
  423.  
  424. if (exists $init{cpio} || exists $init{tar}) {
  425. print <<'END';
  426.  
  427. my %blocks = ();
  428.  
  429. sub flush {
  430.     my ($fh, $varref, $blksz) = @_;
  431.  
  432.     while (length($$varref) >= $blksz) {
  433.         no strict qw/refs/;
  434.         syswrite($fh, $$varref, $blksz);
  435.         substr($$varref, 0, $blksz) = '';
  436.         ++$blocks{$fh};
  437.     }
  438. }
  439.  
  440. END
  441. }
  442.  
  443.  
  444. if (exists $init{cpio}) {
  445.     print <<'INTRO', <<"SUB", <<'END';
  446.  
  447. my %cpout = ();
  448. my %nc = ();
  449.  
  450. sub cpio {
  451.     my ($fh, $fname, $nc) = @_;
  452.     my $text = '';
  453.     my ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
  454.         $atime,$mtime,$ctime,$blksize,$blocks);
  455.     local (*IN);
  456.  
  457.     if ( ! defined $fname ) {
  458.         $fname = 'TRAILER!!!';
  459.         ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
  460.           $atime,$mtime,$ctime,$blksize,$blocks) = (0) x 13;
  461.     } else {
  462.         ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
  463. INTRO
  464.           \$atime,\$mtime,\$ctime,\$blksize,\$blocks) = $stat(_);
  465. SUB
  466.         if (-f _) {
  467.             open(IN, "./$_\0") || do {
  468.                 warn "Couldn't open $fname: $!\n";
  469.                 return;
  470.             }
  471.         } else {
  472.             $text = readlink($_);
  473.             $size = 0 unless defined $text;
  474.         }
  475.     }
  476.  
  477.     $fname =~ s#^\./##;
  478.     $nc{$fh} = $nc;
  479.     if ($nc eq 'n') {
  480.         $cpout{$fh} .=
  481.           sprintf("%06o%06o%06o%06o%06o%06o%06o%06o%011lo%06o%011lo%s\0",
  482.             070707,
  483.             $dev & 0777777,
  484.             $ino & 0777777,
  485.             $mode & 0777777,
  486.             $uid & 0777777,
  487.             $gid & 0777777,
  488.             $nlink & 0777777,
  489.             $rdev & 0177777,
  490.             $mtime,
  491.             length($fname)+1,
  492.             $size,
  493.             $fname);
  494.     } else {
  495.         $cpout{$fh} .= "\0" if length($cpout{$fh}) & 1;
  496.         $cpout{$fh} .= pack("SSSSSSSSLSLa*",
  497.             070707, $dev, $ino, $mode, $uid, $gid, $nlink, $rdev, $mtime,
  498.             length($fname)+1, $size,
  499.             $fname . (length($fname) & 1 ? "\0" : "\0\0"));
  500.     }
  501.  
  502.     if ($text ne '') {
  503.         $cpout{$fh} .= $text;
  504.     } elsif ($size) {
  505.         my $l;
  506.         flush($fh, \$cpout{$fh}, 5120)
  507.             while ($l = length($cpout{$fh})) >= 5120;
  508.         while (sysread(IN, $cpout{$fh}, 5120 - $l, $l)) {
  509.             flush($fh, \$cpout{$fh}, 5120);
  510.             $l = length($cpout{$fh});
  511.         }
  512.         close IN;
  513.     }
  514. }
  515.  
  516. sub cflushall () {
  517.     for my $fh (keys %cpout) {
  518.         cpio($fh, undef, $nc{$fh});
  519.         $cpout{$fh} .= "0" x (5120 - length($cpout{$fh}));
  520.         flush($fh, \$cpout{$fh}, 5120);
  521.         print $blocks{$fh} * 10, " blocks\n";
  522.     }
  523. }
  524.  
  525. END
  526. }
  527.  
  528. if (exists $init{tar}) {
  529.     print <<'INTRO', <<"SUB", <<'END';
  530.  
  531. my %tarout = ();
  532. my %linkseen = ();
  533.  
  534. sub tar {
  535.     my ($fh, $fname) = @_;
  536.     my $prefix = '';
  537.     my $typeflag = '0';
  538.     my $linkname;
  539.     my ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
  540. INTRO
  541.         \$atime,\$mtime,\$ctime,\$blksize,\$blocks) = $stat(_);
  542. SUB
  543.     local (*IN);
  544.  
  545.     if ($nlink > 1) {
  546.         if ($linkname = $linkseen{$fh, $dev, $ino}) {
  547.             if (length($linkname) > 100) {
  548.                 warn "$0: omitting file with linkname ",
  549.                      "too long for tar output: $linkname\n";
  550.                 return;
  551.             }
  552.             $typeflag = '1';
  553.             $size = 0;
  554.         } else {
  555.             $linkseen{$fh, $dev, $ino} = $fname;
  556.         }
  557.     }
  558.     if ($typeflag eq '0') {
  559.         if (-f _) {
  560.             open(IN, "./$_\0") || do {
  561.                 warn "Couldn't open $fname: $!\n";
  562.                 return;
  563.             }
  564.         } else {
  565.             $linkname = readlink($_);
  566.             if (defined $linkname) { $typeflag = '2' }
  567.             elsif (-c _) { $typeflag = '3' }
  568.             elsif (-b _) { $typeflag = '4' }
  569.             elsif (-d _) { $typeflag = '5' }
  570.             elsif (-p _) { $typeflag = '6' }
  571.         }
  572.     }
  573.  
  574.     if (length($fname) > 100) {
  575.         ($prefix, $fname) = ($fname =~ m#\A(.*?)/(.{,100})\Z(?!\n)#);
  576.         if (!defined($fname) || length($prefix) > 155) {
  577.             warn "$0: omitting file with name too long for tar output: ",
  578.                  $fname, "\n";
  579.             return;
  580.         }
  581.     }
  582.  
  583.     $size = 0 if $typeflag ne '0';
  584.     my $header = pack("a100a8a8a8a12a12a8a1a100a6a2a32a32a8a8a155",
  585.                         $fname,
  586.                         sprintf("%7o ", $mode &    0777),
  587.                         sprintf("%7o ", $uid  & 0777777),
  588.                         sprintf("%7o ", $gid  & 0777777),
  589.                         sprintf("%11o ", $size),
  590.                         sprintf("%11o ", $mtime),
  591.                         ' 'x8,
  592.                         $typeflag,
  593.                         defined $linkname ? $linkname : '',
  594.                         "ustar\0",
  595.                         "00",
  596.                         $user{$uid},
  597.                         $group{$gid},
  598.                         ($rdev >> 8) & 0xff,
  599.                         $rdev & 0xff,
  600.                         $prefix,
  601.                      );
  602.     substr($header, 148, 8) = sprintf("%7o ", unpack("%16C*", $header));
  603.     my $l = length($header) % 512;
  604.     $tarout{$fh} .= $header;
  605.     $tarout{$fh} .= "\0" x (512 - $l) if $l;
  606.  
  607.     if ($size) {
  608.         flush($fh, \$tarout{$fh}, 10240)
  609.             while ($l = length($tarout{$fh})) >= 10240;
  610.         while (sysread(IN, $tarout{$fh}, 10240 - $l, $l)) {
  611.             my $slop = length($tarout{$fh}) % 512;
  612.             $tarout{$fh} .= "\0" x (512 - $slop) if $slop;
  613.             flush($fh, \$tarout{$fh}, 10240);
  614.             $l = length($tarout{$fh});
  615.         }
  616.         close IN;
  617.     }
  618. }
  619.  
  620. sub tflushall () {
  621.     my $len;
  622.     for my $fh (keys %tarout) {
  623.         $len = 10240 - length($tarout{$fh});
  624.         $len += 10240 if $len < 1024;
  625.         $tarout{$fh} .= "\0" x $len;
  626.         flush($fh, \$tarout{$fh}, 10240);
  627.     }
  628. }
  629.  
  630. END
  631. }
  632.  
  633. exit;
  634.  
  635. ############################################################################
  636.  
  637. sub tab () {
  638.     my $tabstring;
  639.  
  640.     $tabstring = "\t" x ($indent_depth/2) . ' ' x ($indent_depth%2 * 4);
  641.     if (!$statdone) {
  642.         if ($_ =~ /^(?:name|print|prune|exec|ok|\(|\))/) {
  643.             $init{delayedstat} = 1;
  644.         } else {
  645.             my $statcall = '(($dev,$ino,$mode,$nlink,$uid,$gid) = '
  646.                          . $stat . '($_))';
  647.             if (exists $init{saw_or}) {
  648.                 $tabstring .= "(\$nlink || $statcall) &&\n" . $tabstring;
  649.             } else {
  650.                 $tabstring .= "$statcall &&\n" . $tabstring;
  651.             }
  652.             $statdone = 1;
  653.             $init{declarestat} = 1;
  654.         }
  655.     }
  656.     $tabstring =~ s/^\s+/ / if $out =~ /!$/;
  657.     $tabstring;
  658. }
  659.  
  660. sub fileglob_to_re ($) {
  661.     my $x = shift;
  662.     $x =~ s#([./^\$()+])#\\$1#g;
  663.     $x =~ s#([?*])#.$1#g;
  664.     "^$x\\z";
  665. }
  666.  
  667. sub n ($$) {
  668.     my ($pre, $n) = @_;
  669.     $n =~ s/^-/< / || $n =~ s/^\+/> / || $n =~ s/^/== /;
  670.     $n =~ s/ 0*(\d)/ $1/;
  671.     "($pre $n)";
  672. }
  673.  
  674. sub quote ($) {
  675.     my $string = shift;
  676.     $string =~ s/\\/\\\\/g;
  677.     $string =~ s/'/\\'/g;
  678.     "'$string'";
  679. }
  680.  
  681. __END__
  682.  
  683. =head1 NAME
  684.  
  685. find2perl - translate find command lines to Perl code
  686.  
  687. =head1 SYNOPSIS
  688.  
  689.     find2perl [paths] [predicates] | perl
  690.  
  691. =head1 DESCRIPTION
  692.  
  693. find2perl is a little translator to convert find command lines to
  694. equivalent Perl code.  The resulting code is typically faster than
  695. running find itself.
  696.  
  697. "paths" are a set of paths where find2perl will start its searches and
  698. "predicates" are taken from the following list.
  699.  
  700. =over 4
  701.  
  702. =item C<! PREDICATE>
  703.  
  704. Negate the sense of the following predicate.  The C<!> must be passed as
  705. a distinct argument, so it may need to be surrounded by whitespace and/or
  706. quoted from interpretation by the shell using a backslash (just as with
  707. using C<find(1)>).
  708.  
  709. =item C<( PREDICATES )>
  710.  
  711. Group the given PREDICATES.  The parentheses must be passed as distinct
  712. arguments, so they may need to be surrounded by whitespace and/or
  713. quoted from interpretation by the shell using a backslash (just as with
  714. using C<find(1)>).
  715.  
  716. =item C<PREDICATE1 PREDICATE2>
  717.  
  718. True if _both_ PREDICATE1 and PREDICATE2 are true; PREDICATE2 is not
  719. evaluated if PREDICATE1 is false.
  720.  
  721. =item C<PREDICATE1 -o PREDICATE2>
  722.  
  723. True if either one of PREDICATE1 or PREDICATE2 is true; PREDICATE2 is
  724. not evaluated if PREDICATE1 is true.
  725.  
  726. =item C<-follow>
  727.  
  728. Follow (dereference) symlinks.  The checking of file attributes depends
  729. on the position of the C<-follow> option. If it precedes the file
  730. check option, an C<stat> is done which means the file check applies to the
  731. file the symbolic link is pointing to. If C<-follow> option follows the
  732. file check option, this now applies to the symbolic link itself, i.e.
  733. an C<lstat> is done.
  734.  
  735. =item C<-depth>
  736.  
  737. Change directory traversal algorithm from breadth-first to depth-first.
  738.  
  739. =item C<-prune>
  740.  
  741. Do not descend into the directory currently matched.
  742.  
  743. =item C<-xdev>
  744.  
  745. Do not traverse mount points (prunes search at mount-point directories).
  746.  
  747. =item C<-name GLOB>
  748.  
  749. File name matches specified GLOB wildcard pattern.  GLOB may need to be
  750. quoted to avoid interpretation by the shell (just as with using
  751. C<find(1)>).
  752.  
  753. =item C<-perm PERM>
  754.  
  755. Low-order 9 bits of permission match octal value PERM.
  756.  
  757. =item C<-perm -PERM>
  758.  
  759. The bits specified in PERM are all set in file's permissions.
  760.  
  761. =item C<-type X>
  762.  
  763. The file's type matches perl's C<-X> operator.
  764.  
  765. =item C<-fstype TYPE>
  766.  
  767. Filesystem of current path is of type TYPE (only NFS/non-NFS distinction
  768. is implemented).
  769.  
  770. =item C<-user USER>
  771.  
  772. True if USER is owner of file.
  773.  
  774. =item C<-group GROUP>
  775.  
  776. True if file's group is GROUP.
  777.  
  778. =item C<-nouser>
  779.  
  780. True if file's owner is not in password database.
  781.  
  782. =item C<-nogroup>
  783.  
  784. True if file's group is not in group database.
  785.  
  786. =item C<-inum INUM>
  787.  
  788. True file's inode number is INUM.
  789.  
  790. =item C<-links N>
  791.  
  792. True if (hard) link count of file matches N (see below).
  793.  
  794. =item C<-size N>
  795.  
  796. True if file's size matches N (see below) N is normally counted in
  797. 512-byte blocks, but a suffix of "c" specifies that size should be
  798. counted in characters (bytes) and a suffix of "k" specifes that
  799. size should be counted in 1024-byte blocks.
  800.  
  801. =item C<-atime N>
  802.  
  803. True if last-access time of file matches N (measured in days) (see
  804. below).
  805.  
  806. =item C<-ctime N>
  807.  
  808. True if last-changed time of file's inode matches N (measured in days,
  809. see below).
  810.  
  811. =item C<-mtime N>
  812.  
  813. True if last-modified time of file matches N (measured in days, see below).
  814.  
  815. =item C<-newer FILE>
  816.  
  817. True if last-modified time of file matches N.
  818.  
  819. =item C<-print>
  820.  
  821. Print out path of file (always true). If none of C<-exec>, C<-ls>,
  822. C<-print0>, or C<-ok> is specified, then C<-print> will be added
  823. implicitly.
  824.  
  825. =item C<-print0>
  826.  
  827. Like -print, but terminates with \0 instead of \n.
  828.  
  829. =item C<-exec OPTIONS ;>
  830.  
  831. exec() the arguments in OPTIONS in a subprocess; any occurrence of {} in
  832. OPTIONS will first be substituted with the path of the current
  833. file.  Note that the command "rm" has been special-cased to use perl's
  834. unlink() function instead (as an optimization).  The C<;> must be passed as
  835. a distinct argument, so it may need to be surrounded by whitespace and/or
  836. quoted from interpretation by the shell using a backslash (just as with
  837. using C<find(1)>).
  838.  
  839. =item C<-ok OPTIONS ;>
  840.  
  841. Like -exec, but first prompts user; if user's response does not begin
  842. with a y, skip the exec.  The C<;> must be passed as
  843. a distinct argument, so it may need to be surrounded by whitespace and/or
  844. quoted from interpretation by the shell using a backslash (just as with
  845. using C<find(1)>).
  846.  
  847. =item C<-eval EXPR>
  848.  
  849. Has the perl script eval() the EXPR.  
  850.  
  851. =item C<-ls>
  852.  
  853. Simulates C<-exec ls -dils {} ;>
  854.  
  855. =item C<-tar FILE>
  856.  
  857. Adds current output to tar-format FILE.
  858.  
  859. =item C<-cpio FILE>
  860.  
  861. Adds current output to old-style cpio-format FILE.
  862.  
  863. =item C<-ncpio FILE>
  864.  
  865. Adds current output to "new"-style cpio-format FILE.
  866.  
  867. =back
  868.  
  869. Predicates which take a numeric argument N can come in three forms:
  870.  
  871.    * N is prefixed with a +: match values greater than N
  872.    * N is prefixed with a -: match values less than N
  873.    * N is not prefixed with either + or -: match only values equal to N
  874.  
  875. =head1 SEE ALSO
  876.  
  877. find
  878.  
  879. =cut
  880.