home *** CD-ROM | disk | FTP | other *** search
/ PC World 2005 June / PCWorld_2005-06_cd.bin / software / vyzkuste / firewally / firewally.exe / framework-2.3.exe / scrlbar.tcl < prev    next >
Text File  |  2003-09-01  |  12KB  |  416 lines
  1. # scrlbar.tcl --
  2. #
  3. # This file defines the default bindings for Tk scrollbar widgets.
  4. # It also provides procedures that help in implementing the bindings.
  5. #
  6. # RCS: @(#) $Id: scrlbar.tcl,v 1.10 2002/08/31 06:12:28 das Exp $
  7. #
  8. # Copyright (c) 1994 The Regents of the University of California.
  9. # Copyright (c) 1994-1996 Sun Microsystems, Inc.
  10. #
  11. # See the file "license.terms" for information on usage and redistribution
  12. # of this file, and for a DISCLAIMER OF ALL WARRANTIES.
  13. #
  14.  
  15. #-------------------------------------------------------------------------
  16. # The code below creates the default class bindings for scrollbars.
  17. #-------------------------------------------------------------------------
  18.  
  19. # Standard Motif bindings:
  20. if {[string equal [tk windowingsystem] "x11"]} {
  21.  
  22. bind Scrollbar <Enter> {
  23.     if {$tk_strictMotif} {
  24.     set tk::Priv(activeBg) [%W cget -activebackground]
  25.     %W config -activebackground [%W cget -background]
  26.     }
  27.     %W activate [%W identify %x %y]
  28. }
  29. bind Scrollbar <Motion> {
  30.     %W activate [%W identify %x %y]
  31. }
  32.  
  33. # The "info exists" command in the following binding handles the
  34. # situation where a Leave event occurs for a scrollbar without the Enter
  35. # event.  This seems to happen on some systems (such as Solaris 2.4) for
  36. # unknown reasons.
  37.  
  38. bind Scrollbar <Leave> {
  39.     if {$tk_strictMotif && [info exists tk::Priv(activeBg)]} {
  40.     %W config -activebackground $tk::Priv(activeBg)
  41.     }
  42.     %W activate {}
  43. }
  44. bind Scrollbar <1> {
  45.     tk::ScrollButtonDown %W %x %y
  46. }
  47. bind Scrollbar <B1-Motion> {
  48.     tk::ScrollDrag %W %x %y
  49. }
  50. bind Scrollbar <B1-B2-Motion> {
  51.     tk::ScrollDrag %W %x %y
  52. }
  53. bind Scrollbar <ButtonRelease-1> {
  54.     tk::ScrollButtonUp %W %x %y
  55. }
  56. bind Scrollbar <B1-Leave> {
  57.     # Prevents <Leave> binding from being invoked.
  58. }
  59. bind Scrollbar <B1-Enter> {
  60.     # Prevents <Enter> binding from being invoked.
  61. }
  62. bind Scrollbar <2> {
  63.     tk::ScrollButton2Down %W %x %y
  64. }
  65. bind Scrollbar <B1-2> {
  66.     # Do nothing, since button 1 is already down.
  67. }
  68. bind Scrollbar <B2-1> {
  69.     # Do nothing, since button 2 is already down.
  70. }
  71. bind Scrollbar <B2-Motion> {
  72.     tk::ScrollDrag %W %x %y
  73. }
  74. bind Scrollbar <ButtonRelease-2> {
  75.     tk::ScrollButtonUp %W %x %y
  76. }
  77. bind Scrollbar <B1-ButtonRelease-2> {
  78.     # Do nothing:  B1 release will handle it.
  79. }
  80. bind Scrollbar <B2-ButtonRelease-1> {
  81.     # Do nothing:  B2 release will handle it.
  82. }
  83. bind Scrollbar <B2-Leave> {
  84.     # Prevents <Leave> binding from being invoked.
  85. }
  86. bind Scrollbar <B2-Enter> {
  87.     # Prevents <Enter> binding from being invoked.
  88. }
  89. bind Scrollbar <Control-1> {
  90.     tk::ScrollTopBottom %W %x %y
  91. }
  92. bind Scrollbar <Control-2> {
  93.     tk::ScrollTopBottom %W %x %y
  94. }
  95.  
  96. bind Scrollbar <Up> {
  97.     tk::ScrollByUnits %W v -1
  98. }
  99. bind Scrollbar <Down> {
  100.     tk::ScrollByUnits %W v 1
  101. }
  102. bind Scrollbar <Control-Up> {
  103.     tk::ScrollByPages %W v -1
  104. }
  105. bind Scrollbar <Control-Down> {
  106.     tk::ScrollByPages %W v 1
  107. }
  108. bind Scrollbar <Left> {
  109.     tk::ScrollByUnits %W h -1
  110. }
  111. bind Scrollbar <Right> {
  112.     tk::ScrollByUnits %W h 1
  113. }
  114. bind Scrollbar <Control-Left> {
  115.     tk::ScrollByPages %W h -1
  116. }
  117. bind Scrollbar <Control-Right> {
  118.     tk::ScrollByPages %W h 1
  119. }
  120. bind Scrollbar <Prior> {
  121.     tk::ScrollByPages %W hv -1
  122. }
  123. bind Scrollbar <Next> {
  124.     tk::ScrollByPages %W hv 1
  125. }
  126. bind Scrollbar <Home> {
  127.     tk::ScrollToPos %W 0
  128. }
  129. bind Scrollbar <End> {
  130.     tk::ScrollToPos %W 1
  131. }
  132. }
  133. # tk::ScrollButtonDown --
  134. # This procedure is invoked when a button is pressed in a scrollbar.
  135. # It changes the way the scrollbar is displayed and takes actions
  136. # depending on where the mouse is.
  137. #
  138. # Arguments:
  139. # w -        The scrollbar widget.
  140. # x, y -    Mouse coordinates.
  141.  
  142. proc tk::ScrollButtonDown {w x y} {
  143.     variable ::tk::Priv
  144.     set Priv(relief) [$w cget -activerelief]
  145.     $w configure -activerelief sunken
  146.     set element [$w identify $x $y]
  147.     if {[string equal $element "slider"]} {
  148.     ScrollStartDrag $w $x $y
  149.     } else {
  150.     ScrollSelect $w $element initial
  151.     }
  152. }
  153.  
  154. # ::tk::ScrollButtonUp --
  155. # This procedure is invoked when a button is released in a scrollbar.
  156. # It cancels scans and auto-repeats that were in progress, and restores
  157. # the way the active element is displayed.
  158. #
  159. # Arguments:
  160. # w -        The scrollbar widget.
  161. # x, y -    Mouse coordinates.
  162.  
  163. proc ::tk::ScrollButtonUp {w x y} {
  164.     variable ::tk::Priv
  165.     tk::CancelRepeat
  166.     if {[info exists Priv(relief)]} {
  167.     # Avoid error due to spurious release events
  168.     $w configure -activerelief $Priv(relief)
  169.     ScrollEndDrag $w $x $y
  170.     $w activate [$w identify $x $y]
  171.     }
  172. }
  173.  
  174. # ::tk::ScrollSelect --
  175. # This procedure is invoked when a button is pressed over the scrollbar.
  176. # It invokes one of several scrolling actions depending on where in
  177. # the scrollbar the button was pressed.
  178. #
  179. # Arguments:
  180. # w -        The scrollbar widget.
  181. # element -    The element of the scrollbar that was selected, such
  182. #        as "arrow1" or "trough2".  Shouldn't be "slider".
  183. # repeat -    Whether and how to auto-repeat the action:  "noRepeat"
  184. #        means don't auto-repeat, "initial" means this is the
  185. #        first action in an auto-repeat sequence, and "again"
  186. #        means this is the second repetition or later.
  187.  
  188. proc ::tk::ScrollSelect {w element repeat} {
  189.     variable ::tk::Priv
  190.     if {![winfo exists $w]} return
  191.     switch -- $element {
  192.     "arrow1"    {ScrollByUnits $w hv -1}
  193.     "trough1"    {ScrollByPages $w hv -1}
  194.     "trough2"    {ScrollByPages $w hv 1}
  195.     "arrow2"    {ScrollByUnits $w hv 1}
  196.     default        {return}
  197.     }
  198.     if {[string equal $repeat "again"]} {
  199.     set Priv(afterId) [after [$w cget -repeatinterval] \
  200.         [list tk::ScrollSelect $w $element again]]
  201.     } elseif {[string equal $repeat "initial"]} {
  202.     set delay [$w cget -repeatdelay]
  203.     if {$delay > 0} {
  204.         set Priv(afterId) [after $delay \
  205.             [list tk::ScrollSelect $w $element again]]
  206.     }
  207.     }
  208. }
  209.  
  210. # ::tk::ScrollStartDrag --
  211. # This procedure is called to initiate a drag of the slider.  It just
  212. # remembers the starting position of the mouse and slider.
  213. #
  214. # Arguments:
  215. # w -        The scrollbar widget.
  216. # x, y -    The mouse position at the start of the drag operation.
  217.  
  218. proc ::tk::ScrollStartDrag {w x y} {
  219.     variable ::tk::Priv
  220.  
  221.     if {[string equal [$w cget -command] ""]} {
  222.     return
  223.     }
  224.     set Priv(pressX) $x
  225.     set Priv(pressY) $y
  226.     set Priv(initValues) [$w get]
  227.     set iv0 [lindex $Priv(initValues) 0]
  228.     if {[llength $Priv(initValues)] == 2} {
  229.     set Priv(initPos) $iv0
  230.     } elseif {$iv0 == 0} {
  231.     set Priv(initPos) 0.0
  232.     } else {
  233.     set Priv(initPos) [expr {(double([lindex $Priv(initValues) 2])) \
  234.         / [lindex $Priv(initValues) 0]}]
  235.     }
  236. }
  237.  
  238. # ::tk::ScrollDrag --
  239. # This procedure is called for each mouse motion even when the slider
  240. # is being dragged.  It notifies the associated widget if we're not
  241. # jump scrolling, and it just updates the scrollbar if we are jump
  242. # scrolling.
  243. #
  244. # Arguments:
  245. # w -        The scrollbar widget.
  246. # x, y -    The current mouse position.
  247.  
  248. proc ::tk::ScrollDrag {w x y} {
  249.     variable ::tk::Priv
  250.  
  251.     if {[string equal $Priv(initPos) ""]} {
  252.     return
  253.     }
  254.     set delta [$w delta [expr {$x - $Priv(pressX)}] [expr {$y - $Priv(pressY)}]]
  255.     if {[$w cget -jump]} {
  256.     if {[llength $Priv(initValues)] == 2} {
  257.         $w set [expr {[lindex $Priv(initValues) 0] + $delta}] \
  258.             [expr {[lindex $Priv(initValues) 1] + $delta}]
  259.     } else {
  260.         set delta [expr {round($delta * [lindex $Priv(initValues) 0])}]
  261.         eval [list $w] set [lreplace $Priv(initValues) 2 3 \
  262.             [expr {[lindex $Priv(initValues) 2] + $delta}] \
  263.             [expr {[lindex $Priv(initValues) 3] + $delta}]]
  264.     }
  265.     } else {
  266.     ScrollToPos $w [expr {$Priv(initPos) + $delta}]
  267.     }
  268. }
  269.  
  270. # ::tk::ScrollEndDrag --
  271. # This procedure is called to end an interactive drag of the slider.
  272. # It scrolls the window if we're in jump mode, otherwise it does nothing.
  273. #
  274. # Arguments:
  275. # w -        The scrollbar widget.
  276. # x, y -    The mouse position at the end of the drag operation.
  277.  
  278. proc ::tk::ScrollEndDrag {w x y} {
  279.     variable ::tk::Priv
  280.  
  281.     if {[string equal $Priv(initPos) ""]} {
  282.     return
  283.     }
  284.     if {[$w cget -jump]} {
  285.     set delta [$w delta [expr {$x - $Priv(pressX)}] \
  286.         [expr {$y - $Priv(pressY)}]]
  287.     ScrollToPos $w [expr {$Priv(initPos) + $delta}]
  288.     }
  289.     set Priv(initPos) ""
  290. }
  291.  
  292. # ::tk::ScrollByUnits --
  293. # This procedure tells the scrollbar's associated widget to scroll up
  294. # or down by a given number of units.  It notifies the associated widget
  295. # in different ways for old and new command syntaxes.
  296. #
  297. # Arguments:
  298. # w -        The scrollbar widget.
  299. # orient -    Which kinds of scrollbars this applies to:  "h" for
  300. #        horizontal, "v" for vertical, "hv" for both.
  301. # amount -    How many units to scroll:  typically 1 or -1.
  302.  
  303. proc ::tk::ScrollByUnits {w orient amount} {
  304.     set cmd [$w cget -command]
  305.     if {[string equal $cmd ""] || ([string first \
  306.         [string index [$w cget -orient] 0] $orient] < 0)} {
  307.     return
  308.     }
  309.     set info [$w get]
  310.     if {[llength $info] == 2} {
  311.     uplevel #0 $cmd scroll $amount units
  312.     } else {
  313.     uplevel #0 $cmd [expr {[lindex $info 2] + $amount}]
  314.     }
  315. }
  316.  
  317. # ::tk::ScrollByPages --
  318. # This procedure tells the scrollbar's associated widget to scroll up
  319. # or down by a given number of screenfuls.  It notifies the associated
  320. # widget in different ways for old and new command syntaxes.
  321. #
  322. # Arguments:
  323. # w -        The scrollbar widget.
  324. # orient -    Which kinds of scrollbars this applies to:  "h" for
  325. #        horizontal, "v" for vertical, "hv" for both.
  326. # amount -    How many screens to scroll:  typically 1 or -1.
  327.  
  328. proc ::tk::ScrollByPages {w orient amount} {
  329.     set cmd [$w cget -command]
  330.     if {[string equal $cmd ""] || ([string first \
  331.         [string index [$w cget -orient] 0] $orient] < 0)} {
  332.     return
  333.     }
  334.     set info [$w get]
  335.     if {[llength $info] == 2} {
  336.     uplevel #0 $cmd scroll $amount pages
  337.     } else {
  338.     uplevel #0 $cmd [expr {[lindex $info 2] + $amount*([lindex $info 1] - 1)}]
  339.     }
  340. }
  341.  
  342. # ::tk::ScrollToPos --
  343. # This procedure tells the scrollbar's associated widget to scroll to
  344. # a particular location, given by a fraction between 0 and 1.  It notifies
  345. # the associated widget in different ways for old and new command syntaxes.
  346. #
  347. # Arguments:
  348. # w -        The scrollbar widget.
  349. # pos -        A fraction between 0 and 1 indicating a desired position
  350. #        in the document.
  351.  
  352. proc ::tk::ScrollToPos {w pos} {
  353.     set cmd [$w cget -command]
  354.     if {[string equal $cmd ""]} {
  355.     return
  356.     }
  357.     set info [$w get]
  358.     if {[llength $info] == 2} {
  359.     uplevel #0 $cmd moveto $pos
  360.     } else {
  361.     uplevel #0 $cmd [expr {round([lindex $info 0]*$pos)}]
  362.     }
  363. }
  364.  
  365. # ::tk::ScrollTopBottom
  366. # Scroll to the top or bottom of the document, depending on the mouse
  367. # position.
  368. #
  369. # Arguments:
  370. # w -        The scrollbar widget.
  371. # x, y -    Mouse coordinates within the widget.
  372.  
  373. proc ::tk::ScrollTopBottom {w x y} {
  374.     variable ::tk::Priv
  375.     set element [$w identify $x $y]
  376.     if {[string match *1 $element]} {
  377.     ScrollToPos $w 0
  378.     } elseif {[string match *2 $element]} {
  379.     ScrollToPos $w 1
  380.     }
  381.  
  382.     # Set Priv(relief), since it's needed by tk::ScrollButtonUp.
  383.  
  384.     set Priv(relief) [$w cget -activerelief]
  385. }
  386.  
  387. # ::tk::ScrollButton2Down
  388. # This procedure is invoked when button 2 is pressed over a scrollbar.
  389. # If the button is over the trough or slider, it sets the scrollbar to
  390. # the mouse position and starts a slider drag.  Otherwise it just
  391. # behaves the same as button 1.
  392. #
  393. # Arguments:
  394. # w -        The scrollbar widget.
  395. # x, y -    Mouse coordinates within the widget.
  396.  
  397. proc ::tk::ScrollButton2Down {w x y} {
  398.     variable ::tk::Priv
  399.     set element [$w identify $x $y]
  400.     if {[string match {arrow[12]} $element]} {
  401.     ScrollButtonDown $w $x $y
  402.     return
  403.     }
  404.     ScrollToPos $w [$w fraction $x $y]
  405.     set Priv(relief) [$w cget -activerelief]
  406.  
  407.     # Need the "update idletasks" below so that the widget calls us
  408.     # back to reset the actual scrollbar position before we start the
  409.     # slider drag.
  410.  
  411.     update idletasks
  412.     $w configure -activerelief sunken
  413.     $w activate slider
  414.     ScrollStartDrag $w $x $y
  415. }
  416.