home *** CD-ROM | disk | FTP | other *** search
/ PC World 2005 June / PCWorld_2005-06_cd.bin / software / vyzkuste / firewally / firewally.exe / framework-2.3.exe / Encode.pm < prev    next >
Text File  |  2003-11-07  |  23KB  |  781 lines
  1. #
  2. # $Id: Encode.pm,v 1.98 2003/08/20 11:16:34 dankogai Exp dankogai $
  3. #
  4. package Encode;
  5. use strict;
  6. our $VERSION = do { my @r = (q$Revision: 1.9801 $ =~ /\d+/g); sprintf "%d."."%02d" x $#r, @r };
  7. sub DEBUG () { 0 }
  8. use XSLoader ();
  9. XSLoader::load(__PACKAGE__, $VERSION);
  10.  
  11. require Exporter;
  12. use base qw/Exporter/;
  13.  
  14. # Public, encouraged API is exported by default
  15.  
  16. our @EXPORT = qw(
  17.   decode  decode_utf8  encode  encode_utf8
  18.   encodings  find_encoding clone_encoding
  19. );
  20.  
  21. our @FB_FLAGS  = qw(DIE_ON_ERR WARN_ON_ERR RETURN_ON_ERR LEAVE_SRC
  22.             PERLQQ HTMLCREF XMLCREF);
  23. our @FB_CONSTS = qw(FB_DEFAULT FB_CROAK FB_QUIET FB_WARN
  24.             FB_PERLQQ FB_HTMLCREF FB_XMLCREF);
  25.  
  26. our @EXPORT_OK =
  27.     (
  28.      qw(
  29.        _utf8_off _utf8_on define_encoding from_to is_16bit is_8bit
  30.        is_utf8 perlio_ok resolve_alias utf8_downgrade utf8_upgrade
  31.       ),
  32.      @FB_FLAGS, @FB_CONSTS,
  33.     );
  34.  
  35. our %EXPORT_TAGS =
  36.     (
  37.      all          =>  [ @EXPORT, @EXPORT_OK ],
  38.      fallbacks    =>  [ @FB_CONSTS ],
  39.      fallback_all =>  [ @FB_CONSTS, @FB_FLAGS ],
  40.     );
  41.  
  42. # Documentation moved after __END__ for speed - NI-S
  43.  
  44. our $ON_EBCDIC = (ord("A") == 193);
  45.  
  46. use Encode::Alias;
  47.  
  48. # Make a %Encoding package variable to allow a certain amount of cheating
  49. our %Encoding;
  50. our %ExtModule;
  51. require Encode::Config;
  52. eval { require Encode::ConfigLocal };
  53.  
  54. sub encodings
  55. {
  56.     my $class = shift;
  57.     my %enc;
  58.     if (@_ and $_[0] eq ":all"){
  59.     %enc = ( %Encoding, %ExtModule );
  60.     }else{
  61.     %enc = %Encoding;
  62.     for my $mod (map {m/::/o ? $_ : "Encode::$_" } @_){
  63.         DEBUG and warn $mod;
  64.         for my $enc (keys %ExtModule){
  65.         $ExtModule{$enc} eq $mod and $enc{$enc} = $mod;
  66.         }
  67.     }
  68.     }
  69.     return
  70.     sort { lc $a cmp lc $b }
  71.              grep {!/^(?:Internal|Unicode|Guess)$/o} keys %enc;
  72. }
  73.  
  74. sub perlio_ok{
  75.     my $obj = ref($_[0]) ? $_[0] : find_encoding($_[0]);
  76.     $obj->can("perlio_ok") and return $obj->perlio_ok();
  77.     return 0; # safety net
  78. }
  79.  
  80. sub define_encoding
  81. {
  82.     my $obj  = shift;
  83.     my $name = shift;
  84.     $Encoding{$name} = $obj;
  85.     my $lc = lc($name);
  86.     define_alias($lc => $obj) unless $lc eq $name;
  87.     while (@_){
  88.     my $alias = shift;
  89.     define_alias($alias, $obj);
  90.     }
  91.     return $obj;
  92. }
  93.  
  94. sub getEncoding
  95. {
  96.     my ($class, $name, $skip_external) = @_;
  97.  
  98.     ref($name) && $name->can('renew') and return $name;
  99.     exists $Encoding{$name} and return $Encoding{$name};
  100.     my $lc = lc $name;
  101.     exists $Encoding{$lc} and return $Encoding{$lc};
  102.  
  103.     my $oc = $class->find_alias($name);
  104.     defined($oc) and return $oc;
  105.     $lc ne $name and $oc = $class->find_alias($lc);
  106.     defined($oc) and return $oc;
  107.  
  108.     unless ($skip_external)
  109.     {
  110.     if (my $mod = $ExtModule{$name} || $ExtModule{$lc}){
  111.         $mod =~ s,::,/,g ; $mod .= '.pm';
  112.         eval{ require $mod; };
  113.         exists $Encoding{$name} and return $Encoding{$name};
  114.     }
  115.     }
  116.     return;
  117. }
  118.  
  119. sub find_encoding($;$)
  120. {
  121.     my ($name, $skip_external) = @_;
  122.     return __PACKAGE__->getEncoding($name,$skip_external);
  123. }
  124.  
  125. sub resolve_alias($){
  126.     my $obj = find_encoding(shift);
  127.     defined $obj and return $obj->name;
  128.     return;
  129. }
  130.  
  131. sub clone_encoding($){
  132.     my $obj = find_encoding(shift);
  133.     ref $obj or return;
  134.     eval { require Storable };
  135.     $@ and return;
  136.     return Storable::dclone($obj);
  137. }
  138.  
  139. sub encode($$;$)
  140. {
  141.     my ($name, $string, $check) = @_;
  142.     return undef unless defined $string;
  143.     $check ||=0;
  144.     my $enc = find_encoding($name);
  145.     unless(defined $enc){
  146.     require Carp;
  147.     Carp::croak("Unknown encoding '$name'");
  148.     }
  149.     my $octets = $enc->encode($string,$check);
  150.     $_[1] = $string if $check;
  151.     return $octets;
  152. }
  153.  
  154. sub decode($$;$)
  155. {
  156.     my ($name,$octets,$check) = @_;
  157.     return undef unless defined $octets;
  158.     $check ||=0;
  159.     my $enc = find_encoding($name);
  160.     unless(defined $enc){
  161.     require Carp;
  162.     Carp::croak("Unknown encoding '$name'");
  163.     }
  164.     my $string = $enc->decode($octets,$check);
  165.     $_[1] = $octets if $check;
  166.     return $string;
  167. }
  168.  
  169. sub from_to($$$;$)
  170. {
  171.     my ($string,$from,$to,$check) = @_;
  172.     return undef unless defined $string;
  173.     $check ||=0;
  174.     my $f = find_encoding($from);
  175.     unless (defined $f){
  176.     require Carp;
  177.     Carp::croak("Unknown encoding '$from'");
  178.     }
  179.     my $t = find_encoding($to);
  180.     unless (defined $t){
  181.     require Carp;
  182.     Carp::croak("Unknown encoding '$to'");
  183.     }
  184.     my $uni = $f->decode($string,$check);
  185.     return undef if ($check && length($string));
  186.     $string =  $t->encode($uni,$check);
  187.     return undef if ($check && length($uni));
  188.     return defined($_[0] = $string) ? length($string) : undef ;
  189. }
  190.  
  191. sub encode_utf8($)
  192. {
  193.     my ($str) = @_;
  194.     utf8::encode($str);
  195.     return $str;
  196. }
  197.  
  198. sub decode_utf8($)
  199. {
  200.     my ($str) = @_;
  201.     return undef unless utf8::decode($str);
  202.     return $str;
  203. }
  204.  
  205. predefine_encodings(1);
  206.  
  207. #
  208. # This is to restore %Encoding if really needed;
  209. #
  210.  
  211. sub predefine_encodings{
  212.     use Encode::Encoding;
  213.     no warnings 'redefine';
  214.     my $use_xs = shift;
  215.     if ($ON_EBCDIC) {
  216.     # was in Encode::UTF_EBCDIC
  217.     package Encode::UTF_EBCDIC;
  218.     push @Encode::UTF_EBCDIC::ISA, 'Encode::Encoding';
  219.     *decode = sub{
  220.         my ($obj,$str,$chk) = @_;
  221.         my $res = '';
  222.         for (my $i = 0; $i < length($str); $i++) {
  223.         $res .=
  224.             chr(utf8::unicode_to_native(ord(substr($str,$i,1))));
  225.         }
  226.         $_[1] = '' if $chk;
  227.         return $res;
  228.     };
  229.     *encode = sub{
  230.         my ($obj,$str,$chk) = @_;
  231.         my $res = '';
  232.         for (my $i = 0; $i < length($str); $i++) {
  233.         $res .=
  234.             chr(utf8::native_to_unicode(ord(substr($str,$i,1))));
  235.         }
  236.         $_[1] = '' if $chk;
  237.         return $res;
  238.     };
  239.     $Encode::Encoding{Unicode} =
  240.         bless {Name => "UTF_EBCDIC"} => "Encode::UTF_EBCDIC";
  241.     } else {
  242.     package Encode::Internal;
  243.     push @Encode::Internal::ISA, 'Encode::Encoding';
  244.     *decode = sub{
  245.         my ($obj,$str,$chk) = @_;
  246.         utf8::upgrade($str);
  247.         $_[1] = '' if $chk;
  248.         return $str;
  249.     };
  250.     *encode = \&decode;
  251.     $Encode::Encoding{Unicode} =
  252.         bless {Name => "Internal"} => "Encode::Internal";
  253.     }
  254.  
  255.     {
  256.     # was in Encode::utf8
  257.     package Encode::utf8;
  258.     push @Encode::utf8::ISA, 'Encode::Encoding';
  259.     # 
  260.     if ($use_xs){
  261.         Encode::DEBUG and warn __PACKAGE__, " XS on";
  262.         *decode = \&decode_xs;
  263.         *encode = \&encode_xs;
  264.     }else{
  265.         Encode::DEBUG and warn __PACKAGE__, " XS off";
  266.         *decode = sub{
  267.         my ($obj,$octets,$chk) = @_;
  268.         my $str = Encode::decode_utf8($octets);
  269.         if (defined $str) {
  270.             $_[1] = '' if $chk;
  271.             return $str;
  272.         }
  273.         return undef;
  274.         };
  275.         *encode = sub {
  276.         my ($obj,$string,$chk) = @_;
  277.         my $octets = Encode::encode_utf8($string);
  278.         $_[1] = '' if $chk;
  279.         return $octets;
  280.         };
  281.     }
  282.     *cat_decode = sub{ # ($obj, $dst, $src, $pos, $trm, $chk)
  283.         my ($obj, undef, undef, $pos, $trm) = @_; # currently ignores $chk
  284.         my ($rdst, $rsrc, $rpos) = \@_[1,2,3];
  285.         use bytes;
  286.         if ((my $npos = index($$rsrc, $trm, $pos)) >= 0) {
  287.         $$rdst .= substr($$rsrc, $pos, $npos - $pos + length($trm));
  288.         $$rpos = $npos + length($trm);
  289.         return 1;
  290.         }
  291.         $$rdst .= substr($$rsrc, $pos);
  292.         $$rpos = length($$rsrc);
  293.         return '';
  294.     };
  295.     $Encode::Encoding{utf8} =
  296.         bless {Name => "utf8"} => "Encode::utf8";
  297.     }
  298. }
  299.  
  300. 1;
  301.  
  302. __END__
  303.  
  304. =head1 NAME
  305.  
  306. Encode - character encodings
  307.  
  308. =head1 SYNOPSIS
  309.  
  310.     use Encode;
  311.  
  312. =head2 Table of Contents
  313.  
  314. Encode consists of a collection of modules whose details are too big
  315. to fit in one document.  This POD itself explains the top-level APIs
  316. and general topics at a glance.  For other topics and more details,
  317. see the PODs below:
  318.  
  319.   Name                    Description
  320.   --------------------------------------------------------
  321.   Encode::Alias         Alias definitions to encodings
  322.   Encode::Encoding      Encode Implementation Base Class
  323.   Encode::Supported     List of Supported Encodings
  324.   Encode::CN            Simplified Chinese Encodings
  325.   Encode::JP            Japanese Encodings
  326.   Encode::KR            Korean Encodings
  327.   Encode::TW            Traditional Chinese Encodings
  328.   --------------------------------------------------------
  329.  
  330. =head1 DESCRIPTION
  331.  
  332. The C<Encode> module provides the interfaces between Perl's strings
  333. and the rest of the system.  Perl strings are sequences of
  334. B<characters>.
  335.  
  336. The repertoire of characters that Perl can represent is at least that
  337. defined by the Unicode Consortium. On most platforms the ordinal
  338. values of the characters (as returned by C<ord(ch)>) is the "Unicode
  339. codepoint" for the character (the exceptions are those platforms where
  340. the legacy encoding is some variant of EBCDIC rather than a super-set
  341. of ASCII - see L<perlebcdic>).
  342.  
  343. Traditionally, computer data has been moved around in 8-bit chunks
  344. often called "bytes". These chunks are also known as "octets" in
  345. networking standards. Perl is widely used to manipulate data of many
  346. types - not only strings of characters representing human or computer
  347. languages but also "binary" data being the machine's representation of
  348. numbers, pixels in an image - or just about anything.
  349.  
  350. When Perl is processing "binary data", the programmer wants Perl to
  351. process "sequences of bytes". This is not a problem for Perl - as a
  352. byte has 256 possible values, it easily fits in Perl's much larger
  353. "logical character".
  354.  
  355. =head2 TERMINOLOGY
  356.  
  357. =over 2
  358.  
  359. =item *
  360.  
  361. I<character>: a character in the range 0..(2**32-1) (or more).
  362. (What Perl's strings are made of.)
  363.  
  364. =item *
  365.  
  366. I<byte>: a character in the range 0..255
  367. (A special case of a Perl character.)
  368.  
  369. =item *
  370.  
  371. I<octet>: 8 bits of data, with ordinal values 0..255
  372. (Term for bytes passed to or from a non-Perl context, e.g. a disk file.)
  373.  
  374. =back
  375.  
  376. =head1 PERL ENCODING API
  377.  
  378. =over 2
  379.  
  380. =item $octets  = encode(ENCODING, $string [, CHECK])
  381.  
  382. Encodes a string from Perl's internal form into I<ENCODING> and returns
  383. a sequence of octets.  ENCODING can be either a canonical name or
  384. an alias.  For encoding names and aliases, see L</"Defining Aliases">.
  385. For CHECK, see L</"Handling Malformed Data">.
  386.  
  387. For example, to convert a string from Perl's internal format to
  388. iso-8859-1 (also known as Latin1),
  389.  
  390.   $octets = encode("iso-8859-1", $string);
  391.  
  392. B<CAVEAT>: When you run C<$octets = encode("utf8", $string)>, then $octets
  393. B<may not be equal to> $string.  Though they both contain the same data, the utf8 flag
  394. for $octets is B<always> off.  When you encode anything, utf8 flag of
  395. the result is always off, even when it contains completely valid utf8
  396. string. See L</"The UTF-8 flag"> below.
  397.  
  398. encode($valid_encoding, undef) is harmless but warns you for 
  399. C<Use of uninitialized value in subroutine entry>. 
  400. encode($valid_encoding, '') is harmless and warnless.
  401.  
  402. =item $string = decode(ENCODING, $octets [, CHECK])
  403.  
  404. Decodes a sequence of octets assumed to be in I<ENCODING> into Perl's
  405. internal form and returns the resulting string.  As in encode(),
  406. ENCODING can be either a canonical name or an alias. For encoding names
  407. and aliases, see L</"Defining Aliases">.  For CHECK, see
  408. L</"Handling Malformed Data">.
  409.  
  410. For example, to convert ISO-8859-1 data to a string in Perl's internal format:
  411.  
  412.   $string = decode("iso-8859-1", $octets);
  413.  
  414. B<CAVEAT>: When you run C<$string = decode("utf8", $octets)>, then $string
  415. B<may not be equal to> $octets.  Though they both contain the same data,
  416. the utf8 flag for $string is on unless $octets entirely consists of
  417. ASCII data (or EBCDIC on EBCDIC machines).  See L</"The UTF-8 flag">
  418. below.
  419.  
  420. decode($valid_encoding, undef) is harmless but warns you for 
  421. C<Use of uninitialized value in subroutine entry>. 
  422. decode($valid_encoding, '') is harmless and warnless.
  423.  
  424. =item [$length =] from_to($octets, FROM_ENC, TO_ENC [, CHECK])
  425.  
  426. Converts B<in-place> data between two encodings. The data in $octets
  427. must be encoded as octets and not as characters in Perl's internal
  428. format. For example, to convert ISO-8859-1 data to Microsoft's CP1250 encoding:
  429.  
  430.   from_to($octets, "iso-8859-1", "cp1250");
  431.  
  432. and to convert it back:
  433.  
  434.   from_to($octets, "cp1250", "iso-8859-1");
  435.  
  436. Note that because the conversion happens in place, the data to be
  437. converted cannot be a string constant; it must be a scalar variable.
  438.  
  439. from_to() returns the length of the converted string in octets on success, undef
  440. otherwise.
  441.  
  442. B<CAVEAT>: The following operations look the same but are not quite so;
  443.  
  444.   from_to($data, "iso-8859-1", "utf8"); #1
  445.   $data = decode("iso-8859-1", $data);  #2
  446.  
  447. Both #1 and #2 make $data consist of a completely valid UTF-8 string
  448. but only #2 turns utf8 flag on.  #1 is equivalent to
  449.  
  450.   $data = encode("utf8", decode("iso-8859-1", $data));
  451.  
  452. See L</"The UTF-8 flag"> below.
  453.  
  454. =item $octets = encode_utf8($string);
  455.  
  456. Equivalent to C<$octets = encode("utf8", $string);> The characters
  457. that comprise $string are encoded in Perl's internal format and the
  458. result is returned as a sequence of octets. All possible
  459. characters have a UTF-8 representation so this function cannot fail.
  460.  
  461.  
  462. =item $string = decode_utf8($octets [, CHECK]);
  463.  
  464. equivalent to C<$string = decode("utf8", $octets [, CHECK])>.
  465. The sequence of octets represented by
  466. $octets is decoded from UTF-8 into a sequence of logical
  467. characters. Not all sequences of octets form valid UTF-8 encodings, so
  468. it is possible for this call to fail.  For CHECK, see
  469. L</"Handling Malformed Data">.
  470.  
  471. =back
  472.  
  473. =head2 Listing available encodings
  474.  
  475.   use Encode;
  476.   @list = Encode->encodings();
  477.  
  478. Returns a list of the canonical names of the available encodings that
  479. are loaded.  To get a list of all available encodings including the
  480. ones that are not loaded yet, say
  481.  
  482.   @all_encodings = Encode->encodings(":all");
  483.  
  484. Or you can give the name of a specific module.
  485.  
  486.   @with_jp = Encode->encodings("Encode::JP");
  487.  
  488. When "::" is not in the name, "Encode::" is assumed.
  489.  
  490.   @ebcdic = Encode->encodings("EBCDIC");
  491.  
  492. To find out in detail which encodings are supported by this package,
  493. see L<Encode::Supported>.
  494.  
  495. =head2 Defining Aliases
  496.  
  497. To add a new alias to a given encoding, use:
  498.  
  499.   use Encode;
  500.   use Encode::Alias;
  501.   define_alias(newName => ENCODING);
  502.  
  503. After that, newName can be used as an alias for ENCODING.
  504. ENCODING may be either the name of an encoding or an
  505. I<encoding object>
  506.  
  507. But before you do so, make sure the alias is nonexistent with
  508. C<resolve_alias()>, which returns the canonical name thereof.
  509. i.e.
  510.  
  511.   Encode::resolve_alias("latin1") eq "iso-8859-1" # true
  512.   Encode::resolve_alias("iso-8859-12")   # false; nonexistent
  513.   Encode::resolve_alias($name) eq $name  # true if $name is canonical
  514.  
  515. resolve_alias() does not need C<use Encode::Alias>; it can be
  516. exported via C<use Encode qw(resolve_alias)>.
  517.  
  518. See L<Encode::Alias> for details.
  519.  
  520. =head1 Encoding via PerlIO
  521.  
  522. If your perl supports I<PerlIO> (which is the default), you can use a PerlIO layer to decode
  523. and encode directly via a filehandle.  The following two examples
  524. are totally identical in their functionality.
  525.  
  526.   # via PerlIO
  527.   open my $in,  "<:encoding(shiftjis)", $infile  or die;
  528.   open my $out, ">:encoding(euc-jp)",   $outfile or die;
  529.   while(<$in>){ print $out $_; }
  530.  
  531.   # via from_to
  532.   open my $in,  "<", $infile  or die;
  533.   open my $out, ">", $outfile or die;
  534.   while(<$in>){
  535.     from_to($_, "shiftjis", "euc-jp", 1);
  536.     print $out $_;
  537.   }
  538.  
  539. Unfortunately, it may be that encodings are PerlIO-savvy.  You can check
  540. if your encoding is supported by PerlIO by calling the C<perlio_ok>
  541. method.
  542.  
  543.   Encode::perlio_ok("hz");             # False
  544.   find_encoding("euc-cn")->perlio_ok;  # True where PerlIO is available
  545.  
  546.   use Encode qw(perlio_ok);            # exported upon request
  547.   perlio_ok("euc-jp")
  548.  
  549. Fortunately, all encodings that come with Encode core are PerlIO-savvy
  550. except for hz and ISO-2022-kr.  For gory details, see L<Encode::Encoding> and L<Encode::PerlIO>.
  551.  
  552. =head1 Handling Malformed Data
  553.  
  554. The I<CHECK> argument is used as follows.  When you omit it,
  555. the behaviour is the same as if you had passed a value of 0 for
  556. I<CHECK>.
  557.  
  558. =over 2
  559.  
  560. =item I<CHECK> = Encode::FB_DEFAULT ( == 0)
  561.  
  562. If I<CHECK> is 0, (en|de)code will put a I<substitution character>
  563. in place of a malformed character.  For UCM-based encodings,
  564. E<lt>subcharE<gt> will be used.  For Unicode, the code point C<0xFFFD> is used.
  565. If the data is supposed to be UTF-8, an optional lexical warning
  566. (category utf8) is given.
  567.  
  568. =item I<CHECK> = Encode::FB_CROAK ( == 1)
  569.  
  570. If I<CHECK> is 1, methods will die on error immediately with an error
  571. message.  Therefore, when I<CHECK> is set to 1,  you should trap the
  572. fatal error with eval{} unless you really want to let it die on error.
  573.  
  574. =item I<CHECK> = Encode::FB_QUIET
  575.  
  576. If I<CHECK> is set to Encode::FB_QUIET, (en|de)code will immediately
  577. return the portion of the data that has been processed so far when
  578. an error occurs. The data argument will be overwritten with
  579. everything after that point (that is, the unprocessed part of data).
  580. This is handy when you have to call decode repeatedly in the case
  581. where your source data may contain partial multi-byte character
  582. sequences, for example because you are reading with a fixed-width
  583. buffer. Here is some sample code that does exactly this:
  584.  
  585.   my $data = ''; my $utf8 = '';
  586.   while(defined(read $fh, $buffer, 256)){
  587.     # buffer may end in a partial character so we append
  588.     $data .= $buffer;
  589.     $utf8 .= decode($encoding, $data, Encode::FB_QUIET);
  590.     # $data now contains the unprocessed partial character
  591.   }
  592.  
  593. =item I<CHECK> = Encode::FB_WARN
  594.  
  595. This is the same as above, except that it warns on error.  Handy when
  596. you are debugging the mode above.
  597.  
  598. =item perlqq mode (I<CHECK> = Encode::FB_PERLQQ)
  599.  
  600. =item HTML charref mode (I<CHECK> = Encode::FB_HTMLCREF)
  601.  
  602. =item XML charref mode (I<CHECK> = Encode::FB_XMLCREF)
  603.  
  604. For encodings that are implemented by Encode::XS, CHECK ==
  605. Encode::FB_PERLQQ turns (en|de)code into C<perlqq> fallback mode.
  606.  
  607. When you decode, C<\xI<HH>> will be inserted for a malformed character,
  608. where I<HH> is the hex representation of the octet  that could not be
  609. decoded to utf8.  And when you encode, C<\x{I<HHHH>}> will be inserted,
  610. where I<HHHH> is the Unicode ID of the character that cannot be found
  611. in the character repertoire of the encoding.
  612.  
  613. HTML/XML character reference modes are about the same, in place of
  614. C<\x{I<HHHH>}>, HTML uses C<&#I<NNNN>>; where I<NNNN> is a decimal digit and
  615. XML uses C<&#xI<HHHH>>; where I<HHHH> is the hexadecimal digit.
  616.  
  617. =item The bitmask
  618.  
  619. These modes are actually set via a bitmask.  Here is how the FB_XX
  620. constants are laid out.  You can import the FB_XX constants via
  621. C<use Encode qw(:fallbacks)>; you can import the generic bitmask
  622. constants via C<use Encode qw(:fallback_all)>.
  623.  
  624.                      FB_DEFAULT FB_CROAK FB_QUIET FB_WARN  FB_PERLQQ
  625.  DIE_ON_ERR    0x0001             X
  626.  WARN_ON_ERR   0x0002                               X
  627.  RETURN_ON_ERR 0x0004                      X        X
  628.  LEAVE_SRC     0x0008
  629.  PERLQQ        0x0100                                        X
  630.  HTMLCREF      0x0200
  631.  XMLCREF       0x0400
  632.  
  633. =back
  634.  
  635. =head2 Unimplemented fallback schemes
  636.  
  637. In the future, you will be able to use a code reference to a callback
  638. function for the value of I<CHECK> but its API is still undecided.
  639.  
  640. The fallback scheme does not work on EBCDIC platforms.
  641.  
  642. =head1 Defining Encodings
  643.  
  644. To define a new encoding, use:
  645.  
  646.     use Encode qw(define_encoding);
  647.     define_encoding($object, 'canonicalName' [, alias...]);
  648.  
  649. I<canonicalName> will be associated with I<$object>.  The object
  650. should provide the interface described in L<Encode::Encoding>.
  651. If more than two arguments are provided then additional
  652. arguments are taken as aliases for I<$object>.
  653.  
  654. See L<Encode::Encoding> for more details.
  655.  
  656. =head1 The UTF-8 flag
  657.  
  658. Before the introduction of utf8 support in perl, The C<eq> operator
  659. just compared the strings represented by two scalars. Beginning with
  660. perl 5.8, C<eq> compares two strings with simultaneous consideration
  661. of I<the utf8 flag>. To explain why we made it so, I will quote page
  662. 402 of C<Programming Perl, 3rd ed.>
  663.  
  664. =over 2
  665.  
  666. =item Goal #1:
  667.  
  668. Old byte-oriented programs should not spontaneously break on the old
  669. byte-oriented data they used to work on.
  670.  
  671. =item Goal #2:
  672.  
  673. Old byte-oriented programs should magically start working on the new
  674. character-oriented data when appropriate.
  675.  
  676. =item Goal #3:
  677.  
  678. Programs should run just as fast in the new character-oriented mode
  679. as in the old byte-oriented mode.
  680.  
  681. =item Goal #4:
  682.  
  683. Perl should remain one language, rather than forking into a
  684. byte-oriented Perl and a character-oriented Perl.
  685.  
  686. =back
  687.  
  688. Back when C<Programming Perl, 3rd ed.> was written, not even Perl 5.6.0
  689. was born and many features documented in the book remained
  690. unimplemented for a long time.  Perl 5.8 corrected this and the introduction
  691. of the UTF-8 flag is one of them.  You can think of this perl notion as of a
  692. byte-oriented mode (utf8 flag off) and a character-oriented mode (utf8
  693. flag on).
  694.  
  695. Here is how Encode takes care of the utf8 flag.
  696.  
  697. =over 2
  698.  
  699. =item *
  700.  
  701. When you encode, the resulting utf8 flag is always off.
  702.  
  703. =item *
  704.  
  705. When you decode, the resulting utf8 flag is on unless you can
  706. unambiguously represent data.  Here is the definition of
  707. dis-ambiguity.
  708.  
  709. After C<$utf8 = decode('foo', $octet);>,
  710.  
  711.   When $octet is...   The utf8 flag in $utf8 is
  712.   ---------------------------------------------
  713.   In ASCII only (or EBCDIC only)            OFF
  714.   In ISO-8859-1                              ON
  715.   In any other Encoding                      ON
  716.   ---------------------------------------------
  717.  
  718. As you see, there is one exception, In ASCII.  That way you can assue
  719. Goal #1.  And with Encode Goal #2 is assumed but you still have to be
  720. careful in such cases mentioned in B<CAVEAT> paragraphs.
  721.  
  722. This utf8 flag is not visible in perl scripts, exactly for the same
  723. reason you cannot (or you I<don't have to>) see if a scalar contains a
  724. string, integer, or floating point number.   But you can still peek
  725. and poke these if you will.  See the section below.
  726.  
  727. =back
  728.  
  729. =head2 Messing with Perl's Internals
  730.  
  731. The following API uses parts of Perl's internals in the current
  732. implementation.  As such, they are efficient but may change.
  733.  
  734. =over 2
  735.  
  736. =item is_utf8(STRING [, CHECK])
  737.  
  738. [INTERNAL] Tests whether the UTF-8 flag is turned on in the STRING.
  739. If CHECK is true, also checks the data in STRING for being well-formed
  740. UTF-8.  Returns true if successful, false otherwise.
  741.  
  742. As of perl 5.8.1, L<utf8> also has utf8::is_utif8().
  743.  
  744. =item _utf8_on(STRING)
  745.  
  746. [INTERNAL] Turns on the UTF-8 flag in STRING.  The data in STRING is
  747. B<not> checked for being well-formed UTF-8.  Do not use unless you
  748. B<know> that the STRING is well-formed UTF-8.  Returns the previous
  749. state of the UTF-8 flag (so please don't treat the return value as
  750. indicating success or failure), or C<undef> if STRING is not a string.
  751.  
  752. =item _utf8_off(STRING)
  753.  
  754. [INTERNAL] Turns off the UTF-8 flag in STRING.  Do not use frivolously.
  755. Returns the previous state of the UTF-8 flag (so please don't treat the
  756. return value as indicating success or failure), or C<undef> if STRING is
  757. not a string.
  758.  
  759. =back
  760.  
  761. =head1 SEE ALSO
  762.  
  763. L<Encode::Encoding>,
  764. L<Encode::Supported>,
  765. L<Encode::PerlIO>,
  766. L<encoding>,
  767. L<perlebcdic>,
  768. L<perlfunc/open>,
  769. L<perlunicode>,
  770. L<utf8>,
  771. the Perl Unicode Mailing List E<lt>perl-unicode@perl.orgE<gt>
  772.  
  773. =head1 MAINTAINER
  774.  
  775. This project was originated by Nick Ing-Simmons and later maintained
  776. by Dan Kogai E<lt>dankogai@dan.co.jpE<gt>.  See AUTHORS for a full
  777. list of people involved.  For any questions, use
  778. E<lt>perl-unicode@perl.orgE<gt> so we can all share.
  779.  
  780. =cut
  781.