home *** CD-ROM | disk | FTP | other *** search
/ PC World 2003 March / PCWorld_2003-03_cd.bin / Software / Topware / activeperl / ActivePerl / Perl / lib / Encode / PerlIO.pod < prev    next >
Encoding:
Text File  |  2002-06-19  |  6.1 KB  |  170 lines
  1. =head1 NAME
  2.  
  3. Encode::PerlIO -- a detailed document on Encode and PerlIO
  4.  
  5. =head1 Overview
  6.  
  7. It is very common to want to do encoding transformations when
  8. reading or writing files, network connections, pipes etc.
  9. If Perl is configured to use the new 'perlio' IO system then
  10. C<Encode> provides a "layer" (see L<PerlIO>) which can transform
  11. data as it is read or written.
  12.  
  13. Here is how the blind poet would modernise the encoding:
  14.  
  15.     use Encode;
  16.     open(my $iliad,'<:encoding(iso-8859-7)','iliad.greek');
  17.     open(my $utf8,'>:utf8','iliad.utf8');
  18.     my @epic = <$iliad>;
  19.     print $utf8 @epic;
  20.     close($utf8);
  21.     close($illiad);
  22.  
  23. In addition, the new IO system can also be configured to read/write
  24. UTF-8 encoded characters (as noted above, this is efficient):
  25.  
  26.     open(my $fh,'>:utf8','anything');
  27.     print $fh "Any \x{0021} string \N{SMILEY FACE}\n";
  28.  
  29. Either of the above forms of "layer" specifications can be made the default
  30. for a lexical scope with the C<use open ...> pragma. See L<open>.
  31.  
  32. Once a handle is open, its layers can be altered using C<binmode>.
  33.  
  34. Without any such configuration, or if Perl itself is built using the
  35. system's own IO, then write operations assume that the file handle
  36. accepts only I<bytes> and will C<die> if a character larger than 255 is
  37. written to the handle. When reading, each octet from the handle becomes
  38. a byte-in-a-character. Note that this default is the same behaviour
  39. as bytes-only languages (including Perl before v5.6) would have,
  40. and is sufficient to handle native 8-bit encodings e.g. iso-8859-1,
  41. EBCDIC etc. and any legacy mechanisms for handling other encodings
  42. and binary data.
  43.  
  44. In other cases, it is the program's responsibility to transform
  45. characters into bytes using the API above before doing writes, and to
  46. transform the bytes read from a handle into characters before doing
  47. "character operations" (e.g. C<lc>, C</\W+/>, ...).
  48.  
  49. You can also use PerlIO to convert larger amounts of data you don't
  50. want to bring into memory.  For example, to convert between ISO-8859-1
  51. (Latin 1) and UTF-8 (or UTF-EBCDIC in EBCDIC machines):
  52.  
  53.     open(F, "<:encoding(iso-8859-1)", "data.txt") or die $!;
  54.     open(G, ">:utf8",                 "data.utf") or die $!;
  55.     while (<F>) { print G }
  56.  
  57.     # Could also do "print G <F>" but that would pull
  58.     # the whole file into memory just to write it out again.
  59.  
  60. More examples:
  61.  
  62.     open(my $f, "<:encoding(cp1252)")
  63.     open(my $g, ">:encoding(iso-8859-2)")
  64.     open(my $h, ">:encoding(latin9)")       # iso-8859-15
  65.  
  66. See also L<encoding> for how to change the default encoding of the
  67. data in your script.
  68.  
  69. =head1 How does it work?
  70.  
  71. Here is a crude diagram of how filehandle, PerlIO, and Encode
  72. interact.
  73.  
  74.   filehandle <-> PerlIO        PerlIO <-> scalar (read/printed)
  75.                        \      /
  76.                         Encode   
  77.  
  78. When PerlIO receives data from either direction, it fills a buffer
  79. (currently with 1024 bytes) and passes the buffer to Encode.
  80. Encode tries to convert the valid part and passes it back to PerlIO,
  81. leaving invalid parts (usually a partial character) in the buffer.
  82. PerlIO then appends more data to the buffer, calls Encode again,
  83. and so on until the data stream ends.
  84.  
  85. To do so, PerlIO always calls (de|en)code methods with CHECK set to 1.
  86. This ensures that the method stops at the right place when it
  87. encounters partial character.  The following is what happens when
  88. PerlIO and Encode tries to encode (from utf8) more than 1024 bytes
  89. and the buffer boundary happens to be in the middle of a character.
  90.  
  91.    A   B   C   ....   ~     \x{3000}    ....
  92.   41  42  43   ....  7E   e3   80   80  ....
  93.   <- buffer --------------->
  94.   << encoded >>>>>>>>>>
  95.                        <- next buffer ------
  96.  
  97. Encode converts from the beginning to \x7E, leaving \xe3 in the buffer
  98. because it is invalid (partial character).
  99.  
  100. Unfortunately, this scheme does not work well with escape-based
  101. encodings such as ISO-2022-JP.  Let's see what happens in that case
  102. in the next chapter.
  103.  
  104. =head1 BUGS
  105.  
  106. Now let's see what happens when you try to decode from ISO-2022-JP and
  107. the buffer ends in the middle of a character.
  108.  
  109.               JIS208-ESC   \x{5f3e}
  110.    A   B   C   ....   ~   \e   $   B  |DAN | ....
  111.   41  42  43   ....  7E   1b  24  41  43  46 ....
  112.   <- buffer --------------------------->
  113.   << encoded >>>>>>>>>>>>>>>>>>>>>>>
  114.  
  115. As you see, the next buffer begins with \x43.  But \x43 is 'C' in
  116. ASCII, which is wrong in this case because we are now in JISX 0208
  117. area so it has to convert \x43\x46, not \x43.  Unlike utf8 and EUC,
  118. in escape-based encodings you can't tell if a given octet is a whole
  119. character or just part of it.
  120.  
  121. There are actually several ways to solve this problem but none of
  122. them is fast enough to be practical.  From Encode's point of view,
  123. the easiest solution is for PerlIO to implement a line buffer instead
  124. of a fixed-length buffer, but that makes PerlIO really complicated.
  125.  
  126. So for the time being, using escape-based encodings in the
  127. ":encoding()" layer of PerlIO does not work well.
  128.  
  129. =head2 Workaround
  130.  
  131. If you still insist, you can at least use ":encoding()" by making sure
  132. the buffer never gets full.  Here is an example.
  133.  
  134.   use FileHandle;
  135.   binmode(STDOUT, ":encoding(7bit-jis)");
  136.   STDOUT->autoflush(1); # don't forget this!
  137.   for my $l (@lines){   # $l cannot be longer than 1023 bytes
  138.     print $l;
  139.   } 
  140.  
  141. =head2 How can I tell whether my encoding fully supports PerlIO ?
  142.  
  143. As of this writing, any encoding whose class belongs to Encode::XS and
  144. Encode::Unicode works.  The Encode module has a C<perlio_ok> method
  145. which you can use before appling PerlIO encoding to the filehandle.
  146. Here is an example:
  147.  
  148.   my $use_perlio = perlio_ok($enc);
  149.   my $layer = $use_perlio ? "<:raw" : "<:encoding($enc)";
  150.   open my $fh, $layer, $file or die "$file : $!";
  151.   while(<$fh>){
  152.     $_ = decode($enc, $_) unless $use_perlio;
  153.     # .... 
  154.   }
  155.  
  156. =head1 SEE ALSO
  157.  
  158. L<Encode::Encoding>,
  159. L<Encode::Supported>,
  160. L<Encode::PerlIO>, 
  161. L<encoding>,
  162. L<perlebcdic>, 
  163. L<perlfunc/open>, 
  164. L<perlunicode>, 
  165. L<utf8>, 
  166. the Perl Unicode Mailing List E<lt>perl-unicode@perl.orgE<gt>
  167.  
  168. =cut
  169.  
  170.