home *** CD-ROM | disk | FTP | other *** search
/ PC World 2004 November / PCWorld_2004-11_cd.bin / software / topware / activeperl / ActivePerl-5.8.4.810-MSWin32-x86.exe / ActivePerl-5.8.4.810 / Perl / bin / prove.bat < prev    next >
DOS Batch File  |  2004-06-01  |  10KB  |  350 lines
  1. @rem = '--*-Perl-*--
  2. @echo off
  3. if "%OS%" == "Windows_NT" goto WinNT
  4. perl -x -S "%0" %1 %2 %3 %4 %5 %6 %7 %8 %9
  5. goto endofperl
  6. :WinNT
  7. perl -x -S %0 %*
  8. if NOT "%COMSPEC%" == "%SystemRoot%\system32\cmd.exe" goto endofperl
  9. if %errorlevel% == 9009 echo You do not have Perl in your PATH.
  10. if errorlevel 1 goto script_failed_so_exit_with_non_zero_val 2>nul
  11. goto endofperl
  12. @rem ';
  13. #!perl
  14. #line 15
  15.     eval 'exec C:\TEMP\perl--------------------------------please-run-the-install-script--------------------------------\bin\perl.exe -S $0 ${1+"$@"}'
  16.     if $running_under_some_shell;
  17. #!/usr/bin/perl -w
  18.  
  19. use strict;
  20.  
  21. use Test::Harness;
  22. use Getopt::Long;
  23. use Pod::Usage 1.12;
  24. use File::Spec;
  25.  
  26. use vars qw( $VERSION );
  27. $VERSION = "1.04";
  28.  
  29. my @ext = ();
  30. my $shuffle = 0;
  31. my $dry = 0;
  32. my $blib = 0;
  33. my $lib = 0;
  34. my $recurse = 0;
  35. my @includes = ();
  36. my @switches = ();
  37.  
  38. # Allow cuddling the paths with the -I
  39. @ARGV = map { /^(-I)(.+)/ ? ($1,$2) : $_ } @ARGV;
  40.  
  41. # Stick any default switches at the beginning, so they can be overridden
  42. # by the command line switches.
  43. unshift @ARGV, split( " ", $ENV{PROVE_SWITCHES} ) if defined $ENV{PROVE_SWITCHES};
  44.  
  45. Getopt::Long::Configure( "no_ignore_case" );
  46. Getopt::Long::Configure( "bundling" );
  47. GetOptions(
  48.     'b|blib'        => \$blib,
  49.     'd|debug'        => \$Test::Harness::debug,
  50.     'D|dry'         => \$dry,
  51.     'h|help|?'      => sub {pod2usage({-verbose => 1, -input => \*DATA}); exit},
  52.     'H|man'         => sub {pod2usage({-verbose => 2, -input => \*DATA}); exit},
  53.     'I=s@'          => \@includes,
  54.     'l|lib'        => \$lib,
  55.     'r|recurse'     => \$recurse,
  56.     's|shuffle'     => \$shuffle,
  57.     't'            => sub { unshift @switches, "-t" }, # Always want -t up front
  58.     'T'            => sub { unshift @switches, "-T" }, # Always want -T up front
  59.     'v|verbose'     => \$Test::Harness::verbose,
  60.     'V|version'     => sub { print_version(); exit; },
  61.     'ext=s@'        => \@ext,
  62. ) or exit 1;
  63.  
  64. # Build up extensions regex
  65. @ext = map { split /,/ } @ext;
  66. s/^\.// foreach @ext;
  67. @ext = ("t") unless @ext;
  68. my $ext_regex = join( "|", map { quotemeta } @ext );
  69. $ext_regex = qr/\.($ext_regex)$/;
  70.  
  71. # Handle blib includes
  72. if ( $blib ) {
  73.     my @blibdirs = blibdirs();
  74.     if ( @blibdirs ) {
  75.     unshift @includes, @blibdirs;
  76.     } else {
  77.     warn "No blib directories found.\n";
  78.     }
  79. }
  80.  
  81. # Handle lib includes
  82. if ( $lib ) {
  83.     unshift @includes, "lib";
  84. }
  85.  
  86. # Build up TH switches
  87. push( @switches, map { /\s/ && !/^".*"$/ ? qq["-I$_"] : "-I$_" } @includes );
  88. $Test::Harness::Switches = join( " ", @switches );
  89. print "# \$Test::Harness::Switches: $Test::Harness::Switches\n" if $Test::Harness::debug;
  90.  
  91. my @tests;
  92. @ARGV = File::Spec->curdir unless @ARGV;
  93. push( @tests, -d $_ ? all_in( $_ ) : $_ ) for @ARGV;
  94.  
  95. if ( @tests ) {
  96.     shuffle(@tests) if $shuffle;
  97.     if ( $dry ) {
  98.         print join( "\n", @tests, "" );
  99.     } else {
  100.     print "# ", scalar @tests, " tests to run\n" if $Test::Harness::debug;
  101.         runtests(@tests);
  102.     }
  103. }
  104.  
  105. sub all_in {
  106.     my $start = shift;
  107.  
  108.     my @hits = ();
  109.  
  110.     local *DH;
  111.     if ( opendir( DH, $start ) ) {
  112.         while ( my $file = readdir DH ) {
  113.             next if $file eq File::Spec->updir || $file eq File::Spec->curdir;
  114.             next if $file eq ".svn";
  115.             next if $file eq "CVS";
  116.  
  117.             my $currfile = File::Spec->catfile( $start, $file );
  118.             if ( -d $currfile ) {
  119.                 push( @hits, all_in( $currfile ) ) if $recurse;
  120.             } else {
  121.                 push( @hits, $currfile ) if $currfile =~ $ext_regex;
  122.             }
  123.         }
  124.     } else {
  125.         warn "$start: $!\n";
  126.     }
  127.  
  128.     return @hits;
  129. }
  130.  
  131. sub shuffle {
  132.     # Fisher-Yates shuffle
  133.     my $i = @_;
  134.     while ($i) {
  135.         my $j = rand $i--;
  136.         @_[$i, $j] = @_[$j, $i];
  137.     }
  138. }
  139.  
  140. sub print_version {
  141.     printf( "prove v%s, using Test::Harness v%s and Perl v%vd\n",
  142.     $VERSION, $Test::Harness::VERSION, $^V );
  143. }
  144.  
  145. # Stolen directly from blib.pm
  146. sub blibdirs {
  147.     my $dir = File::Spec->curdir;
  148.     if ($^O eq 'VMS') {
  149.     ($dir = VMS::Filespec::unixify($dir)) =~ s-/\z--;
  150.     }
  151.     my $archdir = "arch";
  152.     if ( $^O eq "MacOS" ) {
  153.     # Double up the MP::A so that it's not used only once.
  154.     $archdir = $MacPerl::Architecture = $MacPerl::Architecture;
  155.     }
  156.  
  157.     my $i = 5;
  158.     while ($i--) {
  159.         my $blib      = File::Spec->catdir( $dir, "blib" );
  160.         my $blib_lib  = File::Spec->catdir( $blib, "lib" );
  161.         my $blib_arch = File::Spec->catdir( $blib, $archdir );
  162.  
  163.     if ( -d $blib && -d $blib_arch && -d $blib_lib ) {
  164.         return ($blib_arch,$blib_lib);
  165.     }
  166.     $dir = File::Spec->catdir($dir, File::Spec->updir);
  167.     }
  168.     warn "$0: Cannot find blib\n";
  169.     return;
  170. }
  171.  
  172. __END__
  173.  
  174. =head1 NAME
  175.  
  176. prove -- A command-line tool for running tests against Test::Harness
  177.  
  178. =head1 SYNOPSIS
  179.  
  180. prove [options] [files/directories]
  181.  
  182. Options:
  183.  
  184.     -b, --blib      Adds blib/lib to the path for your tests, a la "use blib".
  185.     -d, --debug        Includes extra debugging information.
  186.     -D, --dry       Dry run: Show the tests to run, but don't run them.
  187.         --ext=x     Extensions (defaults to .t)
  188.     -h, --help      Display this help
  189.     -H, --man       Longer manpage for prove
  190.     -I              Add libraries to @INC, as Perl's -I
  191.     -l, --lib        Add lib to the path for your tests.
  192.     -r, --recurse   Recursively descend into directories.
  193.     -s, --shuffle   Run the tests in a random order.
  194.     -T             Enable tainting checks
  195.     -t            Enable tainting warnings
  196.     -v, --verbose   Display standard output of test scripts while running them.
  197.     -V, --version   Display version info
  198.  
  199. Single-character options may be stacked.  Default options may be set by
  200. specifying the PROVE_SWITCHES environment variable.
  201.  
  202. =head1 OVERVIEW
  203.  
  204. F<prove> is a command-line interface to the test-running functionality
  205. of C<Test::Harness>.  With no arguments, it will run all tests in the
  206. current directory.
  207.  
  208. Shell metacharacters may be used with command lines options and will be exanded 
  209. via C<glob>.
  210.  
  211. =head1 PROVE VS. "MAKE TEST"
  212.  
  213. F<prove> has a number of advantages over C<make test> when doing development.
  214.  
  215. =over 4
  216.  
  217. =item * F<prove> is designed as a development tool
  218.  
  219. Perl users typically run the test harness through a makefile via
  220. C<make test>.  That's fine for module distributions, but it's
  221. suboptimal for a test/code/debug development cycle.
  222.  
  223. =item * F<prove> is granular 
  224.  
  225. F<prove> lets your run against only the files you want to check.
  226. Running C<prove t/live/ t/master.t> checks every F<*.t> in F<t/live>,
  227. plus F<t/master.t>.
  228.  
  229. =item * F<prove> has an easy verbose mode
  230.  
  231. F<prove> has a C<-v> option to see the raw output from the tests.
  232. To do this with C<make test>, you must set C<HARNESS_VERBOSE=1> in
  233. the environment.
  234.  
  235. =item * F<prove> can run under taint mode
  236.  
  237. F<prove>'s C<-T> runs your tests under C<perl -T>, and C<-t> runs them
  238. under C<perl -t>.
  239.  
  240. =item * F<prove> can shuffle tests
  241.  
  242. You can use F<prove>'s C<--shuffle> option to try to excite problems
  243. that don't show up when tests are run in the same order every time.
  244.  
  245. =item * F<prove> doesn't rely on a make tool
  246.  
  247. Not everyone wants to write a makefile, or use L<ExtUtils::MakeMaker>
  248. to do so.  F<prove> has no external dependencies.
  249.  
  250. =item * Not everything is a module
  251.  
  252. More and more users are using Perl's testing tools outside the
  253. context of a module distribution, and may not even use a makefile
  254. at all.
  255.  
  256. =back
  257.  
  258. =head1 COMMAND LINE OPTIONS
  259.  
  260. =head2 -b, --blib
  261.  
  262. Adds blib/lib to the path for your tests, a la "use blib".
  263.  
  264. =head2 -d, --debug
  265.  
  266. Include debug information about how F<prove> is being run.  This
  267. option doesn't show the output from the test scripts.  That's handled
  268. by -v,--verbose.
  269.  
  270. =head2 -D, --dry
  271.  
  272. Dry run: Show the tests to run, but don't run them.
  273.  
  274. =head2 --ext=extension
  275.  
  276. Specify extensions of the test files to run.  By default, these are .t,
  277. but you may have other non-.t test files, most likely .sh shell scripts.
  278. The --ext is repeatable.
  279.  
  280. =head2 -I
  281.  
  282. Add libraries to @INC, as Perl's -I.
  283.  
  284. =head2 -l, --lib
  285.  
  286. Add C<lib> to @INC.  Equivalent to C<-Ilib>.
  287.  
  288. =head2 -r, --recurse
  289.  
  290. Descends into subdirectories of any directories specified, looking for tests.
  291.  
  292. =head2 -s, --shuffle
  293.  
  294. Sometimes tests are accidentally dependent on tests that have been
  295. run before.  This switch will shuffle the tests to be run prior to
  296. running them, thus ensuring that hidden dependencies in the test
  297. order are likely to be revealed.  The author hopes the run the
  298. algorithm on the preceding sentence to see if he can produce something
  299. slightly less awkward.
  300.  
  301. =head2 -t
  302.  
  303. Runs test programs under perl's -t taint warning mode.
  304.  
  305. =head2 -T
  306.  
  307. Runs test programs under perl's -T taint mode.
  308.  
  309. =head2 -v, --verbose
  310.  
  311. Display standard output of test scripts while running them.
  312.  
  313. =head2 -V, --version
  314.  
  315. Display version info.
  316.  
  317. =head1 BUGS
  318.  
  319. Please use the CPAN bug ticketing system at L<http://rt.cpan.org/>.
  320. You can also mail bugs, fixes and enhancements to 
  321. C<< <bug-test-harness@rt.cpan.org> >>.
  322.  
  323. =head1 TODO
  324.  
  325. =over 4
  326.  
  327. =item *
  328.  
  329. Shuffled tests must be recreatable
  330.  
  331. =back
  332.  
  333. =head1 AUTHORS
  334.  
  335. Andy Lester C<< <andy@petdance.com> >>
  336.  
  337. =head1 COPYRIGHT
  338.  
  339. Copyright 2003 by Andy Lester C<< <andy@petdance.com> >>.
  340.  
  341. This program is free software; you can redistribute it and/or 
  342. modify it under the same terms as Perl itself.
  343.  
  344. See L<http://www.perl.com/perl/misc/Artistic.html>.
  345.  
  346. =cut
  347.  
  348. __END__
  349. :endofperl
  350.