home *** CD-ROM | disk | FTP | other *** search
/ PC World 2004 November / PCWorld_2004-11_cd.bin / software / topware / activeperl / ActivePerl-5.8.4.810-MSWin32-x86.exe / ActivePerl-5.8.4.810 / Perl / bin / h2ph.bat < prev    next >
DOS Batch File  |  2004-06-01  |  26KB  |  851 lines
  1. @rem = '--*-Perl-*--
  2. @echo off
  3. if "%OS%" == "Windows_NT" goto WinNT
  4. perl -x -S "%0" %1 %2 %3 %4 %5 %6 %7 %8 %9
  5. goto endofperl
  6. :WinNT
  7. perl -x -S %0 %*
  8. if NOT "%COMSPEC%" == "%SystemRoot%\system32\cmd.exe" goto endofperl
  9. if %errorlevel% == 9009 echo You do not have Perl in your PATH.
  10. if errorlevel 1 goto script_failed_so_exit_with_non_zero_val 2>nul
  11. goto endofperl
  12. @rem ';
  13. #!perl
  14. #line 15
  15.     eval 'exec C:\TEMP\perl--------------------------------please-run-the-install-script--------------------------------\bin\perl.exe -S $0 ${1+"$@"}'
  16.     if $running_under_some_shell;
  17.  
  18. use strict;
  19.  
  20. use Config;
  21. use File::Path qw(mkpath);
  22. use Getopt::Std;
  23.  
  24. # Make sure read permissions for all are set:
  25. if (defined umask && (umask() & 0444)) {
  26.     umask (umask() & ~0444);
  27. }
  28.  
  29. getopts('Dd:rlhaQe');
  30. use vars qw($opt_D $opt_d $opt_r $opt_l $opt_h $opt_a $opt_Q $opt_e);
  31. die "-r and -a options are mutually exclusive\n" if ($opt_r and $opt_a);
  32. my @inc_dirs = inc_dirs() if $opt_a;
  33.  
  34. my $Exit = 0;
  35.  
  36. my $Dest_dir = $opt_d || $Config{installsitearch};
  37. die "Destination directory $Dest_dir doesn't exist or isn't a directory\n"
  38.     unless -d $Dest_dir;
  39.  
  40. my @isatype = split(' ',<<END);
  41.     char    uchar    u_char
  42.     short    ushort    u_short
  43.     int    uint    u_int
  44.     long    ulong    u_long
  45.     FILE    key_t    caddr_t
  46. END
  47.  
  48. my %isatype;
  49. @isatype{@isatype} = (1) x @isatype;
  50. my $inif = 0;
  51. my %Is_converted;
  52. my %bad_file = ();
  53.  
  54. @ARGV = ('-') unless @ARGV;
  55.  
  56. build_preamble_if_necessary();
  57.  
  58. sub reindent($) {
  59.     my($text) = shift;
  60.     $text =~ s/\n/\n    /g;
  61.     $text =~ s/        /\t/g;
  62.     $text;
  63. }
  64.  
  65. my ($t, $tab, %curargs, $new, $eval_index, $dir, $name, $args, $outfile);
  66. my ($incl, $incl_type, $next);
  67. while (defined (my $file = next_file())) {
  68.     if (-l $file and -d $file) {
  69.         link_if_possible($file) if ($opt_l);
  70.         next;
  71.     }
  72.  
  73.     # Recover from header files with unbalanced cpp directives
  74.     $t = '';
  75.     $tab = 0;
  76.  
  77.     # $eval_index goes into ``#line'' directives, to help locate syntax errors:
  78.     $eval_index = 1;
  79.  
  80.     if ($file eq '-') {
  81.     open(IN, "-");
  82.     open(OUT, ">-");
  83.     } else {
  84.     ($outfile = $file) =~ s/\.h$/.ph/ || next;
  85.     print "$file -> $outfile\n" unless $opt_Q;
  86.     if ($file =~ m|^(.*)/|) {
  87.         $dir = $1;
  88.         mkpath "$Dest_dir/$dir";
  89.     }
  90.  
  91.     if ($opt_a) { # automagic mode:  locate header file in @inc_dirs
  92.         foreach (@inc_dirs) {
  93.         chdir $_;
  94.         last if -f $file;
  95.         }
  96.     }
  97.  
  98.     open(IN,"$file") || (($Exit = 1),(warn "Can't open $file: $!\n"),next);
  99.     open(OUT,">$Dest_dir/$outfile") || die "Can't create $outfile: $!\n";
  100.     }
  101.  
  102.     print OUT
  103.         "require '_h2ph_pre.ph';\n\n",
  104.         "no warnings 'redefine';\n\n";
  105.  
  106.     while (defined (local $_ = next_line($file))) {
  107.     if (s/^\s*\#\s*//) {
  108.         if (s/^define\s+(\w+)//) {
  109.         $name = $1;
  110.         $new = '';
  111.         s/\s+$//;
  112.         s/\(\w+\s*\(\*\)\s*\(\w*\)\)\s*(-?\d+)/$1/; # (int (*)(foo_t))0
  113.         if (s/^\(([\w,\s]*)\)//) {
  114.             $args = $1;
  115.                     my $proto = '() ';
  116.             if ($args ne '') {
  117.                         $proto = '';
  118.             foreach my $arg (split(/,\s*/,$args)) {
  119.                 $arg =~ s/^\s*([^\s].*[^\s])\s*$/$1/;
  120.                 $curargs{$arg} = 1;
  121.             }
  122.             $args =~ s/\b(\w)/\$$1/g;
  123.             $args = "local($args) = \@_;\n$t    ";
  124.             }
  125.             s/^\s+//;
  126.             expr();
  127.             $new =~ s/(["\\])/\\$1/g;       #"]);
  128.             $new = reindent($new);
  129.             $args = reindent($args);
  130.             if ($t ne '') {
  131.             $new =~ s/(['\\])/\\$1/g;   #']);
  132.             if ($opt_h) {
  133.                 print OUT $t,
  134.                             "eval \"\\n#line $eval_index $outfile\\n\" . 'sub $name $proto\{\n$t    ${args}eval q($new);\n$t}' unless defined(\&$name);\n";
  135.                             $eval_index++;
  136.             } else {
  137.                 print OUT $t,
  138.                             "eval 'sub $name $proto\{\n$t    ${args}eval q($new);\n$t}' unless defined(\&$name);\n";
  139.             }
  140.             } else {
  141.                       print OUT "unless(defined(\&$name)) {\n    sub $name $proto\{\n\t${args}eval q($new);\n    }\n}\n";
  142.             }
  143.             %curargs = ();
  144.         } else {
  145.             s/^\s+//;
  146.             expr();
  147.             $new = 1 if $new eq '';
  148.             $new = reindent($new);
  149.             $args = reindent($args);
  150.             if ($t ne '') {
  151.             $new =~ s/(['\\])/\\$1/g;        #']);
  152.  
  153.             if ($opt_h) {
  154.                 print OUT $t,"eval \"\\n#line $eval_index $outfile\\n\" . 'sub $name () {",$new,";}' unless defined(\&$name);\n";
  155.                 $eval_index++;
  156.             } else {
  157.                 print OUT $t,"eval 'sub $name () {",$new,";}' unless defined(\&$name);\n";
  158.             }
  159.             } else {
  160.                 # Shunt around such directives as `#define FOO FOO':
  161.                 next if " \&$name" eq $new;
  162.  
  163.                       print OUT $t,"unless(defined(\&$name)) {\n    sub $name () {\t",$new,";}\n}\n";
  164.             }
  165.         }
  166.         } elsif (/^(include|import|include_next)\s*[<\"](.*)[>\"]/) {
  167.                 $incl_type = $1;
  168.                 $incl = $2;
  169.                 if (($incl_type eq 'include_next') ||
  170.                     ($opt_e && exists($bad_file{$incl}))) {
  171.                     $incl =~ s/\.h$/.ph/;
  172.         print OUT ($t,
  173.                "eval {\n");
  174.                 $tab += 4;
  175.                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  176.                     print OUT ($t, "my(\@REM);\n");
  177.                     if ($incl_type eq 'include_next') {
  178.         print OUT ($t,
  179.                "my(\%INCD) = map { \$INC{\$_} => 1 } ",
  180.                        "(grep { \$_ eq \"$incl\" } ",
  181.                                    "keys(\%INC));\n");
  182.         print OUT ($t,
  183.                        "\@REM = map { \"\$_/$incl\" } ",
  184.                "(grep { not exists(\$INCD{\"\$_/$incl\"})",
  185.                        " and -f \"\$_/$incl\" } \@INC);\n");
  186.                     } else {
  187.                         print OUT ($t,
  188.                                    "\@REM = map { \"\$_/$incl\" } ",
  189.                                    "(grep {-r \"\$_/$incl\" } \@INC);\n");
  190.                     }
  191.         print OUT ($t,
  192.                "require \"\$REM[0]\" if \@REM;\n");
  193.                 $tab -= 4;
  194.                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  195.                 print OUT ($t,
  196.                "};\n");
  197.         print OUT ($t,
  198.                "warn(\$\@) if \$\@;\n");
  199.                 } else {
  200.                     $incl =~ s/\.h$/.ph/;
  201.             print OUT $t,"require '$incl';\n";
  202.                 }
  203.         } elsif (/^ifdef\s+(\w+)/) {
  204.         print OUT $t,"if(defined(&$1)) {\n";
  205.         $tab += 4;
  206.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  207.         } elsif (/^ifndef\s+(\w+)/) {
  208.         print OUT $t,"unless(defined(&$1)) {\n";
  209.         $tab += 4;
  210.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  211.         } elsif (s/^if\s+//) {
  212.         $new = '';
  213.         $inif = 1;
  214.         expr();
  215.         $inif = 0;
  216.         print OUT $t,"if($new) {\n";
  217.         $tab += 4;
  218.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  219.         } elsif (s/^elif\s+//) {
  220.         $new = '';
  221.         $inif = 1;
  222.         expr();
  223.         $inif = 0;
  224.         $tab -= 4;
  225.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  226.         print OUT $t,"}\n elsif($new) {\n";
  227.         $tab += 4;
  228.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  229.         } elsif (/^else/) {
  230.         $tab -= 4;
  231.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  232.         print OUT $t,"} else {\n";
  233.         $tab += 4;
  234.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  235.         } elsif (/^endif/) {
  236.         $tab -= 4;
  237.         $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
  238.         print OUT $t,"}\n";
  239.         } elsif(/^undef\s+(\w+)/) {
  240.         print OUT $t, "undef(&$1) if defined(&$1);\n";
  241.         } elsif(/^error\s+(".*")/) {
  242.         print OUT $t, "die($1);\n";
  243.         } elsif(/^error\s+(.*)/) {
  244.         print OUT $t, "die(\"", quotemeta($1), "\");\n";
  245.         } elsif(/^warning\s+(.*)/) {
  246.         print OUT $t, "warn(\"", quotemeta($1), "\");\n";
  247.         } elsif(/^ident\s+(.*)/) {
  248.         print OUT $t, "# $1\n";
  249.         }
  250.     } elsif(/^\s*(typedef\s*)?enum\s*(\s+[a-zA-Z_]\w*\s*)?/) {
  251.         until(/\{[^}]*\}.*;/ || /;/) {
  252.         last unless defined ($next = next_line($file));
  253.         chomp $next;
  254.         # drop "#define FOO FOO" in enums
  255.         $next =~ s/^\s*#\s*define\s+(\w+)\s+\1\s*$//;
  256.         $_ .= $next;
  257.         print OUT "# $next\n" if $opt_D;
  258.         }
  259.         s/#\s*if.*?#\s*endif//g; # drop #ifdefs
  260.         s@/\*.*?\*/@@g;
  261.         s/\s+/ /g;
  262.         next unless /^\s?(typedef\s?)?enum\s?([a-zA-Z_]\w*)?\s?\{(.*)\}\s?([a-zA-Z_]\w*)?\s?;/;
  263.         (my $enum_subs = $3) =~ s/\s//g;
  264.         my @enum_subs = split(/,/, $enum_subs);
  265.         my $enum_val = -1;
  266.         foreach my $enum (@enum_subs) {
  267.         my ($enum_name, $enum_value) = $enum =~ /^([a-zA-Z_]\w*)(=.+)?$/;
  268.         $enum_value =~ s/^=//;
  269.         $enum_val = (length($enum_value) ? $enum_value : $enum_val + 1);
  270.         if ($opt_h) {
  271.             print OUT ($t,
  272.                    "eval(\"\\n#line $eval_index $outfile\\n",
  273.                    "sub $enum_name () \{ $enum_val; \}\") ",
  274.                    "unless defined(\&$enum_name);\n");
  275.             ++ $eval_index;
  276.         } else {
  277.             print OUT ($t,
  278.                    "eval(\"sub $enum_name () \{ $enum_val; \}\") ",
  279.                    "unless defined(\&$enum_name);\n");
  280.         }
  281.         }
  282.     }
  283.     }
  284.     $Is_converted{$file} = 1;
  285.     if ($opt_e && exists($bad_file{$file})) {
  286.         unlink($Dest_dir . '/' . $outfile);
  287.         $next = '';
  288.     } else {
  289.         print OUT "1;\n";
  290.     queue_includes_from($file) if ($opt_a);
  291.     }
  292. }
  293.  
  294. if ($opt_e && (scalar(keys %bad_file) > 0)) {
  295.     warn "Was unable to convert the following files:\n";
  296.     warn "\t" . join("\n\t",sort(keys %bad_file)) . "\n";
  297. }
  298.  
  299. exit $Exit;
  300.  
  301. sub expr {
  302.     my $joined_args;
  303.     if(keys(%curargs)) {
  304.     $joined_args = join('|', keys(%curargs));
  305.     }
  306.     while ($_ ne '') {
  307.     s/^\&\&// && do { $new .= " &&"; next;}; # handle && operator
  308.     s/^\&([\(a-z\)]+)/$1/i;    # hack for things that take the address of
  309.     s/^(\s+)//        && do {$new .= ' '; next;};
  310.     s/^0X([0-9A-F]+)[UL]*//i 
  311.         && do {my $hex = $1;
  312.            $hex =~ s/^0+//;
  313.            if (length $hex > 8 && !$Config{use64bitint}) {
  314.                # Croak if nv_preserves_uv_bits < 64 ?
  315.                $new .=         hex(substr($hex, -8)) +
  316.                    2**32 * hex(substr($hex,  0, -8));
  317.                # The above will produce "errorneus" code
  318.                # if the hex constant was e.g. inside UINT64_C
  319.                # macro, but then again, h2ph is an approximation.
  320.            } else {
  321.                $new .= lc("0x$hex");
  322.            }
  323.            next;};
  324.     s/^(-?\d+\.\d+E[-+]?\d+)[FL]?//i    && do {$new .= $1; next;};
  325.     s/^(\d+)\s*[LU]*//i    && do {$new .= $1; next;};
  326.     s/^("(\\"|[^"])*")//    && do {$new .= $1; next;};
  327.     s/^'((\\"|[^"])*)'//    && do {
  328.         if ($curargs{$1}) {
  329.         $new .= "ord('\$$1')";
  330.         } else {
  331.         $new .= "ord('$1')";
  332.         }
  333.         next;
  334.     };
  335.         # replace "sizeof(foo)" with "{foo}"
  336.         # also, remove * (C dereference operator) to avoid perl syntax
  337.         # problems.  Where the %sizeof array comes from is anyone's
  338.         # guess (c2ph?), but this at least avoids fatal syntax errors.
  339.         # Behavior is undefined if sizeof() delimiters are unbalanced.
  340.         # This code was modified to able to handle constructs like this:
  341.         #   sizeof(*(p)), which appear in the HP-UX 10.01 header files.
  342.         s/^sizeof\s*\(// && do {
  343.             $new .= '$sizeof';
  344.             my $lvl = 1;  # already saw one open paren
  345.             # tack { on the front, and skip it in the loop
  346.             $_ = "{" . "$_";
  347.             my $index = 1;
  348.             # find balanced closing paren
  349.             while ($index <= length($_) && $lvl > 0) {
  350.                 $lvl++ if substr($_, $index, 1) eq "(";
  351.                 $lvl-- if substr($_, $index, 1) eq ")";
  352.                 $index++;
  353.             }
  354.             # tack } on the end, replacing )
  355.             substr($_, $index - 1, 1) = "}";
  356.             # remove pesky * operators within the sizeof argument
  357.             substr($_, 0, $index - 1) =~ s/\*//g;
  358.             next;
  359.         };
  360.     # Eliminate typedefs
  361.     /\(([\w\s]+)[\*\s]*\)\s*[\w\(]/ && do {
  362.         foreach (split /\s+/, $1) {  # Make sure all the words are types,
  363.         last unless ($isatype{$_} or $_ eq 'struct' or $_ eq 'union');
  364.         }
  365.         s/\([\w\s]+[\*\s]*\)// && next;      # then eliminate them.
  366.     };
  367.     # struct/union member, including arrays:
  368.     s/^([_A-Z]\w*(\[[^\]]+\])?((\.|->)[_A-Z]\w*(\[[^\]]+\])?)+)//i && do {
  369.         my $id = $1;
  370.         $id =~ s/(\.|(->))([^\.\-]*)/->\{$3\}/g;
  371.         $id =~ s/\b([^\$])($joined_args)/$1\$$2/g if length($joined_args);
  372.         while($id =~ /\[\s*([^\$\&\d\]]+)\]/) {
  373.         my($index) = $1;
  374.         $index =~ s/\s//g;
  375.         if(exists($curargs{$index})) {
  376.             $index = "\$$index";
  377.         } else {
  378.             $index = "&$index";
  379.         }
  380.         $id =~ s/\[\s*([^\$\&\d\]]+)\]/[$index]/;
  381.         }
  382.         $new .= " (\$$id)";
  383.     };
  384.     s/^([_a-zA-Z]\w*)//    && do {
  385.         my $id = $1;
  386.         if ($id eq 'struct' || $id eq 'union') {
  387.         s/^\s+(\w+)//;
  388.         $id .= ' ' . $1;
  389.         $isatype{$id} = 1;
  390.         } elsif ($id =~ /^((un)?signed)|(long)|(short)$/) {
  391.         while (s/^\s+(\w+)//) { $id .= ' ' . $1; }
  392.         $isatype{$id} = 1;
  393.         }
  394.         if ($curargs{$id}) {
  395.         $new .= "\$$id";
  396.         $new .= '->' if /^[\[\{]/;
  397.         } elsif ($id eq 'defined') {
  398.         $new .= 'defined';
  399.         } elsif (/^\s*\(/) {
  400.         s/^\s*\((\w),/("$1",/ if $id =~ /^_IO[WR]*$/i;    # cheat
  401.         $new .= " &$id";
  402.         } elsif ($isatype{$id}) {
  403.         if ($new =~ /{\s*$/) {
  404.             $new .= "'$id'";
  405.         } elsif ($new =~ /\(\s*$/ && /^[\s*]*\)/) {
  406.             $new =~ s/\(\s*$//;
  407.             s/^[\s*]*\)//;
  408.         } else {
  409.             $new .= q(').$id.q(');
  410.         }
  411.         } else {
  412.         if ($inif && $new !~ /defined\s*\($/) {
  413.             $new .= '(defined(&' . $id . ') ? &' . $id . ' : 0)';
  414.         } elsif (/^\[/) {
  415.             $new .= " \$$id";
  416.         } else {
  417.             $new .= ' &' . $id;
  418.         }
  419.         }
  420.         next;
  421.     };
  422.     s/^(.)// && do { if ($1 ne '#') { $new .= $1; } next;};
  423.     }
  424. }
  425.  
  426.  
  427. sub next_line
  428. {
  429.     my $file = shift;
  430.     my ($in, $out);
  431.     my $pre_sub_tri_graphs = 1;
  432.  
  433.     READ: while (not eof IN) {
  434.         $in  .= <IN>;
  435.         chomp $in;
  436.         next unless length $in;
  437.  
  438.         while (length $in) {
  439.             if ($pre_sub_tri_graphs) {
  440.                 # Preprocess all tri-graphs 
  441.                 # including things stuck in quoted string constants.
  442.                 $in =~ s/\?\?=/#/g;                         # | ??=|  #|
  443.                 $in =~ s/\?\?\!/|/g;                        # | ??!|  ||
  444.                 $in =~ s/\?\?'/^/g;                         # | ??'|  ^|
  445.                 $in =~ s/\?\?\(/[/g;                        # | ??(|  [|
  446.                 $in =~ s/\?\?\)/]/g;                        # | ??)|  ]|
  447.                 $in =~ s/\?\?\-/~/g;                        # | ??-|  ~|
  448.                 $in =~ s/\?\?\//\\/g;                       # | ??/|  \|
  449.                 $in =~ s/\?\?</{/g;                         # | ??<|  {|
  450.                 $in =~ s/\?\?>/}/g;                         # | ??>|  }|
  451.             }
  452.         if ($in =~ /^\#ifdef __LANGUAGE_PASCAL__/) {
  453.                 # Tru64 disassembler.h evilness: mixed C and Pascal.
  454.         while (<IN>) {
  455.             last if /^\#endif/; 
  456.         }
  457.         next READ;
  458.         }
  459.         if ($in =~ /^extern inline / && # Inlined assembler.
  460.         $^O eq 'linux' && $file =~ m!(?:^|/)asm/[^/]+\.h$!) {
  461.          while (<IN>) {
  462.             last if /^}/; 
  463.         }
  464.         next READ;
  465.         }
  466.             if ($in =~ s/\\$//) {                           # \-newline
  467.                 $out    .= ' ';
  468.                 next READ;
  469.             } elsif ($in =~ s/^([^"'\\\/]+)//) {            # Passthrough
  470.                 $out    .= $1;
  471.             } elsif ($in =~ s/^(\\.)//) {                   # \...
  472.                 $out    .= $1;
  473.             } elsif ($in =~ /^'/) {                         # '...
  474.                 if ($in =~ s/^('(\\.|[^'\\])*')//) {
  475.                     $out    .= $1;
  476.                 } else {
  477.                     next READ;
  478.                 }
  479.             } elsif ($in =~ /^"/) {                         # "...
  480.                 if ($in =~ s/^("(\\.|[^"\\])*")//) {
  481.                     $out    .= $1;
  482.                 } else {
  483.                     next READ;
  484.                 }
  485.             } elsif ($in =~ s/^\/\/.*//) {                  # //...
  486.                 # fall through
  487.             } elsif ($in =~ m/^\/\*/) {                     # /*...
  488.                 # C comment removal adapted from perlfaq6:
  489.                 if ($in =~ s/^\/\*[^*]*\*+([^\/*][^*]*\*+)*\///) {
  490.                     $out    .= ' ';
  491.                 } else {                                    # Incomplete /* */
  492.                     next READ;
  493.                 }
  494.             } elsif ($in =~ s/^(\/)//) {                    # /...
  495.                 $out    .= $1;
  496.             } elsif ($in =~ s/^([^\'\"\\\/]+)//) {
  497.                 $out    .= $1;
  498.             } elsif ($^O eq 'linux' &&
  499.                      $file =~ m!(?:^|/)linux/byteorder/pdp_endian\.h$! &&
  500.                      $in   =~ s!\'T KNOW!!) {
  501.                 $out    =~ s!I DON$!I_DO_NOT_KNOW!;
  502.             } else {
  503.                 if ($opt_e) {
  504.                     warn "Cannot parse $file:\n$in\n";
  505.                     $bad_file{$file} = 1;
  506.                     $in = '';
  507.                     $out = undef;
  508.                     last READ;
  509.                 } else {
  510.         die "Cannot parse:\n$in\n";
  511.                 }
  512.             }
  513.         }
  514.  
  515.         last READ if $out =~ /\S/;
  516.     }
  517.  
  518.     return $out;
  519. }
  520.  
  521.  
  522. # Handle recursive subdirectories without getting a grotesquely big stack.
  523. # Could this be implemented using File::Find?
  524. sub next_file
  525. {
  526.     my $file;
  527.  
  528.     while (@ARGV) {
  529.         $file = shift @ARGV;
  530.  
  531.         if ($file eq '-' or -f $file or -l $file) {
  532.             return $file;
  533.         } elsif (-d $file) {
  534.             if ($opt_r) {
  535.                 expand_glob($file);
  536.             } else {
  537.                 print STDERR "Skipping directory `$file'\n";
  538.             }
  539.         } elsif ($opt_a) {
  540.             return $file;
  541.         } else {
  542.             print STDERR "Skipping `$file':  not a file or directory\n";
  543.         }
  544.     }
  545.  
  546.     return undef;
  547. }
  548.  
  549.  
  550. # Put all the files in $directory into @ARGV for processing.
  551. sub expand_glob
  552. {
  553.     my ($directory)  = @_;
  554.  
  555.     $directory =~ s:/$::;
  556.  
  557.     opendir DIR, $directory;
  558.         foreach (readdir DIR) {
  559.             next if ($_ eq '.' or $_ eq '..');
  560.  
  561.             # expand_glob() is going to be called until $ARGV[0] isn't a
  562.             # directory; so push directories, and unshift everything else.
  563.             if (-d "$directory/$_") { push    @ARGV, "$directory/$_" }
  564.             else                    { unshift @ARGV, "$directory/$_" }
  565.         }
  566.     closedir DIR;
  567. }
  568.  
  569.  
  570. # Given $file, a symbolic link to a directory in the C include directory,
  571. # make an equivalent symbolic link in $Dest_dir, if we can figure out how.
  572. # Otherwise, just duplicate the file or directory.
  573. sub link_if_possible
  574. {
  575.     my ($dirlink)  = @_;
  576.     my $target  = eval 'readlink($dirlink)';
  577.  
  578.     if ($target =~ m:^\.\./: or $target =~ m:^/:) {
  579.         # The target of a parent or absolute link could leave the $Dest_dir
  580.         # hierarchy, so let's put all of the contents of $dirlink (actually,
  581.         # the contents of $target) into @ARGV; as a side effect down the
  582.         # line, $dirlink will get created as an _actual_ directory.
  583.         expand_glob($dirlink);
  584.     } else {
  585.         if (-l "$Dest_dir/$dirlink") {
  586.             unlink "$Dest_dir/$dirlink" or
  587.                 print STDERR "Could not remove link $Dest_dir/$dirlink:  $!\n";
  588.         }
  589.  
  590.         if (eval 'symlink($target, "$Dest_dir/$dirlink")') {
  591.             print "Linking $target -> $Dest_dir/$dirlink\n";
  592.  
  593.             # Make sure that the link _links_ to something:
  594.             if (! -e "$Dest_dir/$target") {
  595.                 mkpath("$Dest_dir/$target", 0755) or
  596.                     print STDERR "Could not create $Dest_dir/$target/\n";
  597.             }
  598.         } else {
  599.             print STDERR "Could not symlink $target -> $Dest_dir/$dirlink:  $!\n";
  600.         }
  601.     }
  602. }
  603.  
  604.  
  605. # Push all #included files in $file onto our stack, except for STDIN
  606. # and files we've already processed.
  607. sub queue_includes_from
  608. {
  609.     my ($file)    = @_;
  610.     my $line;
  611.  
  612.     return if ($file eq "-");
  613.  
  614.     open HEADER, $file or return;
  615.         while (defined($line = <HEADER>)) {
  616.             while (/\\$/) { # Handle continuation lines
  617.                 chop $line;
  618.                 $line .= <HEADER>;
  619.             }
  620.  
  621.             if ($line =~ /^#\s*include\s+<(.*?)>/) {
  622.                 push(@ARGV, $1) unless $Is_converted{$1};
  623.             }
  624.         }
  625.     close HEADER;
  626. }
  627.  
  628.  
  629. # Determine include directories; $Config{usrinc} should be enough for (all
  630. # non-GCC?) C compilers, but gcc uses an additional include directory.
  631. sub inc_dirs
  632. {
  633.     my $from_gcc    = `$Config{cc} -v 2>&1`;
  634.     $from_gcc       =~ s:^Reading specs from (.*?)/specs\b.*:$1/include:s;
  635.  
  636.     length($from_gcc) ? ($from_gcc, $Config{usrinc}) : ($Config{usrinc});
  637. }
  638.  
  639.  
  640. # Create "_h2ph_pre.ph", if it doesn't exist or was built by a different
  641. # version of h2ph.
  642. sub build_preamble_if_necessary
  643. {
  644.     # Increment $VERSION every time this function is modified:
  645.     my $VERSION     = 2;
  646.     my $preamble    = "$Dest_dir/_h2ph_pre.ph";
  647.  
  648.     # Can we skip building the preamble file?
  649.     if (-r $preamble) {
  650.         # Extract version number from first line of preamble:
  651.         open  PREAMBLE, $preamble or die "Cannot open $preamble:  $!";
  652.             my $line = <PREAMBLE>;
  653.             $line =~ /(\b\d+\b)/;
  654.         close PREAMBLE            or die "Cannot close $preamble:  $!";
  655.  
  656.         # Don't build preamble if a compatible preamble exists:
  657.         return if $1 == $VERSION;
  658.     }
  659.  
  660.     my (%define) = _extract_cc_defines();
  661.  
  662.     open  PREAMBLE, ">$preamble" or die "Cannot open $preamble:  $!";
  663.         print PREAMBLE "# This file was created by h2ph version $VERSION\n";
  664.  
  665.         foreach (sort keys %define) {
  666.             if ($opt_D) {
  667.                 print PREAMBLE "# $_=$define{$_}\n";
  668.             }
  669.  
  670.             if ($define{$_} =~ /^(\d+)U?L{0,2}$/i) {
  671.                 print PREAMBLE
  672.                     "unless (defined &$_) { sub $_() { $1 } }\n\n";
  673.             } elsif ($define{$_} =~ /^\w+$/) {
  674.                 print PREAMBLE
  675.                     "unless (defined &$_) { sub $_() { &$define{$_} } }\n\n";
  676.             } else {
  677.                 print PREAMBLE
  678.                     "unless (defined &$_) { sub $_() { \"",
  679.                     quotemeta($define{$_}), "\" } }\n\n";
  680.             }
  681.         }
  682.     close PREAMBLE               or die "Cannot close $preamble:  $!";
  683. }
  684.  
  685.  
  686. # %Config contains information on macros that are pre-defined by the
  687. # system's compiler.  We need this information to make the .ph files
  688. # function with perl as the .h files do with cc.
  689. sub _extract_cc_defines
  690. {
  691.     my %define;
  692.     my $allsymbols  = join " ",
  693.         @Config{'ccsymbols', 'cppsymbols', 'cppccsymbols'};
  694.  
  695.     # Split compiler pre-definitions into `key=value' pairs:
  696.     foreach (split /\s+/, $allsymbols) {
  697.         /(.+?)=(.+)/ and $define{$1} = $2;
  698.  
  699.         if ($opt_D) {
  700.             print STDERR "$_:  $1 -> $2\n";
  701.         }
  702.     }
  703.  
  704.     return %define;
  705. }
  706.  
  707.  
  708. 1;
  709.  
  710. ##############################################################################
  711. __END__
  712.  
  713. =head1 NAME
  714.  
  715. h2ph - convert .h C header files to .ph Perl header files
  716.  
  717. =head1 SYNOPSIS
  718.  
  719. B<h2ph [-d destination directory] [-r | -a] [-l] [headerfiles]>
  720.  
  721. =head1 DESCRIPTION
  722.  
  723. I<h2ph>
  724. converts any C header files specified to the corresponding Perl header file
  725. format.
  726. It is most easily run while in /usr/include:
  727.  
  728.     cd /usr/include; h2ph * sys/*
  729.  
  730. or
  731.  
  732.     cd /usr/include; h2ph * sys/* arpa/* netinet/*
  733.  
  734. or
  735.  
  736.     cd /usr/include; h2ph -r -l .
  737.  
  738. The output files are placed in the hierarchy rooted at Perl's
  739. architecture dependent library directory.  You can specify a different
  740. hierarchy with a B<-d> switch.
  741.  
  742. If run with no arguments, filters standard input to standard output.
  743.  
  744. =head1 OPTIONS
  745.  
  746. =over 4
  747.  
  748. =item -d destination_dir
  749.  
  750. Put the resulting B<.ph> files beneath B<destination_dir>, instead of
  751. beneath the default Perl library location (C<$Config{'installsitsearch'}>).
  752.  
  753. =item -r
  754.  
  755. Run recursively; if any of B<headerfiles> are directories, then run I<h2ph>
  756. on all files in those directories (and their subdirectories, etc.).  B<-r>
  757. and B<-a> are mutually exclusive.
  758.  
  759. =item -a
  760.  
  761. Run automagically; convert B<headerfiles>, as well as any B<.h> files
  762. which they include.  This option will search for B<.h> files in all
  763. directories which your C compiler ordinarily uses.  B<-a> and B<-r> are
  764. mutually exclusive.
  765.  
  766. =item -l
  767.  
  768. Symbolic links will be replicated in the destination directory.  If B<-l>
  769. is not specified, then links are skipped over.
  770.  
  771. =item -h
  772.  
  773. Put ``hints'' in the .ph files which will help in locating problems with
  774. I<h2ph>.  In those cases when you B<require> a B<.ph> file containing syntax
  775. errors, instead of the cryptic
  776.  
  777.     [ some error condition ] at (eval mmm) line nnn
  778.  
  779. you will see the slightly more helpful
  780.  
  781.     [ some error condition ] at filename.ph line nnn
  782.  
  783. However, the B<.ph> files almost double in size when built using B<-h>.
  784.  
  785. =item -D
  786.  
  787. Include the code from the B<.h> file as a comment in the B<.ph> file.
  788. This is primarily used for debugging I<h2ph>.
  789.  
  790. =item -Q
  791.  
  792. ``Quiet'' mode; don't print out the names of the files being converted.
  793.  
  794. =back
  795.  
  796. =head1 ENVIRONMENT
  797.  
  798. No environment variables are used.
  799.  
  800. =head1 FILES
  801.  
  802.  /usr/include/*.h
  803.  /usr/include/sys/*.h
  804.  
  805. etc.
  806.  
  807. =head1 AUTHOR
  808.  
  809. Larry Wall
  810.  
  811. =head1 SEE ALSO
  812.  
  813. perl(1)
  814.  
  815. =head1 DIAGNOSTICS
  816.  
  817. The usual warnings if it can't read or write the files involved.
  818.  
  819. =head1 BUGS
  820.  
  821. Doesn't construct the %sizeof array for you.
  822.  
  823. It doesn't handle all C constructs, but it does attempt to isolate
  824. definitions inside evals so that you can get at the definitions
  825. that it can translate.
  826.  
  827. It's only intended as a rough tool.
  828. You may need to dicker with the files produced.
  829.  
  830. You have to run this program by hand; it's not run as part of the Perl
  831. installation.
  832.  
  833. Doesn't handle complicated expressions built piecemeal, a la:
  834.  
  835.     enum {
  836.         FIRST_VALUE,
  837.         SECOND_VALUE,
  838.     #ifdef ABC
  839.         THIRD_VALUE
  840.     #endif
  841.     };
  842.  
  843. Doesn't necessarily locate all of your C compiler's internally-defined
  844. symbols.
  845.  
  846. =cut
  847.  
  848.  
  849. __END__
  850. :endofperl
  851.