home *** CD-ROM | disk | FTP | other *** search
/ PC World 2005 June / PCWorld_2005-06_cd.bin / software / vyzkuste / firewally / firewally.exe / framework-2.3.exe / auto.tcl < prev    next >
Text File  |  2003-09-01  |  20KB  |  583 lines
  1. # auto.tcl --
  2. #
  3. # utility procs formerly in init.tcl dealing with auto execution
  4. # of commands and can be auto loaded themselves.
  5. #
  6. # RCS: @(#) $Id: auto.tcl,v 1.11 2002/10/22 16:41:27 das Exp $
  7. #
  8. # Copyright (c) 1991-1993 The Regents of the University of California.
  9. # Copyright (c) 1994-1998 Sun Microsystems, Inc.
  10. #
  11. # See the file "license.terms" for information on usage and redistribution
  12. # of this file, and for a DISCLAIMER OF ALL WARRANTIES.
  13. #
  14.  
  15. # auto_reset --
  16. #
  17. # Destroy all cached information for auto-loading and auto-execution,
  18. # so that the information gets recomputed the next time it's needed.
  19. # Also delete any procedures that are listed in the auto-load index
  20. # except those defined in this file.
  21. #
  22. # Arguments: 
  23. # None.
  24.  
  25. proc auto_reset {} {
  26.     global auto_execs auto_index auto_oldpath
  27.     foreach p [info procs] {
  28.     if {[info exists auto_index($p)] && ![string match auto_* $p]
  29.         && ([lsearch -exact {unknown pkg_mkIndex tclPkgSetup
  30.             tcl_findLibrary pkg_compareExtension
  31.             tclMacPkgSearch tclPkgUnknown} $p] < 0)} {
  32.         rename $p {}
  33.     }
  34.     }
  35.     catch {unset auto_execs}
  36.     catch {unset auto_index}
  37.     catch {unset auto_oldpath}
  38. }
  39.  
  40. # tcl_findLibrary --
  41. #
  42. #    This is a utility for extensions that searches for a library directory
  43. #    using a canonical searching algorithm. A side effect is to source
  44. #    the initialization script and set a global library variable.
  45. #
  46. # Arguments:
  47. #     basename    Prefix of the directory name, (e.g., "tk")
  48. #    version        Version number of the package, (e.g., "8.0")
  49. #    patch        Patchlevel of the package, (e.g., "8.0.3")
  50. #    initScript    Initialization script to source (e.g., tk.tcl)
  51. #    enVarName    environment variable to honor (e.g., TK_LIBRARY)
  52. #    varName        Global variable to set when done (e.g., tk_library)
  53.  
  54. proc tcl_findLibrary {basename version patch initScript enVarName varName} {
  55.     upvar #0 $varName the_library
  56.     global env errorInfo
  57.  
  58.     set dirs {}
  59.     set errors {}
  60.  
  61.     # The C application may have hardwired a path, which we honor
  62.     
  63.     set variableSet [info exists the_library]
  64.     if {$variableSet && [string compare $the_library {}]} {
  65.     lappend dirs $the_library
  66.     } else {
  67.  
  68.     # Do the canonical search
  69.  
  70.     # 1. From an environment variable, if it exists
  71.  
  72.         if {[info exists env($enVarName)]} {
  73.             lappend dirs $env($enVarName)
  74.         }
  75.  
  76.     # 2. Relative to the Tcl library
  77.  
  78.         lappend dirs [file join [file dirname [info library]] \
  79.         $basename$version]
  80.  
  81.     # 3. Various locations relative to the executable
  82.     # ../lib/foo1.0        (From bin directory in install hierarchy)
  83.     # ../../lib/foo1.0    (From bin/arch directory in install hierarchy)
  84.     # ../library        (From unix directory in build hierarchy)
  85.     # ../../library        (From unix/arch directory in build hierarchy)
  86.     # ../../foo1.0.1/library
  87.     #        (From unix directory in parallel build hierarchy)
  88.     # ../../../foo1.0.1/library
  89.     #        (From unix/arch directory in parallel build hierarchy)
  90.  
  91.         set parentDir [file dirname [file dirname [info nameofexecutable]]]
  92.         set grandParentDir [file dirname $parentDir]
  93.         lappend dirs [file join $parentDir lib $basename$version]
  94.         lappend dirs [file join $grandParentDir lib $basename$version]
  95.         lappend dirs [file join $parentDir library]
  96.         lappend dirs [file join $grandParentDir library]
  97.         lappend dirs [file join $grandParentDir $basename$patch library]
  98.         lappend dirs [file join [file dirname $grandParentDir] \
  99.         $basename$patch library]
  100.  
  101.     # 4. On MacOSX, check the directories in the tcl_pkgPath
  102.     if {[string equal $::tcl_platform(platform) "unix"] && \
  103.         [string equal $::tcl_platform(os) "Darwin"]} {
  104.         foreach d $::tcl_pkgPath {
  105.         lappend dirs [file join $d $basename$version]
  106.         lappend dirs [file join $d $basename$version Resources Scripts]
  107.         }
  108.     }
  109.     }
  110.     foreach i $dirs {
  111.         set the_library $i
  112.         set file [file join $i $initScript]
  113.  
  114.     # source everything when in a safe interpreter because
  115.     # we have a source command, but no file exists command
  116.  
  117.         if {[interp issafe] || [file exists $file]} {
  118.             if {![catch {uplevel #0 [list source $file]} msg]} {
  119.                 return
  120.             } else {
  121.                 append errors "$file: $msg\n$errorInfo\n"
  122.             }
  123.         }
  124.     }
  125.     if {!$variableSet} {
  126.     unset the_library
  127.     }
  128.     set msg "Can't find a usable $initScript in the following directories: \n"
  129.     append msg "    $dirs\n\n"
  130.     append msg "$errors\n\n"
  131.     append msg "This probably means that $basename wasn't installed properly.\n"
  132.     error $msg
  133. }
  134.  
  135.  
  136. # ----------------------------------------------------------------------
  137. # auto_mkindex
  138. # ----------------------------------------------------------------------
  139. # The following procedures are used to generate the tclIndex file
  140. # from Tcl source files.  They use a special safe interpreter to
  141. # parse Tcl source files, writing out index entries as "proc"
  142. # commands are encountered.  This implementation won't work in a
  143. # safe interpreter, since a safe interpreter can't create the
  144. # special parser and mess with its commands.  
  145.  
  146. if {[interp issafe]} {
  147.     return    ;# Stop sourcing the file here
  148. }
  149.  
  150. # auto_mkindex --
  151. # Regenerate a tclIndex file from Tcl source files.  Takes as argument
  152. # the name of the directory in which the tclIndex file is to be placed,
  153. # followed by any number of glob patterns to use in that directory to
  154. # locate all of the relevant files.
  155. #
  156. # Arguments: 
  157. # dir -        Name of the directory in which to create an index.
  158. # args -    Any number of additional arguments giving the
  159. #        names of files within dir.  If no additional
  160. #        are given auto_mkindex will look for *.tcl.
  161.  
  162. proc auto_mkindex {dir args} {
  163.     global errorCode errorInfo
  164.  
  165.     if {[interp issafe]} {
  166.         error "can't generate index within safe interpreter"
  167.     }
  168.  
  169.     set oldDir [pwd]
  170.     cd $dir
  171.     set dir [pwd]
  172.  
  173.     append index "# Tcl autoload index file, version 2.0\n"
  174.     append index "# This file is generated by the \"auto_mkindex\" command\n"
  175.     append index "# and sourced to set up indexing information for one or\n"
  176.     append index "# more commands.  Typically each line is a command that\n"
  177.     append index "# sets an element in the auto_index array, where the\n"
  178.     append index "# element name is the name of a command and the value is\n"
  179.     append index "# a script that loads the command.\n\n"
  180.     if {$args == ""} {
  181.     set args *.tcl
  182.     }
  183.  
  184.     auto_mkindex_parser::init
  185.     foreach file [eval glob $args] {
  186.         if {[catch {auto_mkindex_parser::mkindex $file} msg] == 0} {
  187.             append index $msg
  188.         } else {
  189.             set code $errorCode
  190.             set info $errorInfo
  191.             cd $oldDir
  192.             error $msg $info $code
  193.         }
  194.     }
  195.     auto_mkindex_parser::cleanup
  196.  
  197.     set fid [open "tclIndex" w]
  198.     puts -nonewline $fid $index
  199.     close $fid
  200.     cd $oldDir
  201. }
  202.  
  203. # Original version of auto_mkindex that just searches the source
  204. # code for "proc" at the beginning of the line.
  205.  
  206. proc auto_mkindex_old {dir args} {
  207.     global errorCode errorInfo
  208.     set oldDir [pwd]
  209.     cd $dir
  210.     set dir [pwd]
  211.     append index "# Tcl autoload index file, version 2.0\n"
  212.     append index "# This file is generated by the \"auto_mkindex\" command\n"
  213.     append index "# and sourced to set up indexing information for one or\n"
  214.     append index "# more commands.  Typically each line is a command that\n"
  215.     append index "# sets an element in the auto_index array, where the\n"
  216.     append index "# element name is the name of a command and the value is\n"
  217.     append index "# a script that loads the command.\n\n"
  218.     if {[string equal $args ""]} {
  219.     set args *.tcl
  220.     }
  221.     foreach file [eval glob $args] {
  222.     set f ""
  223.     set error [catch {
  224.         set f [open $file]
  225.         while {[gets $f line] >= 0} {
  226.         if {[regexp {^proc[     ]+([^     ]*)} $line match procName]} {
  227.             set procName [lindex [auto_qualify $procName "::"] 0]
  228.             append index "set [list auto_index($procName)]"
  229.             append index " \[list source \[file join \$dir [list $file]\]\]\n"
  230.         }
  231.         }
  232.         close $f
  233.     } msg]
  234.     if {$error} {
  235.         set code $errorCode
  236.         set info $errorInfo
  237.         catch {close $f}
  238.         cd $oldDir
  239.         error $msg $info $code
  240.     }
  241.     }
  242.     set f ""
  243.     set error [catch {
  244.     set f [open tclIndex w]
  245.     puts -nonewline $f $index
  246.     close $f
  247.     cd $oldDir
  248.     } msg]
  249.     if {$error} {
  250.     set code $errorCode
  251.     set info $errorInfo
  252.     catch {close $f}
  253.     cd $oldDir
  254.     error $msg $info $code
  255.     }
  256. }
  257.  
  258. # Create a safe interpreter that can be used to parse Tcl source files
  259. # generate a tclIndex file for autoloading.  This interp contains
  260. # commands for things that need index entries.  Each time a command
  261. # is executed, it writes an entry out to the index file.
  262.  
  263. namespace eval auto_mkindex_parser {
  264.     variable parser ""          ;# parser used to build index
  265.     variable index ""           ;# maintains index as it is built
  266.     variable scriptFile ""      ;# name of file being processed
  267.     variable contextStack ""    ;# stack of namespace scopes
  268.     variable imports ""         ;# keeps track of all imported cmds
  269.     variable initCommands ""    ;# list of commands that create aliases
  270.  
  271.     proc init {} {
  272.     variable parser
  273.     variable initCommands
  274.  
  275.     if {![interp issafe]} {
  276.         set parser [interp create -safe]
  277.         $parser hide info
  278.         $parser hide rename
  279.         $parser hide proc
  280.         $parser hide namespace
  281.         $parser hide eval
  282.         $parser hide puts
  283.         $parser invokehidden namespace delete ::
  284.         $parser invokehidden proc unknown {args} {}
  285.  
  286.         # We'll need access to the "namespace" command within the
  287.         # interp.  Put it back, but move it out of the way.
  288.  
  289.         $parser expose namespace
  290.         $parser invokehidden rename namespace _%@namespace
  291.         $parser expose eval
  292.         $parser invokehidden rename eval _%@eval
  293.  
  294.         # Install all the registered psuedo-command implementations
  295.  
  296.         foreach cmd $initCommands {
  297.         eval $cmd
  298.         }
  299.     }
  300.     }
  301.     proc cleanup {} {
  302.     variable parser
  303.     interp delete $parser
  304.     unset parser
  305.     }
  306. }
  307.  
  308. # auto_mkindex_parser::mkindex --
  309. #
  310. # Used by the "auto_mkindex" command to create a "tclIndex" file for
  311. # the given Tcl source file.  Executes the commands in the file, and
  312. # handles things like the "proc" command by adding an entry for the
  313. # index file.  Returns a string that represents the index file.
  314. #
  315. # Arguments: 
  316. #    file    Name of Tcl source file to be indexed.
  317.  
  318. proc auto_mkindex_parser::mkindex {file} {
  319.     variable parser
  320.     variable index
  321.     variable scriptFile
  322.     variable contextStack
  323.     variable imports
  324.  
  325.     set scriptFile $file
  326.  
  327.     set fid [open $file]
  328.     set contents [read $fid]
  329.     close $fid
  330.  
  331.     # There is one problem with sourcing files into the safe
  332.     # interpreter:  references like "$x" will fail since code is not
  333.     # really being executed and variables do not really exist.
  334.     # To avoid this, we replace all $ with \0 (literally, the null char)
  335.     # later, when getting proc names we will have to reverse this replacement,
  336.     # in case there were any $ in the proc name.  This will cause a problem
  337.     # if somebody actually tries to have a \0 in their proc name.  Too bad
  338.     # for them.
  339.     regsub -all {\$} $contents "\0" contents
  340.     
  341.     set index ""
  342.     set contextStack ""
  343.     set imports ""
  344.  
  345.     $parser eval $contents
  346.  
  347.     foreach name $imports {
  348.         catch {$parser eval [list _%@namespace forget $name]}
  349.     }
  350.     return $index
  351. }
  352.  
  353. # auto_mkindex_parser::hook command
  354. #
  355. # Registers a Tcl command to evaluate when initializing the
  356. # slave interpreter used by the mkindex parser.
  357. # The command is evaluated in the master interpreter, and can
  358. # use the variable auto_mkindex_parser::parser to get to the slave
  359.  
  360. proc auto_mkindex_parser::hook {cmd} {
  361.     variable initCommands
  362.  
  363.     lappend initCommands $cmd
  364. }
  365.  
  366. # auto_mkindex_parser::slavehook command
  367. #
  368. # Registers a Tcl command to evaluate when initializing the
  369. # slave interpreter used by the mkindex parser.
  370. # The command is evaluated in the slave interpreter.
  371.  
  372. proc auto_mkindex_parser::slavehook {cmd} {
  373.     variable initCommands
  374.  
  375.     # The $parser variable is defined to be the name of the
  376.     # slave interpreter when this command is used later.
  377.  
  378.     lappend initCommands "\$parser eval [list $cmd]"
  379. }
  380.  
  381. # auto_mkindex_parser::command --
  382. #
  383. # Registers a new command with the "auto_mkindex_parser" interpreter
  384. # that parses Tcl files.  These commands are fake versions of things
  385. # like the "proc" command.  When you execute them, they simply write
  386. # out an entry to a "tclIndex" file for auto-loading.
  387. #
  388. # This procedure allows extensions to register their own commands
  389. # with the auto_mkindex facility.  For example, a package like
  390. # [incr Tcl] might register a "class" command so that class definitions
  391. # could be added to a "tclIndex" file for auto-loading.
  392. #
  393. # Arguments:
  394. #    name     Name of command recognized in Tcl files.
  395. #    arglist    Argument list for command.
  396. #    body     Implementation of command to handle indexing.
  397.  
  398. proc auto_mkindex_parser::command {name arglist body} {
  399.     hook [list auto_mkindex_parser::commandInit $name $arglist $body]
  400. }
  401.  
  402. # auto_mkindex_parser::commandInit --
  403. #
  404. # This does the actual work set up by auto_mkindex_parser::command
  405. # This is called when the interpreter used by the parser is created.
  406. #
  407. # Arguments:
  408. #    name     Name of command recognized in Tcl files.
  409. #    arglist    Argument list for command.
  410. #    body     Implementation of command to handle indexing.
  411.  
  412. proc auto_mkindex_parser::commandInit {name arglist body} {
  413.     variable parser
  414.  
  415.     set ns [namespace qualifiers $name]
  416.     set tail [namespace tail $name]
  417.     if {[string equal $ns ""]} {
  418.         set fakeName "[namespace current]::_%@fake_$tail"
  419.     } else {
  420.         set fakeName "_%@fake_$name"
  421.         regsub -all {::} $fakeName "_" fakeName
  422.         set fakeName "[namespace current]::$fakeName"
  423.     }
  424.     proc $fakeName $arglist $body
  425.  
  426.     # YUK!  Tcl won't let us alias fully qualified command names,
  427.     # so we can't handle names like "::itcl::class".  Instead,
  428.     # we have to build procs with the fully qualified names, and
  429.     # have the procs point to the aliases.
  430.  
  431.     if {[regexp {::} $name]} {
  432.         set exportCmd [list _%@namespace export [namespace tail $name]]
  433.         $parser eval [list _%@namespace eval $ns $exportCmd]
  434.  
  435.     # The following proc definition does not work if you
  436.     # want to tolerate space or something else diabolical
  437.     # in the procedure name, (i.e., space in $alias)
  438.     # The following does not work:
  439.     #   "_%@eval {$alias} \$args"
  440.     # because $alias gets concat'ed to $args.
  441.     # The following does not work because $cmd is somehow undefined
  442.     #   "set cmd {$alias} \; _%@eval {\$cmd} \$args"
  443.     # A gold star to someone that can make test
  444.     # autoMkindex-3.3 work properly
  445.  
  446.         set alias [namespace tail $fakeName]
  447.         $parser invokehidden proc $name {args} "_%@eval {$alias} \$args"
  448.         $parser alias $alias $fakeName
  449.     } else {
  450.         $parser alias $name $fakeName
  451.     }
  452.     return
  453. }
  454.  
  455. # auto_mkindex_parser::fullname --
  456. # Used by commands like "proc" within the auto_mkindex parser.
  457. # Returns the qualified namespace name for the "name" argument.
  458. # If the "name" does not start with "::", elements are added from
  459. # the current namespace stack to produce a qualified name.  Then,
  460. # the name is examined to see whether or not it should really be
  461. # qualified.  If the name has more than the leading "::", it is
  462. # returned as a fully qualified name.  Otherwise, it is returned
  463. # as a simple name.  That way, the Tcl autoloader will recognize
  464. # it properly.
  465. #
  466. # Arguments:
  467. # name -        Name that is being added to index.
  468.  
  469. proc auto_mkindex_parser::fullname {name} {
  470.     variable contextStack
  471.  
  472.     if {![string match ::* $name]} {
  473.         foreach ns $contextStack {
  474.             set name "${ns}::$name"
  475.             if {[string match ::* $name]} {
  476.                 break
  477.             }
  478.         }
  479.     }
  480.  
  481.     if {[string equal [namespace qualifiers $name] ""]} {
  482.         set name [namespace tail $name]
  483.     } elseif {![string match ::* $name]} {
  484.         set name "::$name"
  485.     }
  486.     
  487.     # Earlier, mkindex replaced all $'s with \0.  Now, we have to reverse
  488.     # that replacement.
  489.     regsub -all "\0" $name "\$" name
  490.     return $name
  491. }
  492.  
  493. # Register all of the procedures for the auto_mkindex parser that
  494. # will build the "tclIndex" file.
  495.  
  496. # AUTO MKINDEX:  proc name arglist body
  497. # Adds an entry to the auto index list for the given procedure name.
  498.  
  499. auto_mkindex_parser::command proc {name args} {
  500.     variable index
  501.     variable scriptFile
  502.     # Do some fancy reformatting on the "source" call to handle platform
  503.     # differences with respect to pathnames.  Use format just so that the
  504.     # command is a little easier to read (otherwise it'd be full of 
  505.     # backslashed dollar signs, etc.
  506.     append index [list set auto_index([fullname $name])] \
  507.         [format { [list source [file join $dir %s]]} \
  508.         [file split $scriptFile]] "\n"
  509. }
  510.  
  511. # Conditionally add support for Tcl byte code files.  There are some
  512. # tricky details here.  First, we need to get the tbcload library
  513. # initialized in the current interpreter.  We cannot load tbcload into the
  514. # slave until we have done so because it needs access to the tcl_patchLevel
  515. # variable.  Second, because the package index file may defer loading the
  516. # library until we invoke a command, we need to explicitly invoke auto_load
  517. # to force it to be loaded.  This should be a noop if the package has
  518. # already been loaded
  519.  
  520. auto_mkindex_parser::hook {
  521.     if {![catch {package require tbcload}]} {
  522.     if {[llength [info commands tbcload::bcproc]] == 0} {
  523.         auto_load tbcload::bcproc
  524.     }
  525.     load {} tbcload $auto_mkindex_parser::parser
  526.  
  527.     # AUTO MKINDEX:  tbcload::bcproc name arglist body
  528.     # Adds an entry to the auto index list for the given pre-compiled
  529.     # procedure name.  
  530.  
  531.     auto_mkindex_parser::commandInit tbcload::bcproc {name args} {
  532.         variable index
  533.         variable scriptFile
  534.         # Do some nice reformatting of the "source" call, to get around
  535.         # path differences on different platforms.  We use the format
  536.         # command just so that the code is a little easier to read.
  537.         append index [list set auto_index([fullname $name])] \
  538.             [format { [list source [file join $dir %s]]} \
  539.             [file split $scriptFile]] "\n"
  540.     }
  541.     }
  542. }
  543.  
  544. # AUTO MKINDEX:  namespace eval name command ?arg arg...?
  545. # Adds the namespace name onto the context stack and evaluates the
  546. # associated body of commands.
  547. #
  548. # AUTO MKINDEX:  namespace import ?-force? pattern ?pattern...?
  549. # Performs the "import" action in the parser interpreter.  This is
  550. # important for any commands contained in a namespace that affect
  551. # the index.  For example, a script may say "itcl::class ...",
  552. # or it may import "itcl::*" and then say "class ...".  This
  553. # procedure does the import operation, but keeps track of imported
  554. # patterns so we can remove the imports later.
  555.  
  556. auto_mkindex_parser::command namespace {op args} {
  557.     switch -- $op {
  558.         eval {
  559.             variable parser
  560.             variable contextStack
  561.  
  562.             set name [lindex $args 0]
  563.             set args [lrange $args 1 end]
  564.  
  565.             set contextStack [linsert $contextStack 0 $name]
  566.         $parser eval [list _%@namespace eval $name] $args
  567.             set contextStack [lrange $contextStack 1 end]
  568.         }
  569.         import {
  570.             variable parser
  571.             variable imports
  572.             foreach pattern $args {
  573.                 if {[string compare $pattern "-force"]} {
  574.                     lappend imports $pattern
  575.                 }
  576.             }
  577.             catch {$parser eval "_%@namespace import $args"}
  578.         }
  579.     }
  580. }
  581.  
  582. return
  583.