home *** CD-ROM | disk | FTP | other *** search
/ PC World 2004 November / PCWorld_2004-11_cd.bin / software / topware / activeperl / ActivePerl-5.8.4.810-MSWin32-x86.exe / ActivePerl-5.8.4.810 / Perl / bin / POST < prev    next >
Text File  |  2004-06-01  |  15KB  |  531 lines
  1. #!/usr/bin/perl -w
  2.  
  3. # $Id: lwp-request,v 2.6 2003/10/26 14:39:18 gisle Exp $
  4. #
  5. # Simple user agent using LWP library.
  6.  
  7. =head1 NAME
  8.  
  9. lwp-request - Simple command line user agent
  10.  
  11. =head1 SYNOPSIS
  12.  
  13.  lwp-request [-aeEdvhx] [-m method] [-b <base URL>] [-t <timeout>]
  14.              [-i <if-modified-since>] [-c <content-type>] [-C <credentials>]
  15.              [-p <proxy-url>] [-o <format>] <url>...
  16.  
  17. =head1 DESCRIPTION
  18.  
  19. This program can be used to send requests to WWW servers and your
  20. local file system. The request content for POST and PUT
  21. methods is read from stdin.  The content of the response is printed on
  22. stdout.  Error messages are printed on stderr.  The program returns a
  23. status value indicating the number of URLs that failed.
  24.  
  25. The options are:
  26.  
  27. =over 4
  28.  
  29. =item -m <method>
  30.  
  31. Set which method to use for the request.  If this option is not used,
  32. then the method is derived from the name of the program.
  33.  
  34. =item -f
  35.  
  36. Force request through, even if the program believes that the method is
  37. illegal.  The server might reject the request eventually.
  38.  
  39. =item -b <uri>
  40.  
  41. This URI will be used as the base URI for resolving all relative URIs
  42. given as argument.
  43.  
  44. =item -t <timeout>
  45.  
  46. Set the timeout value for the requests.  The timeout is the amount of
  47. time that the program will wait for a response from the remote server
  48. before it fails.  The default unit for the timeout value is seconds.
  49. You might append "m" or "h" to the timeout value to make it minutes or
  50. hours, respectively.  The default timeout is '3m', i.e. 3 minutes.
  51.  
  52. =item -i <time>
  53.  
  54. Set the If-Modified-Since header in the request. If I<time> is the
  55. name of a file, use the modification timestamp for this file. If
  56. I<time> is not a file, it is parsed as a literal date. Take a look at
  57. L<HTTP::Date> for recognized formats.
  58.  
  59. =item -c <content-type>
  60.  
  61. Set the Content-Type for the request.  This option is only allowed for
  62. requests that take a content, i.e. POST and PUT.  You can
  63. force methods to take content by using the C<-f> option together with
  64. C<-c>.  The default Content-Type for POST is
  65. C<application/x-www-form-urlencoded>.  The default Content-type for
  66. the others is C<text/plain>.
  67.  
  68. =item -p <proxy-url>
  69.  
  70. Set the proxy to be used for the requests.  The program also loads
  71. proxy settings from the environment.  You can disable this with the
  72. C<-P> option.
  73.  
  74. =item -H <header>
  75.  
  76. Send this HTTP header with each request. You can specify several, e.g.:
  77.  
  78.     lwp-request \
  79.     -H 'Referer: http://other.url/' \
  80.     -H 'Host: somehost' \
  81.     http://this.url/
  82.  
  83. =item -C <username>:<password>
  84.  
  85. Provide credentials for documents that are protected by Basic
  86. Authentication.  If the document is protected and you did not specify
  87. the username and password with this option, then you will be prompted
  88. to provide these values.
  89.  
  90. =back
  91.  
  92. The following options controls what is displayed by the program:
  93.  
  94. =over 4
  95.  
  96. =item -u
  97.  
  98. Print request method and absolute URL as requests are made.
  99.  
  100. =item -U
  101.  
  102. Print request headers in addition to request method and absolute URL.
  103.  
  104. =item -s
  105.  
  106. Print response status code.  This option is always on for HEAD requests.
  107.  
  108. =item -S
  109.  
  110. Print response status chain. This shows redirect and authorization
  111. requests that are handled by the library.
  112.  
  113. =item -e
  114.  
  115. Print response headers.  This option is always on for HEAD requests.
  116.  
  117. =item -d
  118.  
  119. Do B<not> print the content of the response.
  120.  
  121. =item -o <format>
  122.  
  123. Process HTML content in various ways before printing it.  If the
  124. content type of the response is not HTML, then this option has no
  125. effect.  The legal format values are; I<text>, I<ps>, I<links>,
  126. I<html> and I<dump>.
  127.  
  128. If you specify the I<text> format then the HTML will be formatted as
  129. plain latin1 text.  If you specify the I<ps> format then it will be
  130. formatted as Postscript.
  131.  
  132. The I<links> format will output all links found in the HTML document.
  133. Relative links will be expanded to absolute ones.
  134.  
  135. The I<html> format will reformat the HTML code and the I<dump> format
  136. will just dump the HTML syntax tree.
  137.  
  138. =item -v
  139.  
  140. Print the version number of the program and quit.
  141.  
  142. =item -h
  143.  
  144. Print usage message and quit.
  145.  
  146. =item -x
  147.  
  148. Extra debugging output.
  149.  
  150. =item -a
  151.  
  152. Set text(ascii) mode for content input and output.  If this option is not
  153. used, content input and output is done in binary mode.
  154.  
  155. =back
  156.  
  157. Because this program is implemented using the LWP library, it will
  158. only support the protocols that LWP supports.
  159.  
  160. =head1 SEE ALSO
  161.  
  162. L<lwp-mirror>, L<LWP>
  163.  
  164. =head1 COPYRIGHT
  165.  
  166. Copyright 1995-1999 Gisle Aas.
  167.  
  168. This library is free software; you can redistribute it and/or
  169. modify it under the same terms as Perl itself.
  170.  
  171. =head1 AUTHOR
  172.  
  173. Gisle Aas <gisle@aas.no>
  174.  
  175. =cut
  176.  
  177. $progname = $0;
  178. $progname =~ s,.*[\\/],,;  # use basename only
  179. $progname =~ s/\.\w*$//;   # strip extension, if any
  180.  
  181. $VERSION = sprintf("%d.%02d", q$Revision: 2.6 $ =~ /(\d+)\.(\d+)/);
  182.  
  183.  
  184. require LWP;
  185. require LWP::Debug;
  186.  
  187. use URI;
  188. use URI::Heuristic qw(uf_uri);
  189.  
  190. use HTTP::Status qw(status_message);
  191. use HTTP::Date qw(time2str str2time);
  192.  
  193.  
  194. # This table lists the methods that are allowed.  It should really be
  195. # a superset for all methods supported for every scheme that may be
  196. # supported by the library.  Currently it might be a bit too HTTP
  197. # specific.  You might use the -f option to force a method through.
  198. #
  199. # "" = No content in request, "C" = Needs content in request
  200. #
  201. %allowed_methods = (
  202.     GET        => "",
  203.     HEAD       => "",
  204.     POST       => "C",
  205.     PUT        => "C",
  206.     DELETE     => "",
  207.     TRACE      => "",
  208.     OPTIONS    => "",
  209. );
  210.  
  211.  
  212. # We make our own specialization of LWP::UserAgent that asks for
  213. # user/password if document is protected.
  214. {
  215.     package RequestAgent;
  216.     @ISA = qw(LWP::UserAgent);
  217.  
  218.     sub new
  219.     { 
  220.     my $self = LWP::UserAgent::new(@_);
  221.     $self->agent("lwp-request/$main::VERSION");
  222.     $self;
  223.     }
  224.  
  225.     sub get_basic_credentials
  226.     {
  227.     my($self, $realm, $uri) = @_;
  228.     if ($main::options{'C'}) {
  229.         return split(':', $main::options{'C'}, 2);
  230.     }
  231.     elsif (-t) {
  232.         my $netloc = $uri->host_port;
  233.         print "Enter username for $realm at $netloc: ";
  234.         my $user = <STDIN>;
  235.         chomp($user);
  236.         return (undef, undef) unless length $user;
  237.         print "Password: ";
  238.         system("stty -echo");
  239.         my $password = <STDIN>;
  240.         system("stty echo");
  241.         print "\n";  # because we disabled echo
  242.         chomp($password);
  243.         return ($user, $password);
  244.     }
  245.     else {
  246.         return (undef, undef)
  247.     }
  248.     }
  249. }
  250.  
  251. $method = uc(lc($progname) eq "lwp-request" ? "GET" : $progname);
  252.  
  253. # Parse command line
  254. use Getopt::Long;
  255.  
  256. my @getopt_args = (
  257.     'a', # content i/o in text(ascii) mode
  258.     'm=s', # set method
  259.     'f', # make request even if method is not in %allowed_methods
  260.     'b=s', # base url
  261.     't=s', # timeout
  262.     'i=s', # if-modified-since
  263.     'c=s', # content type for POST
  264.     'C=s', # credentials for basic authorization
  265.     'H=s@', # extra headers, form "Header: value string"
  266.     #
  267.     'u', # display method, URL and headers of request
  268.     'U', # display request headers also
  269.     's', # display status code
  270.     'S', # display whole chain of status codes
  271.     'e', # display response headers (default for HEAD)
  272.     'd', # don't display content
  273.     #
  274.     'h', # print usage
  275.     'v', # print version
  276.     #
  277.     'x', # extra debugging info
  278.     'p=s', # proxy URL
  279.     'P', # don't load proxy setting from environment
  280.     #
  281.     'o=s', # output format
  282. );
  283.  
  284. Getopt::Long::config("noignorecase", "bundling");
  285. unless (GetOptions(\%options, @getopt_args)) {
  286.     usage();
  287. }
  288. if ($options{'v'}) {
  289.     require LWP;
  290.     my $DISTNAME = 'libwww-perl-' . LWP::Version();
  291.     die <<"EOT";
  292. This is lwp-request version $VERSION ($DISTNAME)
  293.  
  294. Copyright 1995-1999, Gisle Aas.
  295.  
  296. This program is free software; you can redistribute it and/or
  297. modify it under the same terms as Perl itself.
  298. EOT
  299. }
  300.  
  301. usage() if $options{'h'} || !@ARGV;
  302.  
  303. LWP::Debug::level('+') if $options{'x'};
  304.  
  305. # Create the user agent object
  306. $ua = RequestAgent->new;
  307.  
  308. # Load proxy settings from *_proxy environment variables.
  309. $ua->env_proxy unless $options{'P'};
  310.  
  311. $method = uc($options{'m'}) if defined $options{'m'};
  312.  
  313. if ($options{'f'}) {
  314.     if ($options{'c'}) {
  315.         $allowed_methods{$method} = "C";  # force content
  316.     }
  317.     else {
  318.         $allowed_methods{$method} = "";
  319.     }
  320. }
  321. elsif (!defined $allowed_methods{$method}) {
  322.     die "$progname: $method is not an allowed method\n";
  323. }
  324.  
  325. if ($method eq "HEAD") {
  326.     $options{'s'} = 1;
  327.     $options{'e'} = 1 unless $options{'d'};
  328.     $options{'d'} = 1;
  329. }
  330.  
  331. if (defined $options{'t'}) {
  332.     $options{'t'} =~ /^(\d+)([smh])?/;
  333.     die "$progname: Illegal timeout value!\n" unless defined $1;
  334.     $timeout = $1;
  335.     if (defined $2) {
  336.         $timeout *= 60   if $2 eq "m";
  337.         $timeout *= 3600 if $2 eq "h";
  338.     }
  339.     $ua->timeout($timeout);
  340. }
  341.  
  342. if (defined $options{'i'}) {
  343.     if (-e $options{'i'}) {
  344.         $time = (stat _)[9];
  345.     }
  346.     else {
  347.         $time = str2time($options{'i'});
  348.         die "$progname: Illegal time syntax for -i option\n"
  349.             unless defined $time;
  350.     }
  351.     $options{'i'} = time2str($time);
  352. }
  353.  
  354. $content = undef;
  355. if ($allowed_methods{$method} eq "C") {
  356.     # This request needs some content
  357.     unless (defined $options{'c'}) {
  358.         # set default content type
  359.         $options{'c'} = ($method eq "POST") ?
  360.               "application/x-www-form-urlencoded"
  361.             : "text/plain";
  362.     }
  363.     else {
  364.         die "$progname: Illegal Content-type format\n"
  365.             unless $options{'c'} =~ m,^[\w\-]+/[\w\-]+(?:\s*;.*)?$,
  366.     }
  367.     print "Please enter content ($options{'c'}) to be ${method}ed:\n"
  368.         if -t;
  369.     binmode STDIN unless -t or $options{'a'};
  370.     $content = join("", <STDIN>);
  371. }
  372. else {
  373.     die "$progname: Can't set Content-type for $method requests\n"
  374.         if defined $options{'c'};
  375. }
  376.  
  377. # Set up a request.  We will use the same request object for all URLs.
  378. $request = HTTP::Request->new($method);
  379. $request->header('If-Modified-Since', $options{'i'}) if defined $options{'i'};
  380. for my $user_header (@{ $options{'H'} || [] }) {
  381.     my ($header_name, $header_value) = split /:\s*/, $user_header, 2;
  382.     $request->header($header_name, $header_value);
  383.     $ua->agent($header_value) if lc($header_name) eq "user-agent"; # Ugh!
  384. }
  385. #$request->header('Accept', '*/*');
  386. if ($options{'c'}) { # will always be set for request that wants content
  387.     $request->header('Content-Type', $options{'c'});
  388.     $request->header('Content-Length', length $content);  # Not really needed
  389.     $request->content($content);
  390. }
  391.  
  392. $errors = 0;
  393.  
  394. # Ok, now we perform the requests, one URL at a time
  395. while ($url = shift) {
  396.     # Create the URL object, but protect us against bad URLs
  397.     eval {
  398.     if ($url =~ /^\w+:/ || $options{'b'}) {  # is there any scheme specification
  399.         $url = URI->new($url, $options{'b'});
  400.         $url = $url->abs($options{'b'}) if $options{'b'};
  401.     }
  402.     else {
  403.         $url = uf_uri($url);
  404.         }
  405.     };
  406.     if ($@) {
  407.     $@ =~ s/ at .* line \d+.*//;
  408.     print STDERR $@;
  409.     $errors++;
  410.     next;
  411.     }
  412.  
  413.     $ua->proxy($url->scheme, $options{'p'}) if $options{'p'};
  414.  
  415.     # Send the request and get a response back from the server
  416.     $request->url($url);
  417.     $response = $ua->request($request);
  418.  
  419.     if ($options{'u'} || $options{'U'}) {
  420.         my $url = $response->request->url->as_string;
  421.         print "$method $url\n";
  422.         print $response->request->headers_as_string, "\n" if $options{'U'};
  423.     }
  424.  
  425.     if ($options{'S'}) {
  426.     printResponseChain($response);
  427.     }
  428.     elsif ($options{'s'}) {
  429.         print $response->status_line, "\n";
  430.     }
  431.  
  432.     if ($options{'e'}) {
  433.         # Display headers
  434.         print $response->headers_as_string;
  435.         print "\n";  # separate headers and content
  436.     }
  437.  
  438.     unless ($options{'d'}) {
  439.     if ($options{'o'} &&
  440.         $response->content_type eq 'text/html') {
  441.         require HTML::Parse;
  442.         my $html = HTML::Parse::parse_html($response->content);
  443.         {
  444.         $options{'o'} eq 'ps' && do {
  445.             require HTML::FormatPS;
  446.             my $f = HTML::FormatPS->new;
  447.             print $f->format($html);
  448.             last;
  449.         };
  450.         $options{'o'} eq 'text' && do {
  451.             require HTML::FormatText;
  452.             my $f = HTML::FormatText->new;
  453.             print $f->format($html);
  454.             last;
  455.         };
  456.         $options{'o'} eq 'html' && do {
  457.             print $html->as_HTML;
  458.             last;
  459.         };
  460.         $options{'o'} eq 'links' && do {
  461.             my $base = $response->base;
  462.             for ( @{ $html->extract_links } ) {
  463.             my($link, $elem) = @$_;
  464.             my $tag = uc $elem->tag;
  465.             $link = URI->new($link)->abs($base)->as_string;
  466.             print "$tag\t$link\n";
  467.             }
  468.             last;
  469.         };
  470.         $options{'o'} eq 'dump' && do {
  471.             $html->dump;
  472.             last;
  473.         };
  474.         # It is bad to not notice this before now :-(
  475.         die "Illegal -o option value ($options{'o'})\n";
  476.         }
  477.     }
  478.     else {
  479.         binmode STDOUT unless $options{'a'};
  480.         print $response->content;
  481.     }
  482.     }
  483.  
  484.     $errors++ unless $response->is_success;
  485. }
  486.  
  487. exit $errors;
  488.  
  489.  
  490. sub printResponseChain
  491. {
  492.     my($response) = @_;
  493.     return unless defined $response;
  494.     printResponseChain($response->previous);
  495.     my $method = $response->request->method;
  496.     my $url = $response->request->url->as_string;
  497.     my $code = $response->code;
  498.     print "$method $url --> ", $response->status_line, "\n";
  499. }
  500.  
  501.  
  502. sub usage
  503. {
  504.     die <<"EOT";
  505. Usage: $progname [-options] <url>...
  506.     -m <method>   use method for the request (default is '$method')
  507.     -f            make request even if $progname believes method is illegal
  508.     -b <base>     Use the specified URL as base
  509.     -t <timeout>  Set timeout value
  510.     -i <time>     Set the If-Modified-Since header on the request
  511.     -c <conttype> use this content-type for POST, PUT, CHECKIN
  512.     -a            Use text mode for content I/O
  513.     -p <proxyurl> use this as a proxy
  514.     -P            don't load proxy settings from environment
  515.     -H <header>   send this HTTP header (you can specify several)
  516.  
  517.     -u            Display method and URL before any response
  518.     -U            Display request headers (implies -u)
  519.     -s            Display response status code
  520.     -S            Display response status chain
  521.     -e            Display response headers
  522.     -d            Do not display content
  523.     -o <format>   Process HTML content in various ways
  524.  
  525.     -v            Show program version
  526.     -h            Print this message
  527.  
  528.     -x            Extra debugging output
  529. EOT
  530. }
  531.