home *** CD-ROM | disk | FTP | other *** search
/ PC World 2005 June / PCWorld_2005-06_cd.bin / software / vyzkuste / firewally / firewally.exe / framework-2.3.exe / text.tcl < prev    next >
Text File  |  2003-09-01  |  31KB  |  1,137 lines
  1. # text.tcl --
  2. #
  3. # This file defines the default bindings for Tk text widgets and provides
  4. # procedures that help in implementing the bindings.
  5. #
  6. # RCS: @(#) $Id: text.tcl,v 1.24 2002/08/31 06:12:28 das Exp $
  7. #
  8. # Copyright (c) 1992-1994 The Regents of the University of California.
  9. # Copyright (c) 1994-1997 Sun Microsystems, Inc.
  10. # Copyright (c) 1998 by Scriptics Corporation.
  11. #
  12. # See the file "license.terms" for information on usage and redistribution
  13. # of this file, and for a DISCLAIMER OF ALL WARRANTIES.
  14. #
  15.  
  16. #-------------------------------------------------------------------------
  17. # Elements of ::tk::Priv that are used in this file:
  18. #
  19. # afterId -        If non-null, it means that auto-scanning is underway
  20. #            and it gives the "after" id for the next auto-scan
  21. #            command to be executed.
  22. # char -        Character position on the line;  kept in order
  23. #            to allow moving up or down past short lines while
  24. #            still remembering the desired position.
  25. # mouseMoved -        Non-zero means the mouse has moved a significant
  26. #            amount since the button went down (so, for example,
  27. #            start dragging out a selection).
  28. # prevPos -        Used when moving up or down lines via the keyboard.
  29. #            Keeps track of the previous insert position, so
  30. #            we can distinguish a series of ups and downs, all
  31. #            in a row, from a new up or down.
  32. # selectMode -        The style of selection currently underway:
  33. #            char, word, or line.
  34. # x, y -        Last known mouse coordinates for scanning
  35. #            and auto-scanning.
  36. #-------------------------------------------------------------------------
  37.  
  38. #-------------------------------------------------------------------------
  39. # The code below creates the default class bindings for text widgets.
  40. #-------------------------------------------------------------------------
  41.  
  42. # Standard Motif bindings:
  43.  
  44. bind Text <1> {
  45.     tk::TextButton1 %W %x %y
  46.     %W tag remove sel 0.0 end
  47. }
  48. bind Text <B1-Motion> {
  49.     set tk::Priv(x) %x
  50.     set tk::Priv(y) %y
  51.     tk::TextSelectTo %W %x %y
  52. }
  53. bind Text <Double-1> {
  54.     set tk::Priv(selectMode) word
  55.     tk::TextSelectTo %W %x %y
  56.     catch {%W mark set insert sel.last}
  57. }
  58. bind Text <Triple-1> {
  59.     set tk::Priv(selectMode) line
  60.     tk::TextSelectTo %W %x %y
  61.     catch {%W mark set insert sel.last}
  62. }
  63. bind Text <Shift-1> {
  64.     tk::TextResetAnchor %W @%x,%y
  65.     set tk::Priv(selectMode) char
  66.     tk::TextSelectTo %W %x %y
  67. }
  68. bind Text <Double-Shift-1>    {
  69.     set tk::Priv(selectMode) word
  70.     tk::TextSelectTo %W %x %y 1
  71. }
  72. bind Text <Triple-Shift-1>    {
  73.     set tk::Priv(selectMode) line
  74.     tk::TextSelectTo %W %x %y
  75. }
  76. bind Text <B1-Leave> {
  77.     set tk::Priv(x) %x
  78.     set tk::Priv(y) %y
  79.     tk::TextAutoScan %W
  80. }
  81. bind Text <B1-Enter> {
  82.     tk::CancelRepeat
  83. }
  84. bind Text <ButtonRelease-1> {
  85.     tk::CancelRepeat
  86. }
  87. bind Text <Control-1> {
  88.     %W mark set insert @%x,%y
  89. }
  90. bind Text <Left> {
  91.     tk::TextSetCursor %W insert-1c
  92. }
  93. bind Text <Right> {
  94.     tk::TextSetCursor %W insert+1c
  95. }
  96. bind Text <Up> {
  97.     tk::TextSetCursor %W [tk::TextUpDownLine %W -1]
  98. }
  99. bind Text <Down> {
  100.     tk::TextSetCursor %W [tk::TextUpDownLine %W 1]
  101. }
  102. bind Text <Shift-Left> {
  103.     tk::TextKeySelect %W [%W index {insert - 1c}]
  104. }
  105. bind Text <Shift-Right> {
  106.     tk::TextKeySelect %W [%W index {insert + 1c}]
  107. }
  108. bind Text <Shift-Up> {
  109.     tk::TextKeySelect %W [tk::TextUpDownLine %W -1]
  110. }
  111. bind Text <Shift-Down> {
  112.     tk::TextKeySelect %W [tk::TextUpDownLine %W 1]
  113. }
  114. bind Text <Control-Left> {
  115.     tk::TextSetCursor %W [tk::TextPrevPos %W insert tcl_startOfPreviousWord]
  116. }
  117. bind Text <Control-Right> {
  118.     tk::TextSetCursor %W [tk::TextNextWord %W insert]
  119. }
  120. bind Text <Control-Up> {
  121.     tk::TextSetCursor %W [tk::TextPrevPara %W insert]
  122. }
  123. bind Text <Control-Down> {
  124.     tk::TextSetCursor %W [tk::TextNextPara %W insert]
  125. }
  126. bind Text <Shift-Control-Left> {
  127.     tk::TextKeySelect %W [tk::TextPrevPos %W insert tcl_startOfPreviousWord]
  128. }
  129. bind Text <Shift-Control-Right> {
  130.     tk::TextKeySelect %W [tk::TextNextWord %W insert]
  131. }
  132. bind Text <Shift-Control-Up> {
  133.     tk::TextKeySelect %W [tk::TextPrevPara %W insert]
  134. }
  135. bind Text <Shift-Control-Down> {
  136.     tk::TextKeySelect %W [tk::TextNextPara %W insert]
  137. }
  138. bind Text <Prior> {
  139.     tk::TextSetCursor %W [tk::TextScrollPages %W -1]
  140. }
  141. bind Text <Shift-Prior> {
  142.     tk::TextKeySelect %W [tk::TextScrollPages %W -1]
  143. }
  144. bind Text <Next> {
  145.     tk::TextSetCursor %W [tk::TextScrollPages %W 1]
  146. }
  147. bind Text <Shift-Next> {
  148.     tk::TextKeySelect %W [tk::TextScrollPages %W 1]
  149. }
  150. bind Text <Control-Prior> {
  151.     %W xview scroll -1 page
  152. }
  153. bind Text <Control-Next> {
  154.     %W xview scroll 1 page
  155. }
  156.  
  157. bind Text <Home> {
  158.     tk::TextSetCursor %W {insert linestart}
  159. }
  160. bind Text <Shift-Home> {
  161.     tk::TextKeySelect %W {insert linestart}
  162. }
  163. bind Text <End> {
  164.     tk::TextSetCursor %W {insert lineend}
  165. }
  166. bind Text <Shift-End> {
  167.     tk::TextKeySelect %W {insert lineend}
  168. }
  169. bind Text <Control-Home> {
  170.     tk::TextSetCursor %W 1.0
  171. }
  172. bind Text <Control-Shift-Home> {
  173.     tk::TextKeySelect %W 1.0
  174. }
  175. bind Text <Control-End> {
  176.     tk::TextSetCursor %W {end - 1 char}
  177. }
  178. bind Text <Control-Shift-End> {
  179.     tk::TextKeySelect %W {end - 1 char}
  180. }
  181.  
  182. bind Text <Tab> {
  183.     if { [string equal [%W cget -state] "normal"] } {
  184.     tk::TextInsert %W \t
  185.     focus %W
  186.     break
  187.     }
  188. }
  189. bind Text <Shift-Tab> {
  190.     # Needed only to keep <Tab> binding from triggering;  doesn't
  191.     # have to actually do anything.
  192.     break
  193. }
  194. bind Text <Control-Tab> {
  195.     focus [tk_focusNext %W]
  196. }
  197. bind Text <Control-Shift-Tab> {
  198.     focus [tk_focusPrev %W]
  199. }
  200. bind Text <Control-i> {
  201.     tk::TextInsert %W \t
  202. }
  203. bind Text <Return> {
  204.     tk::TextInsert %W \n
  205.     if {[%W cget -autoseparators]} {%W edit separator}
  206. }
  207. bind Text <Delete> {
  208.     if {[string compare [%W tag nextrange sel 1.0 end] ""]} {
  209.     %W delete sel.first sel.last
  210.     } else {
  211.     %W delete insert
  212.     %W see insert
  213.     }
  214. }
  215. bind Text <BackSpace> {
  216.     if {[string compare [%W tag nextrange sel 1.0 end] ""]} {
  217.     %W delete sel.first sel.last
  218.     } elseif {[%W compare insert != 1.0]} {
  219.     %W delete insert-1c
  220.     %W see insert
  221.     }
  222. }
  223.  
  224. bind Text <Control-space> {
  225.     %W mark set anchor insert
  226. }
  227. bind Text <Select> {
  228.     %W mark set anchor insert
  229. }
  230. bind Text <Control-Shift-space> {
  231.     set tk::Priv(selectMode) char
  232.     tk::TextKeyExtend %W insert
  233. }
  234. bind Text <Shift-Select> {
  235.     set tk::Priv(selectMode) char
  236.     tk::TextKeyExtend %W insert
  237. }
  238. bind Text <Control-slash> {
  239.     %W tag add sel 1.0 end
  240. }
  241. bind Text <Control-backslash> {
  242.     %W tag remove sel 1.0 end
  243. }
  244. bind Text <<Cut>> {
  245.     tk_textCut %W
  246. }
  247. bind Text <<Copy>> {
  248.     tk_textCopy %W
  249. }
  250. bind Text <<Paste>> {
  251.     tk_textPaste %W
  252. }
  253. bind Text <<Clear>> {
  254.     catch {%W delete sel.first sel.last}
  255. }
  256. bind Text <<PasteSelection>> {
  257.     if {$tk_strictMotif || ![info exists tk::Priv(mouseMoved)]
  258.     || !$tk::Priv(mouseMoved)} {
  259.     tk::TextPasteSelection %W %x %y
  260.     }
  261. }
  262. bind Text <Insert> {
  263.     catch {tk::TextInsert %W [::tk::GetSelection %W PRIMARY]}
  264. }
  265. bind Text <KeyPress> {
  266.     tk::TextInsert %W %A
  267. }
  268.  
  269. # Ignore all Alt, Meta, and Control keypresses unless explicitly bound.
  270. # Otherwise, if a widget binding for one of these is defined, the
  271. # <KeyPress> class binding will also fire and insert the character,
  272. # which is wrong.  Ditto for <Escape>.
  273.  
  274. bind Text <Alt-KeyPress> {# nothing }
  275. bind Text <Meta-KeyPress> {# nothing}
  276. bind Text <Control-KeyPress> {# nothing}
  277. bind Text <Escape> {# nothing}
  278. bind Text <KP_Enter> {# nothing}
  279. if {[string equal [tk windowingsystem] "classic"]
  280.     || [string equal [tk windowingsystem] "aqua"]} {
  281.     bind Text <Command-KeyPress> {# nothing}
  282. }
  283.  
  284. # Additional emacs-like bindings:
  285.  
  286. bind Text <Control-a> {
  287.     if {!$tk_strictMotif} {
  288.     tk::TextSetCursor %W {insert linestart}
  289.     }
  290. }
  291. bind Text <Control-b> {
  292.     if {!$tk_strictMotif} {
  293.     tk::TextSetCursor %W insert-1c
  294.     }
  295. }
  296. bind Text <Control-d> {
  297.     if {!$tk_strictMotif} {
  298.     %W delete insert
  299.     }
  300. }
  301. bind Text <Control-e> {
  302.     if {!$tk_strictMotif} {
  303.     tk::TextSetCursor %W {insert lineend}
  304.     }
  305. }
  306. bind Text <Control-f> {
  307.     if {!$tk_strictMotif} {
  308.     tk::TextSetCursor %W insert+1c
  309.     }
  310. }
  311. bind Text <Control-k> {
  312.     if {!$tk_strictMotif} {
  313.     if {[%W compare insert == {insert lineend}]} {
  314.         %W delete insert
  315.     } else {
  316.         %W delete insert {insert lineend}
  317.     }
  318.     }
  319. }
  320. bind Text <Control-n> {
  321.     if {!$tk_strictMotif} {
  322.     tk::TextSetCursor %W [tk::TextUpDownLine %W 1]
  323.     }
  324. }
  325. bind Text <Control-o> {
  326.     if {!$tk_strictMotif} {
  327.     %W insert insert \n
  328.     %W mark set insert insert-1c
  329.     }
  330. }
  331. bind Text <Control-p> {
  332.     if {!$tk_strictMotif} {
  333.     tk::TextSetCursor %W [tk::TextUpDownLine %W -1]
  334.     }
  335. }
  336. bind Text <Control-t> {
  337.     if {!$tk_strictMotif} {
  338.     tk::TextTranspose %W
  339.     }
  340. }
  341.  
  342. bind Text <<Undo>> {
  343.     catch { %W edit undo }
  344. }
  345.  
  346. bind Text <<Redo>> {
  347.     catch { %W edit redo }
  348. }
  349.  
  350. if {[string compare $tcl_platform(platform) "windows"]} {
  351. bind Text <Control-v> {
  352.     if {!$tk_strictMotif} {
  353.     tk::TextScrollPages %W 1
  354.     }
  355. }
  356. }
  357.  
  358. bind Text <Meta-b> {
  359.     if {!$tk_strictMotif} {
  360.     tk::TextSetCursor %W [tk::TextPrevPos %W insert tcl_startOfPreviousWord]
  361.     }
  362. }
  363. bind Text <Meta-d> {
  364.     if {!$tk_strictMotif} {
  365.     %W delete insert [tk::TextNextWord %W insert]
  366.     }
  367. }
  368. bind Text <Meta-f> {
  369.     if {!$tk_strictMotif} {
  370.     tk::TextSetCursor %W [tk::TextNextWord %W insert]
  371.     }
  372. }
  373. bind Text <Meta-less> {
  374.     if {!$tk_strictMotif} {
  375.     tk::TextSetCursor %W 1.0
  376.     }
  377. }
  378. bind Text <Meta-greater> {
  379.     if {!$tk_strictMotif} {
  380.     tk::TextSetCursor %W end-1c
  381.     }
  382. }
  383. bind Text <Meta-BackSpace> {
  384.     if {!$tk_strictMotif} {
  385.     %W delete [tk::TextPrevPos %W insert tcl_startOfPreviousWord] insert
  386.     }
  387. }
  388. bind Text <Meta-Delete> {
  389.     if {!$tk_strictMotif} {
  390.     %W delete [tk::TextPrevPos %W insert tcl_startOfPreviousWord] insert
  391.     }
  392. }
  393.  
  394. # Macintosh only bindings:
  395.  
  396. # if text black & highlight black -> text white, other text the same
  397. if {[string equal [tk windowingsystem] "classic"]
  398.     || [string equal [tk windowingsystem] "aqua"]} {
  399. bind Text <FocusIn> {
  400.     %W tag configure sel -borderwidth 0
  401.     %W configure -selectbackground systemHighlight -selectforeground systemHighlightText
  402. }
  403. bind Text <FocusOut> {
  404.     %W tag configure sel -borderwidth 1
  405.     %W configure -selectbackground white -selectforeground black
  406. }
  407. bind Text <Option-Left> {
  408.     tk::TextSetCursor %W [tk::TextPrevPos %W insert tcl_startOfPreviousWord]
  409. }
  410. bind Text <Option-Right> {
  411.     tk::TextSetCursor %W [tk::TextNextWord %W insert]
  412. }
  413. bind Text <Option-Up> {
  414.     tk::TextSetCursor %W [tk::TextPrevPara %W insert]
  415. }
  416. bind Text <Option-Down> {
  417.     tk::TextSetCursor %W [tk::TextNextPara %W insert]
  418. }
  419. bind Text <Shift-Option-Left> {
  420.     tk::TextKeySelect %W [tk::TextPrevPos %W insert tcl_startOfPreviousWord]
  421. }
  422. bind Text <Shift-Option-Right> {
  423.     tk::TextKeySelect %W [tk::TextNextWord %W insert]
  424. }
  425. bind Text <Shift-Option-Up> {
  426.     tk::TextKeySelect %W [tk::TextPrevPara %W insert]
  427. }
  428. bind Text <Shift-Option-Down> {
  429.     tk::TextKeySelect %W [tk::TextNextPara %W insert]
  430. }
  431.  
  432. # End of Mac only bindings
  433. }
  434.  
  435. # A few additional bindings of my own.
  436.  
  437. bind Text <Control-h> {
  438.     if {!$tk_strictMotif} {
  439.     if {[%W compare insert != 1.0]} {
  440.         %W delete insert-1c
  441.         %W see insert
  442.     }
  443.     }
  444. }
  445. bind Text <2> {
  446.     if {!$tk_strictMotif} {
  447.     tk::TextScanMark %W %x %y
  448.     }
  449. }
  450. bind Text <B2-Motion> {
  451.     if {!$tk_strictMotif} {
  452.     tk::TextScanDrag %W %x %y
  453.     }
  454. }
  455. set ::tk::Priv(prevPos) {}
  456.  
  457. # The MouseWheel will typically only fire on Windows.  However,
  458. # someone could use the "event generate" command to produce one
  459. # on other platforms.
  460.  
  461. bind Text <MouseWheel> {
  462.     %W yview scroll [expr {- (%D / 120) * 4}] units
  463. }
  464.  
  465. if {[string equal "x11" [tk windowingsystem]]} {
  466.     # Support for mousewheels on Linux/Unix commonly comes through mapping
  467.     # the wheel to the extended buttons.  If you have a mousewheel, find
  468.     # Linux configuration info at:
  469.     #    http://www.inria.fr/koala/colas/mouse-wheel-scroll/
  470.     bind Text <4> {
  471.     if {!$tk_strictMotif} {
  472.         %W yview scroll -5 units
  473.     }
  474.     }
  475.     bind Text <5> {
  476.     if {!$tk_strictMotif} {
  477.         %W yview scroll 5 units
  478.     }
  479.     }
  480. }
  481.  
  482. # ::tk::TextClosestGap --
  483. # Given x and y coordinates, this procedure finds the closest boundary
  484. # between characters to the given coordinates and returns the index
  485. # of the character just after the boundary.
  486. #
  487. # Arguments:
  488. # w -        The text window.
  489. # x -        X-coordinate within the window.
  490. # y -        Y-coordinate within the window.
  491.  
  492. proc ::tk::TextClosestGap {w x y} {
  493.     set pos [$w index @$x,$y]
  494.     set bbox [$w bbox $pos]
  495.     if {[string equal $bbox ""]} {
  496.     return $pos
  497.     }
  498.     if {($x - [lindex $bbox 0]) < ([lindex $bbox 2]/2)} {
  499.     return $pos
  500.     }
  501.     $w index "$pos + 1 char"
  502. }
  503.  
  504. # ::tk::TextButton1 --
  505. # This procedure is invoked to handle button-1 presses in text
  506. # widgets.  It moves the insertion cursor, sets the selection anchor,
  507. # and claims the input focus.
  508. #
  509. # Arguments:
  510. # w -        The text window in which the button was pressed.
  511. # x -        The x-coordinate of the button press.
  512. # y -        The x-coordinate of the button press.
  513.  
  514. proc ::tk::TextButton1 {w x y} {
  515.     variable ::tk::Priv
  516.  
  517.     set Priv(selectMode) char
  518.     set Priv(mouseMoved) 0
  519.     set Priv(pressX) $x
  520.     $w mark set insert [TextClosestGap $w $x $y]
  521.     $w mark set anchor insert
  522.     # Allow focus in any case on Windows, because that will let the
  523.     # selection be displayed even for state disabled text widgets.
  524.     if {[string equal $::tcl_platform(platform) "windows"] \
  525.         || [string equal [$w cget -state] "normal"]} {focus $w}
  526.     if {[$w cget -autoseparators]} {$w edit separator}
  527. }
  528.  
  529. # ::tk::TextSelectTo --
  530. # This procedure is invoked to extend the selection, typically when
  531. # dragging it with the mouse.  Depending on the selection mode (character,
  532. # word, line) it selects in different-sized units.  This procedure
  533. # ignores mouse motions initially until the mouse has moved from
  534. # one character to another or until there have been multiple clicks.
  535. #
  536. # Arguments:
  537. # w -        The text window in which the button was pressed.
  538. # x -        Mouse x position.
  539. # y -         Mouse y position.
  540.  
  541. proc ::tk::TextSelectTo {w x y {extend 0}} {
  542.     global tcl_platform
  543.     variable ::tk::Priv
  544.  
  545.     set cur [TextClosestGap $w $x $y]
  546.     if {[catch {$w index anchor}]} {
  547.     $w mark set anchor $cur
  548.     }
  549.     set anchor [$w index anchor]
  550.     if {[$w compare $cur != $anchor] || (abs($Priv(pressX) - $x) >= 3)} {
  551.     set Priv(mouseMoved) 1
  552.     }
  553.     switch $Priv(selectMode) {
  554.     char {
  555.         if {[$w compare $cur < anchor]} {
  556.         set first $cur
  557.         set last anchor
  558.         } else {
  559.         set first anchor
  560.         set last $cur
  561.         }
  562.     }
  563.     word {
  564.         if {[$w compare $cur < anchor]} {
  565.         set first [TextPrevPos $w "$cur + 1c" tcl_wordBreakBefore]
  566.         if { !$extend } {
  567.             set last [TextNextPos $w "anchor" tcl_wordBreakAfter]
  568.         } else {
  569.             set last anchor
  570.         }
  571.         } else {
  572.         set last [TextNextPos $w "$cur - 1c" tcl_wordBreakAfter]
  573.         if { !$extend } {
  574.             set first [TextPrevPos $w anchor tcl_wordBreakBefore]
  575.         } else {
  576.             set first anchor
  577.         }
  578.         }
  579.     }
  580.     line {
  581.         if {[$w compare $cur < anchor]} {
  582.         set first [$w index "$cur linestart"]
  583.         set last [$w index "anchor - 1c lineend + 1c"]
  584.         } else {
  585.         set first [$w index "anchor linestart"]
  586.         set last [$w index "$cur lineend + 1c"]
  587.         }
  588.     }
  589.     }
  590.     if {$Priv(mouseMoved) || [string compare $Priv(selectMode) "char"]} {
  591.     $w tag remove sel 0.0 end
  592.     $w mark set insert $cur
  593.     $w tag add sel $first $last
  594.     $w tag remove sel $last end
  595.     update idletasks
  596.     }
  597. }
  598.  
  599. # ::tk::TextKeyExtend --
  600. # This procedure handles extending the selection from the keyboard,
  601. # where the point to extend to is really the boundary between two
  602. # characters rather than a particular character.
  603. #
  604. # Arguments:
  605. # w -        The text window.
  606. # index -    The point to which the selection is to be extended.
  607.  
  608. proc ::tk::TextKeyExtend {w index} {
  609.  
  610.     set cur [$w index $index]
  611.     if {[catch {$w index anchor}]} {
  612.     $w mark set anchor $cur
  613.     }
  614.     set anchor [$w index anchor]
  615.     if {[$w compare $cur < anchor]} {
  616.     set first $cur
  617.     set last anchor
  618.     } else {
  619.     set first anchor
  620.     set last $cur
  621.     }
  622.     $w tag remove sel 0.0 $first
  623.     $w tag add sel $first $last
  624.     $w tag remove sel $last end
  625. }
  626.  
  627. # ::tk::TextPasteSelection --
  628. # This procedure sets the insertion cursor to the mouse position,
  629. # inserts the selection, and sets the focus to the window.
  630. #
  631. # Arguments:
  632. # w -        The text window.
  633. # x, y -     Position of the mouse.
  634.  
  635. proc ::tk::TextPasteSelection {w x y} {
  636.     $w mark set insert [TextClosestGap $w $x $y]
  637.     if {![catch {::tk::GetSelection $w PRIMARY} sel]} {
  638.     set oldSeparator [$w cget -autoseparators]
  639.     if {$oldSeparator} {
  640.         $w configure -autoseparators 0
  641.         $w edit separator
  642.     }
  643.     $w insert insert $sel
  644.     if {$oldSeparator} {
  645.         $w edit separator
  646.         $w configure -autoseparators 1
  647.     }
  648.     }
  649.     if {[string equal [$w cget -state] "normal"]} {focus $w}
  650. }
  651.  
  652. # ::tk::TextAutoScan --
  653. # This procedure is invoked when the mouse leaves a text window
  654. # with button 1 down.  It scrolls the window up, down, left, or right,
  655. # depending on where the mouse is (this information was saved in
  656. # ::tk::Priv(x) and ::tk::Priv(y)), and reschedules itself as an "after"
  657. # command so that the window continues to scroll until the mouse
  658. # moves back into the window or the mouse button is released.
  659. #
  660. # Arguments:
  661. # w -        The text window.
  662.  
  663. proc ::tk::TextAutoScan {w} {
  664.     variable ::tk::Priv
  665.     if {![winfo exists $w]} return
  666.     if {$Priv(y) >= [winfo height $w]} {
  667.     $w yview scroll 2 units
  668.     } elseif {$Priv(y) < 0} {
  669.     $w yview scroll -2 units
  670.     } elseif {$Priv(x) >= [winfo width $w]} {
  671.     $w xview scroll 2 units
  672.     } elseif {$Priv(x) < 0} {
  673.     $w xview scroll -2 units
  674.     } else {
  675.     return
  676.     }
  677.     TextSelectTo $w $Priv(x) $Priv(y)
  678.     set Priv(afterId) [after 50 [list tk::TextAutoScan $w]]
  679. }
  680.  
  681. # ::tk::TextSetCursor
  682. # Move the insertion cursor to a given position in a text.  Also
  683. # clears the selection, if there is one in the text, and makes sure
  684. # that the insertion cursor is visible.  Also, don't let the insertion
  685. # cursor appear on the dummy last line of the text.
  686. #
  687. # Arguments:
  688. # w -        The text window.
  689. # pos -        The desired new position for the cursor in the window.
  690.  
  691. proc ::tk::TextSetCursor {w pos} {
  692.  
  693.     if {[$w compare $pos == end]} {
  694.     set pos {end - 1 chars}
  695.     }
  696.     $w mark set insert $pos
  697.     $w tag remove sel 1.0 end
  698.     $w see insert
  699.     if {[$w cget -autoseparators]} {$w edit separator}
  700. }
  701.  
  702. # ::tk::TextKeySelect
  703. # This procedure is invoked when stroking out selections using the
  704. # keyboard.  It moves the cursor to a new position, then extends
  705. # the selection to that position.
  706. #
  707. # Arguments:
  708. # w -        The text window.
  709. # new -        A new position for the insertion cursor (the cursor hasn't
  710. #        actually been moved to this position yet).
  711.  
  712. proc ::tk::TextKeySelect {w new} {
  713.  
  714.     if {[string equal [$w tag nextrange sel 1.0 end] ""]} {
  715.     if {[$w compare $new < insert]} {
  716.         $w tag add sel $new insert
  717.     } else {
  718.         $w tag add sel insert $new
  719.     }
  720.     $w mark set anchor insert
  721.     } else {
  722.     if {[$w compare $new < anchor]} {
  723.         set first $new
  724.         set last anchor
  725.     } else {
  726.         set first anchor
  727.         set last $new
  728.     }
  729.     $w tag remove sel 1.0 $first
  730.     $w tag add sel $first $last
  731.     $w tag remove sel $last end
  732.     }
  733.     $w mark set insert $new
  734.     $w see insert
  735.     update idletasks
  736. }
  737.  
  738. # ::tk::TextResetAnchor --
  739. # Set the selection anchor to whichever end is farthest from the
  740. # index argument.  One special trick: if the selection has two or
  741. # fewer characters, just leave the anchor where it is.  In this
  742. # case it doesn't matter which point gets chosen for the anchor,
  743. # and for the things like Shift-Left and Shift-Right this produces
  744. # better behavior when the cursor moves back and forth across the
  745. # anchor.
  746. #
  747. # Arguments:
  748. # w -        The text widget.
  749. # index -    Position at which mouse button was pressed, which determines
  750. #        which end of selection should be used as anchor point.
  751.  
  752. proc ::tk::TextResetAnchor {w index} {
  753.  
  754.     if {[string equal [$w tag ranges sel] ""]} {
  755.     # Don't move the anchor if there is no selection now; this makes
  756.     # the widget behave "correctly" when the user clicks once, then
  757.     # shift-clicks somewhere -- ie, the area between the two clicks will be
  758.     # selected. [Bug: 5929].
  759.     return
  760.     }
  761.     set a [$w index $index]
  762.     set b [$w index sel.first]
  763.     set c [$w index sel.last]
  764.     if {[$w compare $a < $b]} {
  765.     $w mark set anchor sel.last
  766.     return
  767.     }
  768.     if {[$w compare $a > $c]} {
  769.     $w mark set anchor sel.first
  770.     return
  771.     }
  772.     scan $a "%d.%d" lineA chA
  773.     scan $b "%d.%d" lineB chB
  774.     scan $c "%d.%d" lineC chC
  775.     if {$lineB < $lineC+2} {
  776.     set total [string length [$w get $b $c]]
  777.     if {$total <= 2} {
  778.         return
  779.     }
  780.     if {[string length [$w get $b $a]] < ($total/2)} {
  781.         $w mark set anchor sel.last
  782.     } else {
  783.         $w mark set anchor sel.first
  784.     }
  785.     return
  786.     }
  787.     if {($lineA-$lineB) < ($lineC-$lineA)} {
  788.     $w mark set anchor sel.last
  789.     } else {
  790.     $w mark set anchor sel.first
  791.     }
  792. }
  793.  
  794. # ::tk::TextInsert --
  795. # Insert a string into a text at the point of the insertion cursor.
  796. # If there is a selection in the text, and it covers the point of the
  797. # insertion cursor, then delete the selection before inserting.
  798. #
  799. # Arguments:
  800. # w -        The text window in which to insert the string
  801. # s -        The string to insert (usually just a single character)
  802.  
  803. proc ::tk::TextInsert {w s} {
  804.     if {[string equal $s ""] || [string equal [$w cget -state] "disabled"]} {
  805.     return
  806.     }
  807.     set compound 0
  808.     catch {
  809.     if {[$w compare sel.first <= insert] \
  810.         && [$w compare sel.last >= insert]} {
  811.             set oldSeparator [$w cget -autoseparators]
  812.             if { $oldSeparator } {
  813.                 $w configure -autoseparators 0
  814.                 $w edit separator
  815.                 set compound 1
  816.             }
  817.         $w delete sel.first sel.last
  818.     }
  819.     }
  820.     $w insert insert $s
  821.     $w see insert
  822.     if { $compound && $oldSeparator } {
  823.         $w edit separator
  824.         $w configure -autoseparators 1
  825.     }
  826. }
  827.  
  828. # ::tk::TextUpDownLine --
  829. # Returns the index of the character one line above or below the
  830. # insertion cursor.  There are two tricky things here.  First,
  831. # we want to maintain the original column across repeated operations,
  832. # even though some lines that will get passed through don't have
  833. # enough characters to cover the original column.  Second, don't
  834. # try to scroll past the beginning or end of the text.
  835. #
  836. # Arguments:
  837. # w -        The text window in which the cursor is to move.
  838. # n -        The number of lines to move: -1 for up one line,
  839. #        +1 for down one line.
  840.  
  841. proc ::tk::TextUpDownLine {w n} {
  842.     variable ::tk::Priv
  843.  
  844.     set i [$w index insert]
  845.     scan $i "%d.%d" line char
  846.     if {[string compare $Priv(prevPos) $i]} {
  847.     set Priv(char) $char
  848.     }
  849.     set new [$w index [expr {$line + $n}].$Priv(char)]
  850.     if {[$w compare $new == end] || [$w compare $new == "insert linestart"]} {
  851.     set new $i
  852.     }
  853.     set Priv(prevPos) $new
  854.     return $new
  855. }
  856.  
  857. # ::tk::TextPrevPara --
  858. # Returns the index of the beginning of the paragraph just before a given
  859. # position in the text (the beginning of a paragraph is the first non-blank
  860. # character after a blank line).
  861. #
  862. # Arguments:
  863. # w -        The text window in which the cursor is to move.
  864. # pos -        Position at which to start search.
  865.  
  866. proc ::tk::TextPrevPara {w pos} {
  867.     set pos [$w index "$pos linestart"]
  868.     while {1} {
  869.     if {([string equal [$w get "$pos - 1 line"] "\n"] \
  870.         && [string compare [$w get $pos] "\n"]) \
  871.         || [string equal $pos "1.0"]} {
  872.         if {[regexp -indices {^[     ]+(.)} [$w get $pos "$pos lineend"] \
  873.             dummy index]} {
  874.         set pos [$w index "$pos + [lindex $index 0] chars"]
  875.         }
  876.         if {[$w compare $pos != insert] || [string equal $pos 1.0]} {
  877.         return $pos
  878.         }
  879.     }
  880.     set pos [$w index "$pos - 1 line"]
  881.     }
  882. }
  883.  
  884. # ::tk::TextNextPara --
  885. # Returns the index of the beginning of the paragraph just after a given
  886. # position in the text (the beginning of a paragraph is the first non-blank
  887. # character after a blank line).
  888. #
  889. # Arguments:
  890. # w -        The text window in which the cursor is to move.
  891. # start -    Position at which to start search.
  892.  
  893. proc ::tk::TextNextPara {w start} {
  894.     set pos [$w index "$start linestart + 1 line"]
  895.     while {[string compare [$w get $pos] "\n"]} {
  896.     if {[$w compare $pos == end]} {
  897.         return [$w index "end - 1c"]
  898.     }
  899.     set pos [$w index "$pos + 1 line"]
  900.     }
  901.     while {[string equal [$w get $pos] "\n"]} {
  902.     set pos [$w index "$pos + 1 line"]
  903.     if {[$w compare $pos == end]} {
  904.         return [$w index "end - 1c"]
  905.     }
  906.     }
  907.     if {[regexp -indices {^[     ]+(.)} [$w get $pos "$pos lineend"] \
  908.         dummy index]} {
  909.     return [$w index "$pos + [lindex $index 0] chars"]
  910.     }
  911.     return $pos
  912. }
  913.  
  914. # ::tk::TextScrollPages --
  915. # This is a utility procedure used in bindings for moving up and down
  916. # pages and possibly extending the selection along the way.  It scrolls
  917. # the view in the widget by the number of pages, and it returns the
  918. # index of the character that is at the same position in the new view
  919. # as the insertion cursor used to be in the old view.
  920. #
  921. # Arguments:
  922. # w -        The text window in which the cursor is to move.
  923. # count -    Number of pages forward to scroll;  may be negative
  924. #        to scroll backwards.
  925.  
  926. proc ::tk::TextScrollPages {w count} {
  927.     set bbox [$w bbox insert]
  928.     $w yview scroll $count pages
  929.     if {[string equal $bbox ""]} {
  930.     return [$w index @[expr {[winfo height $w]/2}],0]
  931.     }
  932.     return [$w index @[lindex $bbox 0],[lindex $bbox 1]]
  933. }
  934.  
  935. # ::tk::TextTranspose --
  936. # This procedure implements the "transpose" function for text widgets.
  937. # It tranposes the characters on either side of the insertion cursor,
  938. # unless the cursor is at the end of the line.  In this case it
  939. # transposes the two characters to the left of the cursor.  In either
  940. # case, the cursor ends up to the right of the transposed characters.
  941. #
  942. # Arguments:
  943. # w -        Text window in which to transpose.
  944.  
  945. proc ::tk::TextTranspose w {
  946.     set pos insert
  947.     if {[$w compare $pos != "$pos lineend"]} {
  948.     set pos [$w index "$pos + 1 char"]
  949.     }
  950.     set new [$w get "$pos - 1 char"][$w get  "$pos - 2 char"]
  951.     if {[$w compare "$pos - 1 char" == 1.0]} {
  952.     return
  953.     }
  954.     $w delete "$pos - 2 char" $pos
  955.     $w insert insert $new
  956.     $w see insert
  957. }
  958.  
  959. # ::tk_textCopy --
  960. # This procedure copies the selection from a text widget into the
  961. # clipboard.
  962. #
  963. # Arguments:
  964. # w -        Name of a text widget.
  965.  
  966. proc ::tk_textCopy w {
  967.     if {![catch {set data [$w get sel.first sel.last]}]} {
  968.     clipboard clear -displayof $w
  969.     clipboard append -displayof $w $data
  970.     }
  971. }
  972.  
  973. # ::tk_textCut --
  974. # This procedure copies the selection from a text widget into the
  975. # clipboard, then deletes the selection (if it exists in the given
  976. # widget).
  977. #
  978. # Arguments:
  979. # w -        Name of a text widget.
  980.  
  981. proc ::tk_textCut w {
  982.     if {![catch {set data [$w get sel.first sel.last]}]} {
  983.     clipboard clear -displayof $w
  984.     clipboard append -displayof $w $data
  985.     $w delete sel.first sel.last
  986.     }
  987. }
  988.  
  989. # ::tk_textPaste --
  990. # This procedure pastes the contents of the clipboard to the insertion
  991. # point in a text widget.
  992. #
  993. # Arguments:
  994. # w -        Name of a text widget.
  995.  
  996. proc ::tk_textPaste w {
  997.     global tcl_platform
  998.     if {![catch {::tk::GetSelection $w CLIPBOARD} sel]} {
  999.     set oldSeparator [$w cget -autoseparators]
  1000.     if { $oldSeparator } {
  1001.         $w configure -autoseparators 0
  1002.         $w edit separator
  1003.     }
  1004.     if {[string compare [tk windowingsystem] "x11"]} {
  1005.         catch { $w delete sel.first sel.last }
  1006.     }
  1007.     $w insert insert $sel
  1008.     if { $oldSeparator } {
  1009.         $w edit separator
  1010.         $w configure -autoseparators 1
  1011.     }
  1012.     }
  1013. }
  1014.  
  1015. # ::tk::TextNextWord --
  1016. # Returns the index of the next word position after a given position in the
  1017. # text.  The next word is platform dependent and may be either the next
  1018. # end-of-word position or the next start-of-word position after the next
  1019. # end-of-word position.
  1020. #
  1021. # Arguments:
  1022. # w -        The text window in which the cursor is to move.
  1023. # start -    Position at which to start search.
  1024.  
  1025. if {[string equal $tcl_platform(platform) "windows"]}  {
  1026.     proc ::tk::TextNextWord {w start} {
  1027.     TextNextPos $w [TextNextPos $w $start tcl_endOfWord] \
  1028.         tcl_startOfNextWord
  1029.     }
  1030. } else {
  1031.     proc ::tk::TextNextWord {w start} {
  1032.     TextNextPos $w $start tcl_endOfWord
  1033.     }
  1034. }
  1035.  
  1036. # ::tk::TextNextPos --
  1037. # Returns the index of the next position after the given starting
  1038. # position in the text as computed by a specified function.
  1039. #
  1040. # Arguments:
  1041. # w -        The text window in which the cursor is to move.
  1042. # start -    Position at which to start search.
  1043. # op -        Function to use to find next position.
  1044.  
  1045. proc ::tk::TextNextPos {w start op} {
  1046.     set text ""
  1047.     set cur $start
  1048.     while {[$w compare $cur < end]} {
  1049.     set text $text[$w get $cur "$cur lineend + 1c"]
  1050.     set pos [$op $text 0]
  1051.     if {$pos >= 0} {
  1052.         ## Adjust for embedded windows and images
  1053.         ## dump gives us 3 items per window/image
  1054.         set dump [$w dump -image -window $start "$start + $pos c"]
  1055.         if {[llength $dump]} {
  1056.         set pos [expr {$pos + ([llength $dump]/3)}]
  1057.         }
  1058.         return [$w index "$start + $pos c"]
  1059.     }
  1060.     set cur [$w index "$cur lineend +1c"]
  1061.     }
  1062.     return end
  1063. }
  1064.  
  1065. # ::tk::TextPrevPos --
  1066. # Returns the index of the previous position before the given starting
  1067. # position in the text as computed by a specified function.
  1068. #
  1069. # Arguments:
  1070. # w -        The text window in which the cursor is to move.
  1071. # start -    Position at which to start search.
  1072. # op -        Function to use to find next position.
  1073.  
  1074. proc ::tk::TextPrevPos {w start op} {
  1075.     set text ""
  1076.     set cur $start
  1077.     while {[$w compare $cur > 0.0]} {
  1078.     set text [$w get "$cur linestart - 1c" $cur]$text
  1079.     set pos [$op $text end]
  1080.     if {$pos >= 0} {
  1081.         ## Adjust for embedded windows and images
  1082.         ## dump gives us 3 items per window/image
  1083.         set dump [$w dump -image -window "$cur linestart" "$start - 1c"]
  1084.         if {[llength $dump]} {
  1085.         ## This is a hokey extra hack for control-arrow movement
  1086.         ## that should be in a while loop to be correct (hobbs)
  1087.         if {[$w compare [lindex $dump 2] > \
  1088.             "$cur linestart - 1c + $pos c"]} {
  1089.             incr pos -1
  1090.         }
  1091.         set pos [expr {$pos + ([llength $dump]/3)}]
  1092.         }
  1093.         return [$w index "$cur linestart - 1c + $pos c"]
  1094.     }
  1095.     set cur [$w index "$cur linestart - 1c"]
  1096.     }
  1097.     return 0.0
  1098. }
  1099.  
  1100. # ::tk::TextScanMark --
  1101. #
  1102. # Marks the start of a possible scan drag operation
  1103. #
  1104. # Arguments:
  1105. # w -    The text window from which the text to get
  1106. # x -    x location on screen
  1107. # y -    y location on screen
  1108.  
  1109. proc ::tk::TextScanMark {w x y} {
  1110.     $w scan mark $x $y
  1111.     set ::tk::Priv(x) $x
  1112.     set ::tk::Priv(y) $y
  1113.     set ::tk::Priv(mouseMoved) 0
  1114. }
  1115.  
  1116. # ::tk::TextScanDrag --
  1117. #
  1118. # Marks the start of a possible scan drag operation
  1119. #
  1120. # Arguments:
  1121. # w -    The text window from which the text to get
  1122. # x -    x location on screen
  1123. # y -    y location on screen
  1124.  
  1125. proc ::tk::TextScanDrag {w x y} {
  1126.     # Make sure these exist, as some weird situations can trigger the
  1127.     # motion binding without the initial press.  [Bug #220269]
  1128.     if {![info exists ::tk::Priv(x)]} { set ::tk::Priv(x) $x }
  1129.     if {![info exists ::tk::Priv(y)]} { set ::tk::Priv(y) $y }
  1130.     if {($x != $::tk::Priv(x)) || ($y != $::tk::Priv(y))} {
  1131.     set ::tk::Priv(mouseMoved) 1
  1132.     }
  1133.     if {[info exists ::tk::Priv(mouseMoved)] && $::tk::Priv(mouseMoved)} {
  1134.     $w scan dragto $x $y
  1135.     }
  1136. }
  1137.