home *** CD-ROM | disk | FTP | other *** search
/ PC World 2005 June / PCWorld_2005-06_cd.bin / software / vyzkuste / firewally / firewally.exe / framework-2.3.exe / Benchmark.pm < prev    next >
Text File  |  2003-11-07  |  27KB  |  1,011 lines
  1. package Benchmark;
  2.  
  3. use strict;
  4.  
  5.  
  6. =head1 NAME
  7.  
  8. Benchmark - benchmark running times of Perl code
  9.  
  10. =head1 SYNOPSIS
  11.  
  12.     use Benchmark qw(:all) ;
  13.  
  14.     timethis ($count, "code");
  15.  
  16.     # Use Perl code in strings...
  17.     timethese($count, {
  18.     'Name1' => '...code1...',
  19.     'Name2' => '...code2...',
  20.     });
  21.  
  22.     # ... or use subroutine references.
  23.     timethese($count, {
  24.     'Name1' => sub { ...code1... },
  25.     'Name2' => sub { ...code2... },
  26.     });
  27.  
  28.     # cmpthese can be used both ways as well
  29.     cmpthese($count, {
  30.     'Name1' => '...code1...',
  31.     'Name2' => '...code2...',
  32.     });
  33.  
  34.     cmpthese($count, {
  35.     'Name1' => sub { ...code1... },
  36.     'Name2' => sub { ...code2... },
  37.     });
  38.  
  39.     # ...or in two stages
  40.     $results = timethese($count, 
  41.         {
  42.         'Name1' => sub { ...code1... },
  43.         'Name2' => sub { ...code2... },
  44.         },
  45.     'none'
  46.     );
  47.     cmpthese( $results ) ;
  48.  
  49.     $t = timeit($count, '...other code...')
  50.     print "$count loops of other code took:",timestr($t),"\n";
  51.  
  52.     $t = countit($time, '...other code...')
  53.     $count = $t->iters ;
  54.     print "$count loops of other code took:",timestr($t),"\n";
  55.  
  56.     # enable hires wallclock timing if possible
  57.     use Benchmark ':hireswallclock';
  58.  
  59. =head1 DESCRIPTION
  60.  
  61. The Benchmark module encapsulates a number of routines to help you
  62. figure out how long it takes to execute some code.
  63.  
  64. timethis - run a chunk of code several times
  65.  
  66. timethese - run several chunks of code several times
  67.  
  68. cmpthese - print results of timethese as a comparison chart
  69.  
  70. timeit - run a chunk of code and see how long it goes
  71.  
  72. countit - see how many times a chunk of code runs in a given time
  73.  
  74.  
  75. =head2 Methods
  76.  
  77. =over 10
  78.  
  79. =item new
  80.  
  81. Returns the current time.   Example:
  82.  
  83.     use Benchmark;
  84.     $t0 = new Benchmark;
  85.     # ... your code here ...
  86.     $t1 = new Benchmark;
  87.     $td = timediff($t1, $t0);
  88.     print "the code took:",timestr($td),"\n";
  89.  
  90. =item debug
  91.  
  92. Enables or disable debugging by setting the C<$Benchmark::Debug> flag:
  93.  
  94.     debug Benchmark 1;
  95.     $t = timeit(10, ' 5 ** $Global ');
  96.     debug Benchmark 0;
  97.  
  98. =item iters
  99.  
  100. Returns the number of iterations.
  101.  
  102. =back
  103.  
  104. =head2 Standard Exports
  105.  
  106. The following routines will be exported into your namespace
  107. if you use the Benchmark module:
  108.  
  109. =over 10
  110.  
  111. =item timeit(COUNT, CODE)
  112.  
  113. Arguments: COUNT is the number of times to run the loop, and CODE is
  114. the code to run.  CODE may be either a code reference or a string to
  115. be eval'd; either way it will be run in the caller's package.
  116.  
  117. Returns: a Benchmark object.
  118.  
  119. =item timethis ( COUNT, CODE, [ TITLE, [ STYLE ]] )
  120.  
  121. Time COUNT iterations of CODE. CODE may be a string to eval or a
  122. code reference; either way the CODE will run in the caller's package.
  123. Results will be printed to STDOUT as TITLE followed by the times.
  124. TITLE defaults to "timethis COUNT" if none is provided. STYLE
  125. determines the format of the output, as described for timestr() below.
  126.  
  127. The COUNT can be zero or negative: this means the I<minimum number of
  128. CPU seconds> to run.  A zero signifies the default of 3 seconds.  For
  129. example to run at least for 10 seconds:
  130.  
  131.     timethis(-10, $code)
  132.  
  133. or to run two pieces of code tests for at least 3 seconds:
  134.  
  135.     timethese(0, { test1 => '...', test2 => '...'})
  136.  
  137. CPU seconds is, in UNIX terms, the user time plus the system time of
  138. the process itself, as opposed to the real (wallclock) time and the
  139. time spent by the child processes.  Less than 0.1 seconds is not
  140. accepted (-0.01 as the count, for example, will cause a fatal runtime
  141. exception).
  142.  
  143. Note that the CPU seconds is the B<minimum> time: CPU scheduling and
  144. other operating system factors may complicate the attempt so that a
  145. little bit more time is spent.  The benchmark output will, however,
  146. also tell the number of C<$code> runs/second, which should be a more
  147. interesting number than the actually spent seconds.
  148.  
  149. Returns a Benchmark object.
  150.  
  151. =item timethese ( COUNT, CODEHASHREF, [ STYLE ] )
  152.  
  153. The CODEHASHREF is a reference to a hash containing names as keys
  154. and either a string to eval or a code reference for each value.
  155. For each (KEY, VALUE) pair in the CODEHASHREF, this routine will
  156. call
  157.  
  158.     timethis(COUNT, VALUE, KEY, STYLE)
  159.  
  160. The routines are called in string comparison order of KEY.
  161.  
  162. The COUNT can be zero or negative, see timethis().
  163.  
  164. Returns a hash of Benchmark objects, keyed by name.
  165.  
  166. =item timediff ( T1, T2 )
  167.  
  168. Returns the difference between two Benchmark times as a Benchmark
  169. object suitable for passing to timestr().
  170.  
  171. =item timestr ( TIMEDIFF, [ STYLE, [ FORMAT ] ] )
  172.  
  173. Returns a string that formats the times in the TIMEDIFF object in
  174. the requested STYLE. TIMEDIFF is expected to be a Benchmark object
  175. similar to that returned by timediff().
  176.  
  177. STYLE can be any of 'all', 'none', 'noc', 'nop' or 'auto'. 'all' shows
  178. each of the 5 times available ('wallclock' time, user time, system time,
  179. user time of children, and system time of children). 'noc' shows all
  180. except the two children times. 'nop' shows only wallclock and the
  181. two children times. 'auto' (the default) will act as 'all' unless
  182. the children times are both zero, in which case it acts as 'noc'.
  183. 'none' prevents output.
  184.  
  185. FORMAT is the L<printf(3)>-style format specifier (without the
  186. leading '%') to use to print the times. It defaults to '5.2f'.
  187.  
  188. =back
  189.  
  190. =head2 Optional Exports
  191.  
  192. The following routines will be exported into your namespace
  193. if you specifically ask that they be imported:
  194.  
  195. =over 10
  196.  
  197. =item clearcache ( COUNT )
  198.  
  199. Clear the cached time for COUNT rounds of the null loop.
  200.  
  201. =item clearallcache ( )
  202.  
  203. Clear all cached times.
  204.  
  205. =item cmpthese ( COUNT, CODEHASHREF, [ STYLE ] )
  206.  
  207. =item cmpthese ( RESULTSHASHREF, [ STYLE ] )
  208.  
  209. Optionally calls timethese(), then outputs comparison chart.  This:
  210.  
  211.     cmpthese( -1, { a => "++\$i", b => "\$i *= 2" } ) ;
  212.  
  213. outputs a chart like:
  214.  
  215.            Rate    b    a
  216.     b 2831802/s   -- -61%
  217.     a 7208959/s 155%   --
  218.  
  219. This chart is sorted from slowest to fastest, and shows the percent speed
  220. difference between each pair of tests.
  221.  
  222. c<cmpthese> can also be passed the data structure that timethese() returns:
  223.  
  224.     $results = timethese( -1, { a => "++\$i", b => "\$i *= 2" } ) ;
  225.     cmpthese( $results );
  226.  
  227. in case you want to see both sets of results.
  228.  
  229. Returns a reference to an ARRAY of rows, each row is an ARRAY of cells from the
  230. above chart, including labels. This:
  231.  
  232.     my $rows = cmpthese( -1, { a => '++$i', b => '$i *= 2' }, "none" );
  233.  
  234. returns a data structure like:
  235.  
  236.     [
  237.         [ '',       'Rate',   'b',    'a' ],
  238.         [ 'b', '2885232/s',  '--', '-59%' ],
  239.         [ 'a', '7099126/s', '146%',  '--' ],
  240.     ]
  241.  
  242. B<NOTE>: This result value differs from previous versions, which returned
  243. the C<timethese()> result structure.  If you want that, just use the two
  244. statement C<timethese>...C<cmpthese> idiom shown above.
  245.  
  246. Incidently, note the variance in the result values between the two examples;
  247. this is typical of benchmarking.  If this were a real benchmark, you would
  248. probably want to run a lot more iterations.
  249.  
  250. =item countit(TIME, CODE)
  251.  
  252. Arguments: TIME is the minimum length of time to run CODE for, and CODE is
  253. the code to run.  CODE may be either a code reference or a string to
  254. be eval'd; either way it will be run in the caller's package.
  255.  
  256. TIME is I<not> negative.  countit() will run the loop many times to
  257. calculate the speed of CODE before running it for TIME.  The actual
  258. time run for will usually be greater than TIME due to system clock
  259. resolution, so it's best to look at the number of iterations divided
  260. by the times that you are concerned with, not just the iterations.
  261.  
  262. Returns: a Benchmark object.
  263.  
  264. =item disablecache ( )
  265.  
  266. Disable caching of timings for the null loop. This will force Benchmark
  267. to recalculate these timings for each new piece of code timed.
  268.  
  269. =item enablecache ( )
  270.  
  271. Enable caching of timings for the null loop. The time taken for COUNT
  272. rounds of the null loop will be calculated only once for each
  273. different COUNT used.
  274.  
  275. =item timesum ( T1, T2 )
  276.  
  277. Returns the sum of two Benchmark times as a Benchmark object suitable
  278. for passing to timestr().
  279.  
  280. =back
  281.  
  282. =head2 :hireswallclock
  283.  
  284. If the Time::HiRes module has been installed, you can specify the
  285. special tag C<:hireswallclock> for Benchmark (if Time::HiRes is not
  286. available, the tag will be silently ignored).  This tag will cause the
  287. wallclock time to be measured in microseconds, instead of integer
  288. seconds.  Note though that the speed computations are still conducted
  289. in CPU time, not wallclock time.
  290.  
  291. =head1 NOTES
  292.  
  293. The data is stored as a list of values from the time and times
  294. functions:
  295.  
  296.       ($real, $user, $system, $children_user, $children_system, $iters)
  297.  
  298. in seconds for the whole loop (not divided by the number of rounds).
  299.  
  300. The timing is done using time(3) and times(3).
  301.  
  302. Code is executed in the caller's package.
  303.  
  304. The time of the null loop (a loop with the same
  305. number of rounds but empty loop body) is subtracted
  306. from the time of the real loop.
  307.  
  308. The null loop times can be cached, the key being the
  309. number of rounds. The caching can be controlled using
  310. calls like these:
  311.  
  312.     clearcache($key);
  313.     clearallcache();
  314.  
  315.     disablecache();
  316.     enablecache();
  317.  
  318. Caching is off by default, as it can (usually slightly) decrease
  319. accuracy and does not usually noticably affect runtimes.
  320.  
  321. =head1 EXAMPLES
  322.  
  323. For example,
  324.  
  325.     use Benchmark qw( cmpthese ) ;
  326.     $x = 3;
  327.     cmpthese( -5, {
  328.         a => sub{$x*$x},
  329.         b => sub{$x**2},
  330.     } );
  331.  
  332. outputs something like this:
  333.  
  334.    Benchmark: running a, b, each for at least 5 CPU seconds...
  335.           Rate    b    a
  336.    b 1559428/s   -- -62%
  337.    a 4152037/s 166%   --
  338.  
  339.  
  340. while 
  341.  
  342.     use Benchmark qw( timethese cmpthese ) ;
  343.     $x = 3;
  344.     $r = timethese( -5, {
  345.         a => sub{$x*$x},
  346.         b => sub{$x**2},
  347.     } );
  348.     cmpthese $r;
  349.  
  350. outputs something like this:
  351.  
  352.     Benchmark: running a, b, each for at least 5 CPU seconds...
  353.              a: 10 wallclock secs ( 5.14 usr +  0.13 sys =  5.27 CPU) @ 3835055.60/s (n=20210743)
  354.              b:  5 wallclock secs ( 5.41 usr +  0.00 sys =  5.41 CPU) @ 1574944.92/s (n=8520452)
  355.            Rate    b    a
  356.     b 1574945/s   -- -59%
  357.     a 3835056/s 144%   --
  358.  
  359.  
  360. =head1 INHERITANCE
  361.  
  362. Benchmark inherits from no other class, except of course
  363. for Exporter.
  364.  
  365. =head1 CAVEATS
  366.  
  367. Comparing eval'd strings with code references will give you
  368. inaccurate results: a code reference will show a slightly slower
  369. execution time than the equivalent eval'd string.
  370.  
  371. The real time timing is done using time(2) and
  372. the granularity is therefore only one second.
  373.  
  374. Short tests may produce negative figures because perl
  375. can appear to take longer to execute the empty loop
  376. than a short test; try:
  377.  
  378.     timethis(100,'1');
  379.  
  380. The system time of the null loop might be slightly
  381. more than the system time of the loop with the actual
  382. code and therefore the difference might end up being E<lt> 0.
  383.  
  384. =head1 SEE ALSO
  385.  
  386. L<Devel::DProf> - a Perl code profiler
  387.  
  388. =head1 AUTHORS
  389.  
  390. Jarkko Hietaniemi <F<jhi@iki.fi>>, Tim Bunce <F<Tim.Bunce@ig.co.uk>>
  391.  
  392. =head1 MODIFICATION HISTORY
  393.  
  394. September 8th, 1994; by Tim Bunce.
  395.  
  396. March 28th, 1997; by Hugo van der Sanden: added support for code
  397. references and the already documented 'debug' method; revamped
  398. documentation.
  399.  
  400. April 04-07th, 1997: by Jarkko Hietaniemi, added the run-for-some-time
  401. functionality.
  402.  
  403. September, 1999; by Barrie Slaymaker: math fixes and accuracy and 
  404. efficiency tweaks.  Added cmpthese().  A result is now returned from 
  405. timethese().  Exposed countit() (was runfor()).
  406.  
  407. December, 2001; by Nicholas Clark: make timestr() recognise the style 'none'
  408. and return an empty string. If cmpthese is calling timethese, make it pass the
  409. style in. (so that 'none' will suppress output). Make sub new dump its
  410. debugging output to STDERR, to be consistent with everything else.
  411. All bugs found while writing a regression test.
  412.  
  413. September, 2002; by Jarkko Hietaniemi: add ':hireswallclock' special tag.
  414.  
  415. =cut
  416.  
  417. # evaluate something in a clean lexical environment
  418. sub _doeval { no strict;  eval shift }
  419.  
  420. #
  421. # put any lexicals at file scope AFTER here
  422. #
  423.  
  424. use Carp;
  425. use Exporter;
  426.  
  427. our(@ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS, $VERSION);
  428.  
  429. @ISA=qw(Exporter);
  430. @EXPORT=qw(timeit timethis timethese timediff timestr);
  431. @EXPORT_OK=qw(timesum cmpthese countit
  432.           clearcache clearallcache disablecache enablecache);
  433. %EXPORT_TAGS=( all => [ @EXPORT, @EXPORT_OK ] ) ;
  434.  
  435. $VERSION = 1.051;
  436.  
  437. # --- ':hireswallclock' special handling
  438.  
  439. my $hirestime;
  440.  
  441. sub mytime () { time }
  442.  
  443. init();
  444.  
  445. sub BEGIN {
  446.     if (eval 'require Time::HiRes') {
  447.     import Time::HiRes qw(time);
  448.     $hirestime = \&Time::HiRes::time;
  449.     }
  450. }
  451.  
  452. sub import {
  453.     my $class = shift;
  454.     if (grep { $_ eq ":hireswallclock" } @_) {
  455.     @_ = grep { $_ ne ":hireswallclock" } @_;
  456.     *mytime = $hirestime if defined $hirestime;
  457.     }
  458.     Benchmark->export_to_level(1, $class, @_);
  459. }
  460.  
  461. our($Debug, $Min_Count, $Min_CPU, $Default_Format, $Default_Style,
  462.     %_Usage, %Cache, $Do_Cache);
  463.  
  464. sub init {
  465.     $Debug = 0;
  466.     $Min_Count = 4;
  467.     $Min_CPU   = 0.4;
  468.     $Default_Format = '5.2f';
  469.     $Default_Style = 'auto';
  470.     # The cache can cause a slight loss of sys time accuracy. If a
  471.     # user does many tests (>10) with *very* large counts (>10000)
  472.     # or works on a very slow machine the cache may be useful.
  473.     disablecache();
  474.     clearallcache();
  475. }
  476.  
  477. sub debug { $Debug = ($_[1] != 0); }
  478.  
  479. sub usage { 
  480.     my $calling_sub = (caller(1))[3];
  481.     $calling_sub =~ s/^Benchmark:://;
  482.     return $_Usage{$calling_sub} || '';
  483. }
  484.  
  485. # The cache needs two branches: 's' for strings and 'c' for code.  The
  486. # empty loop is different in these two cases.
  487.  
  488. $_Usage{clearcache} = <<'USAGE';
  489. usage: clearcache($count);
  490. USAGE
  491.  
  492. sub clearcache    { 
  493.     die usage unless @_ == 1;
  494.     delete $Cache{"$_[0]c"}; delete $Cache{"$_[0]s"}; 
  495. }
  496.  
  497. $_Usage{clearallcache} = <<'USAGE';
  498. usage: clearallcache();
  499. USAGE
  500.  
  501. sub clearallcache { 
  502.     die usage if @_;
  503.     %Cache = (); 
  504. }
  505.  
  506. $_Usage{enablecache} = <<'USAGE';
  507. usage: enablecache();
  508. USAGE
  509.  
  510. sub enablecache   {
  511.     die usage if @_;
  512.     $Do_Cache = 1; 
  513. }
  514.  
  515. $_Usage{disablecache} = <<'USAGE';
  516. usage: disablecache();
  517. USAGE
  518.  
  519. sub disablecache  {
  520.     die usage if @_;
  521.     $Do_Cache = 0; 
  522. }
  523.  
  524.  
  525. # --- Functions to process the 'time' data type
  526.  
  527. sub new { my @t = (mytime, times, @_ == 2 ? $_[1] : 0);
  528.       print STDERR "new=@t\n" if $Debug;
  529.       bless \@t; }
  530.  
  531. sub cpu_p { my($r,$pu,$ps,$cu,$cs) = @{$_[0]}; $pu+$ps         ; }
  532. sub cpu_c { my($r,$pu,$ps,$cu,$cs) = @{$_[0]};         $cu+$cs ; }
  533. sub cpu_a { my($r,$pu,$ps,$cu,$cs) = @{$_[0]}; $pu+$ps+$cu+$cs ; }
  534. sub real  { my($r,$pu,$ps,$cu,$cs) = @{$_[0]}; $r              ; }
  535. sub iters { $_[0]->[5] ; }
  536.  
  537.  
  538. $_Usage{timediff} = <<'USAGE';
  539. usage: $result_diff = timediff($result1, $result2);
  540. USAGE
  541.  
  542. sub timediff {
  543.     my($a, $b) = @_;
  544.  
  545.     die usage unless ref $a and ref $b;
  546.  
  547.     my @r;
  548.     for (my $i=0; $i < @$a; ++$i) {
  549.     push(@r, $a->[$i] - $b->[$i]);
  550.     }
  551.     bless \@r;
  552. }
  553.  
  554. $_Usage{timesum} = <<'USAGE';
  555. usage: $sum = timesum($result1, $result2);
  556. USAGE
  557.  
  558. sub timesum {
  559.     my($a, $b) = @_;
  560.  
  561.     die usage unless ref $a and ref $b;
  562.  
  563.     my @r;
  564.     for (my $i=0; $i < @$a; ++$i) {
  565.      push(@r, $a->[$i] + $b->[$i]);
  566.     }
  567.     bless \@r;
  568. }
  569.  
  570.  
  571. $_Usage{timestr} = <<'USAGE';
  572. usage: $formatted_result = timestr($result1);
  573. USAGE
  574.  
  575. sub timestr {
  576.     my($tr, $style, $f) = @_;
  577.  
  578.     die usage unless ref $tr;
  579.  
  580.     my @t = @$tr;
  581.     warn "bad time value (@t)" unless @t==6;
  582.     my($r, $pu, $ps, $cu, $cs, $n) = @t;
  583.     my($pt, $ct, $tt) = ($tr->cpu_p, $tr->cpu_c, $tr->cpu_a);
  584.     $f = $Default_Format unless defined $f;
  585.     # format a time in the required style, other formats may be added here
  586.     $style ||= $Default_Style;
  587.     return '' if $style eq 'none';
  588.     $style = ($ct>0) ? 'all' : 'noc' if $style eq 'auto';
  589.     my $s = "@t $style"; # default for unknown style
  590.     my $w = $hirestime ? "%2g" : "%2d";
  591.     $s=sprintf("$w wallclock secs (%$f usr %$f sys + %$f cusr %$f csys = %$f CPU)",
  592.                 $r,$pu,$ps,$cu,$cs,$tt) if $style eq 'all';
  593.     $s=sprintf("$w wallclock secs (%$f usr + %$f sys = %$f CPU)",
  594.                 $r,$pu,$ps,$pt) if $style eq 'noc';
  595.     $s=sprintf("$w wallclock secs (%$f cusr + %$f csys = %$f CPU)",
  596.                 $r,$cu,$cs,$ct) if $style eq 'nop';
  597.     $s .= sprintf(" @ %$f/s (n=$n)", $n / ( $pu + $ps )) if $n && $pu+$ps;
  598.     $s;
  599. }
  600.  
  601. sub timedebug {
  602.     my($msg, $t) = @_;
  603.     print STDERR "$msg",timestr($t),"\n" if $Debug;
  604. }
  605.  
  606. # --- Functions implementing low-level support for timing loops
  607.  
  608. $_Usage{runloop} = <<'USAGE';
  609. usage: runloop($number, [$string | $coderef])
  610. USAGE
  611.  
  612. sub runloop {
  613.     my($n, $c) = @_;
  614.  
  615.     $n+=0; # force numeric now, so garbage won't creep into the eval
  616.     croak "negative loopcount $n" if $n<0;
  617.     confess usage unless defined $c;
  618.     my($t0, $t1, $td); # before, after, difference
  619.  
  620.     # find package of caller so we can execute code there
  621.     my($curpack) = caller(0);
  622.     my($i, $pack)= 0;
  623.     while (($pack) = caller(++$i)) {
  624.     last if $pack ne $curpack;
  625.     }
  626.  
  627.     my ($subcode, $subref);
  628.     if (ref $c eq 'CODE') {
  629.     $subcode = "sub { for (1 .. $n) { local \$_; package $pack; &\$c; } }";
  630.         $subref  = eval $subcode;
  631.     }
  632.     else {
  633.     $subcode = "sub { for (1 .. $n) { local \$_; package $pack; $c;} }";
  634.         $subref  = _doeval($subcode);
  635.     }
  636.     croak "runloop unable to compile '$c': $@\ncode: $subcode\n" if $@;
  637.     print STDERR "runloop $n '$subcode'\n" if $Debug;
  638.  
  639.     # Wait for the user timer to tick.  This makes the error range more like 
  640.     # -0.01, +0.  If we don't wait, then it's more like -0.01, +0.01.  This
  641.     # may not seem important, but it significantly reduces the chances of
  642.     # getting a too low initial $n in the initial, 'find the minimum' loop
  643.     # in &countit.  This, in turn, can reduce the number of calls to
  644.     # &runloop a lot, and thus reduce additive errors.
  645.     my $tbase = Benchmark->new(0)->[1];
  646.     while ( ( $t0 = Benchmark->new(0) )->[1] == $tbase ) {} ;
  647.     &$subref;
  648.     $t1 = Benchmark->new($n);
  649.     $td = &timediff($t1, $t0);
  650.     timedebug("runloop:",$td);
  651.     $td;
  652. }
  653.  
  654. $_Usage{timeit} = <<'USAGE';
  655. usage: $result = timeit($count, 'code' );        or
  656.        $result = timeit($count, sub { code } );
  657. USAGE
  658.  
  659. sub timeit {
  660.     my($n, $code) = @_;
  661.     my($wn, $wc, $wd);
  662.  
  663.     die usage unless defined $code and
  664.                      (!ref $code or ref $code eq 'CODE');
  665.  
  666.     printf STDERR "timeit $n $code\n" if $Debug;
  667.     my $cache_key = $n . ( ref( $code ) ? 'c' : 's' );
  668.     if ($Do_Cache && exists $Cache{$cache_key} ) {
  669.     $wn = $Cache{$cache_key};
  670.     } else {
  671.     $wn = &runloop($n, ref( $code ) ? sub { } : '' );
  672.     # Can't let our baseline have any iterations, or they get subtracted
  673.     # out of the result.
  674.     $wn->[5] = 0;
  675.     $Cache{$cache_key} = $wn;
  676.     }
  677.  
  678.     $wc = &runloop($n, $code);
  679.  
  680.     $wd = timediff($wc, $wn);
  681.     timedebug("timeit: ",$wc);
  682.     timedebug("      - ",$wn);
  683.     timedebug("      = ",$wd);
  684.  
  685.     $wd;
  686. }
  687.  
  688.  
  689. my $default_for = 3;
  690. my $min_for     = 0.1;
  691.  
  692.  
  693. $_Usage{countit} = <<'USAGE';
  694. usage: $result = countit($time, 'code' );        or
  695.        $result = countit($time, sub { code } );
  696. USAGE
  697.  
  698. sub countit {
  699.     my ( $tmax, $code ) = @_;
  700.  
  701.     die usage unless @_;
  702.  
  703.     if ( not defined $tmax or $tmax == 0 ) {
  704.     $tmax = $default_for;
  705.     } elsif ( $tmax < 0 ) {
  706.     $tmax = -$tmax;
  707.     }
  708.  
  709.     die "countit($tmax, ...): timelimit cannot be less than $min_for.\n"
  710.     if $tmax < $min_for;
  711.  
  712.     my ($n, $tc);
  713.  
  714.     # First find the minimum $n that gives a significant timing.
  715.     for ($n = 1; ; $n *= 2 ) {
  716.     my $td = timeit($n, $code);
  717.     $tc = $td->[1] + $td->[2];
  718.     last if $tc > 0.1;
  719.     }
  720.  
  721.     my $nmin = $n;
  722.  
  723.     # Get $n high enough that we can guess the final $n with some accuracy.
  724.     my $tpra = 0.1 * $tmax; # Target/time practice.
  725.     while ( $tc < $tpra ) {
  726.     # The 5% fudge is to keep us from iterating again all
  727.     # that often (this speeds overall responsiveness when $tmax is big
  728.     # and we guess a little low).  This does not noticably affect 
  729.     # accuracy since we're not couting these times.
  730.     $n = int( $tpra * 1.05 * $n / $tc ); # Linear approximation.
  731.     my $td = timeit($n, $code);
  732.     my $new_tc = $td->[1] + $td->[2];
  733.         # Make sure we are making progress.
  734.         $tc = $new_tc > 1.2 * $tc ? $new_tc : 1.2 * $tc;
  735.     }
  736.  
  737.     # Now, do the 'for real' timing(s), repeating until we exceed
  738.     # the max.
  739.     my $ntot  = 0;
  740.     my $rtot  = 0;
  741.     my $utot  = 0.0;
  742.     my $stot  = 0.0;
  743.     my $cutot = 0.0;
  744.     my $cstot = 0.0;
  745.     my $ttot  = 0.0;
  746.  
  747.     # The 5% fudge is because $n is often a few % low even for routines
  748.     # with stable times and avoiding extra timeit()s is nice for
  749.     # accuracy's sake.
  750.     $n = int( $n * ( 1.05 * $tmax / $tc ) );
  751.  
  752.     while () {
  753.     my $td = timeit($n, $code);
  754.     $ntot  += $n;
  755.     $rtot  += $td->[0];
  756.     $utot  += $td->[1];
  757.     $stot  += $td->[2];
  758.     $cutot += $td->[3];
  759.     $cstot += $td->[4];
  760.     $ttot = $utot + $stot;
  761.     last if $ttot >= $tmax;
  762.  
  763.         $ttot = 0.01 if $ttot < 0.01;
  764.     my $r = $tmax / $ttot - 1; # Linear approximation.
  765.     $n = int( $r * $ntot );
  766.     $n = $nmin if $n < $nmin;
  767.     }
  768.  
  769.     return bless [ $rtot, $utot, $stot, $cutot, $cstot, $ntot ];
  770. }
  771.  
  772. # --- Functions implementing high-level time-then-print utilities
  773.  
  774. sub n_to_for {
  775.     my $n = shift;
  776.     return $n == 0 ? $default_for : $n < 0 ? -$n : undef;
  777. }
  778.  
  779. $_Usage{timethis} = <<'USAGE';
  780. usage: $result = timethis($time, 'code' );        or
  781.        $result = timethis($time, sub { code } );
  782. USAGE
  783.  
  784. sub timethis{
  785.     my($n, $code, $title, $style) = @_;
  786.     my($t, $forn);
  787.  
  788.     die usage unless defined $code and
  789.                      (!ref $code or ref $code eq 'CODE');
  790.  
  791.     if ( $n > 0 ) {
  792.     croak "non-integer loopcount $n, stopped" if int($n)<$n;
  793.     $t = timeit($n, $code);
  794.     $title = "timethis $n" unless defined $title;
  795.     } else {
  796.     my $fort  = n_to_for( $n );
  797.     $t     = countit( $fort, $code );
  798.     $title = "timethis for $fort" unless defined $title;
  799.     $forn  = $t->[-1];
  800.     }
  801.     local $| = 1;
  802.     $style = "" unless defined $style;
  803.     printf("%10s: ", $title) unless $style eq 'none';
  804.     print timestr($t, $style, $Default_Format),"\n" unless $style eq 'none';
  805.  
  806.     $n = $forn if defined $forn;
  807.  
  808.     # A conservative warning to spot very silly tests.
  809.     # Don't assume that your benchmark is ok simply because
  810.     # you don't get this warning!
  811.     print "            (warning: too few iterations for a reliable count)\n"
  812.     if     $n < $Min_Count
  813.         || ($t->real < 1 && $n < 1000)
  814.         || $t->cpu_a < $Min_CPU;
  815.     $t;
  816. }
  817.  
  818.  
  819. $_Usage{timethese} = <<'USAGE';
  820. usage: timethese($count, { Name1 => 'code1', ... });        or
  821.        timethese($count, { Name1 => sub { code1 }, ... });
  822. USAGE
  823.  
  824. sub timethese{
  825.     my($n, $alt, $style) = @_;
  826.     die usage unless ref $alt eq 'HASH';
  827.  
  828.     my @names = sort keys %$alt;
  829.     $style = "" unless defined $style;
  830.     print "Benchmark: " unless $style eq 'none';
  831.     if ( $n > 0 ) {
  832.     croak "non-integer loopcount $n, stopped" if int($n)<$n;
  833.     print "timing $n iterations of" unless $style eq 'none';
  834.     } else {
  835.     print "running" unless $style eq 'none';
  836.     }
  837.     print " ", join(', ',@names) unless $style eq 'none';
  838.     unless ( $n > 0 ) {
  839.     my $for = n_to_for( $n );
  840.     print ", each" if $n > 1 && $style ne 'none';
  841.     print " for at least $for CPU seconds" unless $style eq 'none';
  842.     }
  843.     print "...\n" unless $style eq 'none';
  844.  
  845.     # we could save the results in an array and produce a summary here
  846.     # sum, min, max, avg etc etc
  847.     my %results;
  848.     foreach my $name (@names) {
  849.         $results{$name} = timethis ($n, $alt -> {$name}, $name, $style);
  850.     }
  851.  
  852.     return \%results;
  853. }
  854.  
  855.  
  856. $_Usage{cmpthese} = <<'USAGE';
  857. usage: cmpthese($count, { Name1 => 'code1', ... });        or
  858.        cmpthese($count, { Name1 => sub { code1 }, ... });  or
  859.        cmpthese($result, $style);
  860. USAGE
  861.  
  862. sub cmpthese{
  863.     my ($results, $style);
  864.  
  865.     if( ref $_[0] ) {
  866.         ($results, $style) = @_;
  867.     }
  868.     else {
  869.         my($count, $code) = @_[0,1];
  870.         $style = $_[2] if defined $_[2];
  871.  
  872.         die usage unless ref $code eq 'HASH';
  873.  
  874.         $results = timethese($count, $code, ($style || "none"));
  875.     }
  876.  
  877.     $style = "" unless defined $style;
  878.  
  879.     # Flatten in to an array of arrays with the name as the first field
  880.     my @vals = map{ [ $_, @{$results->{$_}} ] } keys %$results;
  881.  
  882.     for (@vals) {
  883.     # The epsilon fudge here is to prevent div by 0.  Since clock
  884.     # resolutions are much larger, it's below the noise floor.
  885.     my $rate = $_->[6] / ( $_->[2] + $_->[3] + 0.000000000000001 );
  886.     $_->[7] = $rate;
  887.     }
  888.  
  889.     # Sort by rate
  890.     @vals = sort { $a->[7] <=> $b->[7] } @vals;
  891.  
  892.     # If more than half of the rates are greater than one...
  893.     my $display_as_rate = $vals[$#vals>>1]->[7] > 1;
  894.  
  895.     my @rows;
  896.     my @col_widths;
  897.  
  898.     my @top_row = ( 
  899.         '', 
  900.     $display_as_rate ? 'Rate' : 's/iter', 
  901.     map { $_->[0] } @vals 
  902.     );
  903.  
  904.     push @rows, \@top_row;
  905.     @col_widths = map { length( $_ ) } @top_row;
  906.  
  907.     # Build the data rows
  908.     # We leave the last column in even though it never has any data.  Perhaps
  909.     # it should go away.  Also, perhaps a style for a single column of
  910.     # percentages might be nice.
  911.     for my $row_val ( @vals ) {
  912.     my @row;
  913.  
  914.         # Column 0 = test name
  915.     push @row, $row_val->[0];
  916.     $col_widths[0] = length( $row_val->[0] )
  917.         if length( $row_val->[0] ) > $col_widths[0];
  918.  
  919.         # Column 1 = performance
  920.     my $row_rate = $row_val->[7];
  921.  
  922.     # We assume that we'll never get a 0 rate.
  923.     my $rate = $display_as_rate ? $row_rate : 1 / $row_rate;
  924.  
  925.     # Only give a few decimal places before switching to sci. notation,
  926.     # since the results aren't usually that accurate anyway.
  927.     my $format = 
  928.        $rate >= 100 ? 
  929.            "%0.0f" : 
  930.        $rate >= 10 ?
  931.            "%0.1f" :
  932.        $rate >= 1 ?
  933.            "%0.2f" :
  934.        $rate >= 0.1 ?
  935.            "%0.3f" :
  936.            "%0.2e";
  937.  
  938.     $format .= "/s"
  939.         if $display_as_rate;
  940.  
  941.     my $formatted_rate = sprintf( $format, $rate );
  942.     push @row, $formatted_rate;
  943.     $col_widths[1] = length( $formatted_rate )
  944.         if length( $formatted_rate ) > $col_widths[1];
  945.  
  946.         # Columns 2..N = performance ratios
  947.     my $skip_rest = 0;
  948.     for ( my $col_num = 0 ; $col_num < @vals ; ++$col_num ) {
  949.         my $col_val = $vals[$col_num];
  950.         my $out;
  951.         if ( $skip_rest ) {
  952.         $out = '';
  953.         }
  954.         elsif ( $col_val->[0] eq $row_val->[0] ) {
  955.         $out = "--";
  956.         # $skip_rest = 1;
  957.         }
  958.         else {
  959.         my $col_rate = $col_val->[7];
  960.         $out = sprintf( "%.0f%%", 100*$row_rate/$col_rate - 100 );
  961.         }
  962.         push @row, $out;
  963.         $col_widths[$col_num+2] = length( $out )
  964.         if length( $out ) > $col_widths[$col_num+2];
  965.  
  966.         # A little wierdness to set the first column width properly
  967.         $col_widths[$col_num+2] = length( $col_val->[0] )
  968.         if length( $col_val->[0] ) > $col_widths[$col_num+2];
  969.     }
  970.     push @rows, \@row;
  971.     }
  972.  
  973.     return \@rows if $style eq "none";
  974.  
  975.     # Equalize column widths in the chart as much as possible without
  976.     # exceeding 80 characters.  This does not use or affect cols 0 or 1.
  977.     my @sorted_width_refs = 
  978.        sort { $$a <=> $$b } map { \$_ } @col_widths[2..$#col_widths];
  979.     my $max_width = ${$sorted_width_refs[-1]};
  980.  
  981.     my $total = @col_widths - 1 ;
  982.     for ( @col_widths ) { $total += $_ }
  983.  
  984.     STRETCHER:
  985.     while ( $total < 80 ) {
  986.     my $min_width = ${$sorted_width_refs[0]};
  987.     last
  988.        if $min_width == $max_width;
  989.     for ( @sorted_width_refs ) {
  990.         last 
  991.         if $$_ > $min_width;
  992.         ++$$_;
  993.         ++$total;
  994.         last STRETCHER
  995.         if $total >= 80;
  996.     }
  997.     }
  998.  
  999.     # Dump the output
  1000.     my $format = join( ' ', map { "%${_}s" } @col_widths ) . "\n";
  1001.     substr( $format, 1, 0 ) = '-';
  1002.     for ( @rows ) {
  1003.     printf $format, @$_;
  1004.     }
  1005.  
  1006.     return \@rows ;
  1007. }
  1008.  
  1009.  
  1010. 1;
  1011.