home *** CD-ROM | disk | FTP | other *** search
/ PC World 2003 March / PCWorld_2003-03_cd.bin / Software / Topware / activeperl / ActivePerl / Perl / lib / AutoLoader.pm < prev    next >
Encoding:
Perl POD Document  |  2002-06-19  |  11.0 KB  |  338 lines
  1. package AutoLoader;
  2.  
  3. use 5.006_001;
  4. our(@EXPORT, @EXPORT_OK, $VERSION);
  5.  
  6. my $is_dosish;
  7. my $is_epoc;
  8. my $is_vms;
  9. my $is_macos;
  10.  
  11. BEGIN {
  12.     require Exporter;
  13.     @EXPORT = @EXPORT = ();
  14.     @EXPORT_OK = @EXPORT_OK = qw(AUTOLOAD);
  15.     $is_dosish = $^O eq 'dos' || $^O eq 'os2' || $^O eq 'MSWin32' || $^O eq 'NetWare';
  16.     $is_epoc = $^O eq 'epoc';
  17.     $is_vms = $^O eq 'VMS';
  18.     $is_macos = $^O eq 'MacOS';
  19.     $VERSION = '5.59';
  20. }
  21.  
  22. AUTOLOAD {
  23.     my $sub = $AUTOLOAD;
  24.     my $filename;
  25.     # Braces used to preserve $1 et al.
  26.     {
  27.     # Try to find the autoloaded file from the package-qualified
  28.     # name of the sub. e.g., if the sub needed is
  29.     # Getopt::Long::GetOptions(), then $INC{Getopt/Long.pm} is
  30.     # something like '/usr/lib/perl5/Getopt/Long.pm', and the
  31.     # autoload file is '/usr/lib/perl5/auto/Getopt/Long/GetOptions.al'.
  32.     #
  33.     # However, if @INC is a relative path, this might not work.  If,
  34.     # for example, @INC = ('lib'), then $INC{Getopt/Long.pm} is
  35.     # 'lib/Getopt/Long.pm', and we want to require
  36.     # 'auto/Getopt/Long/GetOptions.al' (without the leading 'lib').
  37.     # In this case, we simple prepend the 'auto/' and let the
  38.     # C<require> take care of the searching for us.
  39.  
  40.     my ($pkg,$func) = ($sub =~ /(.*)::([^:]+)$/);
  41.     $pkg =~ s#::#/#g;
  42.     if (defined($filename = $INC{"$pkg.pm"})) {
  43.         if ($is_macos) {
  44.         $pkg =~ tr#/#:#;
  45.         $filename =~ s#^(.*)$pkg\.pm\z#$1auto:$pkg:$func.al#s;
  46.         } else {
  47.         $filename =~ s#^(.*)$pkg\.pm\z#$1auto/$pkg/$func.al#s;
  48.         }
  49.  
  50.         # if the file exists, then make sure that it is a
  51.         # a fully anchored path (i.e either '/usr/lib/auto/foo/bar.al',
  52.         # or './lib/auto/foo/bar.al'.  This avoids C<require> searching
  53.         # (and failing) to find the 'lib/auto/foo/bar.al' because it
  54.         # looked for 'lib/lib/auto/foo/bar.al', given @INC = ('lib').
  55.  
  56.         if (-r $filename) {
  57.         unless ($filename =~ m|^/|s) {
  58.             if ($is_dosish) {
  59.             unless ($filename =~ m{^([a-z]:)?[\\/]}is) {
  60.                  if ($^O ne 'NetWare') {
  61.                     $filename = "./$filename";
  62.                 } else {
  63.                     $filename = "$filename";
  64.                 }
  65.             }
  66.             }
  67.             elsif ($is_epoc) {
  68.             unless ($filename =~ m{^([a-z?]:)?[\\/]}is) {
  69.                  $filename = "./$filename";
  70.             }
  71.             }
  72.             elsif ($is_vms) {
  73.             # XXX todo by VMSmiths
  74.             $filename = "./$filename";
  75.             }
  76.             elsif (!$is_macos) {
  77.             $filename = "./$filename";
  78.             }
  79.         }
  80.         }
  81.         else {
  82.         $filename = undef;
  83.         }
  84.     }
  85.     unless (defined $filename) {
  86.         # let C<require> do the searching
  87.         $filename = "auto/$sub.al";
  88.         $filename =~ s#::#/#g;
  89.     }
  90.     }
  91.     my $save = $@;
  92.     local $!; # Do not munge the value. 
  93.     eval { local $SIG{__DIE__}; require $filename };
  94.     if ($@) {
  95.     if (substr($sub,-9) eq '::DESTROY') {
  96.         *$sub = sub {};
  97.     } else {
  98.         # The load might just have failed because the filename was too
  99.         # long for some old SVR3 systems which treat long names as errors.
  100.         # If we can succesfully truncate a long name then it's worth a go.
  101.         # There is a slight risk that we could pick up the wrong file here
  102.         # but autosplit should have warned about that when splitting.
  103.         if ($filename =~ s/(\w{12,})\.al$/substr($1,0,11).".al"/e){
  104.         eval { local $SIG{__DIE__}; require $filename };
  105.         }
  106.         if ($@){
  107.         $@ =~ s/ at .*\n//;
  108.         my $error = $@;
  109.         require Carp;
  110.         Carp::croak($error);
  111.         }
  112.     }
  113.     }
  114.     $@ = $save;
  115.     goto &$sub;
  116. }
  117.  
  118. sub import {
  119.     my $pkg = shift;
  120.     my $callpkg = caller;
  121.  
  122.     #
  123.     # Export symbols, but not by accident of inheritance.
  124.     #
  125.  
  126.     if ($pkg eq 'AutoLoader') {
  127.       local $Exporter::ExportLevel = 1;
  128.       Exporter::import $pkg, @_;
  129.     }
  130.  
  131.     #
  132.     # Try to find the autosplit index file.  Eg., if the call package
  133.     # is POSIX, then $INC{POSIX.pm} is something like
  134.     # '/usr/local/lib/perl5/POSIX.pm', and the autosplit index file is in
  135.     # '/usr/local/lib/perl5/auto/POSIX/autosplit.ix', so we require that.
  136.     #
  137.     # However, if @INC is a relative path, this might not work.  If,
  138.     # for example, @INC = ('lib'), then
  139.     # $INC{POSIX.pm} is 'lib/POSIX.pm', and we want to require
  140.     # 'auto/POSIX/autosplit.ix' (without the leading 'lib').
  141.     #
  142.  
  143.     (my $calldir = $callpkg) =~ s#::#/#g;
  144.     my $path = $INC{$calldir . '.pm'};
  145.     if (defined($path)) {
  146.     # Try absolute path name.
  147.     if ($is_macos) {
  148.         (my $malldir = $calldir) =~ tr#/#:#;
  149.         $path =~ s#^(.*)$malldir\.pm\z#$1auto:$malldir:autosplit.ix#s;
  150.     } else {
  151.         $path =~ s#^(.*)$calldir\.pm\z#$1auto/$calldir/autosplit.ix#;
  152.     }
  153.  
  154.     eval { require $path; };
  155.     # If that failed, try relative path with normal @INC searching.
  156.     if ($@) {
  157.         $path ="auto/$calldir/autosplit.ix";
  158.         eval { require $path; };
  159.     }
  160.     if ($@) {
  161.         my $error = $@;
  162.         require Carp;
  163.         Carp::carp($error);
  164.     }
  165.     } 
  166. }
  167.  
  168. sub unimport {
  169.   my $callpkg = caller;
  170.   eval "package $callpkg; sub AUTOLOAD;";
  171. }
  172.  
  173. 1;
  174.  
  175. __END__
  176.  
  177. =head1 NAME
  178.  
  179. AutoLoader - load subroutines only on demand
  180.  
  181. =head1 SYNOPSIS
  182.  
  183.     package Foo;
  184.     use AutoLoader 'AUTOLOAD';   # import the default AUTOLOAD subroutine
  185.  
  186.     package Bar;
  187.     use AutoLoader;              # don't import AUTOLOAD, define our own
  188.     sub AUTOLOAD {
  189.         ...
  190.         $AutoLoader::AUTOLOAD = "...";
  191.         goto &AutoLoader::AUTOLOAD;
  192.     }
  193.  
  194. =head1 DESCRIPTION
  195.  
  196. The B<AutoLoader> module works with the B<AutoSplit> module and the
  197. C<__END__> token to defer the loading of some subroutines until they are
  198. used rather than loading them all at once.
  199.  
  200. To use B<AutoLoader>, the author of a module has to place the
  201. definitions of subroutines to be autoloaded after an C<__END__> token.
  202. (See L<perldata>.)  The B<AutoSplit> module can then be run manually to
  203. extract the definitions into individual files F<auto/funcname.al>.
  204.  
  205. B<AutoLoader> implements an AUTOLOAD subroutine.  When an undefined
  206. subroutine in is called in a client module of B<AutoLoader>,
  207. B<AutoLoader>'s AUTOLOAD subroutine attempts to locate the subroutine in a
  208. file with a name related to the location of the file from which the
  209. client module was read.  As an example, if F<POSIX.pm> is located in
  210. F</usr/local/lib/perl5/POSIX.pm>, B<AutoLoader> will look for perl
  211. subroutines B<POSIX> in F</usr/local/lib/perl5/auto/POSIX/*.al>, where
  212. the C<.al> file has the same name as the subroutine, sans package.  If
  213. such a file exists, AUTOLOAD will read and evaluate it,
  214. thus (presumably) defining the needed subroutine.  AUTOLOAD will then
  215. C<goto> the newly defined subroutine.
  216.  
  217. Once this process completes for a given function, it is defined, so
  218. future calls to the subroutine will bypass the AUTOLOAD mechanism.
  219.  
  220. =head2 Subroutine Stubs
  221.  
  222. In order for object method lookup and/or prototype checking to operate
  223. correctly even when methods have not yet been defined it is necessary to
  224. "forward declare" each subroutine (as in C<sub NAME;>).  See
  225. L<perlsub/"SYNOPSIS">.  Such forward declaration creates "subroutine
  226. stubs", which are place holders with no code.
  227.  
  228. The AutoSplit and B<AutoLoader> modules automate the creation of forward
  229. declarations.  The AutoSplit module creates an 'index' file containing
  230. forward declarations of all the AutoSplit subroutines.  When the
  231. AutoLoader module is 'use'd it loads these declarations into its callers
  232. package.
  233.  
  234. Because of this mechanism it is important that B<AutoLoader> is always
  235. C<use>d and not C<require>d.
  236.  
  237. =head2 Using B<AutoLoader>'s AUTOLOAD Subroutine
  238.  
  239. In order to use B<AutoLoader>'s AUTOLOAD subroutine you I<must>
  240. explicitly import it:
  241.  
  242.     use AutoLoader 'AUTOLOAD';
  243.  
  244. =head2 Overriding B<AutoLoader>'s AUTOLOAD Subroutine
  245.  
  246. Some modules, mainly extensions, provide their own AUTOLOAD subroutines.
  247. They typically need to check for some special cases (such as constants)
  248. and then fallback to B<AutoLoader>'s AUTOLOAD for the rest.
  249.  
  250. Such modules should I<not> import B<AutoLoader>'s AUTOLOAD subroutine.
  251. Instead, they should define their own AUTOLOAD subroutines along these
  252. lines:
  253.  
  254.     use AutoLoader;
  255.     use Carp;
  256.  
  257.     sub AUTOLOAD {
  258.         my $sub = $AUTOLOAD;
  259.         (my $constname = $sub) =~ s/.*:://;
  260.         my $val = constant($constname, @_ ? $_[0] : 0);
  261.         if ($! != 0) {
  262.             if ($! =~ /Invalid/ || $!{EINVAL}) {
  263.                 $AutoLoader::AUTOLOAD = $sub;
  264.                 goto &AutoLoader::AUTOLOAD;
  265.             }
  266.             else {
  267.                 croak "Your vendor has not defined constant $constname";
  268.             }
  269.         }
  270.         *$sub = sub { $val }; # same as: eval "sub $sub { $val }";
  271.         goto &$sub;
  272.     }
  273.  
  274. If any module's own AUTOLOAD subroutine has no need to fallback to the
  275. AutoLoader's AUTOLOAD subroutine (because it doesn't have any AutoSplit
  276. subroutines), then that module should not use B<AutoLoader> at all.
  277.  
  278. =head2 Package Lexicals
  279.  
  280. Package lexicals declared with C<my> in the main block of a package
  281. using B<AutoLoader> will not be visible to auto-loaded subroutines, due to
  282. the fact that the given scope ends at the C<__END__> marker.  A module
  283. using such variables as package globals will not work properly under the
  284. B<AutoLoader>.
  285.  
  286. The C<vars> pragma (see L<perlmod/"vars">) may be used in such
  287. situations as an alternative to explicitly qualifying all globals with
  288. the package namespace.  Variables pre-declared with this pragma will be
  289. visible to any autoloaded routines (but will not be invisible outside
  290. the package, unfortunately).
  291.  
  292. =head2 Not Using AutoLoader
  293.  
  294. You can stop using AutoLoader by simply
  295.  
  296.     no AutoLoader;
  297.  
  298. =head2 B<AutoLoader> vs. B<SelfLoader>
  299.  
  300. The B<AutoLoader> is similar in purpose to B<SelfLoader>: both delay the
  301. loading of subroutines.
  302.  
  303. B<SelfLoader> uses the C<__DATA__> marker rather than C<__END__>.
  304. While this avoids the use of a hierarchy of disk files and the
  305. associated open/close for each routine loaded, B<SelfLoader> suffers a
  306. startup speed disadvantage in the one-time parsing of the lines after
  307. C<__DATA__>, after which routines are cached.  B<SelfLoader> can also
  308. handle multiple packages in a file.
  309.  
  310. B<AutoLoader> only reads code as it is requested, and in many cases
  311. should be faster, but requires a mechanism like B<AutoSplit> be used to
  312. create the individual files.  L<ExtUtils::MakeMaker> will invoke
  313. B<AutoSplit> automatically if B<AutoLoader> is used in a module source
  314. file.
  315.  
  316. =head1 CAVEATS
  317.  
  318. AutoLoaders prior to Perl 5.002 had a slightly different interface.  Any
  319. old modules which use B<AutoLoader> should be changed to the new calling
  320. style.  Typically this just means changing a require to a use, adding
  321. the explicit C<'AUTOLOAD'> import if needed, and removing B<AutoLoader>
  322. from C<@ISA>.
  323.  
  324. On systems with restrictions on file name length, the file corresponding
  325. to a subroutine may have a shorter name that the routine itself.  This
  326. can lead to conflicting file names.  The I<AutoSplit> package warns of
  327. these potential conflicts when used to split a module.
  328.  
  329. AutoLoader may fail to find the autosplit files (or even find the wrong
  330. ones) in cases where C<@INC> contains relative paths, B<and> the program
  331. does C<chdir>.
  332.  
  333. =head1 SEE ALSO
  334.  
  335. L<SelfLoader> - an autoloader that doesn't use external files.
  336.  
  337. =cut
  338.