home *** CD-ROM | disk | FTP | other *** search
/ PC World 2005 June / PCWorld_2005-06_cd.bin / software / vyzkuste / firewally / firewally.exe / framework-2.3.exe / perlbug < prev    next >
Text File  |  2003-11-07  |  37KB  |  1,196 lines
  1. #!/usr/bin/perl
  2.     eval 'exec /usr/bin/perl -S $0 ${1+"$@"}'
  3.     if $running_under_some_shell;
  4.  
  5. my $config_tag1 = 'v5.8.2 - Fri Nov  7 12:03:56     2003';
  6.  
  7. my $patchlevel_date = 1068066294;
  8. my $patch_tags = '';
  9. my @patches = (
  10.     ''
  11. );
  12.  
  13. use Config;
  14. use File::Spec;        # keep perlbug Perl 5.005 compatible
  15. use Getopt::Std;
  16. use strict;
  17.  
  18. sub paraprint;
  19.  
  20. BEGIN {
  21.     eval "use Mail::Send;";
  22.     $::HaveSend = ($@ eq "");
  23.     eval "use Mail::Util;";
  24.     $::HaveUtil = ($@ eq "");
  25. };
  26.  
  27. my $Version = "1.34";
  28.  
  29. # Changed in 1.06 to skip Mail::Send and Mail::Util if not available.
  30. # Changed in 1.07 to see more sendmail execs, and added pipe output.
  31. # Changed in 1.08 to use correct address for sendmail.
  32. # Changed in 1.09 to close the REP file before calling it up in the editor.
  33. #                 Also removed some old comments duplicated elsewhere.
  34. # Changed in 1.10 to run under VMS without Mail::Send; also fixed
  35. #                 temp filename generation.
  36. # Changed in 1.11 to clean up some text and removed Mail::Send deactivator.
  37. # Changed in 1.12 to check for editor errors, make save/send distinction
  38. #                 clearer and add $ENV{REPLYTO}.
  39. # Changed in 1.13 to hopefully make it more difficult to accidentally
  40. #                 send mail
  41. # Changed in 1.14 to make the prompts a little more clear on providing
  42. #                 helpful information. Also let file read fail gracefully.
  43. # Changed in 1.15 to add warnings to stop people using perlbug for non-bugs.
  44. #                 Also report selected environment variables.
  45. # Changed in 1.16 to include @INC, and allow user to re-edit if no changes.
  46. # Changed in 1.17 Win32 support added.  GSAR 97-04-12
  47. # Changed in 1.18 add '-ok' option for reporting build success. CFR 97-06-18
  48. # Changed in 1.19 '-ok' default not '-v'
  49. #                 add local patch information
  50. #                 warn on '-ok' if this is an old system; add '-okay'
  51. # Changed in 1.20 Added patchlevel.h reading and version/config checks
  52. # Changed in 1.21 Added '-nok' for reporting build failure DFD 98-05-05
  53. # Changed in 1.22 Heavy reformatting & minor bugfixes HVDS 98-05-10
  54. # Changed in 1.23 Restore -ok(ay): say 'success'; don't prompt
  55. # Changed in 1.24 Added '-F<file>' to save report HVDS 98-07-01
  56. # Changed in 1.25 Warn on failure to open save file. HVDS 98-07-12
  57. # Changed in 1.26 Don't require -t STDIN for -ok. HVDS 98-07-15
  58. # Changed in 1.27 Added Mac OS and File::Spec support CNANDOR 99-07-27
  59. # Changed in 1.28 Additional questions for Perlbugtron RFOLEY 20.03.2000
  60. # Changed in 1.29 Perlbug(tron): auto(-ok), short prompts RFOLEY 05-05-2000
  61. # Changed in 1.30 Added warnings on failure to open files MSTEVENS 13-07-2000
  62. # Changed in 1.31 Add checks on close().Fix my $var unless. TJENNESS 26-07-2000
  63. # Changed in 1.32 Use File::Spec->tmpdir TJENNESS 20-08-2000
  64. # Changed in 1.33 Don't require -t STDOUT for -ok.
  65. # Changed in 1.34 Added Message-Id RFOLEY 18-06-2002 
  66.  
  67. # TODO: - Allow the user to re-name the file on mail failure, and
  68. #       make sure failure (transmission-wise) of Mail::Send is
  69. #       accounted for.
  70. #       - Test -b option
  71.  
  72. my( $file, $usefile, $cc, $address, $perlbug, $testaddress, $filename, $messageid, $domain,
  73.     $subject, $from, $verbose, $ed, $outfile, $Is_MacOS, $category, $severity,
  74.     $fh, $me, $Is_MSWin32, $Is_Linux, $Is_VMS, $msg, $body, $andcc, %REP, $ok,
  75.     $Is_OpenBSD);
  76.  
  77. my $perl_version = $^V ? sprintf("v%vd", $^V) : $];
  78.  
  79. my $config_tag2 = "$perl_version - $Config{cf_time}";
  80.  
  81. Init();
  82.  
  83. if ($::opt_h) { Help(); exit; }
  84. if ($::opt_d) { Dump(*STDOUT); exit; }
  85. if (!-t STDIN && !($ok and not $::opt_n)) {
  86.     paraprint <<EOF;
  87. Please use perlbug interactively. If you want to
  88. include a file, you can use the -f switch.
  89. EOF
  90.     die "\n";
  91. }
  92.  
  93. Query();
  94. Edit() unless $usefile || ($ok and not $::opt_n);
  95. NowWhat();
  96. Send();
  97.  
  98. exit;
  99.  
  100. sub ask_for_alternatives { # (category|severity)
  101.     my $name = shift;
  102.     my %alts = (
  103.     'category' => {
  104.         'default' => 'core',
  105.         'ok'      => 'install',
  106.         'opts'    => [qw(core docs install library utilities)], # patch, notabug
  107.     },
  108.     'severity' => {
  109.         'default' => 'low',
  110.         'ok'      => 'none',
  111.         'opts'    => [qw(critical high medium low wishlist none)], # zero
  112.     },
  113.     );
  114.     die "Invalid alternative($name) requested\n" unless grep(/^$name$/, keys %alts);
  115.     my $alt = "";
  116.     if ($ok) {
  117.     $alt = $alts{$name}{'ok'};
  118.     } else {
  119.      my @alts = @{$alts{$name}{'opts'}};
  120.     paraprint <<EOF;
  121. Please pick a \u$name from the following:
  122.  
  123.     @alts
  124.  
  125. EOF
  126.     my $err = 0;
  127.     do {
  128.         if ($err++ > 5) {
  129.         die "Invalid $name: aborting.\n";
  130.         }
  131.         print "Please enter a \u$name [$alts{$name}{'default'}]: ";
  132.         $alt = <>;
  133.         chomp $alt;
  134.         if ($alt =~ /^\s*$/) {
  135.         $alt = $alts{$name}{'default'};
  136.         }
  137.     } while !((($alt) = grep(/^$alt/i, @alts)));
  138.     }
  139.     lc $alt;
  140. }
  141.  
  142. sub Init {
  143.     # -------- Setup --------
  144.  
  145.     $Is_MSWin32 = $^O eq 'MSWin32';
  146.     $Is_VMS = $^O eq 'VMS';
  147.     $Is_Linux = lc($^O) eq 'linux';
  148.     $Is_OpenBSD = lc($^O) eq 'openbsd';
  149.     $Is_MacOS = $^O eq 'MacOS';
  150.  
  151.     @ARGV = split m/\s+/,
  152.         MacPerl::Ask('Provide command-line args here (-h for help):')
  153.         if $Is_MacOS && $MacPerl::Version =~ /App/;
  154.  
  155.     if (!getopts("Adhva:s:b:f:F:r:e:SCc:to:n:")) { Help(); exit; };
  156.  
  157.     # This comment is needed to notify metaconfig that we are
  158.     # using the $perladmin, $cf_by, and $cf_time definitions.
  159.  
  160.     # -------- Configuration ---------
  161.  
  162.     # perlbug address
  163.     $perlbug = 'perlbug@perl.org';
  164.  
  165.     # Test address
  166.     $testaddress = 'perlbug-test@perl.org';
  167.  
  168.     # Target address
  169.     $address = $::opt_a || ($::opt_t ? $testaddress : $perlbug);
  170.  
  171.     # Users address, used in message and in Reply-To header
  172.     $from = $::opt_r || "";
  173.  
  174.     # Include verbose configuration information
  175.     $verbose = $::opt_v || 0;
  176.  
  177.     # Subject of bug-report message
  178.     $subject = $::opt_s || "";
  179.  
  180.     # Send a file
  181.     $usefile = ($::opt_f || 0);
  182.  
  183.     # File to send as report
  184.     $file = $::opt_f || "";
  185.  
  186.     # File to output to
  187.     $outfile = $::opt_F || "";
  188.  
  189.     # Body of report
  190.     $body = $::opt_b || "";
  191.     
  192.     # Editor
  193.     $ed = $::opt_e || $ENV{VISUAL} || $ENV{EDITOR} || $ENV{EDIT}
  194.     || ($Is_VMS && "edit/tpu")
  195.     || ($Is_MSWin32 && "notepad")
  196.     || ($Is_MacOS && '')
  197.     || "vi";
  198.  
  199.     # Not OK - provide build failure template by finessing OK report
  200.     if ($::opt_n) {
  201.     if (substr($::opt_n, 0, 2) eq 'ok' )    {
  202.         $::opt_o = substr($::opt_n, 1);
  203.     } else {
  204.         Help();
  205.         exit();
  206.     }
  207.     }
  208.  
  209.     # OK - send "OK" report for build on this system
  210.     $ok = 0;
  211.     if ($::opt_o) {
  212.     if ($::opt_o eq 'k' or $::opt_o eq 'kay') {
  213.         my $age = time - $patchlevel_date;
  214.         if ($::opt_o eq 'k' and $age > 60 * 24 * 60 * 60 ) {
  215.         my $date = localtime $patchlevel_date;
  216.         print <<"EOF";
  217. "perlbug -ok" and "perlbug -nok" do not report on Perl versions which
  218. are more than 60 days old.  This Perl version was constructed on
  219. $date.  If you really want to report this, use
  220. "perlbug -okay" or "perlbug -nokay".
  221. EOF
  222.         exit();
  223.         }
  224.         # force these options
  225.         unless ($::opt_n) {
  226.         $::opt_S = 1; # don't prompt for send
  227.         $::opt_b = 1; # we have a body
  228.         $body = "Perl reported to build OK on this system.\n";
  229.         }
  230.         $::opt_C = 1; # don't send a copy to the local admin
  231.         $::opt_s = 1; # we have a subject line
  232.         $subject = ($::opt_n ? 'Not ' : '')
  233.             . "OK: perl $perl_version ${patch_tags}on"
  234.             ." $::Config{'archname'} $::Config{'osvers'} $subject";
  235.         $ok = 1;
  236.     } else {
  237.         Help();
  238.         exit();
  239.     }
  240.     }
  241.  
  242.     # Possible administrator addresses, in order of confidence
  243.     # (Note that cf_email is not mentioned to metaconfig, since
  244.     # we don't really want it. We'll just take it if we have to.)
  245.     #
  246.     # This has to be after the $ok stuff above because of the way
  247.     # that $::opt_C is forced.
  248.     $cc = $::opt_C ? "" : (
  249.     $::opt_c || $::Config{'perladmin'}
  250.     || $::Config{'cf_email'} || $::Config{'cf_by'}
  251.     );
  252.  
  253.     if ($::HaveUtil) {
  254.         $domain = Mail::Util::maildomain();
  255.     } elsif ($Is_MSWin32) {
  256.         $domain = $ENV{'USERDOMAIN'};
  257.     } else {
  258.         require Sys::Hostname;
  259.         $domain = Sys::Hostname::hostname();
  260.     }
  261.  
  262.     # Message-Id - rjsf
  263.     $messageid = "<$::Config{'version'}_${$}_".time."\@$domain>"; 
  264.  
  265.     # My username
  266.     $me = $Is_MSWin32 ? $ENV{'USERNAME'}
  267.         : $^O eq 'os2' ? $ENV{'USER'} || $ENV{'LOGNAME'}
  268.         : $Is_MacOS ? $ENV{'USER'}
  269.         : eval { getpwuid($<) };    # May be missing
  270.  
  271.     $from = $::Config{'cf_email'}
  272.        if !$from && $::Config{'cf_email'} && $::Config{'cf_by'} && $me &&
  273.                ($me eq $::Config{'cf_by'});
  274. } # sub Init
  275.  
  276. sub Query {
  277.     # Explain what perlbug is
  278.     unless ($ok) {
  279.     paraprint <<EOF;
  280. This program provides an easy way to create a message reporting a bug
  281. in perl, and e-mail it to $address.  It is *NOT* intended for
  282. sending test messages or simply verifying that perl works, *NOR* is it
  283. intended for reporting bugs in third-party perl modules.  It is *ONLY*
  284. a means of reporting verifiable problems with the core perl distribution,
  285. and any solutions to such problems, to the people who maintain perl.
  286.  
  287. If you're just looking for help with perl, try posting to the Usenet
  288. newsgroup comp.lang.perl.misc.  If you're looking for help with using
  289. perl with CGI, try posting to comp.infosystems.www.programming.cgi.
  290. EOF
  291.     }
  292.  
  293.     # Prompt for subject of message, if needed
  294.     
  295.     if (TrivialSubject($subject)) {
  296.     $subject = '';
  297.     }
  298.  
  299.     unless ($subject) {
  300.     paraprint <<EOF;
  301. First of all, please provide a subject for the
  302. message. It should be a concise description of
  303. the bug or problem. "perl bug" or "perl problem"
  304. is not a concise description.
  305. EOF
  306.  
  307.     my $err = 0;
  308.     do {
  309.         print "Subject: ";
  310.         $subject = <>;
  311.         chomp $subject;
  312.         if ($err++ == 5) {
  313.         die "Aborting.\n";
  314.         }
  315.     } while (TrivialSubject($subject));
  316.     }
  317.  
  318.     # Prompt for return address, if needed
  319.     unless ($from) {
  320.     # Try and guess return address
  321.     my $guess;
  322.  
  323.     $guess = $ENV{'REPLY-TO'} || $ENV{'REPLYTO'} || '';
  324.         if ($Is_MacOS) {
  325.             require Mac::InternetConfig;
  326.             $guess = $Mac::InternetConfig::InternetConfig{
  327.                 Mac::InternetConfig::kICEmail()
  328.             };
  329.         }
  330.  
  331.     unless ($guess) {
  332.         # move $domain to where we can use it elsewhere    
  333.         if ($domain) {
  334.         if ($Is_VMS && !$::Config{'d_socket'}) {
  335.             $guess = "$domain\:\:$me";
  336.         } else {
  337.             $guess = "$me\@$domain" if $domain;
  338.         }
  339.         }
  340.     }
  341.  
  342.     if ($guess) {
  343.         unless ($ok) {
  344.         paraprint <<EOF;
  345. Your e-mail address will be useful if you need to be contacted. If the
  346. default shown is not your full internet e-mail address, please correct it.
  347. EOF
  348.         }
  349.     } else {
  350.         paraprint <<EOF;
  351. So that you may be contacted if necessary, please enter
  352. your full internet e-mail address here.
  353. EOF
  354.     }
  355.  
  356.     if ($ok && $guess) {
  357.         # use it
  358.         $from = $guess;
  359.     } else {
  360.         # verify it
  361.         print "Your address [$guess]: ";
  362.         $from = <>;
  363.         chomp $from;
  364.         $from = $guess if $from eq '';
  365.     }
  366.     }
  367.  
  368.     if ($from eq $cc or $me eq $cc) {
  369.     # Try not to copy ourselves
  370.     $cc = "yourself";
  371.     }
  372.  
  373.     # Prompt for administrator address, unless an override was given
  374.     if( !$::opt_C and !$::opt_c ) {
  375.     paraprint <<EOF;
  376. A copy of this report can be sent to your local
  377. perl administrator. If the address is wrong, please
  378. correct it, or enter 'none' or 'yourself' to not send
  379. a copy.
  380. EOF
  381.     print "Local perl administrator [$cc]: ";
  382.     my $entry = scalar <>;
  383.     chomp $entry;
  384.  
  385.     if ($entry ne "") {
  386.         $cc = $entry;
  387.         $cc = '' if $me eq $cc;
  388.     }
  389.     }
  390.  
  391.     $cc = '' if $cc =~ /^(none|yourself|me|myself|ourselves)$/i;
  392.     $andcc = " and $cc" if $cc;
  393.  
  394.     # Prompt for editor, if no override is given
  395. editor:
  396.     unless ($::opt_e || $::opt_f || $::opt_b) {
  397.     paraprint <<EOF;
  398. Now you need to supply the bug report. Try to make
  399. the report concise but descriptive. Include any
  400. relevant detail. If you are reporting something
  401. that does not work as you think it should, please
  402. try to include example of both the actual
  403. result, and what you expected.
  404.  
  405. Some information about your local
  406. perl configuration will automatically be included
  407. at the end of the report. If you are using any
  408. unusual version of perl, please try and confirm
  409. exactly which versions are relevant.
  410.  
  411. You will probably want to use an editor to enter
  412. the report. If "$ed" is the editor you want
  413. to use, then just press Enter, otherwise type in
  414. the name of the editor you would like to use.
  415.  
  416. If you would like to use a prepared file, type
  417. "file", and you will be asked for the filename.
  418. EOF
  419.     print "Editor [$ed]: ";
  420.     my $entry =scalar <>;
  421.     chomp $entry;
  422.  
  423.     $usefile = 0;
  424.     if ($entry eq "file") {
  425.         $usefile = 1;
  426.     } elsif ($entry ne "") {
  427.         $ed = $entry;
  428.     }
  429.     }
  430.  
  431.     # Prompt for category of bug
  432.     $category ||= ask_for_alternatives('category');
  433.  
  434.     # Prompt for severity of bug
  435.     $severity ||= ask_for_alternatives('severity');
  436.  
  437.     # Generate scratch file to edit report in
  438.     $filename = filename();
  439.  
  440.     # Prompt for file to read report from, if needed
  441.     if ($usefile and !$file) {
  442. filename:
  443.     paraprint <<EOF;
  444. What is the name of the file that contains your report?
  445. EOF
  446.     print "Filename: ";
  447.     my $entry = scalar <>;
  448.     chomp $entry;
  449.  
  450.     if ($entry eq "") {
  451.         paraprint <<EOF;
  452. No filename? I'll let you go back and choose an editor again.
  453. EOF
  454.         goto editor;
  455.     }
  456.  
  457.     unless (-f $entry and -r $entry) {
  458.         paraprint <<EOF;
  459. I'm sorry, but I can't read from `$entry'. Maybe you mistyped the name of
  460. the file? If you don't want to send a file, just enter a blank line and you
  461. can get back to the editor selection.
  462. EOF
  463.         goto filename;
  464.     }
  465.     $file = $entry;
  466.     }
  467.  
  468.     # Generate report
  469.     open(REP,">$filename") or die "Unable to create report file `$filename': $!\n";
  470.     my $reptype = !$ok ? "bug" : $::opt_n ? "build failure" : "success";
  471.  
  472.     print REP <<EOF;
  473. This is a $reptype report for perl from $from,
  474. generated with the help of perlbug $Version running under perl $perl_version.
  475.  
  476. EOF
  477.  
  478.     if ($body) {
  479.     print REP $body;
  480.     } elsif ($usefile) {
  481.     open(F, "<$file")
  482.         or die "Unable to read report file from `$file': $!\n";
  483.     while (<F>) {
  484.         print REP $_
  485.     }
  486.     close(F) or die "Error closing `$file': $!";
  487.     } else {
  488.     print REP <<EOF;
  489.  
  490. -----------------------------------------------------------------
  491. [Please enter your report here]
  492.  
  493.  
  494.  
  495. [Please do not change anything below this line]
  496. -----------------------------------------------------------------
  497. EOF
  498.     }
  499.     Dump(*REP);
  500.     close(REP) or die "Error closing report file: $!";
  501.  
  502.     # read in the report template once so that
  503.     # we can track whether the user does any editing.
  504.     # yes, *all* whitespace is ignored.
  505.     open(REP, "<$filename") or die "Unable to open report file `$filename': $!\n";
  506.     while (<REP>) {
  507.     s/\s+//g;
  508.     $REP{$_}++;
  509.     }
  510.     close(REP) or die "Error closing report file `$filename': $!";
  511. } # sub Query
  512.  
  513. sub Dump {
  514.     local(*OUT) = @_;
  515.  
  516.     print OUT <<EFF;
  517. ---
  518. Flags:
  519.     category=$category
  520.     severity=$severity
  521. EFF
  522.     if ($::opt_A) {
  523.     print OUT <<EFF;
  524.     ack=no
  525. EFF
  526.     }
  527.     print OUT <<EFF;
  528. ---
  529. EFF
  530.     print OUT "This perlbug was built using Perl $config_tag1\n",
  531.         "It is being executed now by  Perl $config_tag2.\n\n"
  532.     if $config_tag2 ne $config_tag1;
  533.  
  534.     print OUT <<EOF;
  535. Site configuration information for perl $perl_version:
  536.  
  537. EOF
  538.     if ($::Config{cf_by} and $::Config{cf_time}) {
  539.     print OUT "Configured by $::Config{cf_by} at $::Config{cf_time}.\n\n";
  540.     }
  541.     print OUT Config::myconfig;
  542.  
  543.     if (@patches) {
  544.     print OUT join "\n    ", "Locally applied patches:", @patches;
  545.     print OUT "\n";
  546.     };
  547.  
  548.     print OUT <<EOF;
  549.  
  550. ---
  551. \@INC for perl $perl_version:
  552. EOF
  553.     for my $i (@INC) {
  554.     print OUT "    $i\n";
  555.     }
  556.  
  557.     print OUT <<EOF;
  558.  
  559. ---
  560. Environment for perl $perl_version:
  561. EOF
  562.     my @env =
  563.         qw(PATH LD_LIBRARY_PATH LANG PERL_BADLANG SHELL HOME LOGDIR LANGUAGE);
  564.     push @env, $Config{ldlibpthname} if $Config{ldlibpthname} ne '';
  565.     push @env, grep /^(?:PERL|LC_|LANG|CYGWIN)/, keys %ENV;
  566.     my %env;
  567.     @env{@env} = @env;
  568.     for my $env (sort keys %env) {
  569.     print OUT "    $env",
  570.         exists $ENV{$env} ? "=$ENV{$env}" : ' (unset)',
  571.         "\n";
  572.     }
  573.     if ($verbose) {
  574.     print OUT "\nComplete configuration data for perl $perl_version:\n\n";
  575.     my $value;
  576.     foreach (sort keys %::Config) {
  577.         $value = $::Config{$_};
  578.         $value =~ s/'/\\'/g;
  579.         print OUT "$_='$value'\n";
  580.     }
  581.     }
  582. } # sub Dump
  583.  
  584. sub Edit {
  585.     # Edit the report
  586.     if ($usefile || $body) {
  587.     paraprint <<EOF;
  588. Please make sure that the name of the editor you want to use is correct.
  589. EOF
  590.     print "Editor [$ed]: ";
  591.     my $entry =scalar <>;
  592.     chomp $entry;
  593.     $ed = $entry unless $entry eq '';
  594.     }
  595.  
  596. tryagain:
  597.     my $sts;
  598.     $sts = system("$ed $filename") unless $Is_MacOS;
  599.     if ($Is_MacOS) {
  600.         require ExtUtils::MakeMaker;
  601.         ExtUtils::MM_MacOS::launch_file($filename);
  602.         paraprint <<EOF;
  603. Press Enter when done.
  604. EOF
  605.         scalar <>;
  606.     }
  607.     if ($sts) {
  608.     paraprint <<EOF;
  609. The editor you chose (`$ed') could apparently not be run!
  610. Did you mistype the name of your editor? If so, please
  611. correct it here, otherwise just press Enter.
  612. EOF
  613.     print "Editor [$ed]: ";
  614.     my $entry =scalar <>;
  615.     chomp $entry;
  616.  
  617.     if ($entry ne "") {
  618.         $ed = $entry;
  619.         goto tryagain;
  620.     } else {
  621.         paraprint <<EOF;
  622. You may want to save your report to a file, so you can edit and mail it
  623. yourself.
  624. EOF
  625.     }
  626.     }
  627.  
  628.     return if ($ok and not $::opt_n) || $body;
  629.     # Check that we have a report that has some, eh, report in it.
  630.     my $unseen = 0;
  631.  
  632.     open(REP, "<$filename") or die "Couldn't open `$filename': $!\n";
  633.     # a strange way to check whether any significant editing
  634.     # have been done: check whether any new non-empty lines
  635.     # have been added. Yes, the below code ignores *any* space
  636.     # in *any* line.
  637.     while (<REP>) {
  638.     s/\s+//g;
  639.     $unseen++ if $_ ne '' and not exists $REP{$_};
  640.     }
  641.  
  642.     while ($unseen == 0) {
  643.     paraprint <<EOF;
  644. I am sorry but it looks like you did not report anything.
  645. EOF
  646.     print "Action (Retry Edit/Cancel) ";
  647.     my ($action) = scalar(<>);
  648.     if ($action =~ /^[re]/i) { # <R>etry <E>dit
  649.         goto tryagain;
  650.     } elsif ($action =~ /^[cq]/i) { # <C>ancel, <Q>uit
  651.         Cancel();
  652.     }
  653.     }
  654. } # sub Edit
  655.  
  656. sub Cancel {
  657.     1 while unlink($filename);  # remove all versions under VMS
  658.     print "\nCancelling.\n";
  659.     exit(0);
  660. }
  661.  
  662. sub NowWhat {
  663.     # Report is done, prompt for further action
  664.     if( !$::opt_S ) {
  665.     while(1) {
  666.         paraprint <<EOF;
  667. Now that you have completed your report, would you like to send
  668. the message to $address$andcc, display the message on
  669. the screen, re-edit it, display/change the subject,
  670. or cancel without sending anything?
  671. You may also save the message as a file to mail at another time.
  672. EOF
  673.       retry:
  674.         print "Action (Send/Display/Edit/Subject/Save to File): ";
  675.         my $action = scalar <>;
  676.         chomp $action;
  677.  
  678.         if ($action =~ /^(f|sa)/i) { # <F>ile/<Sa>ve
  679.         my $file_save = $outfile || "perlbug.rep";
  680.         print "\n\nName of file to save message in [$file_save]: ";
  681.         my $file = scalar <>;
  682.         chomp $file;
  683.         $file = $file_save if $file eq "";
  684.  
  685.         unless (open(FILE, ">$file")) {
  686.             print "\nError opening $file: $!\n\n";
  687.             goto retry;
  688.         }
  689.         open(REP, "<$filename") or die "Couldn't open file `$filename': $!\n";
  690.         print FILE "To: $address\nSubject: $subject\n";
  691.         print FILE "Cc: $cc\n" if $cc;
  692.         print FILE "Reply-To: $from\n" if $from;
  693.         print FILE "Message-Id: $messageid\n" if $messageid;
  694.         print FILE "\n";
  695.         while (<REP>) { print FILE }
  696.         close(REP) or die "Error closing report file `$filename': $!";
  697.         close(FILE) or die "Error closing $file: $!";
  698.  
  699.         print "\nMessage saved in `$file'.\n";
  700.         exit;
  701.         } elsif ($action =~ /^(d|l|sh)/i ) { # <D>isplay, <L>ist, <Sh>ow
  702.         # Display the message
  703.         open(REP, "<$filename") or die "Couldn't open file `$filename': $!\n";
  704.         while (<REP>) { print $_ }
  705.         close(REP) or die "Error closing report file `$filename': $!";
  706.         } elsif ($action =~ /^su/i) { # <Su>bject
  707.         print "Subject: $subject\n";
  708.         print "If the above subject is fine, just press Enter.\n";
  709.         print "If not, type in the new subject.\n";
  710.         print "Subject: ";
  711.         my $reply = scalar <STDIN>;
  712.         chomp $reply;
  713.         if ($reply ne '') {
  714.             unless (TrivialSubject($reply)) {
  715.             $subject = $reply;
  716.             print "Subject: $subject\n";
  717.             }
  718.         }
  719.         } elsif ($action =~ /^se/i) { # <S>end
  720.         # Send the message
  721.         print "Are you certain you want to send this message?\n"
  722.             . 'Please type "yes" if you are: ';
  723.         my $reply = scalar <STDIN>;
  724.         chomp $reply;
  725.         if ($reply eq "yes") {
  726.             last;
  727.         } else {
  728.             paraprint <<EOF;
  729. That wasn't a clear "yes", so I won't send your message. If you are sure
  730. your message should be sent, type in "yes" (without the quotes) at the
  731. confirmation prompt.
  732. EOF
  733.         }
  734.         } elsif ($action =~ /^[er]/i) { # <E>dit, <R>e-edit
  735.         # edit the message
  736.         Edit();
  737.         } elsif ($action =~ /^[qc]/i) { # <C>ancel, <Q>uit
  738.         Cancel();
  739.         } elsif ($action =~ /^s/i) {
  740.         paraprint <<EOF;
  741. I'm sorry, but I didn't understand that. Please type "send" or "save".
  742. EOF
  743.         }
  744.     }
  745.     }
  746. } # sub NowWhat
  747.  
  748. sub TrivialSubject {
  749.     my $subject = shift;
  750.     if ($subject =~
  751.     /^(y(es)?|no?|help|perl( (bug|problem))?|bug|problem)$/i ||
  752.     length($subject) < 4 ||
  753.     $subject !~ /\s/) {
  754.     print "\nThat doesn't look like a good subject.  Please be more verbose.\n\n";
  755.         return 1;
  756.     } else {
  757.     return 0;
  758.     }
  759. }
  760.  
  761. sub Send {
  762.     # Message has been accepted for transmission -- Send the message
  763.     if ($outfile) {
  764.     open SENDMAIL, ">$outfile" or die "Couldn't open '$outfile': $!\n";
  765.     goto sendout;
  766.     }
  767.  
  768.     # on linux certain mail implementations won't accept the subject
  769.     # as "~s subject" and thus the Subject header will be corrupted
  770.     # so don't use Mail::Send to be safe
  771.     if ($::HaveSend && !$Is_Linux && !$Is_OpenBSD) {
  772.     $msg = new Mail::Send Subject => $subject, To => $address;
  773.     $msg->cc($cc) if $cc;
  774.     $msg->add("Reply-To",$from) if $from;
  775.  
  776.     $fh = $msg->open;
  777.     open(REP, "<$filename") or die "Couldn't open `$filename': $!\n";
  778.     while (<REP>) { print $fh $_ }
  779.     close(REP) or die "Error closing $filename: $!";
  780.     $fh->close;
  781.  
  782.     print "\nMessage sent.\n";
  783.     } elsif ($Is_VMS) {
  784.     if ( ($address =~ /@/ and $address !~ /^\w+%"/) or
  785.          ($cc      =~ /@/ and $cc      !~ /^\w+%"/) ) {
  786.         my $prefix;
  787.         foreach (qw[ IN MX SMTP UCX PONY WINS ], '') {
  788.         $prefix = "$_%", last if $ENV{"MAIL\$PROTOCOL_$_"};
  789.         }
  790.         $address = qq[${prefix}"$address"] unless $address =~ /^\w+%"/;
  791.         $cc = qq[${prefix}"$cc"] unless !$cc || $cc =~ /^\w+%"/;
  792.     }
  793.     $subject =~ s/"/""/g; $address =~ s/"/""/g; $cc =~ s/"/""/g;
  794.     my $sts = system(qq[mail/Subject="$subject" $filename. "$address","$cc"]);
  795.     if ($sts) {
  796.         die <<EOF;
  797. Can't spawn off mail
  798.     (leaving bug report in $filename): $sts
  799. EOF
  800.     }
  801.     } else {
  802.     my $sendmail = "";
  803.     for (qw(/usr/lib/sendmail /usr/sbin/sendmail /usr/ucblib/sendmail)) {
  804.         $sendmail = $_, last if -e $_;
  805.     }
  806.     if ($^O eq 'os2' and $sendmail eq "") {
  807.         my $path = $ENV{PATH};
  808.         $path =~ s:\\:/: ;
  809.         my @path = split /$Config{'path_sep'}/, $path;
  810.         for (@path) {
  811.         $sendmail = "$_/sendmail", last if -e "$_/sendmail";
  812.         $sendmail = "$_/sendmail.exe", last if -e "$_/sendmail.exe";
  813.         }
  814.     }
  815.  
  816.     paraprint(<<"EOF"), die "\n" if $sendmail eq "";
  817. I am terribly sorry, but I cannot find sendmail, or a close equivalent, and
  818. the perl package Mail::Send has not been installed, so I can't send your bug
  819. report. We apologize for the inconvenience.
  820.  
  821. So you may attempt to find some way of sending your message, it has
  822. been left in the file `$filename'.
  823. EOF
  824.     open(SENDMAIL, "|$sendmail -t -oi") || die "'|$sendmail -t -oi' failed: $!";
  825. sendout:
  826.     print SENDMAIL "To: $address\n";
  827.     print SENDMAIL "Subject: $subject\n";
  828.     print SENDMAIL "Cc: $cc\n" if $cc;
  829.     print SENDMAIL "Reply-To: $from\n" if $from;
  830.     print SENDMAIL "Message-Id: $messageid\n" if $messageid;
  831.     print SENDMAIL "\n\n";
  832.     open(REP, "<$filename") or die "Couldn't open `$filename': $!\n";
  833.     while (<REP>) { print SENDMAIL $_ }
  834.     close(REP) or die "Error closing $filename: $!";
  835.  
  836.     if (close(SENDMAIL)) {
  837.         printf "\nMessage %s.\n", $outfile ? "saved" : "sent";
  838.     } else {
  839.         warn "\nSendmail returned status '", $? >> 8, "'\n";
  840.     }
  841.     }
  842.     1 while unlink($filename);  # remove all versions under VMS
  843. } # sub Send
  844.  
  845. sub Help {
  846.     print <<EOF;
  847.  
  848. A program to help generate bug reports about perl5, and mail them.
  849. It is designed to be used interactively. Normally no arguments will
  850. be needed.
  851.  
  852. Usage:
  853. $0  [-v] [-a address] [-s subject] [-b body | -f inpufile ] [ -F outputfile ]
  854.     [-r returnaddress] [-e editor] [-c adminaddress | -C] [-S] [-t] [-h]
  855. $0  [-v] [-r returnaddress] [-A] [-ok | -okay | -nok | -nokay]
  856.  
  857. Simplest usage:  run "$0", and follow the prompts.
  858.  
  859. Options:
  860.  
  861.   -v    Include Verbose configuration data in the report
  862.   -f    File containing the body of the report. Use this to
  863.         quickly send a prepared message.
  864.   -F    File to output the resulting mail message to, instead of mailing.
  865.   -S    Send without asking for confirmation.
  866.   -a    Address to send the report to. Defaults to `$address'.
  867.   -c    Address to send copy of report to. Defaults to `$cc'.
  868.   -C    Don't send copy to administrator.
  869.   -s    Subject to include with the message. You will be prompted
  870.         if you don't supply one on the command line.
  871.   -b    Body of the report. If not included on the command line, or
  872.         in a file with -f, you will get a chance to edit the message.
  873.   -r    Your return address. The program will ask you to confirm
  874.         this if you don't give it here.
  875.   -e    Editor to use.
  876.   -t    Test mode. The target address defaults to `$testaddress'.
  877.   -d    Data mode.  This prints out your configuration data, without mailing
  878.         anything. You can use this with -v to get more complete data.
  879.   -A    Don't send a bug received acknowledgement to the return address.
  880.   -ok   Report successful build on this system to perl porters
  881.         (use alone or with -v). Only use -ok if *everything* was ok:
  882.         if there were *any* problems at all, use -nok.
  883.   -okay As -ok but allow report from old builds.
  884.   -nok  Report unsuccessful build on this system to perl porters
  885.         (use alone or with -v). You must describe what went wrong
  886.         in the body of the report which you will be asked to edit.
  887.   -nokay As -nok but allow report from old builds.
  888.   -h    Print this help message.
  889.  
  890. EOF
  891. }
  892.  
  893. sub filename {
  894.     my $dir = File::Spec->tmpdir();
  895.     $filename = "bugrep0$$";
  896.     $filename++ while -e File::Spec->catfile($dir, $filename);
  897.     $filename = File::Spec->catfile($dir, $filename);
  898. }
  899.  
  900. sub paraprint {
  901.     my @paragraphs = split /\n{2,}/, "@_";
  902.     print "\n\n";
  903.     for (@paragraphs) {   # implicit local $_
  904.     s/(\S)\s*\n/$1 /g;
  905.     write;
  906.     print "\n";
  907.     }
  908. }
  909.  
  910. format STDOUT =
  911. ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< ~~
  912. $_
  913. .
  914.  
  915. __END__
  916.  
  917. =head1 NAME
  918.  
  919. perlbug - how to submit bug reports on Perl
  920.  
  921. =head1 SYNOPSIS
  922.  
  923. B<perlbug> S<[ B<-v> ]> S<[ B<-a> I<address> ]> S<[ B<-s> I<subject> ]>
  924. S<[ B<-b> I<body> | B<-f> I<inputfile> ]> S<[ B<-F> I<outputfile> ]>
  925. S<[ B<-r> I<returnaddress> ]>
  926. S<[ B<-e> I<editor> ]> S<[ B<-c> I<adminaddress> | B<-C> ]>
  927. S<[ B<-S> ]> S<[ B<-t> ]>  S<[ B<-d> ]>  S<[ B<-A> ]>  S<[ B<-h> ]>
  928.  
  929. B<perlbug> S<[ B<-v> ]> S<[ B<-r> I<returnaddress> ]>
  930.  S<[ B<-A> ]> S<[ B<-ok> | B<-okay> | B<-nok> | B<-nokay> ]>
  931.  
  932. =head1 DESCRIPTION
  933.  
  934. A program to help generate bug reports about perl or the modules that
  935. come with it, and mail them.
  936.  
  937. If you have found a bug with a non-standard port (one that was not part
  938. of the I<standard distribution>), a binary distribution, or a
  939. non-standard module (such as Tk, CGI, etc), then please see the
  940. documentation that came with that distribution to determine the correct
  941. place to report bugs.
  942.  
  943. C<perlbug> is designed to be used interactively. Normally no arguments
  944. will be needed.  Simply run it, and follow the prompts.
  945.  
  946. If you are unable to run B<perlbug> (most likely because you don't have
  947. a working setup to send mail that perlbug recognizes), you may have to
  948. compose your own report, and email it to B<perlbug@perl.org>.  You might
  949. find the B<-d> option useful to get summary information in that case.
  950.  
  951. In any case, when reporting a bug, please make sure you have run through
  952. this checklist:
  953.  
  954. =over 4
  955.  
  956. =item What version of Perl you are running?
  957.  
  958. Type C<perl -v> at the command line to find out.
  959.  
  960. =item Are you running the latest released version of perl?
  961.  
  962. Look at http://www.perl.com/ to find out.  If it is not the latest
  963. released version, get that one and see whether your bug has been
  964. fixed.  Note that bug reports about old versions of Perl, especially
  965. those prior to the 5.0 release, are likely to fall upon deaf ears.
  966. You are on your own if you continue to use perl1 .. perl4.
  967.  
  968. =item Are you sure what you have is a bug?
  969.  
  970. A significant number of the bug reports we get turn out to be documented
  971. features in Perl.  Make sure the behavior you are witnessing doesn't fall
  972. under that category, by glancing through the documentation that comes
  973. with Perl (we'll admit this is no mean task, given the sheer volume of
  974. it all, but at least have a look at the sections that I<seem> relevant).
  975.  
  976. Be aware of the familiar traps that perl programmers of various hues
  977. fall into.  See L<perltrap>.
  978.  
  979. Check in L<perldiag> to see what any Perl error message(s) mean.
  980. If message isn't in perldiag, it probably isn't generated by Perl.
  981. Consult your operating system documentation instead.
  982.  
  983. If you are on a non-UNIX platform check also L<perlport>, as some
  984. features may be unimplemented or work differently.
  985.  
  986. Try to study the problem under the Perl debugger, if necessary.
  987. See L<perldebug>.
  988.  
  989. =item Do you have a proper test case?
  990.  
  991. The easier it is to reproduce your bug, the more likely it will be
  992. fixed, because if no one can duplicate the problem, no one can fix it.
  993. A good test case has most of these attributes: fewest possible number
  994. of lines; few dependencies on external commands, modules, or
  995. libraries; runs on most platforms unimpeded; and is self-documenting.
  996.  
  997. A good test case is almost always a good candidate to be on the perl
  998. test suite.  If you have the time, consider making your test case so
  999. that it will readily fit into the standard test suite.
  1000.  
  1001. Remember also to include the B<exact> error messages, if any.
  1002. "Perl complained something" is not an exact error message.
  1003.  
  1004. If you get a core dump (or equivalent), you may use a debugger
  1005. (B<dbx>, B<gdb>, etc) to produce a stack trace to include in the bug
  1006. report.  NOTE: unless your Perl has been compiled with debug info
  1007. (often B<-g>), the stack trace is likely to be somewhat hard to use
  1008. because it will most probably contain only the function names and not
  1009. their arguments.  If possible, recompile your Perl with debug info and
  1010. reproduce the dump and the stack trace.
  1011.  
  1012. =item Can you describe the bug in plain English?
  1013.  
  1014. The easier it is to understand a reproducible bug, the more likely it
  1015. will be fixed.  Anything you can provide by way of insight into the
  1016. problem helps a great deal.  In other words, try to analyze the
  1017. problem (to the extent you can) and report your discoveries.
  1018.  
  1019. =item Can you fix the bug yourself?
  1020.  
  1021. A bug report which I<includes a patch to fix it> will almost
  1022. definitely be fixed.  Use the C<diff> program to generate your patches
  1023. (C<diff> is being maintained by the GNU folks as part of the B<diffutils>
  1024. package, so you should be able to get it from any of the GNU software
  1025. repositories).  If you do submit a patch, the cool-dude counter at
  1026. perlbug@perl.org will register you as a savior of the world.  Your
  1027. patch may be returned with requests for changes, or requests for more
  1028. detailed explanations about your fix.
  1029.  
  1030. Here are some clues for creating quality patches: Use the B<-c> or
  1031. B<-u> switches to the diff program (to create a so-called context or
  1032. unified diff).  Make sure the patch is not reversed (the first
  1033. argument to diff is typically the original file, the second argument
  1034. your changed file).  Make sure you test your patch by applying it with
  1035. the C<patch> program before you send it on its way.  Try to follow the
  1036. same style as the code you are trying to patch.  Make sure your patch
  1037. really does work (C<make test>, if the thing you're patching supports
  1038. it).
  1039.  
  1040. =item Can you use C<perlbug> to submit the report?
  1041.  
  1042. B<perlbug> will, amongst other things, ensure your report includes
  1043. crucial information about your version of perl.  If C<perlbug> is unable
  1044. to mail your report after you have typed it in, you may have to compose
  1045. the message yourself, add the output produced by C<perlbug -d> and email
  1046. it to B<perlbug@perl.org>.  If, for some reason, you cannot run
  1047. C<perlbug> at all on your system, be sure to include the entire output
  1048. produced by running C<perl -V> (note the uppercase V).
  1049.  
  1050. Whether you use C<perlbug> or send the email manually, please make
  1051. your Subject line informative.  "a bug" not informative.  Neither is
  1052. "perl crashes" nor "HELP!!!".  These don't help.
  1053. A compact description of what's wrong is fine.
  1054.  
  1055. =back
  1056.  
  1057. Having done your bit, please be prepared to wait, to be told the bug
  1058. is in your code, or even to get no reply at all.  The Perl maintainers
  1059. are busy folks, so if your problem is a small one or if it is difficult
  1060. to understand or already known, they may not respond with a personal reply.
  1061. If it is important to you that your bug be fixed, do monitor the
  1062. C<Changes> file in any development releases since the time you submitted
  1063. the bug, and encourage the maintainers with kind words (but never any
  1064. flames!).  Feel free to resend your bug report if the next released
  1065. version of perl comes out and your bug is still present.
  1066.  
  1067. =head1 OPTIONS
  1068.  
  1069. =over 8
  1070.  
  1071. =item B<-a>
  1072.  
  1073. Address to send the report to.  Defaults to B<perlbug@perl.org>.
  1074.  
  1075. =item B<-A>
  1076.  
  1077. Don't send a bug received acknowledgement to the reply address.
  1078. Generally it is only a sensible to use this option if you are a
  1079. perl maintainer actively watching perl porters for your message to
  1080. arrive.
  1081.  
  1082. =item B<-b>
  1083.  
  1084. Body of the report.  If not included on the command line, or
  1085. in a file with B<-f>, you will get a chance to edit the message.
  1086.  
  1087. =item B<-C>
  1088.  
  1089. Don't send copy to administrator.
  1090.  
  1091. =item B<-c>
  1092.  
  1093. Address to send copy of report to.  Defaults to the address of the
  1094. local perl administrator (recorded when perl was built).
  1095.  
  1096. =item B<-d>
  1097.  
  1098. Data mode (the default if you redirect or pipe output).  This prints out
  1099. your configuration data, without mailing anything.  You can use this
  1100. with B<-v> to get more complete data.
  1101.  
  1102. =item B<-e>
  1103.  
  1104. Editor to use.
  1105.  
  1106. =item B<-f>
  1107.  
  1108. File containing the body of the report.  Use this to quickly send a
  1109. prepared message.
  1110.  
  1111. =item B<-F>
  1112.  
  1113. File to output the results to instead of sending as an email. Useful
  1114. particularly when running perlbug on a machine with no direct internet
  1115. connection.
  1116.  
  1117. =item B<-h>
  1118.  
  1119. Prints a brief summary of the options.
  1120.  
  1121. =item B<-ok>
  1122.  
  1123. Report successful build on this system to perl porters. Forces B<-S>
  1124. and B<-C>. Forces and supplies values for B<-s> and B<-b>. Only
  1125. prompts for a return address if it cannot guess it (for use with
  1126. B<make>). Honors return address specified with B<-r>.  You can use this
  1127. with B<-v> to get more complete data.   Only makes a report if this
  1128. system is less than 60 days old.
  1129.  
  1130. =item B<-okay>
  1131.  
  1132. As B<-ok> except it will report on older systems.
  1133.  
  1134. =item B<-nok>
  1135.  
  1136. Report unsuccessful build on this system.  Forces B<-C>.  Forces and
  1137. supplies a value for B<-s>, then requires you to edit the report
  1138. and say what went wrong.  Alternatively, a prepared report may be
  1139. supplied using B<-f>.  Only prompts for a return address if it
  1140. cannot guess it (for use with B<make>). Honors return address
  1141. specified with B<-r>.  You can use this with B<-v> to get more
  1142. complete data.  Only makes a report if this system is less than 60
  1143. days old.
  1144.  
  1145. =item B<-nokay>
  1146.  
  1147. As B<-nok> except it will report on older systems.
  1148.  
  1149. =item B<-r>
  1150.  
  1151. Your return address.  The program will ask you to confirm its default
  1152. if you don't use this option.
  1153.  
  1154. =item B<-S>
  1155.  
  1156. Send without asking for confirmation.
  1157.  
  1158. =item B<-s>
  1159.  
  1160. Subject to include with the message.  You will be prompted if you don't
  1161. supply one on the command line.
  1162.  
  1163. =item B<-t>
  1164.  
  1165. Test mode.  The target address defaults to B<perlbug-test@perl.org>.
  1166.  
  1167. =item B<-v>
  1168.  
  1169. Include verbose configuration data in the report.
  1170.  
  1171. =back
  1172.  
  1173. =head1 AUTHORS
  1174.  
  1175. Kenneth Albanowski (E<lt>kjahds@kjahds.comE<gt>), subsequently I<doc>tored
  1176. by Gurusamy Sarathy (E<lt>gsar@activestate.comE<gt>), Tom Christiansen
  1177. (E<lt>tchrist@perl.comE<gt>), Nathan Torkington (E<lt>gnat@frii.comE<gt>),
  1178. Charles F. Randall (E<lt>cfr@pobox.comE<gt>), Mike Guy
  1179. (E<lt>mjtg@cam.a.ukE<gt>), Dominic Dunlop (E<lt>domo@computer.orgE<gt>),
  1180. Hugo van der Sanden (E<lt>hv@crypt.org<gt>),
  1181. Jarkko Hietaniemi (E<lt>jhi@iki.fiE<gt>), Chris Nandor
  1182. (E<lt>pudge@pobox.comE<gt>), Jon Orwant (E<lt>orwant@media.mit.eduE<gt>,
  1183. and Richard Foley (E<lt>richard@rfi.netE<gt>).
  1184.  
  1185. =head1 SEE ALSO
  1186.  
  1187. perl(1), perldebug(1), perldiag(1), perlport(1), perltrap(1),
  1188. diff(1), patch(1), dbx(1), gdb(1)
  1189.  
  1190. =head1 BUGS
  1191.  
  1192. None known (guess what must have been used to report them?)
  1193.  
  1194. =cut
  1195.  
  1196.