home *** CD-ROM | disk | FTP | other *** search
/ PC World 2005 June / PCWorld_2005-06_cd.bin / software / vyzkuste / firewally / firewally.exe / framework-2.3.exe / DynaLoader.pm < prev    next >
Text File  |  2003-11-07  |  28KB  |  827 lines
  1.  
  2. # Generated from DynaLoader.pm.PL
  3.  
  4. package DynaLoader;
  5.  
  6. #   And Gandalf said: 'Many folk like to know beforehand what is to
  7. #   be set on the table; but those who have laboured to prepare the
  8. #   feast like to keep their secret; for wonder makes the words of
  9. #   praise louder.'
  10.  
  11. #   (Quote from Tolkien suggested by Anno Siegel.)
  12. #
  13. # See pod text at end of file for documentation.
  14. # See also ext/DynaLoader/README in source tree for other information.
  15. #
  16. # Tim.Bunce@ig.co.uk, August 1994
  17.  
  18. use vars qw($VERSION *AUTOLOAD);
  19.  
  20. $VERSION = '1.04';    # avoid typo warning
  21.  
  22. require AutoLoader;
  23. *AUTOLOAD = \&AutoLoader::AUTOLOAD;
  24.  
  25. use Config;
  26.  
  27. # The following require can't be removed during maintenance
  28. # releases, sadly, because of the risk of buggy code that does 
  29. # require Carp; Carp::croak "..."; without brackets dying 
  30. # if Carp hasn't been loaded in earlier compile time. :-( 
  31. # We'll let those bugs get found on the development track.
  32. require Carp if $] < 5.00450; 
  33.  
  34. # enable debug/trace messages from DynaLoader perl code
  35. $dl_debug = $ENV{PERL_DL_DEBUG} || 0 unless defined $dl_debug;
  36.  
  37. #
  38. # Flags to alter dl_load_file behaviour.  Assigned bits:
  39. #   0x01  make symbols available for linking later dl_load_file's.
  40. #         (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
  41. #         (ignored under VMS; effect is built-in to image linking)
  42. #
  43. # This is called as a class method $module->dl_load_flags.  The
  44. # definition here will be inherited and result on "default" loading
  45. # behaviour unless a sub-class of DynaLoader defines its own version.
  46. #
  47.  
  48. sub dl_load_flags { 0x00 }
  49.  
  50. # ($dl_dlext, $dlsrc)
  51. #         = @Config::Config{'dlext', 'dlsrc'};
  52.   ($dl_dlext, $dlsrc) = ('dll','dl_dlopen.xs')
  53. ;
  54. # Some systems need special handling to expand file specifications
  55. # (VMS support by Charles Bailey <bailey@HMIVAX.HUMGEN.UPENN.EDU>)
  56. # See dl_expandspec() for more details. Should be harmless but
  57. # inefficient to define on systems that don't need it.
  58. $Is_VMS    = $^O eq 'VMS';
  59. $do_expand = $Is_VMS;
  60. $Is_MacOS  = $^O eq 'MacOS';
  61.  
  62. my $Mac_FS;
  63. $Mac_FS = eval { require Mac::FileSpec::Unixish } if $Is_MacOS;
  64.  
  65. @dl_require_symbols = ();       # names of symbols we need
  66. @dl_resolve_using   = ();       # names of files to link with
  67. @dl_library_path    = ();       # path to look for files
  68.  
  69. #XSLoader.pm may have added elements before we were required
  70. #@dl_librefs         = ();       # things we have loaded
  71. #@dl_modules         = ();       # Modules we have loaded
  72.  
  73. # This is a fix to support DLD's unfortunate desire to relink -lc
  74. @dl_resolve_using = dl_findfile('-lc') if $dlsrc eq "dl_dld.xs";
  75.  
  76. # Initialise @dl_library_path with the 'standard' library path
  77. # for this platform as determined by Configure.
  78.  
  79. push(@dl_library_path, split(' ', $Config::Config{libpth}));
  80.  
  81.  
  82. my $ldlibpthname         = $Config::Config{ldlibpthname};
  83. my $ldlibpthname_defined = defined $Config::Config{ldlibpthname};
  84. my $pthsep               = $Config::Config{path_sep};
  85.  
  86. # Add to @dl_library_path any extra directories we can gather from environment
  87. # during runtime.
  88.  
  89. if ($ldlibpthname_defined &&
  90.     exists $ENV{$ldlibpthname}) {
  91.     push(@dl_library_path, split(/$pthsep/, $ENV{$ldlibpthname}));
  92. }
  93.  
  94. # E.g. HP-UX supports both its native SHLIB_PATH *and* LD_LIBRARY_PATH.
  95.  
  96. if ($ldlibpthname_defined &&
  97.     $ldlibpthname ne 'LD_LIBRARY_PATH' &&
  98.     exists $ENV{LD_LIBRARY_PATH}) {
  99.     push(@dl_library_path, split(/$pthsep/, $ENV{LD_LIBRARY_PATH}));
  100. }
  101.  
  102.  
  103. # No prizes for guessing why we don't say 'bootstrap DynaLoader;' here.
  104. # NOTE: All dl_*.xs (including dl_none.xs) define a dl_error() XSUB
  105. boot_DynaLoader('DynaLoader') if defined(&boot_DynaLoader) &&
  106.                                 !defined(&dl_error);
  107.  
  108. if ($dl_debug) {
  109.     print STDERR "DynaLoader.pm loaded (@INC, @dl_library_path)\n";
  110.     print STDERR "DynaLoader not linked into this perl\n"
  111.         unless defined(&boot_DynaLoader);
  112. }
  113.  
  114. 1; # End of main code
  115.  
  116.  
  117. sub croak   { require Carp; Carp::croak(@_)   }
  118.  
  119. sub bootstrap_inherit {
  120.     my $module = $_[0];
  121.     local *isa = *{"$module\::ISA"};
  122.     local @isa = (@isa, 'DynaLoader');
  123.     # Cannot goto due to delocalization.  Will report errors on a wrong line?
  124.     bootstrap(@_);
  125. }
  126.  
  127. # The bootstrap function cannot be autoloaded (without complications)
  128. # so we define it here:
  129.  
  130. sub bootstrap {
  131.     # use local vars to enable $module.bs script to edit values
  132.     local(@args) = @_;
  133.     local($module) = $args[0];
  134.     local(@dirs, $file);
  135.  
  136.     unless ($module) {
  137.     require Carp;
  138.     Carp::confess("Usage: DynaLoader::bootstrap(module)");
  139.     }
  140.  
  141.     # A common error on platforms which don't support dynamic loading.
  142.     # Since it's fatal and potentially confusing we give a detailed message.
  143.     croak("Can't load module $module, dynamic loading not available in this perl.\n".
  144.     "  (You may need to build a new perl executable which either supports\n".
  145.     "  dynamic loading or has the $module module statically linked into it.)\n")
  146.     unless defined(&dl_load_file);
  147.  
  148.     my @modparts = split(/::/,$module);
  149.     my $modfname = $modparts[-1];
  150.  
  151.     # Some systems have restrictions on files names for DLL's etc.
  152.     # mod2fname returns appropriate file base name (typically truncated)
  153.     # It may also edit @modparts if required.
  154.     $modfname = &mod2fname(\@modparts) if defined &mod2fname;
  155.  
  156.     # Truncate the module name to 8.3 format for NetWare
  157.     if (($^O eq 'NetWare') && (length($modfname) > 8)) {
  158.         $modfname = substr($modfname, 0, 8);
  159.     }
  160.  
  161.     my $modpname = join(($Is_MacOS ? ':' : '/'),@modparts);
  162.  
  163.     print STDERR "DynaLoader::bootstrap for $module ",
  164.         ($Is_MacOS
  165.                ? "(:auto:$modpname:$modfname.$dl_dlext)\n" :
  166.                "(auto/$modpname/$modfname.$dl_dlext)\n")
  167.     if $dl_debug;
  168.  
  169.     foreach (@INC) {
  170.     chop($_ = VMS::Filespec::unixpath($_)) if $Is_VMS;
  171.     my $dir;
  172.     if ($Is_MacOS) {
  173.         my $path = $_;
  174.         if ($Mac_FS && ! -d $path) {
  175.         $path = Mac::FileSpec::Unixish::nativize($path);
  176.         }
  177.         $path .= ":"  unless /:$/;
  178.         $dir = "${path}auto:$modpname";
  179.     } else {
  180.         $dir = "$_/auto/$modpname";
  181.     }
  182.     
  183.     next unless -d $dir; # skip over uninteresting directories
  184.     
  185.     # check for common cases to avoid autoload of dl_findfile
  186.     my $try = $Is_MacOS ? "$dir:$modfname.$dl_dlext" : "$dir/$modfname.$dl_dlext";
  187.     last if $file = ($do_expand) ? dl_expandspec($try) : ((-f $try) && $try);
  188.     
  189.     # no luck here, save dir for possible later dl_findfile search
  190.     push @dirs, $dir;
  191.     }
  192.     # last resort, let dl_findfile have a go in all known locations
  193.     $file = dl_findfile(map("-L$_",@dirs,@INC), $modfname) unless $file;
  194.  
  195.     croak("Can't locate loadable object for module $module in \@INC (\@INC contains: @INC)")
  196.     unless $file;    # wording similar to error from 'require'
  197.  
  198.     $file = uc($file) if $Is_VMS && $Config::Config{d_vms_case_sensitive_symbols};
  199.     my $bootname = "boot_$module";
  200.     $bootname =~ s/\W/_/g;
  201.     @dl_require_symbols = ($bootname);
  202.  
  203.     # Execute optional '.bootstrap' perl script for this module.
  204.     # The .bs file can be used to configure @dl_resolve_using etc to
  205.     # match the needs of the individual module on this architecture.
  206.     my $bs = $file;
  207.     $bs =~ s/(\.\w+)?(;\d*)?$/\.bs/; # look for .bs 'beside' the library
  208.     if (-s $bs) { # only read file if it's not empty
  209.         print STDERR "BS: $bs ($^O, $dlsrc)\n" if $dl_debug;
  210.         eval { do $bs; };
  211.         warn "$bs: $@\n" if $@;
  212.     }
  213.  
  214.     my $boot_symbol_ref;
  215.  
  216.     if ($^O eq 'darwin') {
  217.         if ($boot_symbol_ref = dl_find_symbol(0, $bootname)) {
  218.             goto boot; #extension library has already been loaded, e.g. darwin
  219.         }
  220.     }
  221.  
  222.     # Many dynamic extension loading problems will appear to come from
  223.     # this section of code: XYZ failed at line 123 of DynaLoader.pm.
  224.     # Often these errors are actually occurring in the initialisation
  225.     # C code of the extension XS file. Perl reports the error as being
  226.     # in this perl code simply because this was the last perl code
  227.     # it executed.
  228.  
  229.     my $libref = dl_load_file($file, $module->dl_load_flags) or
  230.     croak("Can't load '$file' for module $module: ".dl_error());
  231.  
  232.     push(@dl_librefs,$libref);  # record loaded object
  233.  
  234.     my @unresolved = dl_undef_symbols();
  235.     if (@unresolved) {
  236.     require Carp;
  237.     Carp::carp("Undefined symbols present after loading $file: @unresolved\n");
  238.     }
  239.  
  240.     $boot_symbol_ref = dl_find_symbol($libref, $bootname) or
  241.          croak("Can't find '$bootname' symbol in $file\n");
  242.  
  243.     push(@dl_modules, $module); # record loaded module
  244.  
  245.   boot:
  246.     my $xs = dl_install_xsub("${module}::bootstrap", $boot_symbol_ref, $file);
  247.  
  248.     # See comment block above
  249.     &$xs(@args);
  250. }
  251.  
  252.  
  253. #sub _check_file {   # private utility to handle dl_expandspec vs -f tests
  254. #    my($file) = @_;
  255. #    return $file if (!$do_expand && -f $file); # the common case
  256. #    return $file if ( $do_expand && ($file=dl_expandspec($file)));
  257. #    return undef;
  258. #}
  259.  
  260.  
  261. # Let autosplit and the autoloader deal with these functions:
  262. __END__
  263.  
  264.  
  265. sub dl_findfile {
  266.     # Read ext/DynaLoader/DynaLoader.doc for detailed information.
  267.     # This function does not automatically consider the architecture
  268.     # or the perl library auto directories.
  269.     my (@args) = @_;
  270.     my (@dirs,  $dir);   # which directories to search
  271.     my (@found);         # full paths to real files we have found
  272.     my $dl_ext= 'dll'; # $Config::Config{'dlext'} suffix for perl extensions
  273.     my $dl_so = 'dll'; # $Config::Config{'so'} suffix for shared libraries
  274.  
  275.     print STDERR "dl_findfile(@args)\n" if $dl_debug;
  276.  
  277.     # accumulate directories but process files as they appear
  278.     arg: foreach(@args) {
  279.         #  Special fast case: full filepath requires no search
  280.         if ($Is_VMS && m%[:>/\]]% && -f $_) {
  281.         push(@found,dl_expandspec(VMS::Filespec::vmsify($_)));
  282.         last arg unless wantarray;
  283.         next;
  284.         }
  285.     elsif ($Is_MacOS) {
  286.         if (m/:/ && -f $_) {
  287.             push(@found,$_);
  288.             last arg unless wantarray;
  289.         }
  290.     }
  291.         elsif (m:/: && -f $_ && !$do_expand) {
  292.         push(@found,$_);
  293.         last arg unless wantarray;
  294.         next;
  295.     }
  296.  
  297.         # Deal with directories first:
  298.         #  Using a -L prefix is the preferred option (faster and more robust)
  299.         if (m:^-L:) { s/^-L//; push(@dirs, $_); next; }
  300.  
  301.     if ($Is_MacOS) {
  302.             #  Otherwise we try to try to spot directories by a heuristic
  303.             #  (this is a more complicated issue than it first appears)
  304.         if (m/:/ && -d $_) {   push(@dirs, $_); next; }
  305.             #  Only files should get this far...
  306.             my(@names, $name);    # what filenames to look for
  307.         s/^-l//;
  308.         push(@names, $_);
  309.             foreach $dir (@dirs, @dl_library_path) {
  310.                 next unless -d $dir;
  311.         $dir =~ s/^([^:]+)$/:$1/;
  312.         $dir =~ s/:$//;
  313.                 foreach $name (@names) {
  314.                 my($file) = "$dir:$name";
  315.                     print STDERR " checking in $dir for $name\n" if $dl_debug;
  316.             if (-f $file) {
  317.                         push(@found, $file);
  318.                         next arg; # no need to look any further
  319.                     }
  320.                 }
  321.         }
  322.         next;
  323.     }
  324.     
  325.         #  Otherwise we try to try to spot directories by a heuristic
  326.         #  (this is a more complicated issue than it first appears)
  327.         if (m:/: && -d $_) {   push(@dirs, $_); next; }
  328.  
  329.         # VMS: we may be using native VMS directory syntax instead of
  330.         # Unix emulation, so check this as well
  331.         if ($Is_VMS && /[:>\]]/ && -d $_) {   push(@dirs, $_); next; }
  332.  
  333.         #  Only files should get this far...
  334.         my(@names, $name);    # what filenames to look for
  335.         if (m:-l: ) {          # convert -lname to appropriate library name
  336.             s/-l//;
  337.             push(@names,"lib$_.$dl_so");
  338.             push(@names,"lib$_.a");
  339.         } else {                # Umm, a bare name. Try various alternatives:
  340.             # these should be ordered with the most likely first
  341.             push(@names,"$_.$dl_ext")    unless m/\.$dl_ext$/o;
  342.             push(@names,"$_.$dl_so")     unless m/\.$dl_so$/o;
  343.             push(@names,"lib$_.$dl_so")  unless m:/:;
  344.             push(@names,"$_.a")          if !m/\.a$/ and $dlsrc eq "dl_dld.xs";
  345.             push(@names, $_);
  346.         }
  347.         foreach $dir (@dirs, @dl_library_path) {
  348.             next unless -d $dir;
  349.             chop($dir = VMS::Filespec::unixpath($dir)) if $Is_VMS;
  350.             foreach $name (@names) {
  351.         my($file) = "$dir/$name";
  352.                 print STDERR " checking in $dir for $name\n" if $dl_debug;
  353.         $file = ($do_expand) ? dl_expandspec($file) : (-f $file && $file);
  354.         #$file = _check_file($file);
  355.         if ($file) {
  356.                     push(@found, $file);
  357.                     next arg; # no need to look any further
  358.                 }
  359.             }
  360.         }
  361.     }
  362.     if ($dl_debug) {
  363.         foreach(@dirs) {
  364.             print STDERR " dl_findfile ignored non-existent directory: $_\n" unless -d $_;
  365.         }
  366.         print STDERR "dl_findfile found: @found\n";
  367.     }
  368.     return $found[0] unless wantarray;
  369.     @found;
  370. }
  371.  
  372.  
  373. sub dl_expandspec {
  374.     my($spec) = @_;
  375.     # Optional function invoked if DynaLoader.pm sets $do_expand.
  376.     # Most systems do not require or use this function.
  377.     # Some systems may implement it in the dl_*.xs file in which case
  378.     # this autoload version will not be called but is harmless.
  379.  
  380.     # This function is designed to deal with systems which treat some
  381.     # 'filenames' in a special way. For example VMS 'Logical Names'
  382.     # (something like unix environment variables - but different).
  383.     # This function should recognise such names and expand them into
  384.     # full file paths.
  385.     # Must return undef if $spec is invalid or file does not exist.
  386.  
  387.     my $file = $spec; # default output to input
  388.  
  389.     if ($Is_VMS) { # dl_expandspec should be defined in dl_vms.xs
  390.     require Carp;
  391.     Carp::croak("dl_expandspec: should be defined in XS file!\n");
  392.     } else {
  393.     return undef unless -f $file;
  394.     }
  395.     print STDERR "dl_expandspec($spec) => $file\n" if $dl_debug;
  396.     $file;
  397. }
  398.  
  399. sub dl_find_symbol_anywhere
  400. {
  401.     my $sym = shift;
  402.     my $libref;
  403.     foreach $libref (@dl_librefs) {
  404.     my $symref = dl_find_symbol($libref,$sym);
  405.     return $symref if $symref;
  406.     }
  407.     return undef;
  408. }
  409.  
  410. =head1 NAME
  411.  
  412. DynaLoader - Dynamically load C libraries into Perl code
  413.  
  414. dl_error(), dl_findfile(), dl_expandspec(), dl_load_file(), dl_unload_file(), dl_find_symbol(), dl_find_symbol_anywhere(), dl_undef_symbols(), dl_install_xsub(), dl_load_flags(), bootstrap() - routines used by DynaLoader modules
  415.  
  416. =head1 SYNOPSIS
  417.  
  418.     package YourPackage;
  419.     require DynaLoader;
  420.     @ISA = qw(... DynaLoader ...);
  421.     bootstrap YourPackage;
  422.  
  423.     # optional method for 'global' loading
  424.     sub dl_load_flags { 0x01 }     
  425.  
  426.  
  427. =head1 DESCRIPTION
  428.  
  429. This document defines a standard generic interface to the dynamic
  430. linking mechanisms available on many platforms.  Its primary purpose is
  431. to implement automatic dynamic loading of Perl modules.
  432.  
  433. This document serves as both a specification for anyone wishing to
  434. implement the DynaLoader for a new platform and as a guide for
  435. anyone wishing to use the DynaLoader directly in an application.
  436.  
  437. The DynaLoader is designed to be a very simple high-level
  438. interface that is sufficiently general to cover the requirements
  439. of SunOS, HP-UX, NeXT, Linux, VMS and other platforms.
  440.  
  441. It is also hoped that the interface will cover the needs of OS/2, NT
  442. etc and also allow pseudo-dynamic linking (using C<ld -A> at runtime).
  443.  
  444. It must be stressed that the DynaLoader, by itself, is practically
  445. useless for accessing non-Perl libraries because it provides almost no
  446. Perl-to-C 'glue'.  There is, for example, no mechanism for calling a C
  447. library function or supplying arguments.  A C::DynaLib module
  448. is available from CPAN sites which performs that function for some
  449. common system types.  And since the year 2000, there's also Inline::C,
  450. a module that allows you to write Perl subroutines in C.  Also available
  451. from your local CPAN site.
  452.  
  453. DynaLoader Interface Summary
  454.  
  455.   @dl_library_path
  456.   @dl_resolve_using
  457.   @dl_require_symbols
  458.   $dl_debug
  459.   @dl_librefs
  460.   @dl_modules
  461.                                                   Implemented in:
  462.   bootstrap($modulename)                               Perl
  463.   @filepaths = dl_findfile(@names)                     Perl
  464.   $flags = $modulename->dl_load_flags                  Perl
  465.   $symref  = dl_find_symbol_anywhere($symbol)          Perl
  466.  
  467.   $libref  = dl_load_file($filename, $flags)           C
  468.   $status  = dl_unload_file($libref)                   C
  469.   $symref  = dl_find_symbol($libref, $symbol)          C
  470.   @symbols = dl_undef_symbols()                        C
  471.   dl_install_xsub($name, $symref [, $filename])        C
  472.   $message = dl_error                                  C
  473.  
  474. =over 4
  475.  
  476. =item @dl_library_path
  477.  
  478. The standard/default list of directories in which dl_findfile() will
  479. search for libraries etc.  Directories are searched in order:
  480. $dl_library_path[0], [1], ... etc
  481.  
  482. @dl_library_path is initialised to hold the list of 'normal' directories
  483. (F</usr/lib>, etc) determined by B<Configure> (C<$Config{'libpth'}>).  This should
  484. ensure portability across a wide range of platforms.
  485.  
  486. @dl_library_path should also be initialised with any other directories
  487. that can be determined from the environment at runtime (such as
  488. LD_LIBRARY_PATH for SunOS).
  489.  
  490. After initialisation @dl_library_path can be manipulated by an
  491. application using push and unshift before calling dl_findfile().
  492. Unshift can be used to add directories to the front of the search order
  493. either to save search time or to override libraries with the same name
  494. in the 'normal' directories.
  495.  
  496. The load function that dl_load_file() calls may require an absolute
  497. pathname.  The dl_findfile() function and @dl_library_path can be
  498. used to search for and return the absolute pathname for the
  499. library/object that you wish to load.
  500.  
  501. =item @dl_resolve_using
  502.  
  503. A list of additional libraries or other shared objects which can be
  504. used to resolve any undefined symbols that might be generated by a
  505. later call to load_file().
  506.  
  507. This is only required on some platforms which do not handle dependent
  508. libraries automatically.  For example the Socket Perl extension
  509. library (F<auto/Socket/Socket.so>) contains references to many socket
  510. functions which need to be resolved when it's loaded.  Most platforms
  511. will automatically know where to find the 'dependent' library (e.g.,
  512. F</usr/lib/libsocket.so>).  A few platforms need to be told the
  513. location of the dependent library explicitly.  Use @dl_resolve_using
  514. for this.
  515.  
  516. Example usage:
  517.  
  518.     @dl_resolve_using = dl_findfile('-lsocket');
  519.  
  520. =item @dl_require_symbols
  521.  
  522. A list of one or more symbol names that are in the library/object file
  523. to be dynamically loaded.  This is only required on some platforms.
  524.  
  525. =item @dl_librefs
  526.  
  527. An array of the handles returned by successful calls to dl_load_file(),
  528. made by bootstrap, in the order in which they were loaded.
  529. Can be used with dl_find_symbol() to look for a symbol in any of
  530. the loaded files.
  531.  
  532. =item @dl_modules
  533.  
  534. An array of module (package) names that have been bootstrap'ed.
  535.  
  536. =item dl_error()
  537.  
  538. Syntax:
  539.  
  540.     $message = dl_error();
  541.  
  542. Error message text from the last failed DynaLoader function.  Note
  543. that, similar to errno in unix, a successful function call does not
  544. reset this message.
  545.  
  546. Implementations should detect the error as soon as it occurs in any of
  547. the other functions and save the corresponding message for later
  548. retrieval.  This will avoid problems on some platforms (such as SunOS)
  549. where the error message is very temporary (e.g., dlerror()).
  550.  
  551. =item $dl_debug
  552.  
  553. Internal debugging messages are enabled when $dl_debug is set true.
  554. Currently setting $dl_debug only affects the Perl side of the
  555. DynaLoader.  These messages should help an application developer to
  556. resolve any DynaLoader usage problems.
  557.  
  558. $dl_debug is set to C<$ENV{'PERL_DL_DEBUG'}> if defined.
  559.  
  560. For the DynaLoader developer/porter there is a similar debugging
  561. variable added to the C code (see dlutils.c) and enabled if Perl was
  562. built with the B<-DDEBUGGING> flag.  This can also be set via the
  563. PERL_DL_DEBUG environment variable.  Set to 1 for minimal information or
  564. higher for more.
  565.  
  566. =item dl_findfile()
  567.  
  568. Syntax:
  569.  
  570.     @filepaths = dl_findfile(@names)
  571.  
  572. Determine the full paths (including file suffix) of one or more
  573. loadable files given their generic names and optionally one or more
  574. directories.  Searches directories in @dl_library_path by default and
  575. returns an empty list if no files were found.
  576.  
  577. Names can be specified in a variety of platform independent forms.  Any
  578. names in the form B<-lname> are converted into F<libname.*>, where F<.*> is
  579. an appropriate suffix for the platform.
  580.  
  581. If a name does not already have a suitable prefix and/or suffix then
  582. the corresponding file will be searched for by trying combinations of
  583. prefix and suffix appropriate to the platform: "$name.o", "lib$name.*"
  584. and "$name".
  585.  
  586. If any directories are included in @names they are searched before
  587. @dl_library_path.  Directories may be specified as B<-Ldir>.  Any other
  588. names are treated as filenames to be searched for.
  589.  
  590. Using arguments of the form C<-Ldir> and C<-lname> is recommended.
  591.  
  592. Example: 
  593.  
  594.     @dl_resolve_using = dl_findfile(qw(-L/usr/5lib -lposix));
  595.  
  596.  
  597. =item dl_expandspec()
  598.  
  599. Syntax:
  600.  
  601.     $filepath = dl_expandspec($spec)
  602.  
  603. Some unusual systems, such as VMS, require special filename handling in
  604. order to deal with symbolic names for files (i.e., VMS's Logical Names).
  605.  
  606. To support these systems a dl_expandspec() function can be implemented
  607. either in the F<dl_*.xs> file or code can be added to the autoloadable
  608. dl_expandspec() function in F<DynaLoader.pm>.  See F<DynaLoader.pm> for
  609. more information.
  610.  
  611. =item dl_load_file()
  612.  
  613. Syntax:
  614.  
  615.     $libref = dl_load_file($filename, $flags)
  616.  
  617. Dynamically load $filename, which must be the path to a shared object
  618. or library.  An opaque 'library reference' is returned as a handle for
  619. the loaded object.  Returns undef on error.
  620.  
  621. The $flags argument to alters dl_load_file behaviour.  
  622. Assigned bits:
  623.  
  624.  0x01  make symbols available for linking later dl_load_file's.
  625.        (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
  626.        (ignored under VMS; this is a normal part of image linking)
  627.  
  628. (On systems that provide a handle for the loaded object such as SunOS
  629. and HPUX, $libref will be that handle.  On other systems $libref will
  630. typically be $filename or a pointer to a buffer containing $filename.
  631. The application should not examine or alter $libref in any way.)
  632.  
  633. This is the function that does the real work.  It should use the
  634. current values of @dl_require_symbols and @dl_resolve_using if required.
  635.  
  636.     SunOS: dlopen($filename)
  637.     HP-UX: shl_load($filename)
  638.     Linux: dld_create_reference(@dl_require_symbols); dld_link($filename)
  639.     NeXT:  rld_load($filename, @dl_resolve_using)
  640.     VMS:   lib$find_image_symbol($filename,$dl_require_symbols[0])
  641.  
  642. (The dlopen() function is also used by Solaris and some versions of
  643. Linux, and is a common choice when providing a "wrapper" on other
  644. mechanisms as is done in the OS/2 port.)
  645.  
  646. =item dl_unload_file()
  647.  
  648. Syntax:
  649.  
  650.     $status = dl_unload_file($libref)
  651.  
  652. Dynamically unload $libref, which must be an opaque 'library reference' as
  653. returned from dl_load_file.  Returns one on success and zero on failure.
  654.  
  655. This function is optional and may not necessarily be provided on all platforms.
  656. If it is defined, it is called automatically when the interpreter exits for
  657. every shared object or library loaded by DynaLoader::bootstrap.  All such
  658. library references are stored in @dl_librefs by DynaLoader::Bootstrap as it
  659. loads the libraries.  The files are unloaded in last-in, first-out order.
  660.  
  661. This unloading is usually necessary when embedding a shared-object perl (e.g.
  662. one configured with -Duseshrplib) within a larger application, and the perl
  663. interpreter is created and destroyed several times within the lifetime of the
  664. application.  In this case it is possible that the system dynamic linker will
  665. unload and then subsequently reload the shared libperl without relocating any
  666. references to it from any files DynaLoaded by the previous incarnation of the
  667. interpreter.  As a result, any shared objects opened by DynaLoader may point to
  668. a now invalid 'ghost' of the libperl shared object, causing apparently random
  669. memory corruption and crashes.  This behaviour is most commonly seen when using
  670. Apache and mod_perl built with the APXS mechanism.
  671.  
  672.     SunOS: dlclose($libref)
  673.     HP-UX: ???
  674.     Linux: ???
  675.     NeXT:  ???
  676.     VMS:   ???
  677.  
  678. (The dlclose() function is also used by Solaris and some versions of
  679. Linux, and is a common choice when providing a "wrapper" on other
  680. mechanisms as is done in the OS/2 port.)
  681.  
  682. =item dl_load_flags()
  683.  
  684. Syntax:
  685.  
  686.     $flags = dl_load_flags $modulename;
  687.  
  688. Designed to be a method call, and to be overridden by a derived class
  689. (i.e. a class which has DynaLoader in its @ISA).  The definition in
  690. DynaLoader itself returns 0, which produces standard behavior from
  691. dl_load_file().
  692.  
  693. =item dl_find_symbol()
  694.  
  695. Syntax:
  696.  
  697.     $symref = dl_find_symbol($libref, $symbol)
  698.  
  699. Return the address of the symbol $symbol or C<undef> if not found.  If the
  700. target system has separate functions to search for symbols of different
  701. types then dl_find_symbol() should search for function symbols first and
  702. then other types.
  703.  
  704. The exact manner in which the address is returned in $symref is not
  705. currently defined.  The only initial requirement is that $symref can
  706. be passed to, and understood by, dl_install_xsub().
  707.  
  708.     SunOS: dlsym($libref, $symbol)
  709.     HP-UX: shl_findsym($libref, $symbol)
  710.     Linux: dld_get_func($symbol) and/or dld_get_symbol($symbol)
  711.     NeXT:  rld_lookup("_$symbol")
  712.     VMS:   lib$find_image_symbol($libref,$symbol)
  713.  
  714.  
  715. =item dl_find_symbol_anywhere()
  716.  
  717. Syntax:
  718.  
  719.     $symref = dl_find_symbol_anywhere($symbol)
  720.  
  721. Applies dl_find_symbol() to the members of @dl_librefs and returns
  722. the first match found.
  723.  
  724. =item dl_undef_symbols()
  725.  
  726. Example
  727.  
  728.     @symbols = dl_undef_symbols()
  729.  
  730. Return a list of symbol names which remain undefined after load_file().
  731. Returns C<()> if not known.  Don't worry if your platform does not provide
  732. a mechanism for this.  Most do not need it and hence do not provide it,
  733. they just return an empty list.
  734.  
  735.  
  736. =item dl_install_xsub()
  737.  
  738. Syntax:
  739.  
  740.     dl_install_xsub($perl_name, $symref [, $filename])
  741.  
  742. Create a new Perl external subroutine named $perl_name using $symref as
  743. a pointer to the function which implements the routine.  This is simply
  744. a direct call to newXSUB().  Returns a reference to the installed
  745. function.
  746.  
  747. The $filename parameter is used by Perl to identify the source file for
  748. the function if required by die(), caller() or the debugger.  If
  749. $filename is not defined then "DynaLoader" will be used.
  750.  
  751.  
  752. =item bootstrap()
  753.  
  754. Syntax:
  755.  
  756. bootstrap($module)
  757.  
  758. This is the normal entry point for automatic dynamic loading in Perl.
  759.  
  760. It performs the following actions:
  761.  
  762. =over 8
  763.  
  764. =item *
  765.  
  766. locates an auto/$module directory by searching @INC
  767.  
  768. =item *
  769.  
  770. uses dl_findfile() to determine the filename to load
  771.  
  772. =item *
  773.  
  774. sets @dl_require_symbols to C<("boot_$module")>
  775.  
  776. =item *
  777.  
  778. executes an F<auto/$module/$module.bs> file if it exists
  779. (typically used to add to @dl_resolve_using any files which
  780. are required to load the module on the current platform)
  781.  
  782. =item *
  783.  
  784. calls dl_load_flags() to determine how to load the file.
  785.  
  786. =item *
  787.  
  788. calls dl_load_file() to load the file
  789.  
  790. =item *
  791.  
  792. calls dl_undef_symbols() and warns if any symbols are undefined
  793.  
  794. =item *
  795.  
  796. calls dl_find_symbol() for "boot_$module"
  797.  
  798. =item *
  799.  
  800. calls dl_install_xsub() to install it as "${module}::bootstrap"
  801.  
  802. =item *
  803.  
  804. calls &{"${module}::bootstrap"} to bootstrap the module (actually
  805. it uses the function reference returned by dl_install_xsub for speed)
  806.  
  807. =back
  808.  
  809. =back
  810.  
  811.  
  812. =head1 AUTHOR
  813.  
  814. Tim Bunce, 11 August 1994.
  815.  
  816. This interface is based on the work and comments of (in no particular
  817. order): Larry Wall, Robert Sanders, Dean Roehrich, Jeff Okamoto, Anno
  818. Siegel, Thomas Neumann, Paul Marquess, Charles Bailey, myself and others.
  819.  
  820. Larry Wall designed the elegant inherited bootstrap mechanism and
  821. implemented the first Perl 5 dynamic loader using it.
  822.  
  823. Solaris global loading added by Nick Ing-Simmons with design/coding
  824. assistance from Tim Bunce, January 1996.
  825.  
  826. =cut
  827.