home *** CD-ROM | disk | FTP | other *** search
/ PC World 2005 June / PCWorld_2005-06_cd.bin / software / vyzkuste / firewally / firewally.exe / framework-2.3.exe / Tar.pm < prev    next >
Text File  |  2003-10-17  |  35KB  |  1,186 lines
  1. ### the gnu tar specification:
  2. ### http://www.gnu.org/manual/tar/html_node/tar_toc.html
  3. ###
  4. ### and the pax format spec, which tar derives from:
  5. ### http://www.opengroup.org/onlinepubs/007904975/utilities/pax.html
  6.  
  7. package Archive::Tar;
  8. require 5.005_03;
  9.  
  10. use strict;
  11. use vars qw[$DEBUG $error $VERSION $WARN $FOLLOW_SYMLINK $CHOWN $CHMOD];
  12. $DEBUG          = 0;
  13. $WARN           = 1;
  14. $FOLLOW_SYMLINK = 0;
  15. $VERSION        = "1.07";
  16. $CHOWN          = 1;
  17. $CHMOD          = 1;
  18.  
  19. use IO::File;
  20. use Cwd;
  21. use Carp qw(carp);
  22. use FileHandle;
  23. use File::Spec ();
  24. use File::Spec::Unix ();
  25. use File::Path ();
  26.  
  27. use Archive::Tar::File;
  28. use Archive::Tar::Constant;
  29.  
  30. =head1 NAME
  31.  
  32. Archive::Tar - module for manipulations of tar archives
  33.  
  34. =head1 SYNOPSIS
  35.  
  36.     use Archive::Tar;
  37.     my $tar = Archive::Tar->new;
  38.     
  39.     $tar->read('origin.tgz',1); 
  40.     $tar->extract();
  41.     
  42.     $tar->add_files('file/foo.pl', 'docs/README');
  43.     $tar->add_data('file/baz.txt', 'This is the contents now');
  44.     
  45.     $tar->rename('oldname', 'new/file/name');
  46.     
  47.     $tar->write('files.tar');
  48.     
  49. =head1 DESCRIPTION
  50.     
  51. Archive::Tar provides an object oriented mechanism for handling tar
  52. files.  It provides class methods for quick and easy files handling
  53. while also allowing for the creation of tar file objects for custom
  54. manipulation.  If you have the IO::Zlib module installed,
  55. Archive::Tar will also support compressed or gzipped tar files.
  56.  
  57. An object of class Archive::Tar represents a .tar(.gz) archive full 
  58. of files and things.
  59.  
  60. =head1 Object Methods
  61.  
  62. =head2 Archive::Tar->new( [$file, $compressed] )
  63.  
  64. Returns a new Tar object. If given any arguments, C<new()> calls the
  65. C<read()> method automatically, passing on the arguments provided to 
  66. the C<read()> method.
  67.  
  68. If C<new()> is invoked with arguments and the C<read()> method fails 
  69. for any reason, C<new()> returns undef.
  70.  
  71. =cut
  72.  
  73. my $tmpl = {
  74.     _data   => [ ],
  75.     _file   => 'Unknown',
  76. };    
  77.  
  78. ### install get/set accessors for this object.
  79. for my $key ( keys %$tmpl ) {
  80.     no strict 'refs';
  81.     *{__PACKAGE__."::$key"} = sub {
  82.         my $self = shift;
  83.         $self->{$key} = $_[0] if @_;
  84.         return $self->{$key};
  85.     }
  86. }
  87.  
  88. sub new {
  89.  
  90.     ### copying $tmpl here since a shallow copy makes it use the
  91.     ### same aref, causing for files to remain in memory always.
  92.     my $obj = bless { _data => [ ], _file => 'Unknown' }, shift;
  93.  
  94.     $obj->read( @_ ) if @_;
  95.     
  96.     return $obj;
  97. }
  98.  
  99. =head2 $tar->read ( $filename|$handle, $compressed, {opt => 'val'} )
  100.  
  101. Read the given tar file into memory. 
  102. The first argument can either be the name of a file or a reference to
  103. an already open filehandle (or an IO::Zlib object if it's compressed)  
  104. The second argument indicates whether the file referenced by the first 
  105. argument is compressed.
  106.  
  107. The C<read> will I<replace> any previous content in C<$tar>!
  108.  
  109. The second argument may be considered optional if IO::Zlib is
  110. installed, since it will transparently Do The Right Thing. 
  111. Archive::Tar will warn if you try to pass a compressed file if 
  112. IO::Zlib is not available and simply return.
  113.  
  114. The third argument can be a hash reference with options. Note that 
  115. all options are case-sensitive.
  116.  
  117. =over 4
  118.  
  119. =item limit
  120.  
  121. Do not read more than C<limit> files. This is usefull if you have 
  122. very big archives, and are only interested in the first few files.
  123.  
  124. =item extract
  125.  
  126. If set to true, immediately extract entries when reading them. This
  127. gives you the same memory break as the C<extract_archive> function.
  128. Note however that entries will not be read into memory, but written 
  129. straight to disk.
  130.  
  131. =back
  132.  
  133. All files are stored internally as C<Archive::Tar::File> objects.
  134. Please consult the L<Archive::Tar::File> documentation for details.
  135.  
  136. Returns the number of files read in scalar context, and a list of
  137. C<Archive::Tar::File> objects in list context.
  138.  
  139. =cut
  140.  
  141. sub read {
  142.     my $self = shift;    
  143.     my $file = shift || $self->_file;
  144.     my $gzip = shift || 0;
  145.     my $opts = shift || {};
  146.     
  147.     unless( defined $file ) {
  148.         $self->error( qq[No file to read from!] );
  149.         return;
  150.     } else {
  151.         $self->_file( $file );
  152.     }     
  153.     
  154.     my $handle = $self->_get_handle($file, $gzip, READ_ONLY->($gzip) ) 
  155.                     or return;
  156.  
  157.     my $data = $self->_read_tar( $handle, $opts ) or return;
  158.  
  159.     $self->_data( $data );    
  160.  
  161.     return wantarray ? @$data : scalar @$data;
  162. }
  163.  
  164. sub _get_handle {
  165.     my $self = shift;
  166.     my $file = shift;   return unless defined $file;
  167.                         return $file if ref $file;
  168.                         
  169.     my $gzip = shift || 0;
  170.     my $mode = shift || READ_ONLY->($gzip); # default to read only
  171.     
  172.     my $fh; my $bin;
  173.     
  174.     ### only default to ZLIB if we're not trying to /write/ to a handle ###
  175.     if( ZLIB and $gzip || MODE_READ->( $mode ) ) {
  176.         
  177.         ### IO::Zlib will Do The Right Thing, even when passed a plain file ###
  178.         $fh = new IO::Zlib;
  179.     
  180.     } else {    
  181.         if( $gzip ) {
  182.             $self->_error( qq[Compression not available - Install IO::Zlib!] );
  183.             return;
  184.         
  185.         } else {
  186.             $fh = new IO::File;
  187.             $bin++;
  188.         }
  189.     }
  190.         
  191.     unless( $fh->open( $file, $mode ) ) {
  192.         $self->_error( qq[Could not create filehandle for '$file': $!!] );
  193.         return;
  194.     }
  195.     
  196.     binmode $fh if $bin;
  197.     
  198.     return $fh;
  199. }
  200.  
  201. sub _read_tar {
  202.     my $self    = shift;
  203.     my $handle  = shift or return;
  204.     my $opts    = shift || {};
  205.  
  206.     my $count   = $opts->{limit}    || 0;
  207.     my $extract = $opts->{extract}  || 0;
  208.     
  209.     ### set a cap on the amount of files to extract ###
  210.     my $limit   = 0;
  211.     $limit = 1 if $count > 0;
  212.  
  213.     my $tarfile = [ ];
  214.     my $chunk;
  215.     my $read = 0;
  216.     my $real_name;  # to set the name of a file when we're encountering @longlink
  217.     my $data;
  218.          
  219.     LOOP: 
  220.     while( $handle->read( $chunk, HEAD ) ) {        
  221.         
  222.         unless( $read++ ) {
  223.             my $gzip = GZIP_MAGIC_NUM;
  224.             if( $chunk =~ /$gzip/ ) {
  225.                 $self->_error( qq[Can not read compressed format in tar-mode] );
  226.                 return;
  227.             }
  228.         }
  229.               
  230.         ### if we can't read in all bytes... ###
  231.         last if length $chunk != HEAD;
  232.         
  233.         # Apparently this should really be two blocks of 512 zeroes,
  234.         # but GNU tar sometimes gets it wrong. See comment in the
  235.         # source code (tar.c) to GNU cpio.
  236.         last if $chunk eq TAR_END; 
  237.         
  238.         my $entry; 
  239.         unless( $entry = Archive::Tar::File->new( chunk => $chunk ) ) {
  240.             $self->_error( qq[Couldn't read chunk '$chunk'] );
  241.             next;
  242.         }
  243.         
  244.         ### ignore labels:
  245.         ### http://www.gnu.org/manual/tar/html_node/tar_139.html
  246.         next if $entry->is_label;
  247.         
  248.         if( length $entry->type and ($entry->is_file || $entry->is_longlink) ) {
  249.             
  250.             if ( $entry->is_file && !$entry->validate ) {
  251.                 $self->_error( $entry->name . qq[: checksum error] );
  252.                 next LOOP;
  253.             }
  254.           
  255.             ### part II of the @LongLink munging -- need to do /after/
  256.             ### the checksum check.
  257.  
  258.             
  259.             my $block = BLOCK_SIZE->( $entry->size );
  260.  
  261.             $data = $entry->get_content_by_ref;
  262. #            while( $block ) {
  263. #                $handle->read( $data, $block ) or (
  264. #                    $self->_error( qq[Could not read block for ] . $entry->name ),
  265. #                    return
  266. #                );
  267. #                $block > BUFFER 
  268. #                    ? $block -= BUFFER
  269. #                    : last;   
  270. #                last if $block eq TAR_END;             
  271. #            }
  272.             
  273.             ### just read everything into memory 
  274.             ### can't do lazy loading since IO::Zlib doesn't support 'seek'
  275.             ### this is because Compress::Zlib doesn't support it =/            
  276.             if( $handle->read( $$data, $block ) < $block ) {
  277.                 $self->_error( qq[Read error on tarfile ']. $entry->name ."'" );
  278.                 return;
  279.             }
  280.  
  281.             ### throw away trailing garbage ###
  282.             substr ($$data, $entry->size) = "";
  283.         }
  284.         
  285.         
  286.         ### clean up of the entries.. posix tar /apparently/ has some
  287.         ### weird 'feature' that allows for filenames > 255 characters
  288.         ### they'll put a header in with as name '././@LongLink' and the
  289.         ### contents will be the name of the /next/ file in the archive
  290.         ### pretty crappy and kludgy if you ask me
  291.         
  292.         ### set the name for the next entry if this is a @LongLink;
  293.         ### this is one ugly hack =/ but needed for direct extraction
  294.         if( $entry->is_longlink ) {
  295.             $real_name = $data;
  296.             next;
  297.         } elsif ( defined $real_name ) {
  298.             $entry->name( $$real_name );
  299.             undef $real_name;      
  300.         }
  301.  
  302.         $self->_extract_file( $entry )  if $extract && !$entry->is_longlink
  303.                                         && !$entry->is_unknown && !$entry->is_label;
  304.         
  305.         ### Guard against tarfiles with garbage at the end
  306.         last LOOP if $entry->name eq ''; 
  307.     
  308.         ### push only the name on the rv if we're extracting -- for extract_archive
  309.         push @$tarfile, ($extract ? $entry->name : $entry);
  310.     
  311.         if( $limit ) {
  312.             $count-- unless $entry->is_longlink || $entry->is_dir;    
  313.             last LOOP unless $count;
  314.         }
  315.     } continue {
  316.         undef $data;
  317.     }      
  318.     
  319.     return $tarfile;
  320. }    
  321.  
  322. =head2 $tar->contains_file( $filename )
  323.  
  324. Check if the archive contains a certain file.
  325. It will return true if the file is in the archive, false otherwise.
  326.  
  327. Note however, that this function does an exact match using C<eq>
  328. on the full path. So it can not compensate for case-insensitive file-
  329. systems or compare 2 paths to see if they would point to the same
  330. underlying file.
  331.  
  332. =cut
  333.  
  334. sub contains_file {
  335.     my $self = shift;
  336.     my $full = shift or return;
  337.     
  338.     my @parts = File::Spec->splitdir($full);
  339.     my $file  = pop @parts;
  340.     my $path  = File::Spec::Unix->catdir( @parts );
  341.     
  342.     for my $obj ( $self->get_files ) {
  343.         next unless $file eq $obj->name;
  344.         next unless $path eq $obj->prefix;
  345.     
  346.         return 1;       
  347.     }      
  348.     return;
  349. }    
  350.  
  351. =head2 $tar->extract( [@filenames] )
  352.  
  353. Write files whose names are equivalent to any of the names in
  354. C<@filenames> to disk, creating subdirectories as necessary. This
  355. might not work too well under VMS.  
  356. Under MacPerl, the file's modification time will be converted to the
  357. MacOS zero of time, and appropriate conversions will be done to the 
  358. path.  However, the length of each element of the path is not 
  359. inspected to see whether it's longer than MacOS currently allows (32
  360. characters).
  361.  
  362. If C<extract> is called without a list of file names, the entire
  363. contents of the archive are extracted.
  364.  
  365. Returns a list of filenames extracted.
  366.  
  367. =cut
  368.  
  369. sub extract {
  370.     my $self    = shift;
  371.     my @files   = @_ ? @_ : $self->list_files;
  372.  
  373.     unless( scalar @files ) {
  374.         $self->_error( qq[No files found for ] . $self->_file );
  375.         return;
  376.     }
  377.     
  378.     for my $file ( @files ) {
  379.         for my $entry ( @{$self->_data} ) {
  380.             next unless $file eq $entry->name;
  381.     
  382.             unless( $self->_extract_file( $entry ) ) {
  383.                 $self->_error( qq[Could not extract '$file'] );
  384.                 return;
  385.             }        
  386.         }
  387.     }
  388.          
  389.     return @files;        
  390. }
  391.  
  392. sub _extract_file {
  393.     my $self    = shift;
  394.     my $entry   = shift or return;
  395.     my $cwd     = cwd();
  396.     
  397.                             ### splitpath takes a bool at the end to indicate that it's splitting a dir    
  398.     my ($vol,$dirs,$file)   = File::Spec::Unix->splitpath( $entry->name, $entry->is_dir );
  399.     my @dirs                = File::Spec::Unix->splitdir( $dirs );
  400.     my @cwd                 = File::Spec->splitdir( $cwd );
  401.     my $dir                 = File::Spec->catdir(@cwd, @dirs);               
  402.     
  403.     if( -e $dir && !-d _ ) {
  404.         $^W && $self->_error( qq['$dir' exists, but it's not a directory!\n] );
  405.         return;
  406.     }
  407.     
  408.     unless ( -d _ ) {
  409.         eval { File::Path::mkpath( $dir, 0, 0777 ) };
  410.         if( $@ ) {
  411.             $self->_error( qq[Could not create directory '$dir': $@] );
  412.             return;
  413.         }
  414.     }
  415.     
  416.     ### we're done if we just needed to create a dir ###
  417.     return 1 if $entry->is_dir;
  418.     
  419.     my $full = File::Spec->catfile( $dir, $file );
  420.     
  421.     if( $entry->is_unknown ) {
  422.         $self->_error( qq[Unknown file type for file '$full'] );
  423.         return;
  424.     }
  425.     
  426.     if( length $entry->type && $entry->is_file ) {
  427.         my $fh = new FileHandle;
  428.         $fh->open( '>' . $full ) or (
  429.             $self->_error( qq[Could not open file '$full': $!] ),
  430.             return
  431.         );
  432.     
  433.         if( $entry->size ) {
  434.             binmode $fh;
  435.             syswrite $fh, $entry->data or (
  436.                 $self->_error( qq[Could not write data to '$full'] ),
  437.                 return
  438.             );
  439.         }
  440.         
  441.         close $fh or (
  442.             $self->_error( qq[Could not close file '$full'] ),
  443.             return
  444.         );     
  445.     
  446.     } else {
  447.         $self->_make_special_file( $entry, $full ) or return;
  448.     } 
  449.  
  450.     utime time, $entry->mtime - TIME_OFFSET, $full or
  451.         $self->_error( qq[Could not update timestamp] );
  452.  
  453.     if( $CHOWN && CAN_CHOWN ) {
  454.         chown $entry->uid, $entry->gid, $full or
  455.             $self->_error( qq[Could not set uid/gid on '$full'] );
  456.     }
  457.     
  458.     if( $CHMOD ) {
  459.         chmod $entry->mode, $full or
  460.             $self->_error( qq[Could not chown '$full' to ] . $entry->mode );
  461.     }            
  462.     
  463.     return 1;
  464. }
  465.  
  466. sub _make_special_file {
  467.     my $self    = shift;
  468.     my $entry   = shift     or return;
  469.     my $file    = shift;    return unless defined $file;
  470.     
  471.     my $err;
  472.     
  473.     if( $entry->is_symlink ) {
  474.         ON_UNIX && symlink( $entry->linkname, $file ) or 
  475.             $err =  qq[Making symbolink link from '] . $entry->linkname .
  476.                     qq[' to '$file' failed]; 
  477.     
  478.     } elsif ( $entry->is_hardlink ) {
  479.         ON_UNIX && link( $entry->linkname, $file ) or 
  480.             $err =  qq[Making hard link from '] . $entry->linkname .
  481.                     qq[' to '$file' failed];     
  482.     
  483.     } elsif ( $entry->is_fifo ) {
  484.         ON_UNIX && !system('mknod', $file, 'p') or 
  485.             $err = qq[Making fifo ']. $entry->name .qq[' failed];
  486.  
  487.     } elsif ( $entry->is_blockdev or $entry->is_chardev ) {
  488.         my $mode = $entry->is_blockdev ? 'b' : 'c';
  489.             
  490.         ON_UNIX && !system('mknod', $file, $mode, $entry->devmajor, $entry->devminor ) or
  491.             $err =  qq[Making block device ']. $entry->name .qq[' (maj=] .
  492.                     $entry->devmajor . qq[ min=] . $entry->devminor .qq[) failed.];          
  493.  
  494.     } elsif ( $entry->is_socket ) {
  495.         ### the original doesn't do anything special for sockets.... ###     
  496.         1;
  497.     }
  498.     
  499.     return $err ? $self->_error( $err ) : 1;
  500. }
  501.  
  502. =head2 $tar->list_files( [\@properties] )
  503.  
  504. Returns a list of the names of all the files in the archive.
  505.  
  506. If C<list_files()> is passed an array reference as its first argument
  507. it returns a list of hash references containing the requested
  508. properties of each file.  The following list of properties is
  509. supported: name, size, mtime (last modified date), mode, uid, gid,
  510. linkname, uname, gname, devmajor, devminor, prefix.
  511.  
  512. Passing an array reference containing only one element, 'name', is
  513. special cased to return a list of names rather than a list of hash
  514. references, making it equivalent to calling C<list_files> without 
  515. arguments.
  516.  
  517. =cut
  518.  
  519. sub list_files {
  520.     my $self = shift;
  521.     my $aref = shift || [ ];
  522.     
  523.     unless( $self->_data ) {
  524.         $self->read() or return;
  525.     }
  526.     
  527.     if( @$aref == 0 or ( @$aref == 1 and $aref->[0] eq 'name' ) ) {
  528.         return map { $_->name } @{$self->_data};     
  529.     } else {
  530.     
  531.         #my @rv;
  532.         #for my $obj ( @{$self->_data} ) {
  533.         #    push @rv, { map { $_ => $obj->$_() } @$aref };
  534.         #}
  535.         #return @rv;
  536.         
  537.         ### this does the same as the above.. just needs a +{ }
  538.         ### to make sure perl doesn't confuse it for a block
  539.         return map { my $o=$_; +{ map { $_ => $o->$_() } @$aref } } @{$self->_data}; 
  540.     }    
  541. }
  542.  
  543. sub _find_entry {
  544.     my $self = shift;
  545.     my $file = shift;
  546.  
  547.     unless( defined $file ) {
  548.         $self->_error( qq[No file specified] );
  549.         return;
  550.     }
  551.     
  552.     for my $entry ( @{$self->_data} ) {
  553.         return $entry if $entry->name eq $file;      
  554.     }
  555.     
  556.     $self->_error( qq[No such file in archive: '$file'] );
  557.     return;
  558. }    
  559.  
  560. =head2 $tar->get_files( [@filenames] )
  561.  
  562. Returns the C<Archive::Tar::File> objects matching the filenames 
  563. provided. If no filename list was passed, all C<Archive::Tar::File>
  564. objects in the current Tar object are returned.
  565.  
  566. Please refer to the C<Archive::Tar::File> documentation on how to 
  567. handle these objects
  568.  
  569. =cut
  570.  
  571. sub get_files {
  572.     my $self = shift;
  573.     
  574.     return @{ $self->_data } unless @_;
  575.     
  576.     my @list;
  577.     for my $file ( @_ ) {
  578.         push @list, grep { defined } $self->_find_entry( $file );
  579.     }
  580.     
  581.     return @list;
  582. }
  583.  
  584. =head2 $tar->get_content( $file )
  585.  
  586. Return the content of the named file.
  587.  
  588. =cut
  589.     
  590. sub get_content {
  591.     my $self = shift;
  592.     my $entry = $self->_find_entry( shift ) or return;
  593.     
  594.     return $entry->data;        
  595. }    
  596.  
  597. =head2 $tar->replace_content( $file, $content )
  598.  
  599. Make the string $content be the content for the file named $file.
  600.  
  601. =cut
  602.  
  603. sub replace_content {
  604.     my $self = shift;
  605.     my $entry = $self->_find_entry( shift ) or return;
  606.  
  607.     return $entry->replace_content( shift );
  608. }    
  609.  
  610. =head2 $tar->rename( $file, $new_name ) 
  611.  
  612. Rename the file of the in-memory archive to $new_name.
  613.  
  614. Note that you must specify a Unix path for $new_name, since per tar
  615. standard, all files in the archive must be Unix paths.
  616.  
  617. Returns true on success and false on failure.
  618.  
  619. =cut
  620.  
  621. sub rename {
  622.     my $self = shift;
  623.     my $file = shift; return unless defined $file;
  624.     my $new  = shift; return unless defined $new;
  625.     
  626.     my $entry = $self->_find_entry( $file ) or return;
  627.     
  628.     return $entry->rename( $new );
  629. }    
  630.  
  631. =head2 $tar->remove (@filenamelist)
  632.  
  633. Removes any entries with names matching any of the given filenames
  634. from the in-memory archive. Returns a list of C<Archive::Tar::File>
  635. objects that remain. 
  636.  
  637. =cut
  638.  
  639. sub remove {
  640.     my $self = shift;
  641.     my @list = @_;
  642.     
  643.     my %seen = map { $_->name => $_ } @{$self->_data};
  644.     delete $seen{ $_ } for @list;
  645.     
  646.     $self->_data( [values %seen] );
  647.     
  648.     return values %seen;   
  649. }
  650.  
  651. =head2 $tar->clear
  652.  
  653. C<clear> clears the current in-memory archive. This effectively gives
  654. you a 'blank' object, ready to be filled again. Note that C<clear> 
  655. only has effect on the object, not the underlying tarfile.
  656.  
  657. =cut
  658.  
  659. sub clear {
  660.     my $self = shift or return;
  661.     
  662.     $self->_data( [] );
  663.     $self->_file( '' );
  664.     
  665.     return 1;
  666. }    
  667.  
  668.  
  669. =head2 $tar->write ( [$file, $compressed, $prefix] )
  670.  
  671. Write the in-memory archive to disk.  The first argument can either 
  672. be the name of a file or a reference to an already open filehandle (a
  673. GLOB reference). If the second argument is true, the module will use
  674. IO::Zlib to write the file in a compressed format.  If IO::Zlib is 
  675. not available, the C<write> method will fail and return.
  676.  
  677. Specific levels of compression can be chosen by passing the values 2
  678. through 9 as the second parameter.
  679.  
  680. The third argument is an optional prefix. All files will be tucked
  681. away in the directory you specify as prefix. So if you have files
  682. 'a' and 'b' in your archive, and you specify 'foo' as prefix, they
  683. will be written to the archive as 'foo/a' and 'foo/b'.
  684.  
  685. If no arguments are given, C<write> returns the entire formatted
  686. archive as a string, which could be useful if you'd like to stuff the
  687. archive into a socket or a pipe to gzip or something.
  688.  
  689. =cut
  690.  
  691. sub write {
  692.     my $self    = shift;
  693.     my $file    = shift || '';
  694.     my $gzip    = shift || 0;
  695.     my $prefix  = shift || '';
  696.  
  697.     ### only need a handle if we have a file to print to ###
  698.     my $handle = $file 
  699.                     ? ( $self->_get_handle($file, $gzip, WRITE_ONLY->($gzip) ) 
  700.                         or return )
  701.                     : '';       
  702.  
  703.     my @rv;
  704.     for my $entry ( @{$self->_data} ) {
  705.     
  706.         ### names are too long, and will get truncated if we don't add a
  707.         ### '@LongLink' file...
  708.         if( length($entry->name)    > NAME_LENGTH or 
  709.             length($entry->prefix)  > PREFIX_LENGTH 
  710.         ) {
  711.             
  712.             my $longlink = Archive::Tar::File->new( 
  713.                             data => LONGLINK_NAME, 
  714.                             File::Spec::Unix->catfile( grep { length } $entry->prefix, $entry->name ),
  715.                             { type => LONGLINK }
  716.                         );
  717.             unless( $longlink ) {
  718.                 $self->_error( qq[Could not create 'LongLink' entry for oversize file '] . $entry->name ."'" );
  719.                 return;
  720.             };                      
  721.     
  722.     
  723.             if( $file ) {
  724.                 unless( $self->_write_to_handle( $handle, $longlink, $prefix ) ) {
  725.                     $self->_error( qq[Could not write 'LongLink' entry for oversize file '] .  $entry->name ."'" );
  726.                     return; 
  727.                 }
  728.             } else {
  729.                 push @rv, $self->_format_tar_entry( $longlink, $prefix );
  730.                 push @rv, $entry->data              if  $entry->has_content;
  731.                 push @rv, TAR_PAD->( $entry->size ) if  $entry->has_content &&
  732.                                                         $entry->size % BLOCK;
  733.             }     
  734.         }        
  735.  
  736.         if( $file ) {
  737.             unless( $self->_write_to_handle( $handle, $entry, $prefix ) ) {
  738.                 $self->_error( qq[Could not write entry '] . $entry->name . qq[' to archive] );
  739.                 return;          
  740.             }
  741.         } else {
  742.             push @rv, $self->_format_tar_entry( $entry, $prefix );
  743.             push @rv, $entry->data              if  $entry->has_content;
  744.             push @rv, TAR_PAD->( $entry->size ) if  $entry->has_content &&
  745.                                                         $entry->size % BLOCK;
  746.         }
  747.     }
  748.     
  749.     if( $file ) {    
  750.         print $handle TAR_END x 2 or (
  751.             $self->_error( qq[Could not write tar end markers] ),
  752.             return
  753.         );
  754.     } else {
  755.         push @rv, TAR_END x 2;
  756.     }
  757.     
  758.     return $file ? 1 : join '', @rv;
  759. }
  760.  
  761. sub _write_to_handle {
  762.     my $self    = shift;
  763.     my $handle  = shift or return;
  764.     my $entry   = shift or return;
  765.     my $prefix  = shift || '';
  766.     
  767.     ### if the file is a symlink, there are 2 options:
  768.     ### either we leave the symlink intact, but then we don't write any data
  769.     ### OR we follow the symlink, which means we actually make a copy.
  770.     ### if we do the latter, we have to change the TYPE of the entry to 'FILE'
  771.     my $symlink_ok =  $entry->is_symlink && $Archive::Tar::FOLLOW_SYMLINK;
  772.     my $content_ok = !$entry->is_symlink && $entry->has_content ;
  773.     
  774.     ### downgrade to a 'normal' file if it's a symlink we're going to treat
  775.     ### as a regular file
  776.     $entry->_downgrade_to_plainfile if $symlink_ok;
  777.     
  778.     my $header = $self->_format_tar_entry( $entry, $prefix );
  779.         
  780.     unless( $header ) {
  781.         $self->_error( qq[Could not format header for entry: ] . $entry->name );
  782.         return;
  783.     }      
  784.  
  785.     print $handle $header or (
  786.         $self->_error( qq[Could not write header for: ] . $entry->name ),
  787.         return
  788.     );
  789.     
  790.     if( $symlink_ok or $content_ok ) {
  791.         print $handle $entry->data or (
  792.             $self->_error( qq[Could not write data for: ] . $entry->name ),
  793.             return
  794.         );
  795.         ### pad the end of the entry if required ###
  796.         print $handle TAR_PAD->( $entry->size ) if $entry->size % BLOCK;
  797.     }         
  798.     
  799.     return 1;
  800. }
  801.  
  802.  
  803. sub _format_tar_entry {
  804.     my $self        = shift;
  805.     my $entry       = shift or return;
  806.     my $ext_prefix  = shift || '';
  807.  
  808.     my $file    = $entry->name;
  809.     my $prefix  = $entry->prefix || '';
  810.     my $match   = quotemeta $prefix;
  811.     
  812.     ### remove the prefix from the file name ###
  813.     ### not sure if this is still neeeded --kane ###
  814.     if( length $prefix ) {
  815.         $file =~ s/^$match//;
  816.     } 
  817.     
  818.     $prefix = File::Spec::Unix->catdir($ext_prefix, $prefix) if length $ext_prefix;
  819.     
  820.     ### not sure why this is... ###
  821.     my $l = PREFIX_LENGTH; # is ambiguous otherwise...
  822.     substr ($prefix, 0, -$l) = "" if length $prefix >= PREFIX_LENGTH;
  823.     
  824.     my $f1 = "%06o"; my $f2  = "%11o";
  825.     
  826.     ### this might be optimizable with a 'changed' flag in the file objects ###
  827.     my $tar = pack (
  828.                 PACK,
  829.                 $file,
  830.                 
  831.                 (map { sprintf( $f1, $entry->$_() ) } qw[mode uid gid]),
  832.                 (map { sprintf( $f2, $entry->$_() ) } qw[size mtime]),
  833.                 
  834.                 "",  # checksum filed - space padded a bit down 
  835.                 
  836.                 (map { $entry->$_() }                 qw[type linkname magic]),
  837.                 
  838.                 $entry->version || TAR_VERSION,
  839.                 
  840.                 (map { $entry->$_() }                 qw[uname gname]),
  841.                 (map { sprintf( $f1, $entry->$_() ) } qw[devmajor devminor]),
  842.                 
  843.                 $prefix
  844.     );
  845.     
  846.     ### add the checksum ###
  847.     substr($tar,148,7) = sprintf("%6o\0", unpack("%16C*",$tar));
  848.  
  849.     return $tar;
  850. }           
  851.  
  852. =head2 $tar->add_files( @filenamelist )
  853.  
  854. Takes a list of filenames and adds them to the in-memory archive.  
  855.  
  856. The path to the file is automatically converted to a Unix like
  857. equivalent for use in the archive, and, if on MacOs, the file's 
  858. modification time is converted from the MacOS epoch to the Unix epoch.
  859. So tar archives created on MacOS with B<Archive::Tar> can be read 
  860. both with I<tar> on Unix and applications like I<suntar> or 
  861. I<Stuffit Expander> on MacOS.
  862.  
  863. Be aware that the file's type/creator and resource fork will be lost,
  864. which is usually what you want in cross-platform archives.
  865.  
  866. Returns a list of C<Archive::Tar::File> objects that were just added.
  867.  
  868. =cut
  869.  
  870. sub add_files {
  871.     my $self    = shift;
  872.     my @files   = @_ or return ();
  873.     
  874.     my @rv;
  875.     for my $file ( @files ) {
  876.         unless( -e $file ) {
  877.             $self->_error( qq[No such file: '$file'] );
  878.             next;
  879.         }
  880.     
  881.         my $obj = Archive::Tar::File->new( file => $file );
  882.         unless( $obj ) {
  883.             $self->_error( qq[Unable to add file: '$file'] );
  884.             next;
  885.         }      
  886.  
  887.         push @rv, $obj;
  888.     }
  889.     
  890.     push @{$self->{_data}}, @rv;
  891.     
  892.     return @rv;
  893. }
  894.  
  895. =head2 $tar->add_data ( $filename, $data, [$opthashref] )
  896.  
  897. Takes a filename, a scalar full of data and optionally a reference to
  898. a hash with specific options. 
  899.  
  900. Will add a file to the in-memory archive, with name C<$filename> and 
  901. content C<$data>. Specific properties can be set using C<$opthashref>.
  902. The following list of properties is supported: name, size, mtime 
  903. (last modified date), mode, uid, gid, linkname, uname, gname, 
  904. devmajor, devminor, prefix.  (On MacOS, the file's path and 
  905. modification times are converted to Unix equivalents.)
  906.  
  907. Returns the C<Archive::Tar::File> object that was just added, or
  908. C<undef> on failure.
  909.  
  910. =cut
  911.  
  912. sub add_data {
  913.     my $self    = shift;
  914.     my ($file, $data, $opt) = @_; 
  915.  
  916.     my $obj = Archive::Tar::File->new( data => $file, $data, $opt );
  917.     unless( $obj ) {
  918.         $self->_error( qq[Unable to add file: '$file'] );
  919.         return;
  920.     }      
  921.  
  922.     push @{$self->{_data}}, $obj;
  923.  
  924.     return $obj;
  925. }
  926.  
  927. =head2 $tar->error( [$BOOL] )
  928.  
  929. Returns the current errorstring (usually, the last error reported).
  930. If a true value was specified, it will give the C<Carp::longmess> 
  931. equivalent of the error, in effect giving you a stacktrace.
  932.  
  933. For backwards compabillity, this error is also available as 
  934. C<$Archive::Tar::error> allthough it is much recommended you use the
  935. method call instead.
  936.  
  937. =cut
  938.  
  939. {
  940.     $error = '';
  941.     my $longmess;
  942.     
  943.     sub _error {
  944.         my $self    = shift;
  945.         my $msg     = $error = shift;
  946.         $longmess   = Carp::longmess($error);
  947.         
  948.         ### set Archive::Tar::WARN to 0 to disable printing
  949.         ### of errors
  950.         if( $WARN ) {
  951.             carp $DEBUG ? $longmess : $msg;
  952.         }
  953.         
  954.         return;
  955.     }
  956.     
  957.     sub error {
  958.         my $self = shift;
  959.         return shift() ? $longmess : $error;          
  960.     }
  961. }         
  962.  
  963.  
  964. =head1 Class Methods 
  965.  
  966. =head2 Archive::Tar->create_archive($file, $compression, @filelist)
  967.  
  968. Creates a tar file from the list of files provided.  The first
  969. argument can either be the name of the tar file to create or a
  970. reference to an open file handle (e.g. a GLOB reference).
  971.  
  972. The second argument specifies the level of compression to be used, if
  973. any.  Compression of tar files requires the installation of the
  974. IO::Zlib module.  Specific levels or compression may be
  975. requested by passing a value between 2 and 9 as the second argument.
  976. Any other value evaluating as true will result in the default
  977. compression level being used.
  978.  
  979. The remaining arguments list the files to be included in the tar file.
  980. These files must all exist.  Any files which don\'t exist or can\'t be
  981. read are silently ignored.
  982.  
  983. If the archive creation fails for any reason, C<create_archive> will
  984. return.  Please use the C<error> method to find the cause of the
  985. failure.
  986.  
  987. =cut
  988.  
  989. sub create_archive {
  990.     my $class = shift;
  991.     
  992.     my $file    = shift; return unless defined $file;
  993.     my $gzip    = shift || 0;
  994.     my @files   = @_;
  995.     
  996.     unless( @files ) {
  997.         return $class->_error( qq[Cowardly refusing to create empty archive!] );
  998.     }        
  999.     
  1000.     my $tar = $class->new;
  1001.     $tar->add_files( @files );
  1002.     return $tar->write( $file, $gzip );    
  1003. }
  1004.  
  1005. =head2 Archive::Tar->list_archive ($file, $compressed, [\@properties])
  1006.  
  1007. Returns a list of the names of all the files in the archive.  The
  1008. first argument can either be the name of the tar file to create or a
  1009. reference to an open file handle (e.g. a GLOB reference).
  1010.  
  1011. If C<list_archive()> is passed an array reference as its second
  1012. argument it returns a list of hash references containing the requested
  1013. properties of each file.  The following list of properties is
  1014. supported: name, size, mtime (last modified date), mode, uid, gid,
  1015. linkname, uname, gname, devmajor, devminor, prefix.
  1016.  
  1017. Passing an array reference containing only one element, 'name', is
  1018. special cased to return a list of names rather than a list of hash
  1019. references.
  1020.  
  1021. =cut
  1022.  
  1023. sub list_archive {
  1024.     my $class   = shift;
  1025.     my $file    = shift; return unless defined $file;
  1026.     my $gzip    = shift || 0;
  1027.  
  1028.     my $tar = $class->new($file, $gzip);
  1029.     return unless $tar;
  1030.     
  1031.     return $tar->list_files( @_ ); 
  1032. }
  1033.  
  1034. =head2 Archive::Tar->extract_archive ($file, $gzip)
  1035.  
  1036. Extracts the contents of the tar file.  The first argument can either
  1037. be the name of the tar file to create or a reference to an open file
  1038. handle (e.g. a GLOB reference).  All relative paths in the tar file will
  1039. be created underneath the current working directory.
  1040.  
  1041. C<extract_archive> will return a list of files it extract.
  1042. If the archive extraction fails for any reason, C<extract_archive>
  1043. will return.  Please use the C<error> method to find the cause
  1044. of the failure.
  1045.  
  1046. =cut
  1047.  
  1048. sub extract_archive {
  1049.     my $class   = shift;
  1050.     my $file    = shift; return unless defined $file;
  1051.     my $gzip    = shift || 0;
  1052.     
  1053.     my $tar = $class->new( ) or return;
  1054.     
  1055.     return $tar->read( $file, $gzip, { extract => 1 } );
  1056. }
  1057.  
  1058. 1;
  1059.  
  1060. __END__
  1061.  
  1062. =head1 GLOBAL VARIABLES
  1063.  
  1064. =head2 $Archive::Tar::FOLLOW_SYMLINK
  1065.  
  1066. Set this variable to C<1> to make C<Archive::Tar> effectively make a
  1067. copy of the file when extracting. Default this is set to C<0>, which
  1068. means the symlink stays intact. Of course, you will have to pack the
  1069. file linked to as well.
  1070.  
  1071. This option is checked when you write out the tarfile using C<write> 
  1072. or C<create_archive>.
  1073.  
  1074. This works just like C</bin/tar>'s C<-h> option.
  1075.  
  1076. =head2 $Archive::Tar::CHOWN
  1077.  
  1078. By default, C<Archive::Tar> will try to C<chown> your files if it is
  1079. able to. In some cases, this may not be desired. In that case, set 
  1080. this variable to C<0> to disable C<chown>-ing, even if it were
  1081. possible.
  1082.  
  1083. The default is C<1>.
  1084.  
  1085. =head2 $Archive::Tar::CHMOD
  1086.  
  1087. By default, C<Archive::Tar> will try to C<chmod> your files to 
  1088. whatever mode was specified for the particular file in the archive. 
  1089. In some cases, this may not be desired. In that case, set this 
  1090. variable to C<0> to disable C<chmod>-ing.
  1091.  
  1092. The default is C<1>.
  1093.  
  1094. =head2 $Archive::Tar::DEBUG
  1095.  
  1096. Set this variable to C<1> to always get the C<Carp::longmess> output
  1097. of the warnings, instead of the regular C<carp>. This is the same 
  1098. message you would get by doing: 
  1099.     
  1100.     $tar->error(1);
  1101.  
  1102. Defaults to C<0>.
  1103.  
  1104. =head2 $Archive::Tar::WARN
  1105.  
  1106. Set this variable to C<0> if you do not want any warnings printed.
  1107. Personally I recommend against doing this, but people asked for the
  1108. option. Also, be advised that this is of course not threadsafe.
  1109.  
  1110. Defaults to C<1>.
  1111.  
  1112. =head2 $Archive::Tar::error
  1113.  
  1114. Holds the last reported error. Kept for historical reasons, but it's
  1115. use is very much discouraged. Use the C<error()> method instead:
  1116.  
  1117.     warn $tar->error unless $tar->extract;
  1118.  
  1119. =head1 FAQ
  1120.  
  1121. =over 4
  1122.  
  1123. =item What's the minimum perl version required to run Archive::Tar?
  1124.  
  1125. You will need perl version 5.005_03 or newer. 
  1126.  
  1127. =item Isn't Archive::Tar slow?
  1128.  
  1129. Yes it is. It's pure perl, so it's a lot slower then your C</bin/tar>
  1130. However, it's very portable. If speed is an issue, consider using
  1131. C</bin/tar> instead.
  1132.  
  1133. =item Isn't Archive::Tar heavier on memory than /bin/tar?
  1134.  
  1135. Yes it is, see previous answer. Since C<Compress::Zlib> and therefor
  1136. C<IO::Zlib> doesn't support C<seek> on their filehandles, there is little
  1137. choice but to read the archive into memory. 
  1138. This is ok if you want to do in-memory manipulation of the archive.
  1139. If you just want to extract, use the C<extract_archive> class method
  1140. instead. It will optimize and write to disk immediately.
  1141.  
  1142. =item Can't you lazy-load data instead?
  1143.  
  1144. No, not easily. See previous question.
  1145.  
  1146. =item How much memory will an X kb tar file need?
  1147.  
  1148. Probably more than X kb, since it will all be read into memory. If 
  1149. this is a problem, and you don't need to do in memory manipulation 
  1150. of the archive, consider using C</bin/tar> instead.
  1151.  
  1152. =back
  1153.  
  1154. =head1 TODO
  1155.  
  1156. =over 4
  1157.  
  1158. =item Check if passed in handles are open for read/write
  1159.     
  1160. Currently I don't know of any portable pure perl way to do this.
  1161. Suggestions welcome.
  1162.  
  1163. =back
  1164.  
  1165. =head1 AUTHOR
  1166.  
  1167. This module by
  1168. Jos Boumans E<lt>kane@cpan.orgE<gt>.
  1169.  
  1170. =head1 ACKNOWLEDGEMENTS
  1171.  
  1172. Thanks to Sean Burke, Chris Nandor, Chip Salzenberg and Tim Heaney 
  1173. for their help and suggestions.
  1174.  
  1175. =head1 COPYRIGHT
  1176.  
  1177. This module is
  1178. copyright (c) 2002 Jos Boumans E<lt>kane@cpan.orgE<gt>.
  1179. All rights reserved.
  1180.  
  1181. This library is free software;
  1182. you may redistribute and/or modify it under the same
  1183. terms as Perl itself.
  1184.  
  1185. =cut
  1186.