home *** CD-ROM | disk | FTP | other *** search
/ PC World 2005 December (Special) / PCWorld_2005-12_Special_cd.bin / Bezpecnost / lsti / lsti.exe / framework-2.5.exe / Tar.pm < prev    next >
Text File  |  2004-12-03  |  43KB  |  1,388 lines
  1. ### the gnu tar specification:
  2. ### http://www.gnu.org/software/tar/manual/html_mono/tar.html
  3. ###
  4. ### and the pax format spec, which tar derives from:
  5. ### http://www.opengroup.org/onlinepubs/007904975/utilities/pax.html
  6.  
  7. package Archive::Tar;
  8. require 5.005_03;
  9.  
  10. use strict;
  11. use vars qw[$DEBUG $error $VERSION $WARN $FOLLOW_SYMLINK $CHOWN $CHMOD
  12.             $DO_NOT_USE_PREFIX];
  13.             
  14. $DEBUG              = 0;
  15. $WARN               = 1;
  16. $FOLLOW_SYMLINK     = 0;
  17. $VERSION            = "1.23";
  18. $CHOWN              = 1;
  19. $CHMOD              = 1;
  20. $DO_NOT_USE_PREFIX  = 0;
  21.  
  22. use IO::File;
  23. use IO::String;
  24. use Cwd;
  25. use Carp                qw(carp);
  26. use File::Spec          ();
  27. use File::Spec::Unix    ();
  28. use File::Path          ();
  29.  
  30. use Archive::Tar::File;
  31. use Archive::Tar::Constant;
  32.  
  33. =head1 NAME
  34.  
  35. Archive::Tar - module for manipulations of tar archives
  36.  
  37. =head1 SYNOPSIS
  38.  
  39.     use Archive::Tar;
  40.     my $tar = Archive::Tar->new;
  41.     
  42.     $tar->read('origin.tgz',1); 
  43.     $tar->extract();
  44.     
  45.     $tar->add_files('file/foo.pl', 'docs/README');
  46.     $tar->add_data('file/baz.txt', 'This is the contents now');
  47.     
  48.     $tar->rename('oldname', 'new/file/name');
  49.     
  50.     $tar->write('files.tar');
  51.     
  52. =head1 DESCRIPTION
  53.     
  54. Archive::Tar provides an object oriented mechanism for handling tar
  55. files.  It provides class methods for quick and easy files handling
  56. while also allowing for the creation of tar file objects for custom
  57. manipulation.  If you have the IO::Zlib module installed,
  58. Archive::Tar will also support compressed or gzipped tar files.
  59.  
  60. An object of class Archive::Tar represents a .tar(.gz) archive full 
  61. of files and things.
  62.  
  63. =head1 Object Methods
  64.  
  65. =head2 Archive::Tar->new( [$file, $compressed] )
  66.  
  67. Returns a new Tar object. If given any arguments, C<new()> calls the
  68. C<read()> method automatically, passing on the arguments provided to 
  69. the C<read()> method.
  70.  
  71. If C<new()> is invoked with arguments and the C<read()> method fails 
  72. for any reason, C<new()> returns undef.
  73.  
  74. =cut
  75.  
  76. my $tmpl = {
  77.     _data   => [ ],
  78.     _file   => 'Unknown',
  79. };    
  80.  
  81. ### install get/set accessors for this object.
  82. for my $key ( keys %$tmpl ) {
  83.     no strict 'refs';
  84.     *{__PACKAGE__."::$key"} = sub {
  85.         my $self = shift;
  86.         $self->{$key} = $_[0] if @_;
  87.         return $self->{$key};
  88.     }
  89. }
  90.  
  91. sub new {
  92.     my $class = shift;
  93.     $class = ref $class if ref $class;
  94.  
  95.     ### copying $tmpl here since a shallow copy makes it use the
  96.     ### same aref, causing for files to remain in memory always.
  97.     my $obj = bless { _data => [ ], _file => 'Unknown' }, $class;
  98.  
  99.     if (@_) {
  100.         return unless $obj->read( @_ );
  101.     }
  102.     
  103.     return $obj;
  104. }
  105.  
  106. =head2 $tar->read ( $filename|$handle, $compressed, {opt => 'val'} )
  107.  
  108. Read the given tar file into memory. 
  109. The first argument can either be the name of a file or a reference to
  110. an already open filehandle (or an IO::Zlib object if it's compressed)  
  111. The second argument indicates whether the file referenced by the first 
  112. argument is compressed.
  113.  
  114. The C<read> will I<replace> any previous content in C<$tar>!
  115.  
  116. The second argument may be considered optional if IO::Zlib is
  117. installed, since it will transparently Do The Right Thing. 
  118. Archive::Tar will warn if you try to pass a compressed file if 
  119. IO::Zlib is not available and simply return.
  120.  
  121. The third argument can be a hash reference with options. Note that 
  122. all options are case-sensitive.
  123.  
  124. =over 4
  125.  
  126. =item limit
  127.  
  128. Do not read more than C<limit> files. This is useful if you have 
  129. very big archives, and are only interested in the first few files.
  130.  
  131. =item extract
  132.  
  133. If set to true, immediately extract entries when reading them. This
  134. gives you the same memory break as the C<extract_archive> function.
  135. Note however that entries will not be read into memory, but written 
  136. straight to disk.
  137.  
  138. =back
  139.  
  140. All files are stored internally as C<Archive::Tar::File> objects.
  141. Please consult the L<Archive::Tar::File> documentation for details.
  142.  
  143. Returns the number of files read in scalar context, and a list of
  144. C<Archive::Tar::File> objects in list context.
  145.  
  146. =cut
  147.  
  148. sub read {
  149.     my $self = shift;    
  150.     my $file = shift; 
  151.     my $gzip = shift || 0;
  152.     my $opts = shift || {};
  153.     
  154.     unless( defined $file ) {
  155.         $self->_error( qq[No file to read from!] );
  156.         return;
  157.     } else {
  158.         $self->_file( $file );
  159.     }     
  160.     
  161.     my $handle = $self->_get_handle($file, $gzip, READ_ONLY->( ZLIB ) ) 
  162.                     or return;
  163.  
  164.     my $data = $self->_read_tar( $handle, $opts ) or return;
  165.  
  166.     $self->_data( $data );    
  167.  
  168.     return wantarray ? @$data : scalar @$data;
  169. }
  170.  
  171. sub _get_handle {
  172.     my $self = shift;
  173.     my $file = shift;   return unless defined $file;
  174.                         return $file if ref $file;
  175.                         
  176.     my $gzip = shift || 0;
  177.     my $mode = shift || READ_ONLY->( ZLIB ); # default to read only
  178.     
  179.     my $fh; my $bin;
  180.     
  181.     ### only default to ZLIB if we're not trying to /write/ to a handle ###
  182.     if( ZLIB and $gzip || MODE_READ->( $mode ) ) {
  183.         
  184.         ### IO::Zlib will Do The Right Thing, even when passed 
  185.         ### a plain file ###
  186.         $fh = new IO::Zlib;
  187.     
  188.     } else {    
  189.         if( $gzip ) {
  190.             $self->_error(qq[Compression not available - Install IO::Zlib!]);
  191.             return;
  192.         
  193.         } else {
  194.             $fh = new IO::File;
  195.             $bin++;
  196.         }
  197.     }
  198.         
  199.     unless( $fh->open( $file, $mode ) ) {
  200.         $self->_error( qq[Could not create filehandle for '$file': $!!] );
  201.         return;
  202.     }
  203.     
  204.     binmode $fh if $bin;
  205.     
  206.     return $fh;
  207. }
  208.  
  209. sub _read_tar {
  210.     my $self    = shift;
  211.     my $handle  = shift or return;
  212.     my $opts    = shift || {};
  213.  
  214.     my $count   = $opts->{limit}    || 0;
  215.     my $extract = $opts->{extract}  || 0;
  216.     
  217.     ### set a cap on the amount of files to extract ###
  218.     my $limit   = 0;
  219.     $limit = 1 if $count > 0;
  220.  
  221.     my $tarfile = [ ];
  222.     my $chunk;
  223.     my $read = 0;
  224.     my $real_name;  # to set the name of a file when 
  225.                     # we're encountering @longlink
  226.     my $data;
  227.          
  228.     LOOP: 
  229.     while( $handle->read( $chunk, HEAD ) ) {        
  230.         ### IO::Zlib doesn't support this yet
  231.         my $offset = eval { tell $handle } || 'unknown';
  232.             
  233.         unless( $read++ ) {
  234.             my $gzip = GZIP_MAGIC_NUM;
  235.             if( $chunk =~ /$gzip/ ) {
  236.                 $self->_error( qq[Can not read compressed format in tar-mode] );
  237.                 return;
  238.             }
  239.         }
  240.               
  241.         ### if we can't read in all bytes... ###
  242.         last if length $chunk != HEAD;
  243.         
  244.         ### Apparently this should really be two blocks of 512 zeroes,
  245.         ### but GNU tar sometimes gets it wrong. See comment in the
  246.         ### source code (tar.c) to GNU cpio.
  247.         next if $chunk eq TAR_END;
  248.         
  249.         my $entry; 
  250.         unless( $entry = Archive::Tar::File->new( chunk => $chunk ) ) {
  251.             $self->_error( qq[Couldn't read chunk at offset $offset] );
  252.             next;
  253.         }
  254.         
  255.         ### ignore labels:
  256.         ### http://www.gnu.org/manual/tar/html_node/tar_139.html
  257.         next if $entry->is_label;
  258.         
  259.         if( length $entry->type and ($entry->is_file || $entry->is_longlink) ) {
  260.             
  261.             if ( $entry->is_file && !$entry->validate ) {
  262.                 ### sometimes the chunk is rather fux0r3d and a whole 512
  263.                 ### bytes ends p in the ->name area.
  264.                 ### clean it up, if need be
  265.                 my $name = $entry->name;
  266.                 $name = substr($name, 0, 100) if length $name > 100;
  267.                 $name =~ s/\n/ /g;
  268.             
  269.                 $self->_error( $name . qq[: checksum error] );
  270.                 next LOOP;
  271.             }
  272.             
  273.             my $block = BLOCK_SIZE->( $entry->size );
  274.  
  275.             $data = $entry->get_content_by_ref;
  276.             
  277.             ### just read everything into memory 
  278.             ### can't do lazy loading since IO::Zlib doesn't support 'seek'
  279.             ### this is because Compress::Zlib doesn't support it =/ 
  280.             ### this reads in the whole data in one read() call.              
  281.             if( $handle->read( $$data, $block ) < $block ) {
  282.                 $self->_error( qq[Read error on tarfile (missing data) ']. 
  283.                                     $entry->full_path ."' at offset $offset" );
  284.                 next;
  285.             }
  286.  
  287.             ### throw away trailing garbage ###
  288.             substr ($$data, $entry->size) = "";
  289.  
  290.             ### part II of the @LongLink munging -- need to do /after/
  291.             ### the checksum check.
  292.             if( $entry->is_longlink ) {
  293.                 ### weird thing in tarfiles -- if the file is actually a
  294.                 ### @LongLink, the data part seems to have a trailing ^@ 
  295.                 ### (unprintable) char. to display, pipe output through less.
  296.                 ### but that doesn't *always* happen.. so check if the last 
  297.                 ### character is a control character, and if so remove it
  298.                 ### at any rate, we better remove that character here, or tests 
  299.                 ### like 'eq' and hashlook ups based on names will SO not work
  300.                 ### remove it by calculating the proper size, and then
  301.                 ### tossing out everything that's longer than that size.
  302.     
  303.                 ### count number of nulls 
  304.                 my $nulls = $$data =~ tr/\0/\0/;
  305.  
  306.                 ### cut data + size by that many bytes
  307.                 $entry->size( $entry->size - $nulls );
  308.                 substr ($$data, $entry->size) = "";
  309.             }
  310.         }
  311.         
  312.         ### clean up of the entries.. posix tar /apparently/ has some
  313.         ### weird 'feature' that allows for filenames > 255 characters
  314.         ### they'll put a header in with as name '././@LongLink' and the
  315.         ### contents will be the name of the /next/ file in the archive
  316.         ### pretty crappy and kludgy if you ask me
  317.         
  318.         ### set the name for the next entry if this is a @LongLink;
  319.         ### this is one ugly hack =/ but needed for direct extraction
  320.         if( $entry->is_longlink ) {
  321.             $real_name = $data;
  322.             next;
  323.         } elsif ( defined $real_name ) {
  324.             $entry->name( $$real_name );
  325.             $entry->prefix('');
  326.             undef $real_name;      
  327.         }
  328.  
  329.         $self->_extract_file( $entry ) if $extract 
  330.                                             && !$entry->is_longlink
  331.                                             && !$entry->is_unknown 
  332.                                             && !$entry->is_label;
  333.         
  334.         ### Guard against tarfiles with garbage at the end
  335.         last LOOP if $entry->name eq ''; 
  336.     
  337.         ### push only the name on the rv if we're extracting 
  338.         ### -- for extract_archive
  339.         push @$tarfile, ($extract ? $entry->name : $entry);
  340.     
  341.         if( $limit ) {
  342.             $count-- unless $entry->is_longlink || $entry->is_dir;    
  343.             last LOOP unless $count;
  344.         }
  345.     } continue {
  346.         undef $data;
  347.     }      
  348.     
  349.     return $tarfile;
  350. }    
  351.  
  352. =head2 $tar->contains_file( $filename )
  353.  
  354. Check if the archive contains a certain file.
  355. It will return true if the file is in the archive, false otherwise.
  356.  
  357. Note however, that this function does an exact match using C<eq>
  358. on the full path. So it can not compensate for case-insensitive file-
  359. systems or compare 2 paths to see if they would point to the same
  360. underlying file.
  361.  
  362. =cut
  363.  
  364. sub contains_file {
  365.     my $self = shift;
  366.     my $full = shift or return;
  367.     
  368.     return 1 if $self->_find_entry($full);      
  369.     return;
  370. }    
  371.  
  372. =head2 $tar->extract( [@filenames] )
  373.  
  374. Write files whose names are equivalent to any of the names in
  375. C<@filenames> to disk, creating subdirectories as necessary. This
  376. might not work too well under VMS.  
  377. Under MacPerl, the file's modification time will be converted to the
  378. MacOS zero of time, and appropriate conversions will be done to the 
  379. path.  However, the length of each element of the path is not 
  380. inspected to see whether it's longer than MacOS currently allows (32
  381. characters).
  382.  
  383. If C<extract> is called without a list of file names, the entire
  384. contents of the archive are extracted.
  385.  
  386. Returns a list of filenames extracted.
  387.  
  388. =cut
  389.  
  390. sub extract {
  391.     my $self    = shift;
  392.     my @files;
  393.  
  394.     ### you requested the extraction of only certian files
  395.     if( @_ ) { 
  396.         for my $file (@_) {
  397.             my $found;
  398.             for my $entry ( @{$self->_data} ) {
  399.                 next unless $file eq $entry->full_path;
  400.      
  401.                 ### we found the file you're looking for           
  402.                 push @files, $entry;
  403.                 $found++;
  404.             }
  405.             
  406.             unless( $found ) {
  407.                 return $self->_error( qq[Could not find '$file' in archive] );
  408.             }
  409.         }       
  410.     
  411.     ### just grab all the file items
  412.     } else {
  413.         @files = $self->get_files;
  414.     }       
  415.      
  416.     ### nothing found? that's an error 
  417.     unless( scalar @files ) {
  418.         $self->_error( qq[No files found for ] . $self->_file );
  419.         return;
  420.     }
  421.  
  422.     ### now extract them    
  423.     for my $entry ( @files ) {
  424.         unless( $self->_extract_file( $entry ) ) {
  425.             $self->_error(q[Could not extract ']. $entry->full_path .q['] );
  426.             return;
  427.         }        
  428.     }
  429.          
  430.     return @files;        
  431. }
  432.  
  433. =head2 $tar->extract_file( $file, [$extract_path] )
  434.  
  435. Write an entry, whose name is equivalent to the file name provided to
  436. disk. Optionally takes a second parameter, which is the full (unix) 
  437. path (including filename) the entry will be written to.
  438.  
  439. For example:
  440.     
  441.     $tar->extract_file( 'name/in/archive', 'name/i/want/to/give/it' );
  442.  
  443. Returns true on success, false on failure.
  444.  
  445. =cut
  446.  
  447. sub extract_file {
  448.     my $self = shift;
  449.     my $file = shift or return;
  450.     my $alt  = shift;
  451.  
  452.     my $entry = $self->_find_entry( $file ) 
  453.         or $self->_error( qq[Could not find an entry for '$file'] ), return;
  454.  
  455.     return $self->_extract_file( $entry, $alt );
  456. }
  457.  
  458. sub _extract_file {
  459.     my $self    = shift;
  460.     my $entry   = shift or return;
  461.     my $alt     = shift;
  462.     my $cwd     = cwd();
  463.  
  464.     ### you wanted an alternate extraction location ###
  465.     my $name = defined $alt ? $alt : $entry->full_path;
  466.     
  467.                             ### splitpath takes a bool at the end to indicate
  468.                             ### that it's splitting a dir    
  469.     my ($vol,$dirs,$file) = File::Spec::Unix->splitpath(    $name, 
  470.                                                             $entry->is_dir );
  471.     my $dir;
  472.     ### is $name an absolute path? ###
  473.     if( File::Spec->file_name_is_absolute( $name ) ) {
  474.         $dir = $name;
  475.   
  476.     ### it's a relative path ###
  477.     } else {      
  478.         my @dirs    = File::Spec::Unix->splitdir( $dirs );
  479.         my @cwd     = File::Spec->splitdir( $cwd );
  480.         $dir        = File::Spec->catdir(@cwd, @dirs);               
  481.     }
  482.    
  483.     if( -e $dir && !-d _ ) {
  484.         $^W && $self->_error( qq['$dir' exists, but it's not a directory!\n] );
  485.         return;
  486.     }
  487.     
  488.     unless ( -d _ ) {
  489.         eval { File::Path::mkpath( $dir, 0, 0777 ) };
  490.         if( $@ ) {
  491.             $self->_error( qq[Could not create directory '$dir': $@] );
  492.             return;
  493.         }
  494.     }
  495.     
  496.     ### we're done if we just needed to create a dir ###
  497.     return 1 if $entry->is_dir;
  498.     
  499.     my $full = File::Spec->catfile( $dir, $file );
  500.     
  501.     if( $entry->is_unknown ) {
  502.         $self->_error( qq[Unknown file type for file '$full'] );
  503.         return;
  504.     }
  505.     
  506.     if( length $entry->type && $entry->is_file ) {
  507.         my $fh = IO::File->new;
  508.         $fh->open( '>' . $full ) or (
  509.             $self->_error( qq[Could not open file '$full': $!] ),
  510.             return
  511.         );
  512.     
  513.         if( $entry->size ) {
  514.             binmode $fh;
  515.             syswrite $fh, $entry->data or (
  516.                 $self->_error( qq[Could not write data to '$full'] ),
  517.                 return
  518.             );
  519.         }
  520.         
  521.         close $fh or (
  522.             $self->_error( qq[Could not close file '$full'] ),
  523.             return
  524.         );     
  525.     
  526.     } else {
  527.         $self->_make_special_file( $entry, $full ) or return;
  528.     } 
  529.  
  530.     utime time, $entry->mtime - TIME_OFFSET, $full or
  531.         $self->_error( qq[Could not update timestamp] );
  532.  
  533.     if( $CHOWN && CAN_CHOWN ) {
  534.         chown $entry->uid, $entry->gid, $full or
  535.             $self->_error( qq[Could not set uid/gid on '$full'] );
  536.     }
  537.     
  538.     ### only chmod if we're allowed to, but never chmod symlinks, since they'll 
  539.     ### change the perms on the file they're linking too...
  540.     if( $CHMOD and not -l $full ) {
  541.         chmod $entry->mode, $full or
  542.             $self->_error( qq[Could not chown '$full' to ] . $entry->mode );
  543.     }            
  544.     
  545.     return 1;
  546. }
  547.  
  548. sub _make_special_file {
  549.     my $self    = shift;
  550.     my $entry   = shift     or return;
  551.     my $file    = shift;    return unless defined $file;
  552.     
  553.     my $err;
  554.     
  555.     if( $entry->is_symlink ) {
  556.         my $fail;
  557.         if( ON_UNIX ) {
  558.             symlink( $entry->linkname, $file ) or $fail++;
  559.         
  560.         } else {
  561.             $self->_extract_special_file_as_plain_file( $entry, $file ) 
  562.                 or $fail++;   
  563.         }
  564.         
  565.         $err =  qq[Making symbolink link from '] . $entry->linkname .
  566.                 qq[' to '$file' failed] if $fail; 
  567.     
  568.     } elsif ( $entry->is_hardlink ) {
  569.         my $fail;
  570.         if( ON_UNIX ) {
  571.             link( $entry->linkname, $file ) or $fail++;
  572.    
  573.         } else {
  574.             $self->_extract_special_file_as_plain_file( $entry, $file ) 
  575.                 or $fail++;   
  576.         }
  577.         
  578.         $err =  qq[Making hard link from '] . $entry->linkname .
  579.                 qq[' to '$file' failed] if $fail;     
  580.     
  581.     } elsif ( $entry->is_fifo ) {
  582.         ON_UNIX && !system('mknod', $file, 'p') or 
  583.             $err = qq[Making fifo ']. $entry->name .qq[' failed];
  584.  
  585.     } elsif ( $entry->is_blockdev or $entry->is_chardev ) {
  586.         my $mode = $entry->is_blockdev ? 'b' : 'c';
  587.             
  588.         ON_UNIX && !system('mknod', $file, $mode, 
  589.                             $entry->devmajor, $entry->devminor) or
  590.             $err =  qq[Making block device ']. $entry->name .qq[' (maj=] .
  591.                     $entry->devmajor . qq[ min=] . $entry->devminor . 
  592.                     qq[) failed.];          
  593.  
  594.     } elsif ( $entry->is_socket ) {
  595.         ### the original doesn't do anything special for sockets.... ###     
  596.         1;
  597.     }
  598.     
  599.     return $err ? $self->_error( $err ) : 1;
  600. }
  601.  
  602. ### don't know how to make symlinks, let's just extract the file as 
  603. ### a plain file
  604. sub _extract_special_file_as_plain_file {
  605.     my $self    = shift;
  606.     my $entry   = shift     or return;
  607.     my $file    = shift;    return unless defined $file;
  608.     
  609.     my $err;
  610.     TRY: { 
  611.         my $orig = $self->_find_entry( $entry->linkname );
  612.         
  613.         unless( $orig ) {
  614.             $err =  qq[Could not find file '] . $entry->linkname .
  615.                     qq[' in memory.];
  616.             last TRY;
  617.         }
  618.         
  619.         ### clone the entry, make it appear as a normal file ###
  620.         my $clone = $entry->clone;
  621.         $clone->_downgrade_to_plainfile;          
  622.         $self->_extract_file( $clone, $file ) or last TRY;                      
  623.     
  624.         return 1;
  625.     }
  626.     
  627.     return $self->_error($err);
  628. }
  629.  
  630. =head2 $tar->list_files( [\@properties] )
  631.  
  632. Returns a list of the names of all the files in the archive.
  633.  
  634. If C<list_files()> is passed an array reference as its first argument
  635. it returns a list of hash references containing the requested
  636. properties of each file.  The following list of properties is
  637. supported: name, size, mtime (last modified date), mode, uid, gid,
  638. linkname, uname, gname, devmajor, devminor, prefix.
  639.  
  640. Passing an array reference containing only one element, 'name', is
  641. special cased to return a list of names rather than a list of hash
  642. references, making it equivalent to calling C<list_files> without 
  643. arguments.
  644.  
  645. =cut
  646.  
  647. sub list_files {
  648.     my $self = shift;
  649.     my $aref = shift || [ ];
  650.     
  651.     unless( $self->_data ) {
  652.         $self->read() or return;
  653.     }
  654.     
  655.     if( @$aref == 0 or ( @$aref == 1 and $aref->[0] eq 'name' ) ) {
  656.         return map { $_->full_path } @{$self->_data};     
  657.     } else {
  658.     
  659.         #my @rv;
  660.         #for my $obj ( @{$self->_data} ) {
  661.         #    push @rv, { map { $_ => $obj->$_() } @$aref };
  662.         #}
  663.         #return @rv;
  664.         
  665.         ### this does the same as the above.. just needs a +{ }
  666.         ### to make sure perl doesn't confuse it for a block
  667.         return map {    my $o=$_; 
  668.                         +{ map { $_ => $o->$_() } @$aref } 
  669.                     } @{$self->_data}; 
  670.     }    
  671. }
  672.  
  673. sub _find_entry {
  674.     my $self = shift;
  675.     my $file = shift;
  676.  
  677.     unless( defined $file ) {
  678.         $self->_error( qq[No file specified] );
  679.         return;
  680.     }
  681.     
  682.     for my $entry ( @{$self->_data} ) {
  683.         my $path = $entry->full_path;
  684.         return $entry if $path eq $file;      
  685.     }
  686.     
  687.     $self->_error( qq[No such file in archive: '$file'] );
  688.     return;
  689. }    
  690.  
  691. =head2 $tar->get_files( [@filenames] )
  692.  
  693. Returns the C<Archive::Tar::File> objects matching the filenames 
  694. provided. If no filename list was passed, all C<Archive::Tar::File>
  695. objects in the current Tar object are returned.
  696.  
  697. Please refer to the C<Archive::Tar::File> documentation on how to 
  698. handle these objects.
  699.  
  700. =cut
  701.  
  702. sub get_files {
  703.     my $self = shift;
  704.     
  705.     return @{ $self->_data } unless @_;
  706.     
  707.     my @list;
  708.     for my $file ( @_ ) {
  709.         push @list, grep { defined } $self->_find_entry( $file );
  710.     }
  711.     
  712.     return @list;
  713. }
  714.  
  715. =head2 $tar->get_content( $file )
  716.  
  717. Return the content of the named file.
  718.  
  719. =cut
  720.     
  721. sub get_content {
  722.     my $self = shift;
  723.     my $entry = $self->_find_entry( shift ) or return;
  724.     
  725.     return $entry->data;        
  726. }    
  727.  
  728. =head2 $tar->replace_content( $file, $content )
  729.  
  730. Make the string $content be the content for the file named $file.
  731.  
  732. =cut
  733.  
  734. sub replace_content {
  735.     my $self = shift;
  736.     my $entry = $self->_find_entry( shift ) or return;
  737.  
  738.     return $entry->replace_content( shift );
  739. }    
  740.  
  741. =head2 $tar->rename( $file, $new_name ) 
  742.  
  743. Rename the file of the in-memory archive to $new_name.
  744.  
  745. Note that you must specify a Unix path for $new_name, since per tar
  746. standard, all files in the archive must be Unix paths.
  747.  
  748. Returns true on success and false on failure.
  749.  
  750. =cut
  751.  
  752. sub rename {
  753.     my $self = shift;
  754.     my $file = shift; return unless defined $file;
  755.     my $new  = shift; return unless defined $new;
  756.     
  757.     my $entry = $self->_find_entry( $file ) or return;
  758.     
  759.     return $entry->rename( $new );
  760. }    
  761.  
  762. =head2 $tar->remove (@filenamelist)
  763.  
  764. Removes any entries with names matching any of the given filenames
  765. from the in-memory archive. Returns a list of C<Archive::Tar::File>
  766. objects that remain. 
  767.  
  768. =cut
  769.  
  770. sub remove {
  771.     my $self = shift;
  772.     my @list = @_;
  773.     
  774.     my %seen = map { $_->full_path => $_ } @{$self->_data};
  775.     delete $seen{ $_ } for @list;
  776.     
  777.     $self->_data( [values %seen] );
  778.     
  779.     return values %seen;   
  780. }
  781.  
  782. =head2 $tar->clear
  783.  
  784. C<clear> clears the current in-memory archive. This effectively gives
  785. you a 'blank' object, ready to be filled again. Note that C<clear> 
  786. only has effect on the object, not the underlying tarfile.
  787.  
  788. =cut
  789.  
  790. sub clear {
  791.     my $self = shift or return;
  792.     
  793.     $self->_data( [] );
  794.     $self->_file( '' );
  795.     
  796.     return 1;
  797. }    
  798.  
  799.  
  800. =head2 $tar->write ( [$file, $compressed, $prefix] )
  801.  
  802. Write the in-memory archive to disk.  The first argument can either 
  803. be the name of a file or a reference to an already open filehandle (a
  804. GLOB reference). If the second argument is true, the module will use
  805. IO::Zlib to write the file in a compressed format.  If IO::Zlib is 
  806. not available, the C<write> method will fail and return.
  807.  
  808. Note that when you pass in a filehandle, the compression argument
  809. is ignored, as all files are printed verbatim to your filehandle.
  810. If you wish to enable compression with filehandles, use an
  811. C<IO::Zlib> filehandle instead.
  812.  
  813. Specific levels of compression can be chosen by passing the values 2
  814. through 9 as the second parameter.
  815.  
  816. The third argument is an optional prefix. All files will be tucked
  817. away in the directory you specify as prefix. So if you have files
  818. 'a' and 'b' in your archive, and you specify 'foo' as prefix, they
  819. will be written to the archive as 'foo/a' and 'foo/b'.
  820.  
  821. If no arguments are given, C<write> returns the entire formatted
  822. archive as a string, which could be useful if you'd like to stuff the
  823. archive into a socket or a pipe to gzip or something.
  824.  
  825. =cut
  826.  
  827. sub write {
  828.     my $self        = shift;
  829.     my $file        = shift; $file = '' unless defined $file;
  830.     my $gzip        = shift || 0;
  831.     my $ext_prefix  = shift; $ext_prefix = '' unless defined $ext_prefix;
  832.  
  833.     ### only need a handle if we have a file to print to ###
  834.     my $handle = length($file)
  835.                     ? ( $self->_get_handle($file, $gzip, WRITE_ONLY->($gzip) ) 
  836.                         or return )
  837.                     : IO::String->new;  
  838.  
  839.     for my $entry ( @{$self->_data} ) {
  840.         ### entries to be written to the tarfile ###
  841.         my @write_me;
  842.  
  843.         ### only now will we change the object to reflect the current state
  844.         ### of the name and prefix fields -- this needs to be limited to
  845.         ### write() only!
  846.         my $clone = $entry->clone;
  847.  
  848.  
  849.         ### so, if you don't want use to use the prefix, we'll stuff everything
  850.         ### in the name field instead
  851.         if( $DO_NOT_USE_PREFIX ) {
  852.  
  853.             ### you might have an extended prefix, if so, set it in the clone
  854.             ### XXX is ::Unix right?
  855.             $clone->name( length $ext_prefix
  856.                             ? File::Spec::Unix->catdir( $ext_prefix, 
  857.                                                         $clone->full_path) 
  858.                             : $clone->full_path );
  859.             $clone->prefix( '' );
  860.  
  861.         ### otherwise, we'll have to set it properly -- prefix part in the
  862.         ### prefix and name part in the name field.
  863.         } else {
  864.         
  865.             ### split them here, not before!
  866.             my ($prefix,$name) = $clone->_prefix_and_file( $clone->full_path );
  867.     
  868.             ### you might have an extended prefix, if so, set it in the clone
  869.             ### XXX is ::Unix right?
  870.             $prefix = File::Spec::Unix->catdir( $ext_prefix, $prefix )
  871.                 if length $ext_prefix;
  872.  
  873.             $clone->prefix( $prefix );
  874.             $clone->name( $name );
  875.         }
  876.      
  877.         ### names are too long, and will get truncated if we don't add a
  878.         ### '@LongLink' file...
  879.         my $make_longlink = (   length($clone->name)    > NAME_LENGTH or 
  880.                                 length($clone->prefix)  > PREFIX_LENGTH 
  881.                             ) || 0;       
  882.  
  883.         ### perhaps we need to make a longlink file?
  884.         if( $make_longlink ) {
  885.             my $longlink = Archive::Tar::File->new( 
  886.                             data => LONGLINK_NAME, 
  887.                             $clone->full_path,
  888.                             { type => LONGLINK }
  889.                         );
  890.                         
  891.             unless( $longlink ) {
  892.                 $self->_error(  qq[Could not create 'LongLink' entry for ] .
  893.                                 qq[oversize file '] . $clone->full_path ."'" );
  894.                 return;
  895.             };                      
  896.     
  897.             push @write_me, $longlink;
  898.         }
  899.     
  900.         push @write_me, $clone;
  901.  
  902.         ### write the one, optionally 2 a::t::file objects to the handle 
  903.         for my $clone (@write_me) { 
  904.  
  905.             ### if the file is a symlink, there are 2 options:
  906.             ### either we leave the symlink intact, but then we don't write any
  907.             ### data OR we follow the symlink, which means we actually make a 
  908.             ### copy. if we do the latter, we have to change the TYPE of the
  909.             ### clone to 'FILE'
  910.             my $link_ok =  $clone->is_symlink && $Archive::Tar::FOLLOW_SYMLINK;
  911.             my $data_ok = !$clone->is_symlink && $clone->has_content;
  912.  
  913.             ### downgrade to a 'normal' file if it's a symlink we're going to
  914.             ### treat as a regular file
  915.             $clone->_downgrade_to_plainfile if $link_ok;        
  916.  
  917.             ### get the header for this block
  918.             my $header = $self->_format_tar_entry( $clone );
  919.             unless( $header ) {
  920.                 $self->_error(q[Could not format header for: ] . 
  921.                                     $clone->full_path );
  922.                 return;
  923.             }      
  924.  
  925.             unless( print $handle $header ) {
  926.                 $self->_error(q[Could not write header for: ] . 
  927.                                     $clone->full_path);
  928.                 return;
  929.             }
  930.         
  931.             if( $link_ok or $data_ok ) {
  932.                 unless( print $handle $clone->data ) {
  933.                     $self->_error(q[Could not write data for: ] . 
  934.                                     $clone->full_path);
  935.                     return;
  936.                 }
  937.  
  938.                 ### pad the end of the clone if required ###
  939.                 print $handle TAR_PAD->( $clone->size ) if $clone->size % BLOCK
  940.             }
  941.        
  942.         } ### done writing these entries
  943.     }
  944.         
  945.     ### write the end markers ###   
  946.     print $handle TAR_END x 2 or
  947.             return $self->_error( qq[Could not write tar end markers] );
  948.     ### did you want it written to a file, or returned as a string? ###
  949.     return length($file) ? 1 : do { seek $handle, 0, 0; local $/; <$handle> }
  950. }
  951.  
  952. sub _format_tar_entry {
  953.     my $self        = shift;
  954.     my $entry       = shift or return;
  955.     my $ext_prefix  = shift; $ext_prefix = '' unless defined $ext_prefix;
  956.     my $no_prefix   = shift || 0;
  957.  
  958.     my $file    = $entry->name;
  959.     my $prefix  = $entry->prefix; $prefix = '' unless defined $prefix;
  960.     
  961.     ### remove the prefix from the file name 
  962.     ### not sure if this is still neeeded --kane
  963.     ### no it's not -- Archive::Tar::File->_new_from_file will take care of
  964.     ### this for us. Even worse, this would break if we tried to add a file
  965.     ### like x/x. 
  966.     #if( length $prefix ) {
  967.     #    $file =~ s/^$match//;
  968.     #} 
  969.     
  970.     $prefix = File::Spec::Unix->catdir($ext_prefix, $prefix) 
  971.                 if length $ext_prefix;
  972.     
  973.     ### not sure why this is... ###
  974.     my $l = PREFIX_LENGTH; # is ambiguous otherwise...
  975.     substr ($prefix, 0, -$l) = "" if length $prefix >= PREFIX_LENGTH;
  976.     
  977.     my $f1 = "%06o"; my $f2  = "%11o";
  978.     
  979.     ### this might be optimizable with a 'changed' flag in the file objects ###
  980.     my $tar = pack (
  981.                 PACK,
  982.                 $file,
  983.                 
  984.                 (map { sprintf( $f1, $entry->$_() ) } qw[mode uid gid]),
  985.                 (map { sprintf( $f2, $entry->$_() ) } qw[size mtime]),
  986.                 
  987.                 "",  # checksum field - space padded a bit down 
  988.                 
  989.                 (map { $entry->$_() }                 qw[type linkname magic]),
  990.                 
  991.                 $entry->version || TAR_VERSION,
  992.                 
  993.                 (map { $entry->$_() }                 qw[uname gname]),
  994.                 (map { sprintf( $f1, $entry->$_() ) } qw[devmajor devminor]),
  995.                 
  996.                 ($no_prefix ? '' : $prefix)
  997.     );
  998.     
  999.     ### add the checksum ###
  1000.     substr($tar,148,7) = sprintf("%6o\0", unpack("%16C*",$tar));
  1001.  
  1002.     return $tar;
  1003. }           
  1004.  
  1005. =head2 $tar->add_files( @filenamelist )
  1006.  
  1007. Takes a list of filenames and adds them to the in-memory archive.  
  1008.  
  1009. The path to the file is automatically converted to a Unix like
  1010. equivalent for use in the archive, and, if on MacOS, the file's 
  1011. modification time is converted from the MacOS epoch to the Unix epoch.
  1012. So tar archives created on MacOS with B<Archive::Tar> can be read 
  1013. both with I<tar> on Unix and applications like I<suntar> or 
  1014. I<Stuffit Expander> on MacOS.
  1015.  
  1016. Be aware that the file's type/creator and resource fork will be lost,
  1017. which is usually what you want in cross-platform archives.
  1018.  
  1019. Returns a list of C<Archive::Tar::File> objects that were just added.
  1020.  
  1021. =cut
  1022.  
  1023. sub add_files {
  1024.     my $self    = shift;
  1025.     my @files   = @_ or return;
  1026.     
  1027.     my @rv;
  1028.     for my $file ( @files ) {
  1029.         unless( -e $file ) {
  1030.             $self->_error( qq[No such file: '$file'] );
  1031.             next;
  1032.         }
  1033.     
  1034.         my $obj = Archive::Tar::File->new( file => $file );
  1035.         unless( $obj ) {
  1036.             $self->_error( qq[Unable to add file: '$file'] );
  1037.             next;
  1038.         }      
  1039.  
  1040.         push @rv, $obj;
  1041.     }
  1042.     
  1043.     push @{$self->{_data}}, @rv;
  1044.     
  1045.     return @rv;
  1046. }
  1047.  
  1048. =head2 $tar->add_data ( $filename, $data, [$opthashref] )
  1049.  
  1050. Takes a filename, a scalar full of data and optionally a reference to
  1051. a hash with specific options. 
  1052.  
  1053. Will add a file to the in-memory archive, with name C<$filename> and 
  1054. content C<$data>. Specific properties can be set using C<$opthashref>.
  1055. The following list of properties is supported: name, size, mtime 
  1056. (last modified date), mode, uid, gid, linkname, uname, gname, 
  1057. devmajor, devminor, prefix.  (On MacOS, the file's path and 
  1058. modification times are converted to Unix equivalents.)
  1059.  
  1060. Returns the C<Archive::Tar::File> object that was just added, or
  1061. C<undef> on failure.
  1062.  
  1063. =cut
  1064.  
  1065. sub add_data {
  1066.     my $self    = shift;
  1067.     my ($file, $data, $opt) = @_; 
  1068.  
  1069.     my $obj = Archive::Tar::File->new( data => $file, $data, $opt );
  1070.     unless( $obj ) {
  1071.         $self->_error( qq[Unable to add file: '$file'] );
  1072.         return;
  1073.     }      
  1074.  
  1075.     push @{$self->{_data}}, $obj;
  1076.  
  1077.     return $obj;
  1078. }
  1079.  
  1080. =head2 $tar->error( [$BOOL] )
  1081.  
  1082. Returns the current errorstring (usually, the last error reported).
  1083. If a true value was specified, it will give the C<Carp::longmess> 
  1084. equivalent of the error, in effect giving you a stacktrace.
  1085.  
  1086. For backwards compatibility, this error is also available as 
  1087. C<$Archive::Tar::error> although it is much recommended you use the
  1088. method call instead.
  1089.  
  1090. =cut
  1091.  
  1092. {
  1093.     $error = '';
  1094.     my $longmess;
  1095.     
  1096.     sub _error {
  1097.         my $self    = shift;
  1098.         my $msg     = $error = shift;
  1099.         $longmess   = Carp::longmess($error);
  1100.         
  1101.         ### set Archive::Tar::WARN to 0 to disable printing
  1102.         ### of errors
  1103.         if( $WARN ) {
  1104.             carp $DEBUG ? $longmess : $msg;
  1105.         }
  1106.         
  1107.         return;
  1108.     }
  1109.     
  1110.     sub error {
  1111.         my $self = shift;
  1112.         return shift() ? $longmess : $error;          
  1113.     }
  1114. }         
  1115.  
  1116.  
  1117. =head1 Class Methods 
  1118.  
  1119. =head2 Archive::Tar->create_archive($file, $compression, @filelist)
  1120.  
  1121. Creates a tar file from the list of files provided.  The first
  1122. argument can either be the name of the tar file to create or a
  1123. reference to an open file handle (e.g. a GLOB reference).
  1124.  
  1125. The second argument specifies the level of compression to be used, if
  1126. any.  Compression of tar files requires the installation of the
  1127. IO::Zlib module.  Specific levels of compression may be
  1128. requested by passing a value between 2 and 9 as the second argument.
  1129. Any other value evaluating as true will result in the default
  1130. compression level being used.
  1131.  
  1132. Note that when you pass in a filehandle, the compression argument
  1133. is ignored, as all files are printed verbatim to your filehandle.
  1134. If you wish to enable compression with filehandles, use an
  1135. C<IO::Zlib> filehandle instead.
  1136.  
  1137. The remaining arguments list the files to be included in the tar file.
  1138. These files must all exist. Any files which don't exist or can't be
  1139. read are silently ignored.
  1140.  
  1141. If the archive creation fails for any reason, C<create_archive> will
  1142. return false. Please use the C<error> method to find the cause of the
  1143. failure.
  1144.  
  1145. Note that this method does not write C<on the fly> as it were; it
  1146. still reads all the files into memory before writing out the archive.
  1147. Consult the FAQ below if this is a problem.
  1148.  
  1149. =cut
  1150.  
  1151. sub create_archive {
  1152.     my $class = shift;
  1153.     
  1154.     my $file    = shift; return unless defined $file;
  1155.     my $gzip    = shift || 0;
  1156.     my @files   = @_;
  1157.     
  1158.     unless( @files ) {
  1159.         return $class->_error( qq[Cowardly refusing to create empty archive!] );
  1160.     }        
  1161.     
  1162.     my $tar = $class->new;
  1163.     $tar->add_files( @files );
  1164.     return $tar->write( $file, $gzip );    
  1165. }
  1166.  
  1167. =head2 Archive::Tar->list_archive ($file, $compressed, [\@properties])
  1168.  
  1169. Returns a list of the names of all the files in the archive.  The
  1170. first argument can either be the name of the tar file to list or a
  1171. reference to an open file handle (e.g. a GLOB reference).
  1172.  
  1173. If C<list_archive()> is passed an array reference as its third
  1174. argument it returns a list of hash references containing the requested
  1175. properties of each file.  The following list of properties is
  1176. supported: name, size, mtime (last modified date), mode, uid, gid,
  1177. linkname, uname, gname, devmajor, devminor, prefix.
  1178.  
  1179. Passing an array reference containing only one element, 'name', is
  1180. special cased to return a list of names rather than a list of hash
  1181. references.
  1182.  
  1183. =cut
  1184.  
  1185. sub list_archive {
  1186.     my $class   = shift;
  1187.     my $file    = shift; return unless defined $file;
  1188.     my $gzip    = shift || 0;
  1189.  
  1190.     my $tar = $class->new($file, $gzip);
  1191.     return unless $tar;
  1192.     
  1193.     return $tar->list_files( @_ ); 
  1194. }
  1195.  
  1196. =head2 Archive::Tar->extract_archive ($file, $gzip)
  1197.  
  1198. Extracts the contents of the tar file.  The first argument can either
  1199. be the name of the tar file to create or a reference to an open file
  1200. handle (e.g. a GLOB reference).  All relative paths in the tar file will
  1201. be created underneath the current working directory.
  1202.  
  1203. C<extract_archive> will return a list of files it extracted.
  1204. If the archive extraction fails for any reason, C<extract_archive>
  1205. will return false.  Please use the C<error> method to find the cause
  1206. of the failure.
  1207.  
  1208. =cut
  1209.  
  1210. sub extract_archive {
  1211.     my $class   = shift;
  1212.     my $file    = shift; return unless defined $file;
  1213.     my $gzip    = shift || 0;
  1214.     
  1215.     my $tar = $class->new( ) or return;
  1216.     
  1217.     return $tar->read( $file, $gzip, { extract => 1 } );
  1218. }
  1219.  
  1220. =head2 Archive::Tar->can_handle_compressed_files
  1221.  
  1222. A simple checking routine, which will return true if C<Archive::Tar> 
  1223. is able to uncompress compressed archives on the fly with C<IO::Zlib>,
  1224. or false if C<IO::Zlib> is not installed.
  1225.  
  1226. You can use this as a shortcut to determine whether C<Archive::Tar>
  1227. will do what you think before passing compressed archives to its
  1228. C<read> method.
  1229.  
  1230. =cut
  1231.  
  1232. sub can_handle_compressed_files { return ZLIB ? 1 : 0 }
  1233.  
  1234. 1;
  1235.  
  1236. __END__
  1237.  
  1238. =head1 GLOBAL VARIABLES
  1239.  
  1240. =head2 $Archive::Tar::FOLLOW_SYMLINK
  1241.  
  1242. Set this variable to C<1> to make C<Archive::Tar> effectively make a
  1243. copy of the file when extracting. Default is C<0>, which
  1244. means the symlink stays intact. Of course, you will have to pack the
  1245. file linked to as well.
  1246.  
  1247. This option is checked when you write out the tarfile using C<write> 
  1248. or C<create_archive>.
  1249.  
  1250. This works just like C</bin/tar>'s C<-h> option.
  1251.  
  1252. =head2 $Archive::Tar::CHOWN
  1253.  
  1254. By default, C<Archive::Tar> will try to C<chown> your files if it is
  1255. able to. In some cases, this may not be desired. In that case, set 
  1256. this variable to C<0> to disable C<chown>-ing, even if it were
  1257. possible.
  1258.  
  1259. The default is C<1>.
  1260.  
  1261. =head2 $Archive::Tar::CHMOD
  1262.  
  1263. By default, C<Archive::Tar> will try to C<chmod> your files to 
  1264. whatever mode was specified for the particular file in the archive. 
  1265. In some cases, this may not be desired. In that case, set this 
  1266. variable to C<0> to disable C<chmod>-ing.
  1267.  
  1268. The default is C<1>.
  1269.  
  1270. =head2 $Archive::Tar::DO_NOT_USE_PREFIX
  1271.  
  1272. By default, C<Archive::Tar> will try to put paths that are over
  1273. 100 characters in the C<prefix> field of your tar header. However,
  1274. some older tar programs do not implement this spec. To retain 
  1275. compatibility with these older versions, you can set the 
  1276. C<$DO_NOT_USE_PREFIX> variable to a true value, and C<Archive>>Tar>
  1277. will use an alternate way of dealing with paths over 100 characters
  1278. by using the C<GNU Extended Header> feature.
  1279.  
  1280. The default is C<0>.
  1281.  
  1282. =head2 $Archive::Tar::DEBUG
  1283.  
  1284. Set this variable to C<1> to always get the C<Carp::longmess> output
  1285. of the warnings, instead of the regular C<carp>. This is the same 
  1286. message you would get by doing: 
  1287.     
  1288.     $tar->error(1);
  1289.  
  1290. Defaults to C<0>.
  1291.  
  1292. =head2 $Archive::Tar::WARN
  1293.  
  1294. Set this variable to C<0> if you do not want any warnings printed.
  1295. Personally I recommend against doing this, but people asked for the
  1296. option. Also, be advised that this is of course not threadsafe.
  1297.  
  1298. Defaults to C<1>.
  1299.  
  1300. =head2 $Archive::Tar::error
  1301.  
  1302. Holds the last reported error. Kept for historical reasons, but its
  1303. use is very much discouraged. Use the C<error()> method instead:
  1304.  
  1305.     warn $tar->error unless $tar->extract;
  1306.  
  1307. =head1 FAQ
  1308.  
  1309. =over 4
  1310.  
  1311. =item What's the minimum perl version required to run Archive::Tar?
  1312.  
  1313. You will need perl version 5.005_03 or newer. 
  1314.  
  1315. =item Isn't Archive::Tar slow?
  1316.  
  1317. Yes it is. It's pure perl, so it's a lot slower then your C</bin/tar>
  1318. However, it's very portable. If speed is an issue, consider using
  1319. C</bin/tar> instead.
  1320.  
  1321. =item Isn't Archive::Tar heavier on memory than /bin/tar?
  1322.  
  1323. Yes it is, see previous answer. Since C<Compress::Zlib> and therefore
  1324. C<IO::Zlib> doesn't support C<seek> on their filehandles, there is little
  1325. choice but to read the archive into memory. 
  1326. This is ok if you want to do in-memory manipulation of the archive.
  1327. If you just want to extract, use the C<extract_archive> class method
  1328. instead. It will optimize and write to disk immediately.
  1329.  
  1330. =item Can't you lazy-load data instead?
  1331.  
  1332. No, not easily. See previous question.
  1333.  
  1334. =item How much memory will an X kb tar file need?
  1335.  
  1336. Probably more than X kb, since it will all be read into memory. If 
  1337. this is a problem, and you don't need to do in memory manipulation 
  1338. of the archive, consider using C</bin/tar> instead.
  1339.  
  1340. =item What do you do with unsupported filetypes in an archive?
  1341.  
  1342. C<Unix> has a few filetypes that aren't supported on other platforms, 
  1343. like C<Win32>. If we encounter a C<hardlink> or C<symlink> we'll just
  1344. try to make a copy of the original file, rather than throwing an error.
  1345.  
  1346. This does require you to read the entire archive in to memory first,
  1347. since otherwise we wouldn't know what data to fill the copy with.
  1348. (This means that you can not use the class methods on archives that 
  1349. have incompatible filetypes and still expect things to work).
  1350.  
  1351. For other filetypes, like C<chardevs> and C<blockdevs> we'll warn that
  1352. the extraction of this particular item didn't work.
  1353.  
  1354. =back
  1355.  
  1356. =head1 TODO
  1357.  
  1358. =over 4
  1359.  
  1360. =item Check if passed in handles are open for read/write
  1361.     
  1362. Currently I don't know of any portable pure perl way to do this.
  1363. Suggestions welcome.
  1364.  
  1365. =back
  1366.  
  1367. =head1 AUTHOR
  1368.  
  1369. This module by
  1370. Jos Boumans E<lt>kane@cpan.orgE<gt>.
  1371.  
  1372. =head1 ACKNOWLEDGEMENTS
  1373.  
  1374. Thanks to Sean Burke, Chris Nandor, Chip Salzenberg, Tim Heaney and
  1375. especially Andrew Savige for their help and suggestions.
  1376.  
  1377. =head1 COPYRIGHT
  1378.  
  1379. This module is
  1380. copyright (c) 2002 Jos Boumans E<lt>kane@cpan.orgE<gt>.
  1381. All rights reserved.
  1382.  
  1383. This library is free software;
  1384. you may redistribute and/or modify it under the same
  1385. terms as Perl itself.
  1386.  
  1387. =cut
  1388.