home *** CD-ROM | disk | FTP | other *** search
/ PC World 2004 November / PCWorld_2004-11_cd.bin / software / topware / activeperl / ActivePerl-5.8.4.810-MSWin32-x86.exe / ActivePerl-5.8.4.810 / Perl / bin / lwp-download.bat < prev    next >
DOS Batch File  |  2004-06-01  |  8KB  |  305 lines
  1. @rem = '--*-Perl-*--
  2. @echo off
  3. if "%OS%" == "Windows_NT" goto WinNT
  4. perl -x -S "%0" %1 %2 %3 %4 %5 %6 %7 %8 %9
  5. goto endofperl
  6. :WinNT
  7. perl -x -S %0 %*
  8. if NOT "%COMSPEC%" == "%SystemRoot%\system32\cmd.exe" goto endofperl
  9. if %errorlevel% == 9009 echo You do not have Perl in your PATH.
  10. if errorlevel 1 goto script_failed_so_exit_with_non_zero_val 2>nul
  11. goto endofperl
  12. @rem ';
  13. #!/usr/bin/perl -w
  14. #line 15
  15.  
  16. # $Id: lwp-download,v 2.6 2004/04/09 21:31:29 gisle Exp $
  17.  
  18. =head1 NAME
  19.  
  20. lwp-download - Fetch large files from the web
  21.  
  22. =head1 SYNOPSIS
  23.  
  24.  lwp-download [-a] <url> [<local file>]
  25.  
  26. =head1 DESCRIPTION
  27.  
  28. The I<lwp-download> program will down load the document specified by the URL
  29. given as the first command line argument to a local file.  The local
  30. filename used to save the document is guessed from the URL unless
  31. specified as the second command line argument.
  32.  
  33. The I<lwp-download> program is implemented using the I<libwww-perl>
  34. library.  It is better suited to down load big files than the
  35. I<lwp-request> program because it does not store the file in memory.
  36. Another benefit is that it will keep you updated about its progress
  37. and that you don't have much options to worry about.
  38.  
  39. Use the C<-a> option to save the file in text (ascii) mode.  Might make a
  40. difference on dosish systems.
  41.  
  42. =head1 EXAMPLE
  43.  
  44. Fetch the newest and greatest perl version:
  45.  
  46.  $ lwp-download http://www.perl.com/CPAN/src/latest.tar.gz
  47.  Saving to 'latest.tar.gz'...
  48.  11.4 MB received in 8 seconds (1.43 MB/sec)
  49.  
  50. =head1 AUTHOR
  51.  
  52. Gisle Aas <gisle@aas.no>
  53.  
  54. =cut
  55.  
  56. #' get emacs out of quote mode
  57.  
  58. use strict;
  59.  
  60. use LWP::UserAgent ();
  61. use LWP::MediaTypes qw(guess_media_type media_suffix);
  62. use URI ();
  63. use HTTP::Date ();
  64.  
  65. my $progname = $0;
  66. $progname =~ s,.*/,,;    # only basename left in progname
  67. $progname =~ s/\.\w*$//; # strip extension if any
  68.  
  69. #parse option
  70. use Getopt::Std;
  71. my %opt;
  72. unless (getopts('a', \%opt)) {
  73.     usage();
  74. }
  75.  
  76. my $url = URI->new(shift || usage());
  77. my $argfile = shift;
  78. my $version = q$Revision: 2.6 $;
  79.  
  80. my $ua = new LWP::UserAgent;
  81.  
  82. $ua->agent("lwp-download/$version " . $ua->agent);
  83. $ua->env_proxy;
  84.  
  85. my $req = new HTTP::Request GET => $url;
  86.  
  87. my $file;      # name of file we download into
  88. my $length;    # total number of bytes to download
  89. my $flength;   # formatted length
  90. my $size = 0;  # number of bytes received
  91. my $start_t;   # start time of download
  92. my $last_dur;  # time of last callback
  93.  
  94. my $shown = 0; # have we called the show() function yet
  95.  
  96. $SIG{INT} = sub { die "Interrupted\n"; };
  97.  
  98. $| = 1;  # autoflush
  99.  
  100. my $res = $ua->request($req,
  101.   sub {
  102.       unless($file) {
  103.       my $res = $_[1];
  104.       unless ($argfile) {
  105.           # must find a suitable name to use.  First thing
  106.           # to do is to look for the "Content-Disposition"
  107.           # header defined by RFC1806.  This is also supported
  108.           # by Netscape
  109.           my $cd = $res->header("Content-Disposition");
  110.           if ($cd && $cd =~ /\bfilename\s*=\s*(\S+)/) {
  111.           $file = $1;
  112.           $file =~ s/;$//;
  113.           $file =~ s/^([\"\'])(.*)\1$/$2/;
  114.           }
  115.         
  116.           # if this fails we try to make something from the URL
  117.           unless ($file) {
  118.           my $req = $res->request;  # now always there
  119.           my $rurl = $req ? $req->url : $url;
  120.           
  121.           $file = ($rurl->path_segments)[-1];
  122.           if (!defined($file) || !length($file)) {
  123.               $file = "index";
  124.               my $suffix = media_suffix($res->content_type);
  125.               $file .= ".$suffix" if $suffix;
  126.           }
  127.           elsif ($rurl->scheme eq 'ftp' ||
  128.                $file =~ /\.t[bg]z$/   ||
  129.                $file =~ /\.tar(\.(Z|gz|bz2?))?$/
  130.               ) {
  131.               # leave the filename as it was
  132.           }
  133.           else {
  134.               my $ct = guess_media_type($file);
  135.               unless ($ct eq $res->content_type) {
  136.               # need a better suffix for this type
  137.               my $suffix = media_suffix($res->content_type);
  138.               $file .= ".$suffix" if $suffix;
  139.               }
  140.           }
  141.           }
  142.  
  143.           # Check if the file is already present
  144.           if (-f $file && -t) {
  145.           $shown = 1;
  146.           print "Overwrite $file? [y] ";
  147.           my $ans = <STDIN>;
  148.           unless (defined($ans) && $ans =~ /^y?\n/) {
  149.               if (defined $ans) {
  150.               print "Ok, aborting.\n";
  151.               }
  152.               else {
  153.               print "\nAborting.\n";
  154.               }
  155.               exit 1;
  156.           }
  157.           $shown = 0;
  158.           }
  159.           else {
  160.           print "Saving to '$file'...\n";
  161.           }
  162.       }
  163.       else {
  164.           $file = $argfile;
  165.       }
  166.       open(FILE, ">$file") || die "Can't open $file: $!";
  167.           binmode FILE unless $opt{a};
  168.       $length = $res->content_length;
  169.       $flength = fbytes($length) if defined $length;
  170.       $start_t = time;
  171.       $last_dur = 0;
  172.       }
  173.  
  174.       print FILE $_[0] or die "Can't write to $file: $!";
  175.       $size += length($_[0]);
  176.  
  177.       if (defined $length) {
  178.       my $dur  = time - $start_t;
  179.       if ($dur != $last_dur) {  # don't update too often
  180.           $last_dur = $dur;
  181.           my $perc = $size / $length;
  182.           my $speed;
  183.           $speed = fbytes($size/$dur) . "/sec" if $dur > 3;
  184.           my $secs_left = fduration($dur/$perc - $dur);
  185.           $perc = int($perc*100);
  186.           my $show = "$perc% of $flength";
  187.           $show .= " (at $speed, $secs_left remaining)" if $speed;
  188.           show($show, 1);
  189.       }
  190.       }
  191.       else {
  192.       show( fbytes($size) . " received");
  193.       }
  194.   }
  195. );
  196.  
  197. if (fileno(FILE)) {
  198.     close(FILE) || die "Can't write to $file: $!";
  199.  
  200.     show("");  # clear text
  201.     print "\r";
  202.     print fbytes($size);
  203.     print " of ", fbytes($length) if defined($length) && $length != $size;
  204.     print " received";
  205.     my $dur = time - $start_t;
  206.     if ($dur) {
  207.     my $speed = fbytes($size/$dur) . "/sec";
  208.     print " in ", fduration($dur), " ($speed)";
  209.     }
  210.     print "\n";
  211.  
  212.     if (my $mtime = $res->last_modified) {
  213.     utime time, $mtime, $file;
  214.     }
  215.  
  216.     if ($res->header("X-Died") || !$res->is_success) {
  217.     if (-t) {
  218.         print "Transfer aborted.  Delete $file? [n] ";
  219.         my $ans = <STDIN>;
  220.         if (defined($ans) && $ans =~ /^y\n/) {
  221.         unlink($file) && print "Deleted.\n";
  222.         }
  223.         elsif ($length > $size) {
  224.         print "Truncated file kept: ", fbytes($length - $size), " missing\n";
  225.         }
  226.         else {
  227.         print "File kept.\n";
  228.         }
  229.             exit 1;
  230.     }
  231.     else {
  232.         print "Transfer aborted, $file kept\n";
  233.     }
  234.     }
  235.     exit 0;
  236. }
  237.  
  238. # Did not manage to create any file
  239. print "\n" if $shown;
  240. if ($res->header("X-Died")) {
  241.     print "$progname: Aborted\n";
  242. }
  243. else {
  244.     print "$progname: ", $res->status_line, "\n";
  245. }
  246. exit 1;
  247.  
  248.  
  249. sub fbytes
  250. {
  251.     my $n = int(shift);
  252.     if ($n >= 1024 * 1024) {
  253.     return sprintf "%.3g MB", $n / (1024.0 * 1024);
  254.     }
  255.     elsif ($n >= 1024) {
  256.     return sprintf "%.3g KB", $n / 1024.0;
  257.     }
  258.     else {
  259.     return "$n bytes";
  260.     }
  261. }
  262.  
  263. sub fduration
  264. {
  265.     use integer;
  266.     my $secs = int(shift);
  267.     my $hours = $secs / (60*60);
  268.     $secs -= $hours * 60*60;
  269.     my $mins = $secs / 60;
  270.     $secs %= 60;
  271.     if ($hours) {
  272.     return "$hours hours $mins minutes";
  273.     }
  274.     elsif ($mins >= 2) {
  275.     return "$mins minutes";
  276.     }
  277.     else {
  278.     $secs += $mins * 60;
  279.     return "$secs seconds";
  280.     }
  281. }
  282.  
  283.  
  284. BEGIN {
  285.     my @ani = qw(- \ | /);
  286.     my $ani = 0;
  287.  
  288.     sub show
  289.     {
  290.         my($mess, $show_ani) = @_;
  291.         print "\r$mess" . (" " x (75 - length $mess));
  292.     print $show_ani ? "$ani[$ani++]\b" : " ";
  293.         $ani %= @ani;
  294.         $shown++;
  295.     }
  296. }
  297.  
  298. sub usage
  299. {
  300.     die "Usage: $progname [-a] <url> [<lpath>]\n";
  301. }
  302.  
  303. __END__
  304. :endofperl
  305.