home *** CD-ROM | disk | FTP | other *** search
/ PC World 2005 June / PCWorld_2005-06_cd.bin / software / vyzkuste / firewally / firewally.exe / framework-2.3.exe / h2ph < prev    next >
Text File  |  2003-11-07  |  25KB  |  835 lines
  1. #!/usr/bin/perl
  2.     eval 'exec /usr/bin/perl -S $0 ${1+"$@"}'
  3.     if $running_under_some_shell;
  4.  
  5. use strict;
  6.  
  7. use Config;
  8. use File::Path qw(mkpath);
  9. use Getopt::Std;
  10.  
  11. # Make sure read permissions for all are set:
  12. if (defined umask && (umask() & 0444)) {
  13.     umask (umask() & ~0444);
  14. }
  15.  
  16. getopts('Dd:rlhaQe');
  17. use vars qw($opt_D $opt_d $opt_r $opt_l $opt_h $opt_a $opt_Q $opt_e);
  18. die "-r and -a options are mutually exclusive\n" if ($opt_r and $opt_a);
  19. my @inc_dirs = inc_dirs() if $opt_a;
  20.  
  21. my $Exit = 0;
  22.  
  23. my $Dest_dir = $opt_d || $Config{installsitearch};
  24. die "Destination directory $Dest_dir doesn't exist or isn't a directory\n"
  25.     unless -d $Dest_dir;
  26.  
  27. my @isatype = split(' ',<<END);
  28.     char    uchar    u_char
  29.     short    ushort    u_short
  30.     int    uint    u_int
  31.     long    ulong    u_long
  32.     FILE    key_t    caddr_t
  33. END
  34.  
  35. my %isatype;
  36. @isatype{@isatype} = (1) x @isatype;
  37. my $inif = 0;
  38. my %Is_converted;
  39. my %bad_file = ();
  40.  
  41. @ARGV = ('-') unless @ARGV;
  42.  
  43. build_preamble_if_necessary();
  44.  
  45. sub reindent($) {
  46.     my($text) = shift;
  47.     $text =~ s/\n/\n    /g;
  48.     $text =~ s/        /\t/g;
  49.     $text;
  50. }
  51.  
  52. my ($t, $tab, %curargs, $new, $eval_index, $dir, $name, $args, $outfile);
  53. my ($incl, $incl_type, $next);
  54. while (defined (my $file = next_file())) {
  55.     if (-l $file and -d $file) {
  56.         link_if_possible($file) if ($opt_l);
  57.         next;
  58.     }
  59.  
  60.     # Recover from header files with unbalanced cpp directives
  61.     $t = '';
  62.     $tab = 0;
  63.  
  64.     # $eval_index goes into ``#line'' directives, to help locate syntax errors:
  65.     $eval_index = 1;
  66.  
  67.     if ($file eq '-') {
  68.     open(IN, "-");
  69.     open(OUT, ">-");
  70.     } else {
  71.     ($outfile = $file) =~ s/\.h$/.ph/ || next;
  72.     print "$file -> $outfile\n" unless $opt_Q;
  73.     if ($file =~ m|^(.*)/|) {
  74.         $dir = $1;
  75.         mkpath "$Dest_dir/$dir";
  76.     }
  77.  
  78.     if ($opt_a) { # automagic mode:  locate header file in @inc_dirs
  79.         foreach (@inc_dirs) {
  80.         chdir $_;
  81.         last if -f $file;
  82.         }
  83.     }
  84.  
  85.     open(IN,"$file") || (($Exit = 1),(warn "Can't open $file: $!\n"),next);
  86.     open(OUT,">$Dest_dir/$outfile") || die "Can't create $outfile: $!\n";
  87.     }
  88.  
  89.     print OUT
  90.         "require '_h2ph_pre.ph';\n\n",
  91.         "no warnings 'redefine';\n\n";
  92.  
  93.     while (defined (local $_ = next_line($file))) {
  94.     if (s/^\s*\#\s*//) {
  95.         if (s/^define\s+(\w+)//) {
  96.         $name = $1;
  97.         $new = '';
  98.         s/\s+$//;
  99.         s/\(\w+\s*\(\*\)\s*\(\w*\)\)\s*(-?\d+)/$1/; # (int (*)(foo_t))0
  100.         if (s/^\(([\w,\s]*)\)//) {
  101.             $args = $1;
  102.                     my $proto = '() ';
  103.             if ($args ne '') {
  104.                         $proto = '';
  105.             foreach my $arg (split(/,\s*/,$args)) {
  106.                 $arg =~ s/^\s*([^\s].*[^\s])\s*$/$1/;
  107.                 $curargs{$arg} = 1;
  108.             }
  109.             $args =~ s/\b(\w)/\$$1/g;
  110.             $args = "local($args) = \@_;\n$t    ";
  111.             }
  112.             s/^\s+//;
  113.             expr();
  114.             $new =~ s/(["\\])/\\$1/g;       #"]);
  115.             $new = reindent($new);
  116.             $args = reindent($args);
  117.             if ($t ne '') {
  118.             $new =~ s/(['\\])/\\$1/g;   #']);
  119.             if ($opt_h) {
  120.                 print OUT $t,
  121.                             "eval \"\\n#line $eval_index $outfile\\n\" . 'sub $name $proto\{\n$t    ${args}eval q($new);\n$t}' unless defined(\&$name);\n";
  122.                             $eval_index++;
  123.             } else {
  124.                 print OUT $t,
  125.                             "eval 'sub $name $proto\{\n$t    ${args}eval q($new);\n$t}' unless defined(\&$name);\n";
  126.             }
  127.             } else {
  128.                       print OUT "unless(defined(\&$name)) {\n    sub $name $proto\{\n\t${args}eval q($new);\n    }\n}\n";
  129.             }
  130.             %curargs = ();
  131.         } else {
  132.             s/^\s+//;
  133.             expr();
  134.             $new = 1 if $new eq '';
  135.             $new = reindent($new);
  136.             $args = reindent($args);
  137.             if ($t ne '') {
  138.             $new =~ s/(['\\])/\\$1/g;        #']);
  139.  
  140.             if ($opt_h) {
  141.                 print OUT $t,"eval \"\\n#line $eval_index $outfile\\n\" . 'sub $name () {",$new,";}' unless defined(\&$name);\n";
  142.                 $eval_index++;
  143.             } else {
  144.                 print OUT $t,"eval 'sub $name () {",$new,";}' unless defined(\&$name);\n";
  145.             }
  146.             } else {
  147.                 # Shunt around such directives as `#define FOO FOO':
  148.                 next if " \&$name" eq $new;
  149.  
  150.                       print OUT $t,"unless(defined(\&$name)) {\n    sub $name () {\t",$new,";}\n}\n";
  151.             }
  152.         }
  153.         } elsif (/^(include|import|include_next)\s*[<\"](.*)[>\"]/) {
  154.                 $incl_type = $1;
  155.                 $incl = $2;
  156.                 if (($incl_type eq 'include_next') ||
  157.                     ($opt_e && exists($bad_file{$incl}))) {
  158.                     $incl =~ s/\.h$/.ph/;
  159.         print OUT ($t,
  160.                "eval {\n");
  161.                 $tab += 4;
  162.                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  163.                     print OUT ($t, "my(\@REM);\n");
  164.                     if ($incl_type eq 'include_next') {
  165.         print OUT ($t,
  166.                "my(\%INCD) = map { \$INC{\$_} => 1 } ",
  167.                        "(grep { \$_ eq \"$incl\" } ",
  168.                                    "keys(\%INC));\n");
  169.         print OUT ($t,
  170.                        "\@REM = map { \"\$_/$incl\" } ",
  171.                "(grep { not exists(\$INCD{\"\$_/$incl\"})",
  172.                        " and -f \"\$_/$incl\" } \@INC);\n");
  173.                     } else {
  174.                         print OUT ($t,
  175.                                    "\@REM = map { \"\$_/$incl\" } ",
  176.                                    "(grep {-r \"\$_/$incl\" } \@INC);\n");
  177.                     }
  178.         print OUT ($t,
  179.                "require \"\$REM[0]\" if \@REM;\n");
  180.                 $tab -= 4;
  181.                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  182.                 print OUT ($t,
  183.                "};\n");
  184.         print OUT ($t,
  185.                "warn(\$\@) if \$\@;\n");
  186.                 } else {
  187.                     $incl =~ s/\.h$/.ph/;
  188.             print OUT $t,"require '$incl';\n";
  189.                 }
  190.         } elsif (/^ifdef\s+(\w+)/) {
  191.         print OUT $t,"if(defined(&$1)) {\n";
  192.         $tab += 4;
  193.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  194.         } elsif (/^ifndef\s+(\w+)/) {
  195.         print OUT $t,"unless(defined(&$1)) {\n";
  196.         $tab += 4;
  197.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  198.         } elsif (s/^if\s+//) {
  199.         $new = '';
  200.         $inif = 1;
  201.         expr();
  202.         $inif = 0;
  203.         print OUT $t,"if($new) {\n";
  204.         $tab += 4;
  205.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  206.         } elsif (s/^elif\s+//) {
  207.         $new = '';
  208.         $inif = 1;
  209.         expr();
  210.         $inif = 0;
  211.         $tab -= 4;
  212.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  213.         print OUT $t,"}\n elsif($new) {\n";
  214.         $tab += 4;
  215.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  216.         } elsif (/^else/) {
  217.         $tab -= 4;
  218.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  219.         print OUT $t,"} else {\n";
  220.         $tab += 4;
  221.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  222.         } elsif (/^endif/) {
  223.         $tab -= 4;
  224.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  225.         print OUT $t,"}\n";
  226.         } elsif(/^undef\s+(\w+)/) {
  227.         print OUT $t, "undef(&$1) if defined(&$1);\n";
  228.         } elsif(/^error\s+(".*")/) {
  229.         print OUT $t, "die($1);\n";
  230.         } elsif(/^error\s+(.*)/) {
  231.         print OUT $t, "die(\"", quotemeta($1), "\");\n";
  232.         } elsif(/^warning\s+(.*)/) {
  233.         print OUT $t, "warn(\"", quotemeta($1), "\");\n";
  234.         } elsif(/^ident\s+(.*)/) {
  235.         print OUT $t, "# $1\n";
  236.         }
  237.     } elsif(/^\s*(typedef\s*)?enum\s*(\s+[a-zA-Z_]\w*\s*)?/) {
  238.         until(/\{[^}]*\}.*;/ || /;/) {
  239.         last unless defined ($next = next_line($file));
  240.         chomp $next;
  241.         # drop "#define FOO FOO" in enums
  242.         $next =~ s/^\s*#\s*define\s+(\w+)\s+\1\s*$//;
  243.         $_ .= $next;
  244.         print OUT "# $next\n" if $opt_D;
  245.         }
  246.         s/#\s*if.*?#\s*endif//g; # drop #ifdefs
  247.         s@/\*.*?\*/@@g;
  248.         s/\s+/ /g;
  249.         next unless /^\s?(typedef\s?)?enum\s?([a-zA-Z_]\w*)?\s?\{(.*)\}\s?([a-zA-Z_]\w*)?\s?;/;
  250.         (my $enum_subs = $3) =~ s/\s//g;
  251.         my @enum_subs = split(/,/, $enum_subs);
  252.         my $enum_val = -1;
  253.         foreach my $enum (@enum_subs) {
  254.         my ($enum_name, $enum_value) = $enum =~ /^([a-zA-Z_]\w*)(=.+)?$/;
  255.         $enum_value =~ s/^=//;
  256.         $enum_val = (length($enum_value) ? $enum_value : $enum_val + 1);
  257.         if ($opt_h) {
  258.             print OUT ($t,
  259.                    "eval(\"\\n#line $eval_index $outfile\\n",
  260.                    "sub $enum_name () \{ $enum_val; \}\") ",
  261.                    "unless defined(\&$enum_name);\n");
  262.             ++ $eval_index;
  263.         } else {
  264.             print OUT ($t,
  265.                    "eval(\"sub $enum_name () \{ $enum_val; \}\") ",
  266.                    "unless defined(\&$enum_name);\n");
  267.         }
  268.         }
  269.     }
  270.     }
  271.     $Is_converted{$file} = 1;
  272.     if ($opt_e && exists($bad_file{$file})) {
  273.         unlink($Dest_dir . '/' . $outfile);
  274.         $next = '';
  275.     } else {
  276.         print OUT "1;\n";
  277.     queue_includes_from($file) if ($opt_a);
  278.     }
  279. }
  280.  
  281. if ($opt_e && (scalar(keys %bad_file) > 0)) {
  282.     warn "Was unable to convert the following files:\n";
  283.     warn "\t" . join("\n\t",sort(keys %bad_file)) . "\n";
  284. }
  285.  
  286. exit $Exit;
  287.  
  288. sub expr {
  289.     my $joined_args;
  290.     if(keys(%curargs)) {
  291.     $joined_args = join('|', keys(%curargs));
  292.     }
  293.     while ($_ ne '') {
  294.     s/^\&\&// && do { $new .= " &&"; next;}; # handle && operator
  295.     s/^\&([\(a-z\)]+)/$1/i;    # hack for things that take the address of
  296.     s/^(\s+)//        && do {$new .= ' '; next;};
  297.     s/^0X([0-9A-F]+)[UL]*//i 
  298.         && do {my $hex = $1;
  299.            $hex =~ s/^0+//;
  300.            if (length $hex > 8 && !$Config{use64bitint}) {
  301.                # Croak if nv_preserves_uv_bits < 64 ?
  302.                $new .=         hex(substr($hex, -8)) +
  303.                    2**32 * hex(substr($hex,  0, -8));
  304.                # The above will produce "errorneus" code
  305.                # if the hex constant was e.g. inside UINT64_C
  306.                # macro, but then again, h2ph is an approximation.
  307.            } else {
  308.                $new .= lc("0x$hex");
  309.            }
  310.            next;};
  311.     s/^(-?\d+\.\d+E[-+]?\d+)[FL]?//i    && do {$new .= $1; next;};
  312.     s/^(\d+)\s*[LU]*//i    && do {$new .= $1; next;};
  313.     s/^("(\\"|[^"])*")//    && do {$new .= $1; next;};
  314.     s/^'((\\"|[^"])*)'//    && do {
  315.         if ($curargs{$1}) {
  316.         $new .= "ord('\$$1')";
  317.         } else {
  318.         $new .= "ord('$1')";
  319.         }
  320.         next;
  321.     };
  322.         # replace "sizeof(foo)" with "{foo}"
  323.         # also, remove * (C dereference operator) to avoid perl syntax
  324.         # problems.  Where the %sizeof array comes from is anyone's
  325.         # guess (c2ph?), but this at least avoids fatal syntax errors.
  326.         # Behavior is undefined if sizeof() delimiters are unbalanced.
  327.         # This code was modified to able to handle constructs like this:
  328.         #   sizeof(*(p)), which appear in the HP-UX 10.01 header files.
  329.         s/^sizeof\s*\(// && do {
  330.             $new .= '$sizeof';
  331.             my $lvl = 1;  # already saw one open paren
  332.             # tack { on the front, and skip it in the loop
  333.             $_ = "{" . "$_";
  334.             my $index = 1;
  335.             # find balanced closing paren
  336.             while ($index <= length($_) && $lvl > 0) {
  337.                 $lvl++ if substr($_, $index, 1) eq "(";
  338.                 $lvl-- if substr($_, $index, 1) eq ")";
  339.                 $index++;
  340.             }
  341.             # tack } on the end, replacing )
  342.             substr($_, $index - 1, 1) = "}";
  343.             # remove pesky * operators within the sizeof argument
  344.             substr($_, 0, $index - 1) =~ s/\*//g;
  345.             next;
  346.         };
  347.     # Eliminate typedefs
  348.     /\(([\w\s]+)[\*\s]*\)\s*[\w\(]/ && do {
  349.         foreach (split /\s+/, $1) {  # Make sure all the words are types,
  350.         last unless ($isatype{$_} or $_ eq 'struct' or $_ eq 'union');
  351.         }
  352.         s/\([\w\s]+[\*\s]*\)// && next;      # then eliminate them.
  353.     };
  354.     # struct/union member, including arrays:
  355.     s/^([_A-Z]\w*(\[[^\]]+\])?((\.|->)[_A-Z]\w*(\[[^\]]+\])?)+)//i && do {
  356.         my $id = $1;
  357.         $id =~ s/(\.|(->))([^\.\-]*)/->\{$3\}/g;
  358.         $id =~ s/\b([^\$])($joined_args)/$1\$$2/g if length($joined_args);
  359.         while($id =~ /\[\s*([^\$\&\d\]]+)\]/) {
  360.         my($index) = $1;
  361.         $index =~ s/\s//g;
  362.         if(exists($curargs{$index})) {
  363.             $index = "\$$index";
  364.         } else {
  365.             $index = "&$index";
  366.         }
  367.         $id =~ s/\[\s*([^\$\&\d\]]+)\]/[$index]/;
  368.         }
  369.         $new .= " (\$$id)";
  370.     };
  371.     s/^([_a-zA-Z]\w*)//    && do {
  372.         my $id = $1;
  373.         if ($id eq 'struct' || $id eq 'union') {
  374.         s/^\s+(\w+)//;
  375.         $id .= ' ' . $1;
  376.         $isatype{$id} = 1;
  377.         } elsif ($id =~ /^((un)?signed)|(long)|(short)$/) {
  378.         while (s/^\s+(\w+)//) { $id .= ' ' . $1; }
  379.         $isatype{$id} = 1;
  380.         }
  381.         if ($curargs{$id}) {
  382.         $new .= "\$$id";
  383.         $new .= '->' if /^[\[\{]/;
  384.         } elsif ($id eq 'defined') {
  385.         $new .= 'defined';
  386.         } elsif (/^\s*\(/) {
  387.         s/^\s*\((\w),/("$1",/ if $id =~ /^_IO[WR]*$/i;    # cheat
  388.         $new .= " &$id";
  389.         } elsif ($isatype{$id}) {
  390.         if ($new =~ /{\s*$/) {
  391.             $new .= "'$id'";
  392.         } elsif ($new =~ /\(\s*$/ && /^[\s*]*\)/) {
  393.             $new =~ s/\(\s*$//;
  394.             s/^[\s*]*\)//;
  395.         } else {
  396.             $new .= q(').$id.q(');
  397.         }
  398.         } else {
  399.         if ($inif && $new !~ /defined\s*\($/) {
  400.             $new .= '(defined(&' . $id . ') ? &' . $id . ' : 0)';
  401.         } elsif (/^\[/) {
  402.             $new .= " \$$id";
  403.         } else {
  404.             $new .= ' &' . $id;
  405.         }
  406.         }
  407.         next;
  408.     };
  409.     s/^(.)// && do { if ($1 ne '#') { $new .= $1; } next;};
  410.     }
  411. }
  412.  
  413.  
  414. sub next_line
  415. {
  416.     my $file = shift;
  417.     my ($in, $out);
  418.     my $pre_sub_tri_graphs = 1;
  419.  
  420.     READ: while (not eof IN) {
  421.         $in  .= <IN>;
  422.         chomp $in;
  423.         next unless length $in;
  424.  
  425.         while (length $in) {
  426.             if ($pre_sub_tri_graphs) {
  427.                 # Preprocess all tri-graphs 
  428.                 # including things stuck in quoted string constants.
  429.                 $in =~ s/\?\?=/#/g;                         # | ??=|  #|
  430.                 $in =~ s/\?\?\!/|/g;                        # | ??!|  ||
  431.                 $in =~ s/\?\?'/^/g;                         # | ??'|  ^|
  432.                 $in =~ s/\?\?\(/[/g;                        # | ??(|  [|
  433.                 $in =~ s/\?\?\)/]/g;                        # | ??)|  ]|
  434.                 $in =~ s/\?\?\-/~/g;                        # | ??-|  ~|
  435.                 $in =~ s/\?\?\//\\/g;                       # | ??/|  \|
  436.                 $in =~ s/\?\?</{/g;                         # | ??<|  {|
  437.                 $in =~ s/\?\?>/}/g;                         # | ??>|  }|
  438.             }
  439.         if ($in =~ /^\#ifdef __LANGUAGE_PASCAL__/) {
  440.                 # Tru64 disassembler.h evilness: mixed C and Pascal.
  441.         while (<IN>) {
  442.             last if /^\#endif/; 
  443.         }
  444.         next READ;
  445.         }
  446.         if ($in =~ /^extern inline / && # Inlined assembler.
  447.         $^O eq 'linux' && $file =~ m!(?:^|/)asm/[^/]+\.h$!) {
  448.          while (<IN>) {
  449.             last if /^}/; 
  450.         }
  451.         next READ;
  452.         }
  453.             if ($in =~ s/\\$//) {                           # \-newline
  454.                 $out    .= ' ';
  455.                 next READ;
  456.             } elsif ($in =~ s/^([^"'\\\/]+)//) {            # Passthrough
  457.                 $out    .= $1;
  458.             } elsif ($in =~ s/^(\\.)//) {                   # \...
  459.                 $out    .= $1;
  460.             } elsif ($in =~ /^'/) {                         # '...
  461.                 if ($in =~ s/^('(\\.|[^'\\])*')//) {
  462.                     $out    .= $1;
  463.                 } else {
  464.                     next READ;
  465.                 }
  466.             } elsif ($in =~ /^"/) {                         # "...
  467.                 if ($in =~ s/^("(\\.|[^"\\])*")//) {
  468.                     $out    .= $1;
  469.                 } else {
  470.                     next READ;
  471.                 }
  472.             } elsif ($in =~ s/^\/\/.*//) {                  # //...
  473.                 # fall through
  474.             } elsif ($in =~ m/^\/\*/) {                     # /*...
  475.                 # C comment removal adapted from perlfaq6:
  476.                 if ($in =~ s/^\/\*[^*]*\*+([^\/*][^*]*\*+)*\///) {
  477.                     $out    .= ' ';
  478.                 } else {                                    # Incomplete /* */
  479.                     next READ;
  480.                 }
  481.             } elsif ($in =~ s/^(\/)//) {                    # /...
  482.                 $out    .= $1;
  483.             } elsif ($in =~ s/^([^\'\"\\\/]+)//) {
  484.                 $out    .= $1;
  485.             } elsif ($^O eq 'linux' &&
  486.                      $file =~ m!(?:^|/)linux/byteorder/pdp_endian\.h$! &&
  487.                      $in   =~ s!\'T KNOW!!) {
  488.                 $out    =~ s!I DON$!I_DO_NOT_KNOW!;
  489.             } else {
  490.                 if ($opt_e) {
  491.                     warn "Cannot parse $file:\n$in\n";
  492.                     $bad_file{$file} = 1;
  493.                     $in = '';
  494.                     $out = undef;
  495.                     last READ;
  496.                 } else {
  497.         die "Cannot parse:\n$in\n";
  498.                 }
  499.             }
  500.         }
  501.  
  502.         last READ if $out =~ /\S/;
  503.     }
  504.  
  505.     return $out;
  506. }
  507.  
  508.  
  509. # Handle recursive subdirectories without getting a grotesquely big stack.
  510. # Could this be implemented using File::Find?
  511. sub next_file
  512. {
  513.     my $file;
  514.  
  515.     while (@ARGV) {
  516.         $file = shift @ARGV;
  517.  
  518.         if ($file eq '-' or -f $file or -l $file) {
  519.             return $file;
  520.         } elsif (-d $file) {
  521.             if ($opt_r) {
  522.                 expand_glob($file);
  523.             } else {
  524.                 print STDERR "Skipping directory `$file'\n";
  525.             }
  526.         } elsif ($opt_a) {
  527.             return $file;
  528.         } else {
  529.             print STDERR "Skipping `$file':  not a file or directory\n";
  530.         }
  531.     }
  532.  
  533.     return undef;
  534. }
  535.  
  536.  
  537. # Put all the files in $directory into @ARGV for processing.
  538. sub expand_glob
  539. {
  540.     my ($directory)  = @_;
  541.  
  542.     $directory =~ s:/$::;
  543.  
  544.     opendir DIR, $directory;
  545.         foreach (readdir DIR) {
  546.             next if ($_ eq '.' or $_ eq '..');
  547.  
  548.             # expand_glob() is going to be called until $ARGV[0] isn't a
  549.             # directory; so push directories, and unshift everything else.
  550.             if (-d "$directory/$_") { push    @ARGV, "$directory/$_" }
  551.             else                    { unshift @ARGV, "$directory/$_" }
  552.         }
  553.     closedir DIR;
  554. }
  555.  
  556.  
  557. # Given $file, a symbolic link to a directory in the C include directory,
  558. # make an equivalent symbolic link in $Dest_dir, if we can figure out how.
  559. # Otherwise, just duplicate the file or directory.
  560. sub link_if_possible
  561. {
  562.     my ($dirlink)  = @_;
  563.     my $target  = eval 'readlink($dirlink)';
  564.  
  565.     if ($target =~ m:^\.\./: or $target =~ m:^/:) {
  566.         # The target of a parent or absolute link could leave the $Dest_dir
  567.         # hierarchy, so let's put all of the contents of $dirlink (actually,
  568.         # the contents of $target) into @ARGV; as a side effect down the
  569.         # line, $dirlink will get created as an _actual_ directory.
  570.         expand_glob($dirlink);
  571.     } else {
  572.         if (-l "$Dest_dir/$dirlink") {
  573.             unlink "$Dest_dir/$dirlink" or
  574.                 print STDERR "Could not remove link $Dest_dir/$dirlink:  $!\n";
  575.         }
  576.  
  577.         if (eval 'symlink($target, "$Dest_dir/$dirlink")') {
  578.             print "Linking $target -> $Dest_dir/$dirlink\n";
  579.  
  580.             # Make sure that the link _links_ to something:
  581.             if (! -e "$Dest_dir/$target") {
  582.                 mkpath("$Dest_dir/$target", 0755) or
  583.                     print STDERR "Could not create $Dest_dir/$target/\n";
  584.             }
  585.         } else {
  586.             print STDERR "Could not symlink $target -> $Dest_dir/$dirlink:  $!\n";
  587.         }
  588.     }
  589. }
  590.  
  591.  
  592. # Push all #included files in $file onto our stack, except for STDIN
  593. # and files we've already processed.
  594. sub queue_includes_from
  595. {
  596.     my ($file)    = @_;
  597.     my $line;
  598.  
  599.     return if ($file eq "-");
  600.  
  601.     open HEADER, $file or return;
  602.         while (defined($line = <HEADER>)) {
  603.             while (/\\$/) { # Handle continuation lines
  604.                 chop $line;
  605.                 $line .= <HEADER>;
  606.             }
  607.  
  608.             if ($line =~ /^#\s*include\s+<(.*?)>/) {
  609.                 push(@ARGV, $1) unless $Is_converted{$1};
  610.             }
  611.         }
  612.     close HEADER;
  613. }
  614.  
  615.  
  616. # Determine include directories; $Config{usrinc} should be enough for (all
  617. # non-GCC?) C compilers, but gcc uses an additional include directory.
  618. sub inc_dirs
  619. {
  620.     my $from_gcc    = `$Config{cc} -v 2>&1`;
  621.     $from_gcc       =~ s:^Reading specs from (.*?)/specs\b.*:$1/include:s;
  622.  
  623.     length($from_gcc) ? ($from_gcc, $Config{usrinc}) : ($Config{usrinc});
  624. }
  625.  
  626.  
  627. # Create "_h2ph_pre.ph", if it doesn't exist or was built by a different
  628. # version of h2ph.
  629. sub build_preamble_if_necessary
  630. {
  631.     # Increment $VERSION every time this function is modified:
  632.     my $VERSION     = 2;
  633.     my $preamble    = "$Dest_dir/_h2ph_pre.ph";
  634.  
  635.     # Can we skip building the preamble file?
  636.     if (-r $preamble) {
  637.         # Extract version number from first line of preamble:
  638.         open  PREAMBLE, $preamble or die "Cannot open $preamble:  $!";
  639.             my $line = <PREAMBLE>;
  640.             $line =~ /(\b\d+\b)/;
  641.         close PREAMBLE            or die "Cannot close $preamble:  $!";
  642.  
  643.         # Don't build preamble if a compatible preamble exists:
  644.         return if $1 == $VERSION;
  645.     }
  646.  
  647.     my (%define) = _extract_cc_defines();
  648.  
  649.     open  PREAMBLE, ">$preamble" or die "Cannot open $preamble:  $!";
  650.         print PREAMBLE "# This file was created by h2ph version $VERSION\n";
  651.  
  652.         foreach (sort keys %define) {
  653.             if ($opt_D) {
  654.                 print PREAMBLE "# $_=$define{$_}\n";
  655.             }
  656.  
  657.             if ($define{$_} =~ /^(\d+)U?L{0,2}$/i) {
  658.                 print PREAMBLE
  659.                     "unless (defined &$_) { sub $_() { $1 } }\n\n";
  660.             } elsif ($define{$_} =~ /^\w+$/) {
  661.                 print PREAMBLE
  662.                     "unless (defined &$_) { sub $_() { &$define{$_} } }\n\n";
  663.             } else {
  664.                 print PREAMBLE
  665.                     "unless (defined &$_) { sub $_() { \"",
  666.                     quotemeta($define{$_}), "\" } }\n\n";
  667.             }
  668.         }
  669.     close PREAMBLE               or die "Cannot close $preamble:  $!";
  670. }
  671.  
  672.  
  673. # %Config contains information on macros that are pre-defined by the
  674. # system's compiler.  We need this information to make the .ph files
  675. # function with perl as the .h files do with cc.
  676. sub _extract_cc_defines
  677. {
  678.     my %define;
  679.     my $allsymbols  = join " ",
  680.         @Config{'ccsymbols', 'cppsymbols', 'cppccsymbols'};
  681.  
  682.     # Split compiler pre-definitions into `key=value' pairs:
  683.     foreach (split /\s+/, $allsymbols) {
  684.         /(.+?)=(.+)/ and $define{$1} = $2;
  685.  
  686.         if ($opt_D) {
  687.             print STDERR "$_:  $1 -> $2\n";
  688.         }
  689.     }
  690.  
  691.     return %define;
  692. }
  693.  
  694.  
  695. 1;
  696.  
  697. ##############################################################################
  698. __END__
  699.  
  700. =head1 NAME
  701.  
  702. h2ph - convert .h C header files to .ph Perl header files
  703.  
  704. =head1 SYNOPSIS
  705.  
  706. B<h2ph [-d destination directory] [-r | -a] [-l] [headerfiles]>
  707.  
  708. =head1 DESCRIPTION
  709.  
  710. I<h2ph>
  711. converts any C header files specified to the corresponding Perl header file
  712. format.
  713. It is most easily run while in /usr/include:
  714.  
  715.     cd /usr/include; h2ph * sys/*
  716.  
  717. or
  718.  
  719.     cd /usr/include; h2ph * sys/* arpa/* netinet/*
  720.  
  721. or
  722.  
  723.     cd /usr/include; h2ph -r -l .
  724.  
  725. The output files are placed in the hierarchy rooted at Perl's
  726. architecture dependent library directory.  You can specify a different
  727. hierarchy with a B<-d> switch.
  728.  
  729. If run with no arguments, filters standard input to standard output.
  730.  
  731. =head1 OPTIONS
  732.  
  733. =over 4
  734.  
  735. =item -d destination_dir
  736.  
  737. Put the resulting B<.ph> files beneath B<destination_dir>, instead of
  738. beneath the default Perl library location (C<$Config{'installsitsearch'}>).
  739.  
  740. =item -r
  741.  
  742. Run recursively; if any of B<headerfiles> are directories, then run I<h2ph>
  743. on all files in those directories (and their subdirectories, etc.).  B<-r>
  744. and B<-a> are mutually exclusive.
  745.  
  746. =item -a
  747.  
  748. Run automagically; convert B<headerfiles>, as well as any B<.h> files
  749. which they include.  This option will search for B<.h> files in all
  750. directories which your C compiler ordinarily uses.  B<-a> and B<-r> are
  751. mutually exclusive.
  752.  
  753. =item -l
  754.  
  755. Symbolic links will be replicated in the destination directory.  If B<-l>
  756. is not specified, then links are skipped over.
  757.  
  758. =item -h
  759.  
  760. Put ``hints'' in the .ph files which will help in locating problems with
  761. I<h2ph>.  In those cases when you B<require> a B<.ph> file containing syntax
  762. errors, instead of the cryptic
  763.  
  764.     [ some error condition ] at (eval mmm) line nnn
  765.  
  766. you will see the slightly more helpful
  767.  
  768.     [ some error condition ] at filename.ph line nnn
  769.  
  770. However, the B<.ph> files almost double in size when built using B<-h>.
  771.  
  772. =item -D
  773.  
  774. Include the code from the B<.h> file as a comment in the B<.ph> file.
  775. This is primarily used for debugging I<h2ph>.
  776.  
  777. =item -Q
  778.  
  779. ``Quiet'' mode; don't print out the names of the files being converted.
  780.  
  781. =back
  782.  
  783. =head1 ENVIRONMENT
  784.  
  785. No environment variables are used.
  786.  
  787. =head1 FILES
  788.  
  789.  /usr/include/*.h
  790.  /usr/include/sys/*.h
  791.  
  792. etc.
  793.  
  794. =head1 AUTHOR
  795.  
  796. Larry Wall
  797.  
  798. =head1 SEE ALSO
  799.  
  800. perl(1)
  801.  
  802. =head1 DIAGNOSTICS
  803.  
  804. The usual warnings if it can't read or write the files involved.
  805.  
  806. =head1 BUGS
  807.  
  808. Doesn't construct the %sizeof array for you.
  809.  
  810. It doesn't handle all C constructs, but it does attempt to isolate
  811. definitions inside evals so that you can get at the definitions
  812. that it can translate.
  813.  
  814. It's only intended as a rough tool.
  815. You may need to dicker with the files produced.
  816.  
  817. You have to run this program by hand; it's not run as part of the Perl
  818. installation.
  819.  
  820. Doesn't handle complicated expressions built piecemeal, a la:
  821.  
  822.     enum {
  823.         FIRST_VALUE,
  824.         SECOND_VALUE,
  825.     #ifdef ABC
  826.         THIRD_VALUE
  827.     #endif
  828.     };
  829.  
  830. Doesn't necessarily locate all of your C compiler's internally-defined
  831. symbols.
  832.  
  833. =cut
  834.  
  835.