home *** CD-ROM | disk | FTP | other *** search
/ PC World 2005 June / PCWorld_2005-06_cd.bin / software / vyzkuste / firewally / firewally.exe / framework-2.3.exe / menu.vim < prev    next >
Text File  |  2003-08-12  |  33KB  |  956 lines
  1. " Vim support file to define the default menus
  2. " You can also use this as a start for your own set of menus.
  3. "
  4. " Maintainer:    Bram Moolenaar <Bram@vim.org>
  5. " Last Change:    2003 May 04
  6.  
  7. " Note that ":an" (short for ":anoremenu") is often used to make a menu work
  8. " in all modes and avoid side effects from mappings defined by the user.
  9.  
  10. " Make sure the '<' and 'C' flags are not included in 'cpoptions', otherwise
  11. " <CR> would not be recognized.  See ":help 'cpoptions'".
  12. let s:cpo_save = &cpo
  13. set cpo&vim
  14.  
  15. " Avoid installing the menus twice
  16. if !exists("did_install_default_menus")
  17. let did_install_default_menus = 1
  18.  
  19.  
  20. if exists("v:lang") || &langmenu != ""
  21.   " Try to find a menu translation file for the current language.
  22.   if &langmenu != ""
  23.     if &langmenu =~ "none"
  24.       let s:lang = ""
  25.     else
  26.       let s:lang = &langmenu
  27.     endif
  28.   else
  29.     let s:lang = v:lang
  30.   endif
  31.   " A language name must be at least two characters, don't accept "C"
  32.   if strlen(s:lang) > 1
  33.     " We always use a lowercase name.
  34.     " Change "iso-8859" to "iso_8859" and "iso8859" to "iso_8859", some
  35.     " systems appear to use this.
  36.     " Change spaces to underscores.
  37.     let s:lang = substitute(tolower(s:lang), "\\.iso-", ".iso_", "")
  38.     let s:lang = substitute(s:lang, "\\.iso8859", ".iso_8859", "")
  39.     let s:lang = substitute(s:lang, " ", "_", "g")
  40.     " Remove "@euro", otherwise "LC_ALL=de_DE@euro gvim" will show English menus
  41.     let s:lang = substitute(s:lang, "@euro", "", "")
  42.     menutrans clear
  43.     exe "runtime! lang/menu_" . s:lang . ".vim"
  44.  
  45.     if !exists("did_menu_trans")
  46.       " There is no exact match, try matching with a wildcard added
  47.       " (e.g. find menu_de_de.iso_8859-1.vim if s:lang == de_DE).
  48.       exe "runtime! lang/menu_" . s:lang . "*.vim"
  49.  
  50.       if !exists("did_menu_trans") && strlen($LANG) > 1
  51.     " On windows locale names are complicated, try using $LANG, it might
  52.     " have been set by set_init_1().
  53.     exe "runtime! lang/menu_" . tolower($LANG) . "*.vim"
  54.       endif
  55.     endif
  56.   endif
  57. endif
  58.  
  59.  
  60. " Help menu
  61. an 9999.10 &Help.&Overview<Tab><F1>    :help<CR>
  62. an 9999.20 &Help.&User\ Manual        :help usr_toc<CR>
  63. an 9999.30 &Help.&How-to\ links        :help how-to<CR>
  64. an <silent> 9999.40 &Help.&Find\.\.\.    :call <SID>Helpfind()<CR>
  65. an 9999.45 &Help.-sep1-            <Nop>
  66. an 9999.50 &Help.&Credits        :help credits<CR>
  67. an 9999.60 &Help.Co&pying        :help copying<CR>
  68. an 9999.70 &Help.O&rphans        :help kcc<CR>
  69. an 9999.75 &Help.-sep2-            <Nop>
  70. an 9999.80 &Help.&Version        :version<CR>
  71. an 9999.90 &Help.&About            :intro<CR>
  72.  
  73. fun! s:Helpfind()
  74.   if !exists("g:menutrans_help_dialog")
  75.     let g:menutrans_help_dialog = "Enter a command or word to find help on:\n\nPrepend i_ for Input mode commands (e.g.: i_CTRL-X)\nPrepend c_ for command-line editing commands (e.g.: c_<Del>)\nPrepend ' for an option name (e.g.: 'shiftwidth')"
  76.   endif
  77.   let h = inputdialog(g:menutrans_help_dialog)
  78.   if h != ""
  79.     let v:errmsg = ""
  80.     silent! exe "help " . h
  81.     if v:errmsg != ""
  82.       echo v:errmsg
  83.     endif
  84.   endif
  85. endfun
  86.  
  87. " File menu
  88. an 10.310 &File.&Open\.\.\.<Tab>:e        :browse confirm e<CR>
  89. an 10.320 &File.Sp&lit-Open\.\.\.<Tab>:sp    :browse sp<CR>
  90. an 10.325 &File.&New<Tab>:enew            :confirm enew<CR>
  91. an <silent> 10.330 &File.&Close<Tab>:close
  92.     \ :if winheight(2) < 0 <Bar>
  93.     \   confirm enew <Bar>
  94.     \ else <Bar>
  95.     \   confirm close <Bar>
  96.     \ endif<CR>
  97. an 10.335 &File.-SEP1-                <Nop>
  98. an <silent> 10.340 &File.&Save<Tab>:w        :if expand("%") == ""<Bar>browse confirm w<Bar>else<Bar>confirm w<Bar>endif<CR>
  99. an 10.350 &File.Save\ &As\.\.\.<Tab>:sav    :browse confirm saveas<CR>
  100.  
  101. if has("diff")
  102.   an 10.400 &File.-SEP2-            <Nop>
  103.   an 10.410 &File.Split\ &Diff\ with\.\.\.    :browse vert diffsplit<CR>
  104.   an 10.420 &File.Split\ Patched\ &By\.\.\.    :browse vert diffpatch<CR>
  105. endif
  106.  
  107. if has("printer")
  108.   an 10.500 &File.-SEP3-            <Nop>
  109.   an 10.510 &File.&Print            :hardcopy<CR>
  110.   vunmenu   &File.&Print
  111.   vnoremenu &File.&Print            :hardcopy<CR>
  112. elseif has("unix")
  113.   an 10.500 &File.-SEP3-            <Nop>
  114.   an 10.510 &File.&Print            :w !lpr<CR>
  115.   vunmenu   &File.&Print
  116.   vnoremenu &File.&Print            :w !lpr<CR>
  117. endif
  118. an 10.600 &File.-SEP4-                <Nop>
  119. an 10.610 &File.Sa&ve-Exit<Tab>:wqa        :confirm wqa<CR>
  120. an 10.620 &File.E&xit<Tab>:qa            :confirm qa<CR>
  121.  
  122. " Pasting blockwise and linewise selections is not possible in Insert and
  123. " Visual mode without the +virtualedit feature.  They are pasted as if they
  124. " were characterwise instead.  Add to that some tricks to leave the cursor in
  125. " the right position, also for "gi".
  126. if has("virtualedit")
  127.   nnoremap <silent> <script> <SID>Paste :call <SID>Paste()<CR>
  128.   func! <SID>Paste()
  129.     let ove = &ve
  130.     set ve=all
  131.     normal `^
  132.     if @+ != ''
  133.       normal "+gP
  134.     endif
  135.     let c = col(".")
  136.     normal i
  137.     if col(".") < c    " compensate for i<ESC> moving the cursor left
  138.       normal l
  139.     endif
  140.     let &ve = ove
  141.   endfunc
  142. else
  143.   nnoremap <silent> <script> <SID>Paste "=@+.'xy'<CR>gPFx"_2x
  144. endif
  145.  
  146. " Edit menu
  147. an 20.310 &Edit.&Undo<Tab>u            u
  148. an 20.320 &Edit.&Redo<Tab>^R            <C-R>
  149. an 20.330 &Edit.Rep&eat<Tab>\.            .
  150.  
  151. an 20.335 &Edit.-SEP1-                <Nop>
  152. vnoremenu 20.340 &Edit.Cu&t<Tab>"+x        "+x
  153. vnoremenu 20.350 &Edit.&Copy<Tab>"+y        "+y
  154. cnoremenu 20.350 &Edit.&Copy<Tab>"+y        <C-Y>
  155. nnoremenu 20.360 &Edit.&Paste<Tab>"+gP        "+gP
  156. cnoremenu     &Edit.&Paste<Tab>"+gP        <C-R>+
  157. if has("virtualedit")
  158.   vnoremenu <script>     &Edit.&Paste<Tab>"+gP    "-c<Esc><SID>Paste
  159.   inoremenu <script>     &Edit.&Paste<Tab>"+gP    <Esc><SID>Pastegi
  160. else
  161.   vnoremenu <script>     &Edit.&Paste<Tab>"+gP    "-c<Esc>gix<Esc><SID>Paste"_x
  162.   inoremenu <script>     &Edit.&Paste<Tab>"+gP    x<Esc><SID>Paste"_s
  163. endif
  164. nnoremenu 20.370 &Edit.Put\ &Before<Tab>[p    [p
  165. inoremenu     &Edit.Put\ &Before<Tab>[p    <C-O>[p
  166. nnoremenu 20.380 &Edit.Put\ &After<Tab>]p    ]p
  167. inoremenu     &Edit.Put\ &After<Tab>]p    <C-O>]p
  168. if has("win32") || has("win16")
  169.   vnoremenu 20.390 &Edit.&Delete<Tab>x        x
  170. endif
  171. an <silent> 20.400 &Edit.&Select\ all<Tab>ggVG    :if &slm != ""<Bar>exe ":norm gggH<C-O>G"<Bar>else<Bar>exe ":norm ggVG"<Bar>endif<CR>
  172.  
  173. an 20.405     &Edit.-SEP2-                <Nop>
  174. if has("win32")  || has("win16") || has("gui_gtk") || has("gui_motif")
  175.   an 20.410     &Edit.&Find\.\.\.            :promptfind<CR>
  176.   vunmenu     &Edit.&Find\.\.\.
  177.   vnoremenu     &Edit.&Find\.\.\.            y:promptfind <C-R>"<CR>
  178.   an 20.420     &Edit.Find\ and\ Rep&lace\.\.\.    :promptrepl<CR>
  179.   vunmenu     &Edit.Find\ and\ Rep&lace\.\.\.
  180.   vnoremenu     &Edit.Find\ and\ Rep&lace\.\.\.    y:promptrepl <C-R>"<CR>
  181. else
  182.   an 20.410     &Edit.&Find<Tab>/            /
  183.   an 20.420     &Edit.Find\ and\ Rep&lace<Tab>:%s    :%s/
  184.   vunmenu     &Edit.Find\ and\ Rep&lace<Tab>:%s
  185.   vnoremenu     &Edit.Find\ and\ Rep&lace<Tab>:s    :s/
  186. endif
  187.  
  188. an 20.425     &Edit.-SEP3-                <Nop>
  189. an 20.430     &Edit.Settings\ &Window        :options<CR>
  190.  
  191. " Edit/Global Settings
  192. an 20.440.100 &Edit.&Global\ Settings.Toggle\ Pattern\ &Highlight<Tab>:set\ hls!    :set hls! hls?<CR>
  193. an 20.440.110 &Edit.&Global\ Settings.Toggle\ &Ignore-case<Tab>:set\ ic!    :set ic! ic?<CR>
  194. an 20.440.110 &Edit.&Global\ Settings.Toggle\ &Showmatch<Tab>:set\ sm!    :set sm! sm?<CR>
  195.  
  196. an 20.440.120 &Edit.&Global\ Settings.&Context\ lines.\ 1\  :set so=1<CR>
  197. an 20.440.120 &Edit.&Global\ Settings.&Context\ lines.\ 2\  :set so=2<CR>
  198. an 20.440.120 &Edit.&Global\ Settings.&Context\ lines.\ 3\  :set so=3<CR>
  199. an 20.440.120 &Edit.&Global\ Settings.&Context\ lines.\ 4\  :set so=4<CR>
  200. an 20.440.120 &Edit.&Global\ Settings.&Context\ lines.\ 5\  :set so=5<CR>
  201. an 20.440.120 &Edit.&Global\ Settings.&Context\ lines.\ 7\  :set so=7<CR>
  202. an 20.440.120 &Edit.&Global\ Settings.&Context\ lines.\ 10\  :set so=10<CR>
  203. an 20.440.120 &Edit.&Global\ Settings.&Context\ lines.\ 100\  :set so=100<CR>
  204.  
  205. an 20.440.130.40 &Edit.&Global\ Settings.&Virtual\ Edit.Never :set ve=<CR>
  206. an 20.440.130.50 &Edit.&Global\ Settings.&Virtual\ Edit.Block\ Selection :set ve=block<CR>
  207. an 20.440.130.60 &Edit.&Global\ Settings.&Virtual\ Edit.Insert\ mode :set ve=insert<CR>
  208. an 20.440.130.70 &Edit.&Global\ Settings.&Virtual\ Edit.Block\ and\ Insert :set ve=block,insert<CR>
  209. an 20.440.130.80 &Edit.&Global\ Settings.&Virtual\ Edit.Always :set ve=all<CR>
  210. an 20.440.140 &Edit.&Global\ Settings.Toggle\ Insert\ &Mode<Tab>:set\ im!    :set im!<CR>
  211. an 20.440.145 &Edit.&Global\ Settings.Toggle\ Vi\ C&ompatible<Tab>:set\ cp!    :set cp!<CR>
  212. an <silent> 20.440.150 &Edit.&Global\ Settings.Search\ &Path\.\.\.  :call <SID>SearchP()<CR>
  213. an <silent> 20.440.160 &Edit.&Global\ Settings.Ta&g\ Files\.\.\.  :call <SID>TagFiles()<CR>
  214. "
  215. " GUI options
  216. an 20.440.300 &Edit.&Global\ Settings.-SEP1-                <Nop>
  217. an <silent> 20.440.310 &Edit.&Global\ Settings.Toggle\ &Toolbar        :call <SID>ToggleGuiOption("T")<CR>
  218. an <silent> 20.440.320 &Edit.&Global\ Settings.Toggle\ &Bottom\ Scrollbar :call <SID>ToggleGuiOption("b")<CR>
  219. an <silent> 20.440.330 &Edit.&Global\ Settings.Toggle\ &Left\ Scrollbar    :call <SID>ToggleGuiOption("l")<CR>
  220. an <silent> 20.440.340 &Edit.&Global\ Settings.Toggle\ &Right\ Scrollbar :call <SID>ToggleGuiOption("r")<CR>
  221.  
  222. fun! s:SearchP()
  223.   if !exists("g:menutrans_path_dialog")
  224.     let g:menutrans_path_dialog = "Enter search path for files.\nSeparate directory names with a comma."
  225.   endif
  226.   let n = inputdialog(g:menutrans_path_dialog, substitute(&path, '\\ ', ' ', 'g'))
  227.   if n != ""
  228.     let &path = substitute(n, ' ', '\\ ', 'g')
  229.   endif
  230. endfun
  231.  
  232. fun! s:TagFiles()
  233.   if !exists("g:menutrans_tags_dialog")
  234.     let g:menutrans_tags_dialog = "Enter names of tag files.\nSeparate the names with a comma."
  235.   endif
  236.   let n = inputdialog(g:menutrans_tags_dialog, substitute(&tags, '\\ ', ' ', 'g'))
  237.   if n != ""
  238.     let &tags = substitute(n, ' ', '\\ ', 'g')
  239.   endif
  240. endfun
  241.  
  242. fun! s:ToggleGuiOption(option)
  243.     " If a:option is already set in guioptions, then we want to remove it
  244.     if match(&guioptions, "\\C" . a:option) > -1
  245.     exec "set go-=" . a:option
  246.     else
  247.     exec "set go+=" . a:option
  248.     endif
  249. endfun
  250.  
  251. " Edit/File Settings
  252.  
  253. " Boolean options
  254. an 20.440.100 &Edit.F&ile\ Settings.Toggle\ Line\ &Numbering<Tab>:set\ nu!    :set nu! nu?<CR>
  255. an 20.440.110 &Edit.F&ile\ Settings.Toggle\ &List\ Mode<Tab>:set\ list!    :set list! list?<CR>
  256. an 20.440.120 &Edit.F&ile\ Settings.Toggle\ Line\ &Wrap<Tab>:set\ wrap!    :set wrap! wrap?<CR>
  257. an 20.440.130 &Edit.F&ile\ Settings.Toggle\ W&rap\ at\ word<Tab>:set\ lbr!    :set lbr! lbr?<CR>
  258. an 20.440.160 &Edit.F&ile\ Settings.Toggle\ &expand-tab<Tab>:set\ et!    :set et! et?<CR>
  259. an 20.440.170 &Edit.F&ile\ Settings.Toggle\ &auto-indent<Tab>:set\ ai!    :set ai! ai?<CR>
  260. an 20.440.180 &Edit.F&ile\ Settings.Toggle\ &C-indenting<Tab>:set\ cin!    :set cin! cin?<CR>
  261.  
  262. " other options
  263. an 20.440.600 &Edit.F&ile\ Settings.-SEP2-        <Nop>
  264. an 20.440.610.20 &Edit.F&ile\ Settings.&Shiftwidth.2    :set sw=2 sw?<CR>
  265. an 20.440.610.30 &Edit.F&ile\ Settings.&Shiftwidth.3    :set sw=3 sw?<CR>
  266. an 20.440.610.40 &Edit.F&ile\ Settings.&Shiftwidth.4    :set sw=4 sw?<CR>
  267. an 20.440.610.50 &Edit.F&ile\ Settings.&Shiftwidth.5    :set sw=5 sw?<CR>
  268. an 20.440.610.60 &Edit.F&ile\ Settings.&Shiftwidth.6    :set sw=6 sw?<CR>
  269. an 20.440.610.80 &Edit.F&ile\ Settings.&Shiftwidth.8    :set sw=8 sw?<CR>
  270.  
  271. an 20.440.620.20 &Edit.F&ile\ Settings.Soft\ &Tabstop.2    :set sts=2 sts?<CR>
  272. an 20.440.620.30 &Edit.F&ile\ Settings.Soft\ &Tabstop.3    :set sts=3 sts?<CR>
  273. an 20.440.620.40 &Edit.F&ile\ Settings.Soft\ &Tabstop.4    :set sts=4 sts?<CR>
  274. an 20.440.620.50 &Edit.F&ile\ Settings.Soft\ &Tabstop.5    :set sts=5 sts?<CR>
  275. an 20.440.620.60 &Edit.F&ile\ Settings.Soft\ &Tabstop.6    :set sts=6 sts?<CR>
  276. an 20.440.620.80 &Edit.F&ile\ Settings.Soft\ &Tabstop.8    :set sts=8 sts?<CR>
  277.  
  278. an <silent> 20.440.630 &Edit.F&ile\ Settings.Te&xt\ Width\.\.\.  :call <SID>TextWidth()<CR>
  279. an <silent> 20.440.640 &Edit.F&ile\ Settings.&File\ Format\.\.\.  :call <SID>FileFormat()<CR>
  280. fun! s:TextWidth()
  281.   if !exists("g:menutrans_textwidth_dialog")
  282.     let g:menutrans_textwidth_dialog = "Enter new text width (0 to disable formatting): "
  283.   endif
  284.   let n = inputdialog(g:menutrans_textwidth_dialog, &tw)
  285.   if n != ""
  286.     " remove leading zeros to avoid it being used as an octal number
  287.     let &tw = substitute(n, "^0*", "", "")
  288.   endif
  289. endfun
  290.  
  291. fun! s:FileFormat()
  292.   if !exists("g:menutrans_fileformat_dialog")
  293.     let g:menutrans_fileformat_dialog = "Select format for writing the file"
  294.   endif
  295.   if !exists("g:menutrans_fileformat_choices")
  296.     let g:menutrans_fileformat_choices = "&Unix\n&Dos\n&Mac\n&Cancel"
  297.   endif
  298.   if &ff == "dos"
  299.     let def = 2
  300.   elseif &ff == "mac"
  301.     let def = 3
  302.   else
  303.     let def = 1
  304.   endif
  305.   let n = confirm(g:menutrans_fileformat_dialog, g:menutrans_fileformat_choices, def, "Question")
  306.   if n == 1
  307.     set ff=unix
  308.   elseif n == 2
  309.     set ff=dos
  310.   elseif n == 3
  311.     set ff=mac
  312.   endif
  313. endfun
  314.  
  315. " Setup the Edit.Color Scheme submenu
  316. let s:n = globpath(&runtimepath, "colors/*.vim")
  317. let s:idx = 100
  318. while strlen(s:n) > 0
  319.   let s:i = stridx(s:n, "\n")
  320.   if s:i < 0
  321.     let s:name = s:n
  322.     let s:n = ""
  323.   else
  324.     let s:name = strpart(s:n, 0, s:i)
  325.     let s:n = strpart(s:n, s:i + 1, 19999)
  326.   endif
  327.   " Ignore case for VMS and windows
  328.   let s:name = substitute(s:name, '\c.*[/\\:\]]\([^/\\:]*\)\.vim', '\1', '')
  329.   exe "an 20.450." . s:idx . ' &Edit.C&olor\ Scheme.' . s:name . " :colors " . s:name . "<CR>"
  330.   unlet s:name
  331.   unlet s:i
  332.   let s:idx = s:idx + 10
  333. endwhile
  334. unlet s:n
  335. unlet s:idx
  336.  
  337. " Setup the Edit.Keymap submenu
  338. if has("keymap")
  339.   let s:n = globpath(&runtimepath, "keymap/*.vim")
  340.   if s:n != ""
  341.     let s:idx = 100
  342.     an 20.460.90 &Edit.&Keymap.None :set keymap=<CR>
  343.     while strlen(s:n) > 0
  344.       let s:i = stridx(s:n, "\n")
  345.       if s:i < 0
  346.     let s:name = s:n
  347.     let s:n = ""
  348.       else
  349.     let s:name = strpart(s:n, 0, s:i)
  350.     let s:n = strpart(s:n, s:i + 1, 19999)
  351.       endif
  352.       " Ignore case for VMS and windows
  353.       let s:name = substitute(s:name, '\c.*[/\\:\]]\([^/\\:_]*\)\(_[0-9a-zA-Z-]*\)\=\.vim', '\1', '')
  354.       exe "an 20.460." . s:idx . ' &Edit.&Keymap.' . s:name . " :set keymap=" . s:name . "<CR>"
  355.       unlet s:name
  356.       unlet s:i
  357.       let s:idx = s:idx + 10
  358.     endwhile
  359.     unlet s:idx
  360.   endif
  361.   unlet s:n
  362. endif
  363. if has("win32") || has("win16") || has("gui_gtk") || has("gui_photon")
  364.   an 20.470 &Edit.Select\ Fo&nt\.\.\.    :set guifont=*<CR>
  365. endif
  366.  
  367. " Programming menu
  368. an 40.300 &Tools.&Jump\ to\ this\ tag<Tab>g^]    g<C-]>
  369. vunmenu &Tools.&Jump\ to\ this\ tag<Tab>g^]
  370. vnoremenu &Tools.&Jump\ to\ this\ tag<Tab>g^]    g<C-]>
  371. an 40.310 &Tools.Jump\ &back<Tab>^T        <C-T>
  372. if has("vms")
  373.   an 40.320 &Tools.Build\ &Tags\ File        :!mc vim:ctags .<CR>
  374. else
  375.   an 40.320 &Tools.Build\ &Tags\ File        :!ctags -R .<CR>
  376. endif
  377.  
  378. " Tools.Fold Menu
  379. if has("folding")
  380.   an 40.330 &Tools.-SEP1-                        <Nop>
  381.   " open close folds
  382.   an 40.340.110 &Tools.&Folding.&Enable/Disable\ folds<Tab>zi        zi
  383.   an 40.340.120 &Tools.&Folding.&View\ Cursor\ Line<Tab>zv        zv
  384.   an 40.340.120 &Tools.&Folding.Vie&w\ Cursor\ Line\ only<Tab>zMzx    zMzx
  385.   an 40.340.130 &Tools.&Folding.C&lose\ more\ folds<Tab>zm        zm
  386.   an 40.340.140 &Tools.&Folding.&Close\ all\ folds<Tab>zM        zM
  387.   an 40.340.150 &Tools.&Folding.O&pen\ more\ folds<Tab>zr        zr
  388.   an 40.340.160 &Tools.&Folding.&Open\ all\ folds<Tab>zR        zR
  389.   " fold method
  390.   an 40.340.200 &Tools.&Folding.-SEP1-            <Nop>
  391.   an 40.340.210 &Tools.&Folding.Fold\ Met&hod.M&anual    :set fdm=manual<CR>
  392.   an 40.340.210 &Tools.&Folding.Fold\ Met&hod.I&ndent    :set fdm=indent<CR>
  393.   an 40.340.210 &Tools.&Folding.Fold\ Met&hod.E&xpression :set fdm=expr<CR>
  394.   an 40.340.210 &Tools.&Folding.Fold\ Met&hod.S&yntax    :set fdm=syntax<CR>
  395.   an 40.340.210 &Tools.&Folding.Fold\ Met&hod.&Diff    :set fdm=diff<CR>
  396.   an 40.340.210 &Tools.&Folding.Fold\ Met&hod.Ma&rker    :set fdm=marker<CR>
  397.   " create and delete folds
  398.   vnoremenu 40.340.220 &Tools.&Folding.Create\ &Fold<Tab>zf    zf
  399.   an 40.340.230 &Tools.&Folding.&Delete\ Fold<Tab>zd        zd
  400.   an 40.340.240 &Tools.&Folding.Delete\ &All\ Folds<Tab>zD    zD
  401.   " moving around in folds
  402.   an 40.340.300 &Tools.&Folding.-SEP2-                <Nop>
  403.   an 40.340.310.10 &Tools.&Folding.Fold\ col&umn\ width.\ &0\     :set fdc=0<CR>
  404.   an 40.340.310.20 &Tools.&Folding.Fold\ col&umn\ width.\ &2\     :set fdc=2<CR>
  405.   an 40.340.310.30 &Tools.&Folding.Fold\ col&umn\ width.\ &3\     :set fdc=3<CR>
  406.   an 40.340.310.40 &Tools.&Folding.Fold\ col&umn\ width.\ &4\     :set fdc=4<CR>
  407.   an 40.340.310.50 &Tools.&Folding.Fold\ col&umn\ width.\ &5\     :set fdc=5<CR>
  408.   an 40.340.310.60 &Tools.&Folding.Fold\ col&umn\ width.\ &6\     :set fdc=6<CR>
  409.   an 40.340.310.70 &Tools.&Folding.Fold\ col&umn\ width.\ &7\     :set fdc=7<CR>
  410.   an 40.340.310.80 &Tools.&Folding.Fold\ col&umn\ width.\ &8\     :set fdc=8<CR>
  411. endif  " has folding
  412.  
  413. if has("diff")
  414.   an 40.350.100 &Tools.&Diff.&Update        :diffupdate<CR>
  415.   an 40.350.110 &Tools.&Diff.&Get\ Block    :diffget<CR>
  416.   vunmenu &Tools.&Diff.&Get\ Block
  417.   vnoremenu &Tools.&Diff.&Get\ Block        :diffget<CR>
  418.   an 40.350.120 &Tools.&Diff.&Put\ Block    :diffput<CR>
  419.   vunmenu &Tools.&Diff.&Put\ Block
  420.   vnoremenu &Tools.&Diff.&Put\ Block        :diffput<CR>
  421. endif
  422.  
  423. an 40.358 &Tools.-SEP2-                    <Nop>
  424. an 40.360 &Tools.&Make<Tab>:make            :make<CR>
  425. an 40.370 &Tools.&List\ Errors<Tab>:cl            :cl<CR>
  426. an 40.380 &Tools.L&ist\ Messages<Tab>:cl!        :cl!<CR>
  427. an 40.390 &Tools.&Next\ Error<Tab>:cn            :cn<CR>
  428. an 40.400 &Tools.&Previous\ Error<Tab>:cp        :cp<CR>
  429. an 40.410 &Tools.&Older\ List<Tab>:cold            :colder<CR>
  430. an 40.420 &Tools.N&ewer\ List<Tab>:cnew            :cnewer<CR>
  431. an 40.430.50 &Tools.Error\ &Window.&Update<Tab>:cwin    :cwin<CR>
  432. an 40.430.60 &Tools.Error\ &Window.&Open<Tab>:copen    :copen<CR>
  433. an 40.430.70 &Tools.Error\ &Window.&Close<Tab>:cclose    :cclose<CR>
  434.  
  435. an 40.520 &Tools.-SEP3-                    <Nop>
  436. an <silent> 40.530 &Tools.&Convert\ to\ HEX<Tab>:%!xxd
  437.     \ :call <SID>XxdConv()<CR>
  438. an <silent> 40.540 &Tools.Conve&rt\ back<Tab>:%!xxd\ -r
  439.     \ :call <SID>XxdBack()<CR>
  440.  
  441. " Use a function to do the conversion, so that it also works with 'insertmode'
  442. " set.
  443. func! s:XxdConv()
  444.   let mod = &mod
  445.   if has("vms")
  446.     %!mc vim:xxd
  447.   else
  448.     call s:XxdFind()
  449.     exe '%!"' . g:xxdprogram . '"'
  450.   endif
  451.   if getline(1) =~ "^0000000:"        " only if it worked
  452.     set ft=xxd
  453.   endif
  454.   let &mod = mod
  455. endfun
  456.  
  457. func! s:XxdBack()
  458.   let mod = &mod
  459.   if has("vms")
  460.     %!mc vim:xxd -r
  461.   else
  462.     call s:XxdFind()
  463.     exe '%!"' . g:xxdprogram . '" -r'
  464.   endif
  465.   set ft=
  466.   doautocmd filetypedetect BufReadPost
  467.   let &mod = mod
  468. endfun
  469.  
  470. func! s:XxdFind()
  471.   if !exists("g:xxdprogram")
  472.     " On the PC xxd may not be in the path but in the install directory
  473.     if (has("win32") || has("dos32")) && !executable("xxd")
  474.       let g:xxdprogram = $VIMRUNTIME . (&shellslash ? '/' : '\') . "xxd.exe"
  475.     else
  476.       let g:xxdprogram = "xxd"
  477.     endif
  478.   endif
  479. endfun
  480.  
  481. " Setup the Tools.Compiler submenu
  482. let s:n = globpath(&runtimepath, "compiler/*.vim")
  483. let s:idx = 100
  484. while strlen(s:n) > 0
  485.   let s:i = stridx(s:n, "\n")
  486.   if s:i < 0
  487.     let s:name = s:n
  488.     let s:n = ""
  489.   else
  490.     let s:name = strpart(s:n, 0, s:i)
  491.     let s:n = strpart(s:n, s:i + 1, 19999)
  492.   endif
  493.   " Ignore case for VMS and windows
  494.   let s:name = substitute(s:name, '\c.*[/\\:\]]\([^/\\:]*\)\.vim', '\1', '')
  495.   exe "an 30.440." . s:idx . ' &Tools.&Set\ Compiler.' . s:name . " :compiler " . s:name . "<CR>"
  496.   unlet s:name
  497.   unlet s:i
  498.   let s:idx = s:idx + 10
  499. endwhile
  500. unlet s:n
  501. unlet s:idx
  502.  
  503. if !exists("no_buffers_menu")
  504.  
  505. " Buffer list menu -- Setup functions & actions
  506.  
  507. " wait with building the menu until after loading 'session' files. Makes
  508. " startup faster.
  509. let s:bmenu_wait = 1
  510.  
  511. if !exists("bmenu_priority")
  512.   let bmenu_priority = 60
  513. endif
  514.  
  515. func! s:BMAdd()
  516.   if s:bmenu_wait == 0
  517.     " when adding too many buffers, redraw in short format
  518.     if s:bmenu_count == &menuitems && s:bmenu_short == 0
  519.       call s:BMShow()
  520.     else
  521.       call <SID>BMFilename(expand("<afile>"), expand("<abuf>"))
  522.       let s:bmenu_count = s:bmenu_count + 1
  523.     endif
  524.   endif
  525. endfunc
  526.  
  527. func! s:BMRemove()
  528.   if s:bmenu_wait == 0
  529.     let name = expand("<afile>")
  530.     if isdirectory(name)
  531.       return
  532.     endif
  533.     let munge = <SID>BMMunge(name, expand("<abuf>"))
  534.  
  535.     if s:bmenu_short == 0
  536.       exe 'silent! aun &Buffers.' . munge
  537.     else
  538.       exe 'silent! aun &Buffers.' . <SID>BMHash2(munge) . munge
  539.     endif
  540.     let s:bmenu_count = s:bmenu_count - 1
  541.   endif
  542. endfunc
  543.  
  544. " Create the buffer menu (delete an existing one first).
  545. func! s:BMShow(...)
  546.   let s:bmenu_wait = 1
  547.   let s:bmenu_short = 1
  548.   let s:bmenu_count = 0
  549.   "
  550.   " get new priority, if exists
  551.   if a:0 == 1
  552.     let g:bmenu_priority = a:1
  553.   endif
  554.  
  555.   " remove old menu, if exists; keep one entry to avoid a torn off menu to
  556.   " disappear.
  557.   silent! unmenu &Buffers
  558.   exe 'noremenu ' . g:bmenu_priority . ".1 &Buffers.Dummy l"
  559.   silent! unmenu! &Buffers
  560.  
  561.   " create new menu; set 'cpo' to include the <CR>
  562.   let cpo_save = &cpo
  563.   set cpo&vim
  564.   exe 'an <silent> ' . g:bmenu_priority . ".2 &Buffers.&Refresh\\ menu :call <SID>BMShow()<CR>"
  565.   exe 'an ' . g:bmenu_priority . ".4 &Buffers.&Delete :bd<CR>"
  566.   exe 'an ' . g:bmenu_priority . ".6 &Buffers.&Alternate :b #<CR>"
  567.   exe 'an ' . g:bmenu_priority . ".7 &Buffers.&Next :bnext<CR>"
  568.   exe 'an ' . g:bmenu_priority . ".8 &Buffers.&Previous :bprev<CR>"
  569.   exe 'an ' . g:bmenu_priority . ".9 &Buffers.-SEP- :"
  570.   let &cpo = cpo_save
  571.   unmenu &Buffers.Dummy
  572.  
  573.   " figure out how many buffers there are
  574.   let buf = 1
  575.   while buf <= bufnr('$')
  576.     if bufexists(buf) && !isdirectory(bufname(buf)) && buflisted(buf)
  577.                         \ && !getbufvar(buf, "&bufsecret")
  578.       let s:bmenu_count = s:bmenu_count + 1
  579.     endif
  580.     let buf = buf + 1
  581.   endwhile
  582.   if s:bmenu_count <= &menuitems
  583.     let s:bmenu_short = 0
  584.   endif
  585.  
  586.   " iterate through buffer list, adding each buffer to the menu:
  587.   let buf = 1
  588.   while buf <= bufnr('$')
  589.     if bufexists(buf) && !isdirectory(bufname(buf)) && buflisted(buf)
  590.                         \ && !getbufvar(buf, "&bufsecret")
  591.       call <SID>BMFilename(bufname(buf), buf)
  592.     endif
  593.     let buf = buf + 1
  594.   endwhile
  595.   let s:bmenu_wait = 0
  596.   aug buffer_list
  597.   au!
  598.   au BufCreate,BufFilePost * call <SID>BMAdd()
  599.   au BufDelete,BufFilePre * call <SID>BMRemove()
  600.   aug END
  601. endfunc
  602.  
  603. func! s:BMHash(name)
  604.   " Make name all upper case, so that chars are between 32 and 96
  605.   let nm = substitute(a:name, ".*", '\U\0', "")
  606.   if has("ebcdic")
  607.     " HACK: Replace all non alphabetics with 'Z'
  608.     "       Just to make it work for now.
  609.     let nm = substitute(nm, "[^A-Z]", 'Z', "g")
  610.     let sp = char2nr('A') - 1
  611.   else
  612.     let sp = char2nr(' ')
  613.   endif
  614.   " convert first six chars into a number for sorting:
  615.   return (char2nr(nm[0]) - sp) * 0x800000 + (char2nr(nm[1]) - sp) * 0x20000 + (char2nr(nm[2]) - sp) * 0x1000 + (char2nr(nm[3]) - sp) * 0x80 + (char2nr(nm[4]) - sp) * 0x20 + (char2nr(nm[5]) - sp)
  616. endfunc
  617.  
  618. func! s:BMHash2(name)
  619.   let nm = substitute(a:name, ".", '\L\0', "")
  620.   " Not exactly right for EBCDIC...
  621.   if nm[0] < 'a' || nm[0] > 'z'
  622.     return '&others.'
  623.   elseif nm[0] <= 'd'
  624.     return '&abcd.'
  625.   elseif nm[0] <= 'h'
  626.     return '&efgh.'
  627.   elseif nm[0] <= 'l'
  628.     return '&ijkl.'
  629.   elseif nm[0] <= 'p'
  630.     return '&mnop.'
  631.   elseif nm[0] <= 't'
  632.     return '&qrst.'
  633.   else
  634.     return '&u-z.'
  635.   endif
  636. endfunc
  637.  
  638. " insert a buffer name into the buffer menu:
  639. func! s:BMFilename(name, num)
  640.   if isdirectory(a:name)
  641.     return
  642.   endif
  643.   let munge = <SID>BMMunge(a:name, a:num)
  644.   let hash = <SID>BMHash(munge)
  645.   if s:bmenu_short == 0
  646.     let name = 'an ' . g:bmenu_priority . '.' . hash . ' &Buffers.' . munge
  647.   else
  648.     let name = 'an ' . g:bmenu_priority . '.' . hash . '.' . hash . ' &Buffers.' . <SID>BMHash2(munge) . munge
  649.   endif
  650.   " set 'cpo' to include the <CR>
  651.   let cpo_save = &cpo
  652.   set cpo&vim
  653.   exe name . ' :b' . a:num . '<CR>'
  654.   let &cpo = cpo_save
  655. endfunc
  656.  
  657. " Truncate a long path to fit it in a menu item.
  658. if !exists("g:bmenu_max_pathlen")
  659.   let g:bmenu_max_pathlen = 35
  660. endif
  661. func! s:BMTruncName(fname)
  662.   let name = a:fname
  663.   if g:bmenu_max_pathlen < 5
  664.     let name = ""
  665.   else
  666.     let len = strlen(name)
  667.     if len > g:bmenu_max_pathlen
  668.       let amountl = (g:bmenu_max_pathlen / 2) - 2
  669.       let amountr = g:bmenu_max_pathlen - amountl - 3
  670.       let pattern = '^\(.\{,' . amountl . '}\).\{-}\(.\{,' . amountr . '}\)$'
  671.       let left = substitute(name, pattern, '\1', '')
  672.       let right = substitute(name, pattern, '\2', '')
  673.       if strlen(left) + strlen(right) < len
  674.     let name = left . '...' . right
  675.       endif
  676.     endif
  677.   endif
  678.   return name
  679. endfunc
  680.  
  681. func! s:BMMunge(fname, bnum)
  682.   let name = a:fname
  683.   if name == ''
  684.     if !exists("g:menutrans_no_file")
  685.       let g:menutrans_no_file = "[No file]"
  686.     endif
  687.     let name = g:menutrans_no_file
  688.   else
  689.     let name = fnamemodify(name, ':p:~')
  690.   endif
  691.   " detach file name and separate it out:
  692.   let name2 = fnamemodify(name, ':t')
  693.   if a:bnum >= 0
  694.     let name2 = name2 . ' (' . a:bnum . ')'
  695.   endif
  696.   let name = name2 . "\t" . <SID>BMTruncName(fnamemodify(name,':h'))
  697.   let name = escape(name, "\\. \t|")
  698.   let name = substitute(name, "&", "&&", "g")
  699.   let name = substitute(name, "\n", "^@", "g")
  700.   return name
  701. endfunc
  702.  
  703. " When just starting Vim, load the buffer menu later
  704. if has("vim_starting")
  705.   augroup LoadBufferMenu
  706.     au! VimEnter * if !exists("no_buffers_menu") | call <SID>BMShow() | endif
  707.     au  VimEnter * au! LoadBufferMenu
  708.   augroup END
  709. else
  710.   call <SID>BMShow()
  711. endif
  712.  
  713. endif " !exists("no_buffers_menu")
  714.  
  715. " Window menu
  716. an 70.300 &Window.&New<Tab>^Wn            <C-W>n
  717. an 70.310 &Window.S&plit<Tab>^Ws        <C-W>s
  718. an 70.320 &Window.Sp&lit\ To\ #<Tab>^W^^    <C-W><C-^>
  719. an 70.330 &Window.Split\ &Vertically<Tab>^Wv    <C-W>v
  720. if has("vertsplit")
  721.   an <silent> 70.332 &Window.Split\ File\ E&xplorer    :call MenuExplOpen()<CR>
  722.   if !exists("*MenuExplOpen")
  723.     fun MenuExplOpen()
  724.       if @% == ""
  725.     20vsp .
  726.       else
  727.     exe "20vsp " . expand("%:p:h")
  728.       endif
  729.     endfun
  730.   endif
  731. endif
  732. an 70.335 &Window.-SEP1-                <Nop>
  733. an 70.340 &Window.&Close<Tab>^Wc            :confirm close<CR>
  734. an 70.345 &Window.Close\ &Other(s)<Tab>^Wo        :confirm only<CR>
  735. an 70.350 &Window.-SEP2-                <Nop>
  736. an 70.355 &Window.Move\ &To.&Top<Tab>^WK        <C-W>K
  737. an 70.355 &Window.Move\ &To.&Bottom<Tab>^WJ        <C-W>J
  738. an 70.355 &Window.Move\ &To.&Left\ side<Tab>^WH        <C-W>H
  739. an 70.355 &Window.Move\ &To.&Right\ side<Tab>^WL    <C-W>L
  740. an 70.360 &Window.Rotate\ &Up<Tab>^WR            <C-W>R
  741. an 70.362 &Window.Rotate\ &Down<Tab>^Wr            <C-W>r
  742. an 70.365 &Window.-SEP3-                <Nop>
  743. an 70.370 &Window.&Equal\ Size<Tab>^W=            <C-W>=
  744. an 70.380 &Window.&Max\ Height<Tab>^W_            <C-W>_
  745. an 70.390 &Window.M&in\ Height<Tab>^W1_            <C-W>1_
  746. an 70.400 &Window.Max\ &Width<Tab>^W\|            <C-W>\|
  747. an 70.410 &Window.Min\ Widt&h<Tab>^W1\|            <C-W>1\|
  748.  
  749. " The popup menu
  750. an 1.10 PopUp.&Undo            u
  751. an 1.15 PopUp.-SEP1-            <Nop>
  752. vnoremenu 1.20 PopUp.Cu&t        "+x
  753. vnoremenu 1.30 PopUp.&Copy        "+y
  754. cnoremenu 1.30 PopUp.&Copy        <C-Y>
  755. nnoremenu 1.40 PopUp.&Paste        "+gP
  756. cnoremenu 1.40 PopUp.&Paste        <C-R>+
  757. if has("virtualedit")
  758.   vnoremenu <script> 1.40 PopUp.&Paste    "-c<Esc><SID>Paste
  759.   inoremenu <script> 1.40 PopUp.&Paste    <Esc><SID>Pastegi
  760. else
  761.   vnoremenu <script> 1.40 PopUp.&Paste    "-c<Esc>gix<Esc><SID>Paste"_x
  762.   inoremenu <script> 1.40 PopUp.&Paste    x<Esc><SID>Paste"_s
  763. endif
  764. vnoremenu 1.50 PopUp.&Delete        x
  765. an 1.55 PopUp.-SEP2-            <Nop>
  766. vnoremenu 1.60 PopUp.Select\ Blockwise    <C-V>
  767. an 1.70 PopUp.Select\ &Word        vaw
  768. an 1.80 PopUp.Select\ &Line        V
  769. an 1.90 PopUp.Select\ &Block        <C-V>
  770. an 1.100 PopUp.Select\ &All        ggVG
  771.  
  772. " The GUI toolbar (for MS-Windows and GTK)
  773. if has("toolbar")
  774.   an 1.10 ToolBar.Open            :browse confirm e<CR>
  775.   an <silent> 1.20 ToolBar.Save        :if expand("%") == ""<Bar>browse confirm w<Bar>else<Bar>confirm w<Bar>endif<CR>
  776.   an 1.30 ToolBar.SaveAll        :wa<CR>
  777.  
  778.   if has("printer")
  779.     an 1.40   ToolBar.Print        :hardcopy<CR>
  780.     vunmenu   ToolBar.Print
  781.     vnoremenu ToolBar.Print        :hardcopy<CR>
  782.   elseif has("unix")
  783.     an 1.40   ToolBar.Print        :w !lpr<CR>
  784.     vunmenu   ToolBar.Print
  785.     vnoremenu ToolBar.Print        :w !lpr<CR>
  786.   endif
  787.  
  788.   an 1.45 ToolBar.-sep1-        <Nop>
  789.   an 1.50 ToolBar.Undo            u
  790.   an 1.60 ToolBar.Redo            <C-R>
  791.  
  792.   an 1.65 ToolBar.-sep2-        <Nop>
  793.   vnoremenu 1.70 ToolBar.Cut        "+x
  794.   vnoremenu 1.80 ToolBar.Copy        "+y
  795.   cnoremenu 1.80 ToolBar.Copy        <C-Y>
  796.   nnoremenu 1.90 ToolBar.Paste        "+gP
  797.   cnoremenu     ToolBar.Paste        <C-R>+
  798.   if has("virtualedit")
  799.     vnoremenu <script>     ToolBar.Paste    "-c<Esc><SID>Paste
  800.     inoremenu <script>     ToolBar.Paste    <Esc><SID>Pastegi
  801.   else
  802.     vnoremenu <script>     ToolBar.Paste    "-c<Esc>gix<Esc><SID>Paste"_x
  803.     inoremenu <script>     ToolBar.Paste    x<Esc><SID>Paste"_s
  804.   endif
  805.  
  806.   if !has("gui_athena")
  807.     an 1.95   ToolBar.-sep3-        <Nop>
  808.     an 1.100  ToolBar.Find        :promptfind<CR>
  809.     vunmenu   ToolBar.Find
  810.     vnoremenu ToolBar.Find        y:promptfind <C-R>"<CR>
  811.     an 1.110  ToolBar.FindNext        n
  812.     an 1.120  ToolBar.FindPrev        N
  813.     an 1.130  ToolBar.Replace        :promptrepl<CR>
  814.     vunmenu   ToolBar.Replace
  815.     vnoremenu ToolBar.Replace        y:promptrepl <C-R>"<CR>
  816.   endif
  817.  
  818. if 0    " disabled; These are in the Windows menu
  819.   an 1.135 ToolBar.-sep4-        <Nop>
  820.   an 1.140 ToolBar.New            <C-W>n
  821.   an 1.150 ToolBar.WinSplit        <C-W>s
  822.   an 1.160 ToolBar.WinMax        :resize 200<CR>
  823.   an 1.170 ToolBar.WinMin        :resize 1<CR>
  824.   an 1.180 ToolBar.WinVSplit        <C-W>v
  825.   an 1.190 ToolBar.WinMaxWidth        <C-W>500>
  826.   an 1.200 ToolBar.WinMinWidth        <C-W>1\|
  827.   an 1.210 ToolBar.WinClose        :close<CR>
  828. endif
  829.  
  830.   an 1.215 ToolBar.-sep5-        <Nop>
  831.   an <silent> 1.220 ToolBar.LoadSesn    :call <SID>LoadVimSesn()<CR>
  832.   an <silent> 1.230 ToolBar.SaveSesn    :call <SID>SaveVimSesn()<CR>
  833.   an 1.240 ToolBar.RunScript        :browse so<CR>
  834.  
  835.   an 1.245 ToolBar.-sep6-        <Nop>
  836.   an 1.250 ToolBar.Make            :make<CR>
  837.   an 1.270 ToolBar.RunCtags        :!ctags -R .<CR>
  838.   an 1.280 ToolBar.TagJump        g<C-]>
  839.  
  840.   an 1.295 ToolBar.-sep7-        <Nop>
  841.   an 1.300 ToolBar.Help            :help<CR>
  842.   an <silent> 1.310 ToolBar.FindHelp    :call <SID>Helpfind()<CR>
  843.  
  844. " Only set the tooltips here if not done in a language menu file
  845. if exists("*Do_toolbar_tmenu")
  846.   call Do_toolbar_tmenu()
  847. else
  848.   let did_toolbar_tmenu = 1
  849.   tmenu ToolBar.Open        Open file
  850.   tmenu ToolBar.Save        Save current file
  851.   tmenu ToolBar.SaveAll        Save all files
  852.   tmenu ToolBar.Print        Print
  853.   tmenu ToolBar.Undo        Undo
  854.   tmenu ToolBar.Redo        Redo
  855.   tmenu ToolBar.Cut        Cut to clipboard
  856.   tmenu ToolBar.Copy        Copy to clipboard
  857.   tmenu ToolBar.Paste        Paste from Clipboard
  858.   if !has("gui_athena")
  859.     tmenu ToolBar.Find        Find...
  860.     tmenu ToolBar.FindNext    Find Next
  861.     tmenu ToolBar.FindPrev    Find Previous
  862.     tmenu ToolBar.Replace        Find / Replace...
  863.   endif
  864.  if 0    " disabled; These are in the Windows menu
  865.   tmenu ToolBar.New        New Window
  866.   tmenu ToolBar.WinSplit    Split Window
  867.   tmenu ToolBar.WinMax        Maximise Window
  868.   tmenu ToolBar.WinMin        Minimise Window
  869.   tmenu ToolBar.WinVSplit    Split Window Vertically
  870.   tmenu ToolBar.WinMaxWidth    Maximise Window Width
  871.   tmenu ToolBar.WinMinWidth    Minimise Window Width
  872.   tmenu ToolBar.WinClose    Close Window
  873.  endif
  874.   tmenu ToolBar.LoadSesn    Load session
  875.   tmenu ToolBar.SaveSesn    Save current session
  876.   tmenu ToolBar.RunScript    Run a Vim Script
  877.   tmenu ToolBar.Make        Make current project
  878.   tmenu ToolBar.RunCtags    Build tags in current directory tree
  879.   tmenu ToolBar.TagJump        Jump to tag under cursor
  880.   tmenu ToolBar.Help        Vim Help
  881.   tmenu ToolBar.FindHelp    Search Vim Help
  882. endif
  883.  
  884. " Select a session to load; default to current session name if present
  885. fun! s:LoadVimSesn()
  886.   if strlen(v:this_session) > 0
  887.     let name = v:this_session
  888.   else
  889.     let name = "Session.vim"
  890.   endif
  891.   execute "browse so " . name
  892. endfun
  893.  
  894. " Select a session to save; default to current session name if present
  895. fun! s:SaveVimSesn()
  896.   if strlen(v:this_session) == 0
  897.     let v:this_session = "Session.vim"
  898.   endif
  899.   execute "browse mksession! " . v:this_session
  900. endfun
  901.  
  902. endif
  903.  
  904. endif " !exists("did_install_default_menus")
  905.  
  906. " Define these items always, so that syntax can be switched on when it wasn't.
  907. " But skip them when the Syntax menu was disabled by the user.
  908. if !exists("did_install_syntax_menu")
  909.   an 50.212 &Syntax.&Manual        :syn manual<CR>
  910.   an 50.214 &Syntax.A&utomatic        :syn on<CR>
  911.   an <silent> 50.216 &Syntax.on/off\ for\ &This\ file :call <SID>SynOnOff()<CR>
  912.   if !exists("*s:SynOnOff")
  913.     fun s:SynOnOff()
  914.       if has("syntax_items")
  915.     syn clear
  916.       else
  917.     if !exists("g:syntax_on")
  918.       syn manual
  919.     endif
  920.     set syn=ON
  921.       endif
  922.     endfun
  923.   endif
  924. endif
  925.  
  926.  
  927. " Install the Syntax menu only when filetype.vim has been loaded or when
  928. " manual syntax highlighting is enabled.
  929. " Avoid installing the Syntax menu twice.
  930. if (exists("did_load_filetypes") || exists("syntax_on"))
  931.     \ && !exists("did_install_syntax_menu")
  932.   let did_install_syntax_menu = 1
  933.  
  934. " Skip setting up the individual syntax selection menus unless
  935. " do_syntax_sel_menu is defined (it takes quite a bit of time).
  936. if exists("do_syntax_sel_menu")
  937.   runtime! synmenu.vim
  938. else
  939.   an 50.10 &Syntax.&Show\ filetypes\ in\ menu    :let do_syntax_sel_menu = 1<Bar>runtime! synmenu.vim<Bar>aunmenu &Syntax.&Show\ filetypes\ in\ menu<CR>
  940.   an 50.195 &Syntax.-SEP1-        <Nop>
  941. endif
  942.  
  943. an 50.210 &Syntax.&Off            :syn off<CR>
  944. an 50.700 &Syntax.-SEP3-        <Nop>
  945. an 50.710 &Syntax.Co&lor\ test        :sp $VIMRUNTIME/syntax/colortest.vim<Bar>so %<CR>
  946. an 50.720 &Syntax.&Highlight\ test    :so $VIMRUNTIME/syntax/hitest.vim<CR>
  947. an 50.730 &Syntax.&Convert\ to\ HTML    :so $VIMRUNTIME/syntax/2html.vim<CR>
  948.  
  949. endif " !exists("did_install_syntax_menu")
  950.  
  951. " Restore the previous value of 'cpoptions'.
  952. let &cpo = s:cpo_save
  953. unlet s:cpo_save
  954.  
  955. " vim: set sw=2 :
  956.