home *** CD-ROM | disk | FTP | other *** search
/ PC World 2005 June / PCWorld_2005-06_cd.bin / software / vyzkuste / firewally / firewally.exe / framework-2.3.exe / Concise.pm < prev    next >
Text File  |  2003-11-07  |  37KB  |  1,138 lines
  1. package B::Concise;
  2. # Copyright (C) 2000-2003 Stephen McCamant. All rights reserved.
  3. # This program is free software; you can redistribute and/or modify it
  4. # under the same terms as Perl itself.
  5.  
  6. # Note: we need to keep track of how many use declarations/BEGIN
  7. # blocks this module uses, so we can avoid printing them when user
  8. # asks for the BEGIN blocks in her program. Update the comments and
  9. # the count in concise_specials if you add or delete one. The
  10. # -MO=Concise counts as use #1.
  11.  
  12. use strict; # use #2
  13. use warnings; # uses #3 and #4, since warnings uses Carp
  14.  
  15. use Exporter (); # use #5
  16.  
  17. our $VERSION   = "0.56";
  18. our @ISA       = qw(Exporter);
  19. our @EXPORT_OK = qw(set_style set_style_standard add_callback
  20.             concise_subref concise_cv concise_main);
  21.  
  22. # use #6
  23. use B qw(class ppname main_start main_root main_cv cstring svref_2object
  24.      SVf_IOK SVf_NOK SVf_POK SVf_IVisUV SVf_FAKE OPf_KIDS CVf_ANON);
  25.  
  26. my %style = 
  27.   ("terse" =>
  28.    ["(?(#label =>\n)?)(*(    )*)#class (#addr) #name (?([#targ])?) "
  29.     . "#svclass~(?((#svaddr))?)~#svval~(?(label \"#coplabel\")?)\n",
  30.     "(*(    )*)goto #class (#addr)\n",
  31.     "#class pp_#name"],
  32.    "concise" =>
  33.    ["#hyphseq2 (*(   (x( ;)x))*)<#classsym> "
  34.     . "#exname#arg(?([#targarglife])?)~#flags(?(/#private)?)(x(;~->#next)x)\n",
  35.     "  (*(    )*)     goto #seq\n",
  36.     "(?(<#seq>)?)#exname#arg(?([#targarglife])?)"],
  37.    "linenoise" =>
  38.    ["(x(;(*( )*))x)#noise#arg(?([#targarg])?)(x( ;\n)x)",
  39.     "gt_#seq ",
  40.     "(?(#seq)?)#noise#arg(?([#targarg])?)"],
  41.    "debug" =>
  42.    ["#class (#addr)\n\top_next\t\t#nextaddr\n\top_sibling\t#sibaddr\n\t"
  43.     . "op_ppaddr\tPL_ppaddr[OP_#NAME]\n\top_type\t\t#typenum\n\top_seq\t\t"
  44.     . "#seqnum\n\top_flags\t#flagval\n\top_private\t#privval\n"
  45.     . "(?(\top_first\t#firstaddr\n)?)(?(\top_last\t\t#lastaddr\n)?)"
  46.     . "(?(\top_sv\t\t#svaddr\n)?)",
  47.     "    GOTO #addr\n",
  48.     "#addr"],
  49.    "env" => [$ENV{B_CONCISE_FORMAT}, $ENV{B_CONCISE_GOTO_FORMAT},
  50.          $ENV{B_CONCISE_TREE_FORMAT}],
  51.   );
  52.  
  53. my($format, $gotofmt, $treefmt);
  54. my $curcv;
  55. my $cop_seq_base;
  56. my @callbacks;
  57.  
  58. sub set_style {
  59.     ($format, $gotofmt, $treefmt) = @_;
  60. }
  61.  
  62. sub set_style_standard {
  63.     my($name) = @_;
  64.     set_style(@{$style{$name}});
  65. }
  66.  
  67. sub add_callback {
  68.     push @callbacks, @_;
  69. }
  70.  
  71. sub concise_subref {
  72.     my($order, $subref) = @_;
  73.     concise_cv_obj($order, svref_2object($subref));
  74. }
  75.  
  76. # This should have been called concise_subref, but it was exported
  77. # under this name in versions before 0.56
  78. sub concise_cv { concise_subref(@_); }
  79.  
  80. sub concise_cv_obj {
  81.     my ($order, $cv) = @_;
  82.     $curcv = $cv;
  83.     sequence($cv->START);
  84.     if ($order eq "exec") {
  85.     walk_exec($cv->START);
  86.     } elsif ($order eq "basic") {
  87.     walk_topdown($cv->ROOT, sub { $_[0]->concise($_[1]) }, 0);
  88.     } else {
  89.     print tree($cv->ROOT, 0)
  90.     }
  91. }
  92.  
  93. sub concise_main {
  94.     my($order) = @_;
  95.     sequence(main_start);
  96.     $curcv = main_cv;
  97.     if ($order eq "exec") {
  98.     return if class(main_start) eq "NULL";
  99.     walk_exec(main_start);
  100.     } elsif ($order eq "tree") {
  101.     return if class(main_root) eq "NULL";
  102.     print tree(main_root, 0);
  103.     } elsif ($order eq "basic") {
  104.     return if class(main_root) eq "NULL";
  105.     walk_topdown(main_root,
  106.              sub { $_[0]->concise($_[1]) }, 0);
  107.     }
  108. }
  109.  
  110. sub concise_specials {
  111.     my($name, $order, @cv_s) = @_;
  112.     my $i = 1;
  113.     if ($name eq "BEGIN") {
  114.     splice(@cv_s, 0, 7); # skip 7 BEGIN blocks in this file
  115.     } elsif ($name eq "CHECK") {
  116.     pop @cv_s; # skip the CHECK block that calls us
  117.     }
  118.     for my $cv (@cv_s) {    
  119.     print "$name $i:\n";
  120.     $i++;
  121.     concise_cv_obj($order, $cv);
  122.     }
  123. }
  124.  
  125. my $start_sym = "\e(0"; # "\cN" sometimes also works
  126. my $end_sym   = "\e(B"; # "\cO" respectively
  127.  
  128. my @tree_decorations = 
  129.   (["  ", "--", "+-", "|-", "| ", "`-", "-", 1],
  130.    [" ", "-", "+", "+", "|", "`", "", 0],
  131.    ["  ", map("$start_sym$_$end_sym", "qq", "wq", "tq", "x ", "mq", "q"), 1],
  132.    [" ", map("$start_sym$_$end_sym", "q", "w", "t", "x", "m"), "", 0],
  133.   );
  134. my $tree_style = 0;
  135.  
  136. my $base = 36;
  137. my $big_endian = 1;
  138.  
  139. my $order = "basic";
  140.  
  141. set_style_standard("concise");
  142.  
  143. sub compile {
  144.     my @options = grep(/^-/, @_);
  145.     my @args = grep(!/^-/, @_);
  146.     my $do_main = 0;
  147.     for my $o (@options) {
  148.     if ($o eq "-basic") {
  149.         $order = "basic";
  150.     } elsif ($o eq "-exec") {
  151.         $order = "exec";
  152.     } elsif ($o eq "-tree") {
  153.         $order = "tree";
  154.     } elsif ($o eq "-compact") {
  155.         $tree_style |= 1;
  156.     } elsif ($o eq "-loose") {
  157.         $tree_style &= ~1;
  158.     } elsif ($o eq "-vt") {
  159.         $tree_style |= 2;
  160.     } elsif ($o eq "-ascii") {
  161.         $tree_style &= ~2;
  162.     } elsif ($o eq "-main") {
  163.         $do_main = 1;
  164.     } elsif ($o =~ /^-base(\d+)$/) {
  165.         $base = $1;
  166.     } elsif ($o eq "-bigendian") {
  167.         $big_endian = 1;
  168.     } elsif ($o eq "-littleendian") {
  169.         $big_endian = 0;
  170.     } elsif (exists $style{substr($o, 1)}) {
  171.         set_style(@{$style{substr($o, 1)}});
  172.     } else {
  173.         warn "Option $o unrecognized";
  174.     }
  175.     }
  176.     return sub {
  177.     if (@args) {
  178.         for my $objname (@args) {
  179.         if ($objname eq "BEGIN") {
  180.             concise_specials("BEGIN", $order,
  181.                      B::begin_av->isa("B::AV") ?
  182.                      B::begin_av->ARRAY : ());
  183.         } elsif ($objname eq "INIT") {
  184.             concise_specials("INIT", $order,
  185.                      B::init_av->isa("B::AV") ?
  186.                      B::init_av->ARRAY : ());
  187.         } elsif ($objname eq "CHECK") {
  188.             concise_specials("CHECK", $order,
  189.                      B::check_av->isa("B::AV") ?
  190.                      B::check_av->ARRAY : ());
  191.         } elsif ($objname eq "END") {
  192.             concise_specials("END", $order,
  193.                      B::end_av->isa("B::AV") ?
  194.                      B::end_av->ARRAY : ());
  195.         } else {
  196.             $objname = "main::" . $objname unless $objname =~ /::/;
  197.             print "$objname:\n";
  198.             eval "concise_subref(\$order, \\&$objname)";
  199.             die "concise_subref($order, \\&$objname) failed: $@" if $@;
  200.         }
  201.         }
  202.     }
  203.     if (!@args or $do_main) {
  204.         print "main program:\n" if $do_main;
  205.         concise_main($order);
  206.     }
  207.     }
  208. }
  209.  
  210. my %labels;
  211. my $lastnext;
  212.  
  213. my %opclass = ('OP' => "0", 'UNOP' => "1", 'BINOP' => "2", 'LOGOP' => "|",
  214.            'LISTOP' => "@", 'PMOP' => "/", 'SVOP' => "\$", 'GVOP' => "*",
  215.            'PVOP' => '"', 'LOOP' => "{", 'COP' => ";", 'PADOP' => "#");
  216.  
  217. no warnings 'qw'; # "Possible attempt to put comments..."; use #7
  218. my @linenoise =
  219.   qw'#  () sc (  @? 1  $* gv *{ m$ m@ m% m? p/ *$ $  $# & a& pt \\ s\\ rf bl
  220.      `  *? <> ?? ?/ r/ c/ // qr s/ /c y/ =  @= C  sC Cp sp df un BM po +1 +I
  221.      -1 -I 1+ I+ 1- I- ** *  i* /  i/ %$ i% x  +  i+ -  i- .  "  << >> <  i<
  222.      >  i> <= i, >= i. == i= != i! <? i? s< s> s, s. s= s! s? b& b^ b| -0 -i
  223.      !  ~  a2 si cs rd sr e^ lg sq in %x %o ab le ss ve ix ri sf FL od ch cy
  224.      uf lf uc lc qm @  [f [  @[ eh vl ky dl ex %  ${ @{ uk pk st jn )  )[ a@
  225.      a% sl +] -] [- [+ so rv GS GW MS MW .. f. .f && || ^^ ?: &= |= -> s{ s}
  226.      v} ca wa di rs ;; ;  ;d }{ {  }  {} f{ it {l l} rt }l }n }r dm }g }e ^o
  227.      ^c ^| ^# um bm t~ u~ ~d DB db ^s se ^g ^r {w }w pf pr ^O ^K ^R ^W ^d ^v
  228.      ^e ^t ^k t. fc ic fl .s .p .b .c .l .a .h g1 s1 g2 s2 ?. l? -R -W -X -r
  229.      -w -x -e -o -O -z -s -M -A -C -S -c -b -f -d -p -l -u -g -k -t -T -B cd
  230.      co cr u. cm ut r. l@ s@ r@ mD uD oD rD tD sD wD cD f$ w$ p$ sh e$ k$ g3
  231.      g4 s4 g5 s5 T@ C@ L@ G@ A@ S@ Hg Hc Hr Hw Mg Mc Ms Mr Sg Sc So rq do {e
  232.      e} {t t} g6 G6 6e g7 G7 7e g8 G8 8e g9 G9 9e 6s 7s 8s 9s 6E 7E 8E 9E Pn
  233.      Pu GP SP EP Gn Gg GG SG EG g0 c$ lk t$ ;s n> // /= CO';
  234.  
  235. my $chars = "0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ";
  236.  
  237. sub op_flags {
  238.     my($x) = @_;
  239.     my(@v);
  240.     push @v, "v" if ($x & 3) == 1;
  241.     push @v, "s" if ($x & 3) == 2;
  242.     push @v, "l" if ($x & 3) == 3;
  243.     push @v, "K" if $x & 4;
  244.     push @v, "P" if $x & 8;
  245.     push @v, "R" if $x & 16;
  246.     push @v, "M" if $x & 32;
  247.     push @v, "S" if $x & 64;
  248.     push @v, "*" if $x & 128;
  249.     return join("", @v);
  250. }
  251.  
  252. sub base_n {
  253.     my $x = shift;
  254.     return "-" . base_n(-$x) if $x < 0;
  255.     my $str = "";
  256.     do { $str .= substr($chars, $x % $base, 1) } while $x = int($x / $base);
  257.     $str = reverse $str if $big_endian;
  258.     return $str;
  259. }
  260.  
  261. my %sequence_num;
  262. my $seq_max = 1;
  263.  
  264. sub seq {
  265.     my($op) = @_;
  266.     return "-" if not exists $sequence_num{$$op};
  267.     return base_n($sequence_num{$$op});
  268. }
  269.  
  270. sub walk_topdown {
  271.     my($op, $sub, $level) = @_;
  272.     $sub->($op, $level);
  273.     if ($op->flags & OPf_KIDS) {
  274.     for (my $kid = $op->first; $$kid; $kid = $kid->sibling) {
  275.         walk_topdown($kid, $sub, $level + 1);
  276.     }
  277.     }
  278.     if (class($op) eq "PMOP") {
  279.     my $maybe_root = $op->pmreplroot;
  280.     if (ref($maybe_root) and $maybe_root->isa("B::OP")) {
  281.         # It really is the root of the replacement, not something
  282.         # else stored here for lack of space elsewhere
  283.         walk_topdown($maybe_root, $sub, $level + 1);
  284.     }
  285.     }
  286. }
  287.  
  288. sub walklines {
  289.     my($ar, $level) = @_;
  290.     for my $l (@$ar) {
  291.     if (ref($l) eq "ARRAY") {
  292.         walklines($l, $level + 1);
  293.     } else {
  294.         $l->concise($level);
  295.     }
  296.     }
  297. }
  298.  
  299. sub walk_exec {
  300.     my($top, $level) = @_;
  301.     my %opsseen;
  302.     my @lines;
  303.     my @todo = ([$top, \@lines]);
  304.     while (@todo and my($op, $targ) = @{shift @todo}) {
  305.     for (; $$op; $op = $op->next) {
  306.         last if $opsseen{$$op}++;
  307.         push @$targ, $op;
  308.         my $name = $op->name;
  309.         if (class($op) eq "LOGOP") {
  310.         my $ar = [];
  311.         push @$targ, $ar;
  312.         push @todo, [$op->other, $ar];
  313.         } elsif ($name eq "subst" and $ {$op->pmreplstart}) {
  314.         my $ar = [];
  315.         push @$targ, $ar;
  316.         push @todo, [$op->pmreplstart, $ar];
  317.         } elsif ($name =~ /^enter(loop|iter)$/) {
  318.         $labels{$op->nextop->seq} = "NEXT";
  319.         $labels{$op->lastop->seq} = "LAST";
  320.         $labels{$op->redoop->seq} = "REDO";        
  321.         }
  322.     }
  323.     }
  324.     walklines(\@lines, 0);
  325. }
  326.  
  327. # The structure of this routine is purposely modeled after op.c's peep()
  328. sub sequence {
  329.     my($op) = @_;
  330.     my $oldop = 0;
  331.     return if class($op) eq "NULL" or exists $sequence_num{$$op};
  332.     for (; $$op; $op = $op->next) {
  333.     last if exists $sequence_num{$$op};
  334.     my $name = $op->name;
  335.     if ($name =~ /^(null|scalar|lineseq|scope)$/) {
  336.         next if $oldop and $ {$op->next};
  337.     } else {
  338.         $sequence_num{$$op} = $seq_max++;
  339.         if (class($op) eq "LOGOP") {
  340.         my $other = $op->other;
  341.         $other = $other->next while $other->name eq "null";
  342.         sequence($other);
  343.         } elsif (class($op) eq "LOOP") {
  344.         my $redoop = $op->redoop;
  345.         $redoop = $redoop->next while $redoop->name eq "null";
  346.         sequence($redoop);
  347.         my $nextop = $op->nextop;
  348.         $nextop = $nextop->next while $nextop->name eq "null";
  349.         sequence($nextop);
  350.         my $lastop = $op->lastop;
  351.         $lastop = $lastop->next while $lastop->name eq "null";
  352.         sequence($lastop);
  353.         } elsif ($name eq "subst" and $ {$op->pmreplstart}) {
  354.         my $replstart = $op->pmreplstart;
  355.         $replstart = $replstart->next while $replstart->name eq "null";
  356.         sequence($replstart);
  357.         }
  358.     }
  359.     $oldop = $op;
  360.     }
  361. }
  362.  
  363. sub fmt_line {
  364.     my($hr, $fmt, $level) = @_;
  365.     my $text = $fmt;
  366.     $text =~ s/\(\?\(([^\#]*?)\#(\w+)([^\#]*?)\)\?\)/
  367.       $hr->{$2} ? $1.$hr->{$2}.$3 : ""/eg;
  368.     $text =~ s/\(x\((.*?);(.*?)\)x\)/$order eq "exec" ? $1 : $2/egs;
  369.     $text =~ s/\(\*\(([^;]*?)\)\*\)/$1 x $level/egs;
  370.     $text =~ s/\(\*\((.*?);(.*?)\)\*\)/$1 x ($level - 1) . $2 x ($level>0)/egs;
  371.     $text =~ s/#([a-zA-Z]+)(\d+)/sprintf("%-$2s", $hr->{$1})/eg;
  372.     $text =~ s/#([a-zA-Z]+)/$hr->{$1}/eg;
  373.     $text =~ s/[ \t]*~+[ \t]*/ /g;
  374.     return $text;
  375. }
  376.  
  377. my %priv;
  378. $priv{$_}{128} = "LVINTRO"
  379.   for ("pos", "substr", "vec", "threadsv", "gvsv", "rv2sv", "rv2hv", "rv2gv",
  380.        "rv2av", "rv2arylen", "aelem", "helem", "aslice", "hslice", "padsv",
  381.        "padav", "padhv", "enteriter");
  382. $priv{$_}{64} = "REFC" for ("leave", "leavesub", "leavesublv", "leavewrite");
  383. $priv{"aassign"}{64} = "COMMON";
  384. $priv{"aassign"}{32} = "PHASH";
  385. $priv{"sassign"}{64} = "BKWARD";
  386. $priv{$_}{64} = "RTIME" for ("match", "subst", "substcont");
  387. @{$priv{"trans"}}{1,2,4,8,16,64} = ("<UTF", ">UTF", "IDENT", "SQUASH", "DEL",
  388.                     "COMPL", "GROWS");
  389. $priv{"repeat"}{64} = "DOLIST";
  390. $priv{"leaveloop"}{64} = "CONT";
  391. @{$priv{$_}}{32,64,96} = ("DREFAV", "DREFHV", "DREFSV")
  392.   for ("entersub", map("rv2${_}v", "a", "s", "h", "g"), "aelem", "helem");
  393. $priv{"entersub"}{16} = "DBG";
  394. $priv{"entersub"}{32} = "TARG";
  395. @{$priv{$_}}{4,8,128} = ("INARGS","AMPER","NO()") for ("entersub", "rv2cv");
  396. $priv{"gv"}{32} = "EARLYCV";
  397. $priv{"aelem"}{16} = $priv{"helem"}{16} = "LVDEFER";
  398. $priv{$_}{16} = "OURINTR" for ("gvsv", "rv2sv", "rv2av", "rv2hv", "r2gv",
  399.     "enteriter");
  400. $priv{$_}{16} = "TARGMY"
  401.   for (map(($_,"s$_"),"chop", "chomp"),
  402.        map(($_,"i_$_"), "postinc", "postdec", "multiply", "divide", "modulo",
  403.        "add", "subtract", "negate"), "pow", "concat", "stringify",
  404.        "left_shift", "right_shift", "bit_and", "bit_xor", "bit_or",
  405.        "complement", "atan2", "sin", "cos", "rand", "exp", "log", "sqrt",
  406.        "int", "hex", "oct", "abs", "length", "index", "rindex", "sprintf",
  407.        "ord", "chr", "crypt", "quotemeta", "join", "push", "unshift", "flock",
  408.        "chdir", "chown", "chroot", "unlink", "chmod", "utime", "rename",
  409.        "link", "symlink", "mkdir", "rmdir", "wait", "waitpid", "system",
  410.        "exec", "kill", "getppid", "getpgrp", "setpgrp", "getpriority",
  411.        "setpriority", "time", "sleep");
  412. @{$priv{"const"}}{8,16,32,64,128} = ("STRICT","ENTERED", '$[', "BARE", "WARN");
  413. $priv{"flip"}{64} = $priv{"flop"}{64} = "LINENUM";
  414. $priv{"list"}{64} = "GUESSED";
  415. $priv{"delete"}{64} = "SLICE";
  416. $priv{"exists"}{64} = "SUB";
  417. $priv{$_}{64} = "LOCALE"
  418.   for ("sort", "prtf", "sprintf", "slt", "sle", "seq", "sne", "sgt", "sge",
  419.        "scmp", "lc", "uc", "lcfirst", "ucfirst");
  420. @{$priv{"sort"}}{1,2,4} = ("NUM", "INT", "REV");
  421. $priv{"threadsv"}{64} = "SVREFd";
  422. @{$priv{$_}}{16,32,64,128} = ("INBIN","INCR","OUTBIN","OUTCR")
  423.   for ("open", "backtick");
  424. $priv{"exit"}{128} = "VMS";
  425. $priv{$_}{2} = "FTACCESS"
  426.   for ("ftrread", "ftrwrite", "ftrexec", "fteread", "ftewrite", "fteexec");
  427.  
  428. sub private_flags {
  429.     my($name, $x) = @_;
  430.     my @s;
  431.     for my $flag (128, 96, 64, 32, 16, 8, 4, 2, 1) {
  432.     if ($priv{$name}{$flag} and $x & $flag and $x >= $flag) {
  433.         $x -= $flag;
  434.         push @s, $priv{$name}{$flag};
  435.     }
  436.     }
  437.     push @s, $x if $x;
  438.     return join(",", @s);
  439. }
  440.  
  441. sub concise_sv {
  442.     my($sv, $hr) = @_;
  443.     $hr->{svclass} = class($sv);
  444.     $hr->{svclass} = "UV"
  445.       if $hr->{svclass} eq "IV" and $sv->FLAGS & SVf_IVisUV;
  446.     $hr->{svaddr} = sprintf("%#x", $$sv);
  447.     if ($hr->{svclass} eq "GV") {
  448.     my $gv = $sv;
  449.     my $stash = $gv->STASH->NAME;
  450.     if ($stash eq "main") {
  451.         $stash = "";
  452.     } else {
  453.         $stash = $stash . "::";
  454.     }
  455.     $hr->{svval} = "*$stash" . $gv->SAFENAME;
  456.     return "*$stash" . $gv->SAFENAME;
  457.     } else {
  458.     while (class($sv) eq "RV") {
  459.         $hr->{svval} .= "\\";
  460.         $sv = $sv->RV;
  461.     }
  462.     if (class($sv) eq "SPECIAL") {
  463.         $hr->{svval} .= ["Null", "sv_undef", "sv_yes", "sv_no"]->[$$sv];
  464.     } elsif ($sv->FLAGS & SVf_NOK) {
  465.         $hr->{svval} .= $sv->NV;
  466.     } elsif ($sv->FLAGS & SVf_IOK) {
  467.         $hr->{svval} .= $sv->int_value;
  468.     } elsif ($sv->FLAGS & SVf_POK) {
  469.         $hr->{svval} .= cstring($sv->PV);
  470.     } elsif (class($sv) eq "HV") {
  471.         $hr->{svval} .= 'HASH';
  472.     }
  473.     return $hr->{svclass} . " " .  $hr->{svval};
  474.     }
  475. }
  476.  
  477. sub concise_op {
  478.     my ($op, $level, $format) = @_;
  479.     my %h;
  480.     $h{exname} = $h{name} = $op->name;
  481.     $h{NAME} = uc $h{name};
  482.     $h{class} = class($op);
  483.     $h{extarg} = $h{targ} = $op->targ;
  484.     $h{extarg} = "" unless $h{extarg};
  485.     if ($h{name} eq "null" and $h{targ}) {
  486.     # targ holds the old type
  487.     $h{exname} = "ex-" . substr(ppname($h{targ}), 3);
  488.     $h{extarg} = "";
  489.     } elsif ($op->name =~ /^leave(sub(lv)?|write)?$/) {
  490.     # targ potentially holds a reference count
  491.     if ($op->private & 64) {
  492.         my $refs = "ref" . ($h{targ} != 1 ? "s" : "");
  493.         $h{targarglife} = $h{targarg} = "$h{targ} $refs";
  494.     }
  495.     } elsif ($h{targ}) {
  496.     my $padname = (($curcv->PADLIST->ARRAY)[0]->ARRAY)[$h{targ}];
  497.     if (defined $padname and class($padname) ne "SPECIAL") {
  498.         $h{targarg}  = $padname->PVX;
  499.         if ($padname->FLAGS & SVf_FAKE) {
  500.         $h{targarglife} = "$h{targarg}:FAKE";
  501.         }
  502.         else {
  503.         my $intro = $padname->NVX - $cop_seq_base;
  504.         my $finish = int($padname->IVX) - $cop_seq_base;
  505.         $finish = "end" if $finish == 999999999 - $cop_seq_base;
  506.         $h{targarglife} = "$h{targarg}:$intro,$finish";
  507.         }
  508.     } else {
  509.         $h{targarglife} = $h{targarg} = "t" . $h{targ};
  510.     }
  511.     }
  512.     $h{arg} = "";
  513.     $h{svclass} = $h{svaddr} = $h{svval} = "";
  514.     if ($h{class} eq "PMOP") {
  515.     my $precomp = $op->precomp;
  516.     if (defined $precomp) {
  517.         $precomp = cstring($precomp); # Escape literal control sequences
  518.          $precomp = "/$precomp/";
  519.     } else {
  520.         $precomp = "";
  521.     }
  522.     my $pmreplroot = $op->pmreplroot;
  523.     my $pmreplstart;
  524.     if (ref($pmreplroot) eq "B::GV") {
  525.         # with C<@stash_array = split(/pat/, str);>,
  526.         #  *stash_array is stored in /pat/'s pmreplroot.
  527.         $h{arg} = "($precomp => \@" . $pmreplroot->NAME . ")";
  528.     } elsif (!ref($pmreplroot) and $pmreplroot) {
  529.         # same as the last case, except the value is actually a
  530.         # pad offset for where the GV is kept (this happens under
  531.         # ithreads)
  532.         my $gv = (($curcv->PADLIST->ARRAY)[1]->ARRAY)[$pmreplroot];
  533.         $h{arg} = "($precomp => \@" . $gv->NAME . ")";
  534.     } elsif ($ {$op->pmreplstart}) {
  535.         undef $lastnext;
  536.         $pmreplstart = "replstart->" . seq($op->pmreplstart);
  537.         $h{arg} = "(" . join(" ", $precomp, $pmreplstart) . ")";
  538.     } else {
  539.         $h{arg} = "($precomp)";
  540.     }
  541.     } elsif ($h{class} eq "PVOP" and $h{name} ne "trans") {
  542.     $h{arg} = '("' . $op->pv . '")';
  543.     $h{svval} = '"' . $op->pv . '"';
  544.     } elsif ($h{class} eq "COP") {
  545.     my $label = $op->label;
  546.     $h{coplabel} = $label;
  547.     $label = $label ? "$label: " : "";
  548.     my $loc = $op->file;
  549.     $loc =~ s[.*/][];
  550.     $loc .= ":" . $op->line;
  551.     my($stash, $cseq) = ($op->stash->NAME, $op->cop_seq - $cop_seq_base);
  552.     my $arybase = $op->arybase;
  553.     $arybase = $arybase ? ' $[=' . $arybase : "";
  554.     $h{arg} = "($label$stash $cseq $loc$arybase)";
  555.     } elsif ($h{class} eq "LOOP") {
  556.     $h{arg} = "(next->" . seq($op->nextop) . " last->" . seq($op->lastop)
  557.       . " redo->" . seq($op->redoop) . ")";
  558.     } elsif ($h{class} eq "LOGOP") {
  559.     undef $lastnext;
  560.     $h{arg} = "(other->" . seq($op->other) . ")";
  561.     } elsif ($h{class} eq "SVOP") {
  562.     if (! ${$op->sv}) {
  563.         my $sv = (($curcv->PADLIST->ARRAY)[1]->ARRAY)[$op->targ];
  564.         $h{arg} = "[" . concise_sv($sv, \%h) . "]";
  565.         $h{targarglife} = $h{targarg} = "";
  566.     } else {
  567.         $h{arg} = "(" . concise_sv($op->sv, \%h) . ")";
  568.     }
  569.     } elsif ($h{class} eq "PADOP") {
  570.     my $sv = (($curcv->PADLIST->ARRAY)[1]->ARRAY)[$op->padix];
  571.     $h{arg} = "[" . concise_sv($sv, \%h) . "]";
  572.     }
  573.     $h{seq} = $h{hyphseq} = seq($op);
  574.     $h{seq} = "" if $h{seq} eq "-";
  575.     $h{seqnum} = $op->seq;
  576.     $h{next} = $op->next;
  577.     $h{next} = (class($h{next}) eq "NULL") ? "(end)" : seq($h{next});
  578.     $h{nextaddr} = sprintf("%#x", $ {$op->next});
  579.     $h{sibaddr} = sprintf("%#x", $ {$op->sibling});
  580.     $h{firstaddr} = sprintf("%#x", $ {$op->first}) if $op->can("first");
  581.     $h{lastaddr} = sprintf("%#x", $ {$op->last}) if $op->can("last");
  582.  
  583.     $h{classsym} = $opclass{$h{class}};
  584.     $h{flagval} = $op->flags;
  585.     $h{flags} = op_flags($op->flags);
  586.     $h{privval} = $op->private;
  587.     $h{private} = private_flags($h{name}, $op->private);
  588.     $h{addr} = sprintf("%#x", $$op);
  589.     $h{label} = $labels{$op->seq};
  590.     $h{typenum} = $op->type;
  591.     $h{noise} = $linenoise[$op->type];
  592.     $_->(\%h, $op, \$format, \$level) for @callbacks;
  593.     return fmt_line(\%h, $format, $level);
  594. }
  595.  
  596. sub B::OP::concise {
  597.     my($op, $level) = @_;
  598.     if ($order eq "exec" and $lastnext and $$lastnext != $$op) {
  599.     my $h = {"seq" => seq($lastnext), "class" => class($lastnext),
  600.          "addr" => sprintf("%#x", $$lastnext)};
  601.     print fmt_line($h, $gotofmt, $level+1);
  602.     }
  603.     $lastnext = $op->next;
  604.     print concise_op($op, $level, $format);
  605. }
  606.  
  607. # B::OP::terse (see Terse.pm) now just calls this
  608. sub b_terse {
  609.     my($op, $level) = @_;
  610.  
  611.     # This isn't necessarily right, but there's no easy way to get
  612.     # from an OP to the right CV. This is a limitation of the
  613.     # ->terse() interface style, and there isn't much to do about
  614.     # it. In particular, we can die in concise_op if the main pad
  615.     # isn't long enough, or has the wrong kind of entries, compared to
  616.     # the pad a sub was compiled with. The fix for that would be to
  617.     # make a backwards compatible "terse" format that never even
  618.     # looked at the pad, just like the old B::Terse. I don't think
  619.     # that's worth the effort, though.
  620.     $curcv = main_cv unless $curcv;
  621.  
  622.     if ($order eq "exec" and $lastnext and $$lastnext != $$op) {
  623.     my $h = {"seq" => seq($lastnext), "class" => class($lastnext),
  624.          "addr" => sprintf("%#x", $$lastnext)};
  625.     print fmt_line($h, $style{"terse"}[1], $level+1);
  626.     }
  627.     $lastnext = $op->next;
  628.     print concise_op($op, $level, $style{"terse"}[0]);
  629. }
  630.  
  631. sub tree {
  632.     my $op = shift;
  633.     my $level = shift;
  634.     my $style = $tree_decorations[$tree_style];
  635.     my($space, $single, $kids, $kid, $nokid, $last, $lead, $size) = @$style;
  636.     my $name = concise_op($op, $level, $treefmt);
  637.     if (not $op->flags & OPf_KIDS) {
  638.     return $name . "\n";
  639.     }
  640.     my @lines;
  641.     for (my $kid = $op->first; $$kid; $kid = $kid->sibling) {
  642.     push @lines, tree($kid, $level+1);
  643.     }
  644.     my $i;
  645.     for ($i = $#lines; substr($lines[$i], 0, 1) eq " "; $i--) {
  646.     $lines[$i] = $space . $lines[$i];
  647.     }
  648.     if ($i > 0) {
  649.     $lines[$i] = $last . $lines[$i];
  650.     while ($i-- > 1) {
  651.         if (substr($lines[$i], 0, 1) eq " ") {
  652.         $lines[$i] = $nokid . $lines[$i];
  653.         } else {
  654.         $lines[$i] = $kid . $lines[$i];        
  655.         }
  656.     }
  657.     $lines[$i] = $kids . $lines[$i];
  658.     } else {
  659.     $lines[0] = $single . $lines[0];
  660.     }
  661.     return("$name$lead" . shift @lines,
  662.            map(" " x (length($name)+$size) . $_, @lines));
  663. }
  664.  
  665. # *** Warning: fragile kludge ahead ***
  666. # Because the B::* modules run in the same interpreter as the code
  667. # they're compiling, their presence tends to distort the view we have
  668. # of the code we're looking at. In particular, perl gives sequence
  669. # numbers to both OPs in general and COPs in particular. If the
  670. # program we're looking at were run on its own, these numbers would
  671. # start at 1. Because all of B::Concise and all the modules it uses
  672. # are compiled first, though, by the time we get to the user's program
  673. # the sequence numbers are alreay at pretty high numbers, which would
  674. # be distracting if you're trying to tell OPs apart. Therefore we'd
  675. # like to subtract an offset from all the sequence numbers we display,
  676. # to restore the simpler view of the world. The trick is to know what
  677. # that offset will be, when we're still compiling B::Concise!  If we
  678. # hardcoded a value, it would have to change every time B::Concise or
  679. # other modules we use do. To help a little, what we do here is
  680. # compile a little code at the end of the module, and compute the base
  681. # sequence number for the user's program as being a small offset
  682. # later, so all we have to worry about are changes in the offset.
  683. # (Note that we now only play this game with COP sequence numbers. OP
  684. # sequence numbers aren't used to refer to OPs from a distance, and
  685. # they don't have much significance, so we just generate our own
  686. # sequence numbers which are easier to control. This way we also don't
  687. # stand in the way of a possible future removal of OP sequence
  688. # numbers).
  689.  
  690. # When you say "perl -MO=Concise -e '$a'", the output should look like:
  691.  
  692. # 4  <@> leave[t1] vKP/REFC ->(end)
  693. # 1     <0> enter ->2
  694.  #^ smallest OP sequence number should be 1
  695. # 2     <;> nextstate(main 1 -e:1) v ->3
  696.  #                         ^ smallest COP sequence number should be 1
  697. # -     <1> ex-rv2sv vK/1 ->4
  698. # 3        <$> gvsv(*a) s ->4
  699.  
  700. # If the second of the marked numbers there isn't 1, it means you need
  701. # to update the corresponding magic number in the next line.
  702. # Remember, this needs to stay the last things in the module.
  703.  
  704. # Why is this different for MacOS?  Does it matter?
  705. my $cop_seq_mnum = $^O eq 'MacOS' ? 12 : 11;
  706. $cop_seq_base = svref_2object(eval 'sub{0;}')->START->cop_seq + $cop_seq_mnum;
  707.  
  708. 1;
  709.  
  710. __END__
  711.  
  712. =head1 NAME
  713.  
  714. B::Concise - Walk Perl syntax tree, printing concise info about ops
  715.  
  716. =head1 SYNOPSIS
  717.  
  718.     perl -MO=Concise[,OPTIONS] foo.pl
  719.  
  720.     use B::Concise qw(set_style add_callback);
  721.  
  722. =head1 DESCRIPTION
  723.  
  724. This compiler backend prints the internal OPs of a Perl program's syntax
  725. tree in one of several space-efficient text formats suitable for debugging
  726. the inner workings of perl or other compiler backends. It can print OPs in
  727. the order they appear in the OP tree, in the order they will execute, or
  728. in a text approximation to their tree structure, and the format of the
  729. information displyed is customizable. Its function is similar to that of
  730. perl's B<-Dx> debugging flag or the B<B::Terse> module, but it is more
  731. sophisticated and flexible.
  732.  
  733. =head1 EXAMPLE
  734.  
  735. Here's is a short example of output, using the default formatting
  736. conventions :
  737.  
  738.     % perl -MO=Concise -e '$a = $b + 42'
  739.     8  <@> leave[1 ref] vKP/REFC ->(end)
  740.     1     <0> enter ->2
  741.     2     <;> nextstate(main 1 -e:1) v ->3
  742.     7     <2> sassign vKS/2 ->8
  743.     5        <2> add[t1] sK/2 ->6
  744.     -           <1> ex-rv2sv sK/1 ->4
  745.     3              <$> gvsv(*b) s ->4
  746.     4           <$> const(IV 42) s ->5
  747.     -        <1> ex-rv2sv sKRM*/1 ->7
  748.     6           <$> gvsv(*a) s ->7
  749.  
  750. Each line corresponds to an operator. Null ops appear as C<ex-opname>,
  751. where I<opname> is the op that has been optimized away by perl.
  752.  
  753. The number on the first row indicates the op's sequence number. It's
  754. given in base 36 by default.
  755.  
  756. The symbol between angle brackets indicates the op's type : for example,
  757. <2> is a BINOP, <@> a LISTOP, etc. (see L</"OP class abbreviations">).
  758.  
  759. The opname may be followed by op-specific information in parentheses
  760. (e.g. C<gvsv(*b)>), and by targ information in brackets (e.g.
  761. C<leave[t1]>).
  762.  
  763. Next come the op flags. The common flags are listed below
  764. (L</"OP flags abbreviations">). The private flags follow, separated
  765. by a slash. For example, C<vKP/REFC> means that the leave op has
  766. public flags OPf_WANT_VOID, OPf_KIDS, and OPf_PARENS, and the private
  767. flag OPpREFCOUNTED.
  768.  
  769. Finally an arrow points to the sequence number of the next op.
  770.  
  771. =head1 OPTIONS
  772.  
  773. Arguments that don't start with a hyphen are taken to be the names of
  774. subroutines to print the OPs of; if no such functions are specified,
  775. the main body of the program (outside any subroutines, and not
  776. including use'd or require'd files) is printed. Passing C<BEGIN>,
  777. C<CHECK>, C<INIT>, or C<END> will cause all of the corresponding
  778. special blocks to be printed.
  779.  
  780. =over 4
  781.  
  782. =item B<-basic>
  783.  
  784. Print OPs in the order they appear in the OP tree (a preorder
  785. traversal, starting at the root). The indentation of each OP shows its
  786. level in the tree.  This mode is the default, so the flag is included
  787. simply for completeness.
  788.  
  789. =item B<-exec>
  790.  
  791. Print OPs in the order they would normally execute (for the majority
  792. of constructs this is a postorder traversal of the tree, ending at the
  793. root). In most cases the OP that usually follows a given OP will
  794. appear directly below it; alternate paths are shown by indentation. In
  795. cases like loops when control jumps out of a linear path, a 'goto'
  796. line is generated.
  797.  
  798. =item B<-tree>
  799.  
  800. Print OPs in a text approximation of a tree, with the root of the tree
  801. at the left and 'left-to-right' order of children transformed into
  802. 'top-to-bottom'. Because this mode grows both to the right and down,
  803. it isn't suitable for large programs (unless you have a very wide
  804. terminal).
  805.  
  806. =item B<-compact>
  807.  
  808. Use a tree format in which the minimum amount of space is used for the
  809. lines connecting nodes (one character in most cases). This squeezes out
  810. a few precious columns of screen real estate.
  811.  
  812. =item B<-loose>
  813.  
  814. Use a tree format that uses longer edges to separate OP nodes. This format
  815. tends to look better than the compact one, especially in ASCII, and is
  816. the default.
  817.  
  818. =item B<-vt>
  819.  
  820. Use tree connecting characters drawn from the VT100 line-drawing set.
  821. This looks better if your terminal supports it.
  822.  
  823. =item B<-ascii>
  824.  
  825. Draw the tree with standard ASCII characters like C<+> and C<|>. These don't
  826. look as clean as the VT100 characters, but they'll work with almost any
  827. terminal (or the horizontal scrolling mode of less(1)) and are suitable
  828. for text documentation or email. This is the default.
  829.  
  830. =item B<-main>
  831.  
  832. Include the main program in the output, even if subroutines were also
  833. specified.
  834.  
  835. =item B<-base>I<n>
  836.  
  837. Print OP sequence numbers in base I<n>. If I<n> is greater than 10, the
  838. digit for 11 will be 'a', and so on. If I<n> is greater than 36, the digit
  839. for 37 will be 'A', and so on until 62. Values greater than 62 are not
  840. currently supported. The default is 36.
  841.  
  842. =item B<-bigendian>
  843.  
  844. Print sequence numbers with the most significant digit first. This is the
  845. usual convention for Arabic numerals, and the default.
  846.  
  847. =item B<-littleendian>
  848.  
  849. Print seqence numbers with the least significant digit first.
  850.  
  851. =item B<-concise>
  852.  
  853. Use the author's favorite set of formatting conventions. This is the
  854. default, of course.
  855.  
  856. =item B<-terse>
  857.  
  858. Use formatting conventions that emulate the output of B<B::Terse>. The
  859. basic mode is almost indistinguishable from the real B<B::Terse>, and the
  860. exec mode looks very similar, but is in a more logical order and lacks
  861. curly brackets. B<B::Terse> doesn't have a tree mode, so the tree mode
  862. is only vaguely reminiscient of B<B::Terse>.
  863.  
  864. =item B<-linenoise>
  865.  
  866. Use formatting conventions in which the name of each OP, rather than being
  867. written out in full, is represented by a one- or two-character abbreviation.
  868. This is mainly a joke.
  869.  
  870. =item B<-debug>
  871.  
  872. Use formatting conventions reminiscient of B<B::Debug>; these aren't
  873. very concise at all.
  874.  
  875. =item B<-env>
  876.  
  877. Use formatting conventions read from the environment variables
  878. C<B_CONCISE_FORMAT>, C<B_CONCISE_GOTO_FORMAT>, and C<B_CONCISE_TREE_FORMAT>.
  879.  
  880. =back
  881.  
  882. =head1 FORMATTING SPECIFICATIONS
  883.  
  884. For each general style ('concise', 'terse', 'linenoise', etc.) there are
  885. three specifications: one of how OPs should appear in the basic or exec
  886. modes, one of how 'goto' lines should appear (these occur in the exec
  887. mode only), and one of how nodes should appear in tree mode. Each has the
  888. same format, described below. Any text that doesn't match a special
  889. pattern is copied verbatim.
  890.  
  891. =over 4
  892.  
  893. =item B<(x(>I<exec_text>B<;>I<basic_text>B<)x)>
  894.  
  895. Generates I<exec_text> in exec mode, or I<basic_text> in basic mode.
  896.  
  897. =item B<(*(>I<text>B<)*)>
  898.  
  899. Generates one copy of I<text> for each indentation level.
  900.  
  901. =item B<(*(>I<text1>B<;>I<text2>B<)*)>
  902.  
  903. Generates one fewer copies of I<text1> than the indentation level, followed
  904. by one copy of I<text2> if the indentation level is more than 0.
  905.  
  906. =item B<(?(>I<text1>B<#>I<var>I<Text2>B<)?)>
  907.  
  908. If the value of I<var> is true (not empty or zero), generates the
  909. value of I<var> surrounded by I<text1> and I<Text2>, otherwise
  910. nothing.
  911.  
  912. =item B<#>I<var>
  913.  
  914. Generates the value of the variable I<var>.
  915.  
  916. =item B<#>I<var>I<N>
  917.  
  918. Generates the value of I<var>, left jutified to fill I<N> spaces.
  919.  
  920. =item B<~>
  921.  
  922. Any number of tildes and surrounding whitespace will be collapsed to
  923. a single space.
  924.  
  925. =back
  926.  
  927. The following variables are recognized:
  928.  
  929. =over 4
  930.  
  931. =item B<#addr>
  932.  
  933. The address of the OP, in hexidecimal.
  934.  
  935. =item B<#arg>
  936.  
  937. The OP-specific information of the OP (such as the SV for an SVOP, the
  938. non-local exit pointers for a LOOP, etc.) enclosed in paretheses.
  939.  
  940. =item B<#class>
  941.  
  942. The B-determined class of the OP, in all caps.
  943.  
  944. =item B<#classsym>
  945.  
  946. A single symbol abbreviating the class of the OP.
  947.  
  948. =item B<#coplabel>
  949.  
  950. The label of the statement or block the OP is the start of, if any.
  951.  
  952. =item B<#exname>
  953.  
  954. The name of the OP, or 'ex-foo' if the OP is a null that used to be a foo.
  955.  
  956. =item B<#extarg>
  957.  
  958. The target of the OP, or nothing for a nulled OP.
  959.  
  960. =item B<#firstaddr>
  961.  
  962. The address of the OP's first child, in hexidecimal.
  963.  
  964. =item B<#flags>
  965.  
  966. The OP's flags, abbreviated as a series of symbols.
  967.  
  968. =item B<#flagval>
  969.  
  970. The numeric value of the OP's flags.
  971.  
  972. =item B<#hyphseq>
  973.  
  974. The sequence number of the OP, or a hyphen if it doesn't have one.
  975.  
  976. =item B<#label>
  977.  
  978. 'NEXT', 'LAST', or 'REDO' if the OP is a target of one of those in exec
  979. mode, or empty otherwise.
  980.  
  981. =item B<#lastaddr>
  982.  
  983. The address of the OP's last child, in hexidecimal.
  984.  
  985. =item B<#name>
  986.  
  987. The OP's name.
  988.  
  989. =item B<#NAME>
  990.  
  991. The OP's name, in all caps.
  992.  
  993. =item B<#next>
  994.  
  995. The sequence number of the OP's next OP.
  996.  
  997. =item B<#nextaddr>
  998.  
  999. The address of the OP's next OP, in hexidecimal.
  1000.  
  1001. =item B<#noise>
  1002.  
  1003. A one- or two-character abbreviation for the OP's name.
  1004.  
  1005. =item B<#private>
  1006.  
  1007. The OP's private flags, rendered with abbreviated names if possible.
  1008.  
  1009. =item B<#privval>
  1010.  
  1011. The numeric value of the OP's private flags.
  1012.  
  1013. =item B<#seq>
  1014.  
  1015. The sequence number of the OP. Note that this is now a sequence number
  1016. generated by B::Concise, rather than the real op_seq value (for which
  1017. see B<#seqnum>).
  1018.  
  1019. =item B<#seqnum>
  1020.  
  1021. The real sequence number of the OP, as a regular number and not adjusted
  1022. to be relative to the start of the real program. (This will generally be
  1023. a fairly large number because all of B<B::Concise> is compiled before
  1024. your program is).
  1025.  
  1026. =item B<#sibaddr>
  1027.  
  1028. The address of the OP's next youngest sibling, in hexidecimal.
  1029.  
  1030. =item B<#svaddr>
  1031.  
  1032. The address of the OP's SV, if it has an SV, in hexidecimal.
  1033.  
  1034. =item B<#svclass>
  1035.  
  1036. The class of the OP's SV, if it has one, in all caps (e.g., 'IV').
  1037.  
  1038. =item B<#svval>
  1039.  
  1040. The value of the OP's SV, if it has one, in a short human-readable format.
  1041.  
  1042. =item B<#targ>
  1043.  
  1044. The numeric value of the OP's targ.
  1045.  
  1046. =item B<#targarg>
  1047.  
  1048. The name of the variable the OP's targ refers to, if any, otherwise the
  1049. letter t followed by the OP's targ in decimal.
  1050.  
  1051. =item B<#targarglife>
  1052.  
  1053. Same as B<#targarg>, but followed by the COP sequence numbers that delimit
  1054. the variable's lifetime (or 'end' for a variable in an open scope) for a
  1055. variable.
  1056.  
  1057. =item B<#typenum>
  1058.  
  1059. The numeric value of the OP's type, in decimal.
  1060.  
  1061. =back
  1062.  
  1063. =head1 ABBREVIATIONS
  1064.  
  1065. =head2 OP flags abbreviations
  1066.  
  1067.     v      OPf_WANT_VOID    Want nothing (void context)
  1068.     s      OPf_WANT_SCALAR  Want single value (scalar context)
  1069.     l      OPf_WANT_LIST    Want list of any length (list context)
  1070.     K      OPf_KIDS         There is a firstborn child.
  1071.     P      OPf_PARENS       This operator was parenthesized.
  1072.                              (Or block needs explicit scope entry.)
  1073.     R      OPf_REF          Certified reference.
  1074.                              (Return container, not containee).
  1075.     M      OPf_MOD          Will modify (lvalue).
  1076.     S      OPf_STACKED      Some arg is arriving on the stack.
  1077.     *      OPf_SPECIAL      Do something weird for this op (see op.h)
  1078.  
  1079. =head2 OP class abbreviations
  1080.  
  1081.     0      OP (aka BASEOP)  An OP with no children
  1082.     1      UNOP             An OP with one child
  1083.     2      BINOP            An OP with two children
  1084.     |      LOGOP            A control branch OP
  1085.     @      LISTOP           An OP that could have lots of children
  1086.     /      PMOP             An OP with a regular expression
  1087.     $      SVOP             An OP with an SV
  1088.     "      PVOP             An OP with a string
  1089.     {      LOOP             An OP that holds pointers for a loop
  1090.     ;      COP              An OP that marks the start of a statement
  1091.     #      PADOP            An OP with a GV on the pad
  1092.  
  1093. =head1 Using B::Concise outside of the O framework
  1094.  
  1095. It is possible to extend B<B::Concise> by using it outside of the B<O>
  1096. framework and providing new styles and new variables.
  1097.  
  1098.     use B::Concise qw(set_style add_callback);
  1099.     set_style($format, $gotofmt, $treefmt);
  1100.     add_callback
  1101.     (
  1102.         sub
  1103.         {
  1104.             my ($h, $op, $level, $format) = @_;
  1105.             $h->{variable} = some_func($op);
  1106.         }
  1107.     );
  1108.     B::Concise::compile(@options)->();
  1109.  
  1110. You can specify a style by calling the B<set_style> subroutine.  If you
  1111. have a new variable in your style, or you want to change the value of an
  1112. existing variable, you will need to add a callback to specify the value
  1113. for that variable.
  1114.  
  1115. This is done by calling B<add_callback> passing references to any
  1116. callback subroutines.  The subroutines are called in the same order as
  1117. they are added.  Each subroutine is passed four parameters.  These are a
  1118. reference to a hash, the keys of which are the names of the variables
  1119. and the values of which are their values, the op, the level and the
  1120. format.
  1121.  
  1122. To define your own variables, simply add them to the hash, or change
  1123. existing values if you need to.  The level and format are passed in as
  1124. references to scalars, but it is unlikely that they will need to be
  1125. changed or even used.
  1126.  
  1127. To switch back to one of the standard styles like C<concise> or
  1128. C<terse>, use C<set_style_standard>.
  1129.  
  1130. To see the output, call the subroutine returned by B<compile> in the
  1131. same way that B<O> does.
  1132.  
  1133. =head1 AUTHOR
  1134.  
  1135. Stephen McCamant, E<lt>smcc@CSUA.Berkeley.EDUE<gt>.
  1136.  
  1137. =cut
  1138.