home *** CD-ROM | disk | FTP | other *** search
/ PC World 2003 March / PCWorld_2003-03_cd.bin / Software / Topware / activeperl / ActivePerl / Perl / bin / s2p.bat < prev    next >
Encoding:
DOS Batch File  |  2002-12-01  |  53.9 KB  |  2,006 lines
  1. @rem = '--*-Perl-*--
  2. @echo off
  3. if "%OS%" == "Windows_NT" goto WinNT
  4. perl -x -S "%0" %1 %2 %3 %4 %5 %6 %7 %8 %9
  5. goto endofperl
  6. :WinNT
  7. perl -x -S %0 %*
  8. if NOT "%COMSPEC%" == "%SystemRoot%\system32\cmd.exe" goto endofperl
  9. if %errorlevel% == 9009 echo You do not have Perl in your PATH.
  10. if errorlevel 1 goto script_failed_so_exit_with_non_zero_val 2>nul
  11. goto endofperl
  12. @rem ';
  13. #!perl
  14. #line 15
  15.     eval 'exec D:\p4\Apps\Gecko\MSI\data\ActivePerl\Perl\bin\perl.exe -S $0 ${1+"$@"}'
  16.     if $running_under_some_shell;
  17. my $startperl;
  18. my $perlpath;
  19. ($startperl = <<'/../') =~ s/\s*\z//;
  20. #!perl
  21. /../
  22. ($perlpath = <<'/../') =~ s/\s*\z//;
  23. D:\p4\Apps\Gecko\MSI\data\ActivePerl\Perl\bin\perl.exe
  24. /../
  25.  
  26. $0 =~ s/^.*?(\w+)[\.\w]*$/$1/;
  27.  
  28. # (p)sed - a stream editor
  29. # History:  Aug 12 2000: Original version.
  30. #           Mar 25 2002: Rearrange generated Perl program.
  31.  
  32. use strict;
  33. use integer;
  34. use Symbol;
  35.  
  36. =head1 NAME
  37.  
  38. psed - a stream editor
  39.  
  40. =head1 SYNOPSIS
  41.  
  42.    psed [-an] script [file ...]
  43.    psed [-an] [-e script] [-f script-file] [file ...]
  44.  
  45.    s2p  [-an] [-e script] [-f script-file]
  46.  
  47. =head1 DESCRIPTION
  48.  
  49. A stream editor reads the input stream consisting of the specified files
  50. (or standard input, if none are given), processes is line by line by
  51. applying a script consisting of edit commands, and writes resulting lines
  52. to standard output. The filename `C<->' may be used to read standard input.
  53.  
  54. The edit script is composed from arguments of B<-e> options and
  55. script-files, in the given order. A single script argument may be specified
  56. as the first parameter.
  57.  
  58. If this program is invoked with the name F<s2p>, it will act as a
  59. sed-to-Perl translator. See L<"sed Script Translation">.
  60.  
  61. B<sed> returns an exit code of 0 on success or >0 if an error occurred.
  62.  
  63. =head1 OPTIONS
  64.  
  65. =over 4
  66.  
  67. =item B<-a>
  68.  
  69. A file specified as argument to the B<w> edit command is by default
  70. opened before input processing starts. Using B<-a>, opening of such
  71. files is delayed until the first line is actually written to the file.
  72.  
  73. =item B<-e> I<script>
  74.  
  75. The editing commands defined by I<script> are appended to the script.
  76. Multiple commands must be separated by newlines.
  77.  
  78. =item B<-f> I<script-file>
  79.  
  80. Editing commands from the specified I<script-file> are read and appended
  81. to the script.
  82.  
  83. =item B<-n>
  84.  
  85. By default, a line is written to standard output after the editing script
  86. has been applied to it. The B<-n> option suppresses automatic printing.
  87.  
  88. =back
  89.  
  90. =head1 COMMANDS
  91.  
  92. B<sed> command syntax is defined as
  93.  
  94. Z<> Z<> Z<> Z<>[I<address>[B<,>I<address>]][B<!>]I<function>[I<argument>]
  95.  
  96. with whitespace being permitted before or after addresses, and between
  97. the function character and the argument. The I<address>es and the
  98. address inverter (C<!>) are used to restrict the application of a
  99. command to the selected line(s) of input.
  100.  
  101. Each command must be on a line of its own, except where noted in
  102. the synopses below.
  103.  
  104. The edit cycle performed on each input line consist of reading the line
  105. (without its trailing newline character) into the I<pattern space>,
  106. applying the applicable commands of the edit script, writing the final
  107. contents of the pattern space and a newline to the standard output.
  108. A I<hold space> is provided for saving the contents of the
  109. pattern space for later use.
  110.  
  111. =head2 Addresses
  112.  
  113. A sed address is either a line number or a pattern, which may be combined
  114. arbitrarily to construct ranges. Lines are numbered across all input files.
  115.  
  116. Any address may be followed by an exclamation mark (`C<!>'), selecting
  117. all lines not matching that address.
  118.  
  119. =over 4
  120.  
  121. =item I<number>
  122.  
  123. The line with the given number is selected.
  124.  
  125. =item B<$>
  126.  
  127. A dollar sign (C<$>) is the line number of the last line of the input stream.
  128.  
  129. =item B</>I<regular expression>B</>
  130.  
  131. A pattern address is a basic regular expression (see 
  132. L<"Basic Regular Expressions">), between the delimiting character C</>.
  133. Any other character except C<\> or newline may be used to delimit a
  134. pattern address when the initial delimiter is prefixed with a
  135. backslash (`C<\>').
  136.  
  137. =back
  138.  
  139. If no address is given, the command selects every line.
  140.  
  141. If one address is given, it selects the line (or lines) matching the
  142. address.
  143.  
  144. Two addresses select a range that begins whenever the first address
  145. matches, and ends (including that line) when the second address matches.
  146. If the first (second) address is a matching pattern, the second 
  147. address is not applied to the very same line to determine the end of
  148. the range. Likewise, if the second address is a matching pattern, the
  149. first address is not applied to the very same line to determine the
  150. begin of another range. If both addresses are line numbers,
  151. and the second line number is less than the first line number, then
  152. only the first line is selected.
  153.  
  154.  
  155. =head2 Functions
  156.  
  157. The maximum permitted number of addresses is indicated with each
  158. function synopsis below.
  159.  
  160. The argument I<text> consists of one or more lines following the command.
  161. Embedded newlines in I<text> must be preceded with a backslash.  Other
  162. backslashes in I<text> are deleted and the following character is taken
  163. literally.
  164.  
  165. =over 4
  166.  
  167. =cut
  168.  
  169. my %ComTab;
  170. my %GenKey;
  171. #--------------------------------------------------------------------------
  172. $ComTab{'a'}=[ 1, 'txt', \&Emit,       '{ push( @Q, <<'."'TheEnd' ) }\n" ]; #ok
  173.  
  174. =item [1addr]B<a\> I<text>
  175.  
  176. Write I<text> (which must start on the line following the command)
  177. to standard output immediately before reading the next line
  178. of input, either by executing the B<N> function or by beginning a new cycle.
  179.  
  180. =cut
  181.  
  182. #--------------------------------------------------------------------------
  183. $ComTab{'b'}=[ 2, 'str', \&Branch,     '{ goto XXX; }'                   ]; #ok
  184.  
  185. =item [2addr]B<b> [I<label>]
  186.  
  187. Branch to the B<:> function with the specified I<label>. If no label
  188. is given, branch to the end of the script.
  189.  
  190. =cut
  191.  
  192. #--------------------------------------------------------------------------
  193. $ComTab{'c'}=[ 2, 'txt', \&Change,     <<'-X-'                           ]; #ok
  194. { print <<'TheEnd'; } $doPrint = 0; goto EOS;
  195. -X-
  196. ### continue OK => next CYCLE;
  197.  
  198. =item [2addr]B<c\> I<text>
  199.  
  200. The line, or range of lines, selected by the address is deleted. 
  201. The I<text> (which must start on the line following the command)
  202. is written to standard output. With an address range, this occurs at
  203. the end of the range.
  204.  
  205. =cut
  206.  
  207. #--------------------------------------------------------------------------
  208. $ComTab{'d'}=[ 2, '',    \&Emit,       <<'-X-'                           ]; #ok
  209. { $doPrint = 0;
  210.   goto EOS;
  211. }
  212. -X-
  213. ### continue OK => next CYCLE;
  214.  
  215. =item [2addr]B<d>
  216.  
  217. Deletes the pattern space and starts the next cycle.
  218.  
  219. =cut
  220.  
  221. #--------------------------------------------------------------------------
  222. $ComTab{'D'}=[ 2, '',    \&Emit,       <<'-X-'                           ]; #ok
  223. { s/^.*\n?//;
  224.   if(length($_)){ goto BOS } else { goto EOS }
  225. }
  226. -X-
  227. ### continue OK => next CYCLE;
  228.  
  229. =item [2addr]B<D>
  230.  
  231. Deletes the pattern space through the first embedded newline or to the end.
  232. If the pattern space becomes empty, a new cycle is started, otherwise
  233. execution of the script is restarted.
  234.  
  235. =cut
  236.  
  237. #--------------------------------------------------------------------------
  238. $ComTab{'g'}=[ 2, '',    \&Emit,       '{ $_ = $Hold };'                 ]; #ok
  239.  
  240. =item [2addr]B<g>
  241.  
  242. Replace the contents of the pattern space with the hold space.
  243.  
  244. =cut
  245.  
  246. #--------------------------------------------------------------------------
  247. $ComTab{'G'}=[ 2, '',    \&Emit,       '{ $_ .= "\n"; $_ .= $Hold };'    ]; #ok
  248.  
  249. =item [2addr]B<G>
  250.  
  251. Append a newline and the contents of the hold space to the pattern space.
  252.  
  253. =cut
  254.  
  255. #--------------------------------------------------------------------------
  256. $ComTab{'h'}=[ 2, '',    \&Emit,       '{ $Hold = $_ }'                  ]; #ok
  257.  
  258. =item [2addr]B<h>
  259.  
  260. Replace the contents of the hold space with the pattern space.
  261.  
  262. =cut
  263.  
  264. #--------------------------------------------------------------------------
  265. $ComTab{'H'}=[ 2, '',    \&Emit,       '{ $Hold .= "\n"; $Hold .= $_; }' ]; #ok
  266.  
  267. =item [2addr]B<H>
  268.  
  269. Append a newline and the contents of the pattern space to the hold space.
  270.  
  271. =cut
  272.  
  273. #--------------------------------------------------------------------------
  274. $ComTab{'i'}=[ 1, 'txt', \&Emit,       '{ print <<'."'TheEnd' }\n"       ]; #ok
  275.  
  276. =item [1addr]B<i\> I<text>
  277.  
  278. Write the I<text> (which must start on the line following the command)
  279. to standard output.
  280.  
  281. =cut
  282.  
  283. #--------------------------------------------------------------------------
  284. $ComTab{'l'}=[ 2, '',    \&Emit,       '{ _l() }'                        ]; #okUTF8
  285.  
  286. =item [2addr]B<l>
  287.  
  288. Print the contents of the pattern space: non-printable characters are
  289. shown in C-style escaped form; long lines are split and have a trailing
  290. `C<\>' at the point of the split; the true end of a line is marked with
  291. a `C<$>'. Escapes are: `\a', `\t', `\n', `\f', `\r', `\e' for
  292. BEL, HT, LF, FF, CR, ESC, respectively, and `\' followed by a three-digit
  293. octal number for all other non-printable characters.
  294.  
  295. =cut
  296.  
  297. #--------------------------------------------------------------------------
  298. $ComTab{'n'}=[ 2, '',    \&Emit,       <<'-X-'                           ]; #ok
  299. { print $_, "\n" if $doPrint;
  300.   printQ() if @Q;
  301.   $CondReg = 0;
  302.   last CYCLE unless getsARGV();
  303.   chomp();
  304. }
  305. -X-
  306.  
  307. =item [2addr]B<n>
  308.  
  309. If automatic printing is enabled, write the pattern space to the standard
  310. output. Replace the pattern space with the next line of input. If
  311. there is no more input, processing is terminated.
  312.  
  313. =cut
  314.  
  315. #--------------------------------------------------------------------------
  316. $ComTab{'N'}=[ 2, '',    \&Emit,       <<'-X-'                           ]; #ok
  317. { printQ() if @Q;
  318.   $CondReg = 0;
  319.   last CYCLE unless getsARGV( $h );
  320.   chomp( $h );
  321.   $_ .= "\n$h";
  322. }
  323. -X-
  324.  
  325. =item [2addr]B<N>
  326.  
  327. Append a newline and the next line of input to the pattern space. If
  328. there is no more input, processing is terminated.
  329.  
  330. =cut
  331.  
  332. #--------------------------------------------------------------------------
  333. $ComTab{'p'}=[ 2, '',    \&Emit,       '{ print $_, "\n"; }'             ]; #ok
  334.  
  335. =item [2addr]B<p>
  336.  
  337. Print the pattern space to the standard output. (Use the B<-n> option
  338. to suppress automatic printing at the end of a cycle if you want to
  339. avoid double printing of lines.)
  340.  
  341. =cut
  342.  
  343. #--------------------------------------------------------------------------
  344. $ComTab{'P'}=[ 2, '',    \&Emit,       <<'-X-'                           ]; #ok
  345. { if( /^(.*)/ ){ print $1, "\n"; } }
  346. -X-
  347.  
  348. =item [2addr]B<P>
  349.  
  350. Prints the pattern space through the first embedded newline or to the end.
  351.  
  352. =cut
  353.  
  354. #--------------------------------------------------------------------------
  355. $ComTab{'q'}=[ 1, '',    \&Emit,       <<'-X-'                           ]; #ok
  356. { print $_, "\n" if $doPrint;
  357.   last CYCLE;
  358. }
  359. -X-
  360.  
  361. =item [1addr]B<q>
  362.  
  363. Branch to the end of the script and quit without starting a new cycle.
  364.  
  365. =cut
  366.  
  367. #--------------------------------------------------------------------------
  368. $ComTab{'r'}=[ 1, 'str', \&Emit,       "{ _r( '-X-' ) }"                 ]; #ok
  369.  
  370. =item [1addr]B<r> I<file>
  371.  
  372. Copy the contents of the I<file> to standard output immediately before
  373. the next attempt to read a line of input. Any error encountered while
  374. reading I<file> is silently ignored.
  375.  
  376. =cut
  377.  
  378. #--------------------------------------------------------------------------
  379. $ComTab{'s'}=[ 2, 'sub', \&Emit,       ''                                ]; #ok
  380.  
  381. =item [2addr]B<s/>I<regular expression>B</>I<replacement>B</>I<flags>
  382.  
  383. Substitute the I<replacement> string for the first substring in
  384. the pattern space that matches the I<regular expression>.
  385. Any character other than backslash or newline can be used instead of a 
  386. slash to delimit the regular expression and the replacement.
  387. To use the delimiter as a literal character within the regular expression
  388. and the replacement, precede the character by a backslash (`C<\>').
  389.  
  390. Literal newlines may be embedded in the replacement string by
  391. preceding a newline with a backslash.
  392.  
  393. Within the replacement, an ampersand (`C<&>') is replaced by the string
  394. matching the regular expression. The strings `C<\1>' through `C<\9>' are
  395. replaced by the corresponding subpattern (see L<"Basic Regular Expressions">).
  396. To get a literal `C<&>' or `C<\>' in the replacement text, precede it
  397. by a backslash.
  398.  
  399. The following I<flags> modify the behaviour of the B<s> command:
  400.  
  401. =over 8
  402.  
  403. =item B<g>
  404.  
  405. The replacement is performed for all matching, non-overlapping substrings
  406. of the pattern space.
  407.  
  408. =item B<1>..B<9>
  409.  
  410. Replace only the n-th matching substring of the pattern space.
  411.  
  412. =item B<p>
  413.  
  414. If the substitution was made, print the new value of the pattern space.
  415.  
  416. =item B<w> I<file>
  417.  
  418. If the substitution was made, write the new value of the pattern space
  419. to the specified file.
  420.  
  421. =back
  422.  
  423. =cut
  424.  
  425. #--------------------------------------------------------------------------
  426. $ComTab{'t'}=[ 2, 'str', \&Branch,     '{ goto XXX if _t() }'            ]; #ok
  427.  
  428. =item [2addr]B<t> [I<label>]
  429.  
  430. Branch to the B<:> function with the specified I<label> if any B<s>
  431. substitutions have been made since the most recent reading of an input line
  432. or execution of a B<t> function. If no label is given, branch to the end of
  433. the script. 
  434.  
  435.  
  436. =cut
  437.  
  438. #--------------------------------------------------------------------------
  439. $ComTab{'w'}=[ 2, 'str', \&Write,      "{ _w( '-X-' ) }"                 ]; #ok
  440.  
  441. =item [2addr]B<w> I<file>
  442.  
  443. The contents of the pattern space are written to the I<file>.
  444.  
  445. =cut
  446.  
  447. #--------------------------------------------------------------------------
  448. $ComTab{'x'}=[ 2, '',    \&Emit,       '{ ($Hold, $_) = ($_, $Hold) }'   ]; #ok
  449.  
  450. =item [2addr]B<x>
  451.  
  452. Swap the contents of the pattern space and the hold space.
  453.  
  454. =cut
  455.  
  456. #--------------------------------------------------------------------------
  457. $ComTab{'y'}=[ 2, 'tra', \&Emit,       ''                                ]; #ok
  458. =item [2addr]B<y>B</>I<string1>B</>I<string2>B</>
  459.  
  460. In the pattern space, replace all characters occuring in I<string1> by the
  461. character at the corresponding position in I<string2>. It is possible
  462. to use any character (other than a backslash or newline) instead of a
  463. slash to delimit the strings.  Within I<string1> and I<string2>, a
  464. backslash followed by any character other than a newline is that literal
  465. character, and a backslash followed by an `n' is replaced by a newline
  466. character.
  467.  
  468. =cut
  469.  
  470. #--------------------------------------------------------------------------
  471. $ComTab{'='}=[ 1, '',    \&Emit,       '{ print "$.\n" }'                ]; #ok
  472.  
  473. =item [1addr]B<=>
  474.  
  475. Prints the current line number on the standard output.
  476.  
  477. =cut
  478.  
  479. #--------------------------------------------------------------------------
  480. $ComTab{':'}=[ 0, 'str', \&Label,      ''                                ]; #ok
  481.  
  482. =item [0addr]B<:> [I<label>]
  483.  
  484. The command specifies the position of the I<label>. It has no other effect.
  485.  
  486. =cut
  487.  
  488. #--------------------------------------------------------------------------
  489. $ComTab{'{'}=[ 2, '',    \&BeginBlock, '{'                               ]; #ok
  490. $ComTab{'}'}=[ 0, '',    \&EndBlock,   ';}'                              ]; #ok
  491. # ';' to avoid warning on empty {}-block
  492.  
  493. =item [2addr]B<{> [I<command>]
  494.  
  495. =item [0addr]B<}>
  496.  
  497. These two commands begin and end a command list. The first command may
  498. be given on the same line as the opening B<{> command. The commands
  499. within the list are jointly selected by the address(es) given on the
  500. B<{> command (but may still have individual addresses).
  501.  
  502. =cut
  503.  
  504. #--------------------------------------------------------------------------
  505. $ComTab{'#'}=[ 0, 'str', \&Comment,    ''                                ]; #ok
  506.  
  507. =item [0addr]B<#> [I<comment>]
  508.  
  509. The entire line is ignored (treated as a comment). If, however, the first
  510. two characters in the script are `C<#n>', automatic printing of output is
  511. suppressed, as if the B<-n> option were given on the command line.
  512.  
  513. =back
  514.  
  515. =cut
  516.  
  517. use vars qw{ $isEOF $Hold %wFiles @Q $CondReg $doPrint };
  518.  
  519. my $useDEBUG    = exists( $ENV{PSEDDEBUG} );
  520. my $useEXTBRE   = $ENV{PSEDEXTBRE} || '';
  521. $useEXTBRE =~ s/[^<>wWyB]//g; # gawk RE's handle these
  522.  
  523. my $doAutoPrint = 1;          # automatic printing of pattern space (-n => 0)
  524. my $doOpenWrite = 1;          # open w command output files at start (-a => 0)
  525. my $svOpenWrite = 0;          # save $doOpenWrite
  526. my $doGenerate  = $0 eq 's2p';
  527.  
  528. # Collected and compiled script
  529. #
  530. my( @Commands, %Defined, @BlockStack, %Label, $labNum, $Code, $Func );
  531. $Code = '';
  532.  
  533. ##################
  534. #  Compile Time
  535. #
  536. # Labels
  537. # 
  538. # Error handling
  539. #
  540. sub Warn($;$){
  541.     my( $msg, $loc ) = @_;
  542.     $loc ||= '';
  543.     $loc .= ': ' if length( $loc );
  544.     warn( "$0: $loc$msg\n" );
  545. }
  546.  
  547. $labNum = 0;
  548. sub newLabel(){
  549.     return 'L_'.++$labNum;
  550. }
  551.  
  552. # safeHere: create safe here delimiter and  modify opcode and argument
  553. #
  554. sub safeHere($$){
  555.     my( $codref, $argref ) = @_;
  556.     my $eod = 'EOD000';
  557.     while( $$argref =~ /^$eod$/m ){
  558.         $eod++;
  559.     }
  560.     $$codref =~ s/TheEnd/$eod/e;
  561.     $$argref .= "$eod\n"; 
  562. }
  563.  
  564. # Emit: create address logic and emit command
  565. #
  566. sub Emit($$$$$$){
  567.     my( $addr1, $addr2, $negated, $opcode, $arg, $fl ) = @_;
  568.     my $cond = '';
  569.     if( defined( $addr1 ) ){
  570.         if( defined( $addr2 ) ){
  571.         $addr1 .= $addr2 =~ /^\d+$/ ? "..$addr2" : "...$addr2";
  572.         } else {
  573.         $addr1 .= ' == $.' if $addr1 =~ /^\d+$/;
  574.     }
  575.     $cond = $negated ? "unless( $addr1 )\n" : "if( $addr1 )\n";
  576.     }
  577.  
  578.     if( $opcode eq '' ){
  579.     $Code .= "$cond$arg\n";
  580.  
  581.     } elsif( $opcode =~ s/-X-/$arg/e ){
  582.     $Code .= "$cond$opcode\n";
  583.  
  584.     } elsif( $opcode =~ /TheEnd/ ){
  585.     safeHere( \$opcode, \$arg );
  586.     $Code .= "$cond$opcode$arg";
  587.  
  588.     } else {
  589.     $Code .= "$cond$opcode\n";
  590.     }
  591.     0;
  592. }
  593.  
  594. # Write (w command, w flag): store pathname
  595. #
  596. sub Write($$$$$$){
  597.     my( $addr1, $addr2, $negated, $opcode, $path, $fl ) = @_;
  598.     $wFiles{$path} = '';
  599.     Emit( $addr1, $addr2, $negated, $opcode, $path, $fl );
  600. }
  601.  
  602.  
  603. # Label (: command): label definition
  604. #
  605. sub Label($$$$$$){
  606.     my( $addr1, $addr2, $negated, $opcode, $lab, $fl ) = @_;
  607.     my $rc = 0;
  608.     $lab =~ s/\s+//;
  609.     if( length( $lab ) ){
  610.     my $h;
  611.     if( ! exists( $Label{$lab} ) ){
  612.         $h = $Label{$lab}{name} = newLabel();
  613.         } else {
  614.         $h = $Label{$lab}{name};
  615.         if( exists( $Label{$lab}{defined} ) ){
  616.         my $dl = $Label{$lab}{defined};
  617.         Warn( "duplicate label $lab (first defined at $dl)", $fl );
  618.         $rc = 1;
  619.         }
  620.     }
  621.         $Label{$lab}{defined} = $fl;
  622.     $Code .= "$h:;\n";
  623.     }
  624.     $rc;
  625. }
  626.  
  627. # BeginBlock ({ command): push block start
  628. #
  629. sub BeginBlock($$$$$$){
  630.     my( $addr1, $addr2, $negated, $opcode, $arg, $fl ) = @_;
  631.     push( @BlockStack, [ $fl, $addr1, $addr2, $negated ] );
  632.     Emit( $addr1, $addr2, $negated, $opcode, $arg, $fl );
  633. }
  634.  
  635. # EndBlock (} command): check proper nesting
  636. #
  637. sub EndBlock($$$$$$){
  638.     my( $addr1, $addr2, $negated, $opcode, $arg, $fl ) = @_;
  639.     my $rc;
  640.     my $jcom = pop( @BlockStack );
  641.     if( defined( $jcom ) ){
  642.     $rc = Emit( $addr1, $addr2, $negated, $opcode, $arg, $fl );
  643.     } else {
  644.     Warn( "unexpected `}'", $fl );
  645.     $rc = 1;
  646.     }
  647.     $rc;
  648. }
  649.  
  650. # Branch (t, b commands): check or create label, substitute default
  651. #
  652. sub Branch($$$$$$){
  653.     my( $addr1, $addr2, $negated, $opcode, $lab, $fl ) = @_;
  654.     $lab =~ s/\s+//; # no spaces at end
  655.     my $h;
  656.     if( length( $lab ) ){
  657.     if( ! exists( $Label{$lab} ) ){
  658.         $h = $Label{$lab}{name} = newLabel();
  659.         } else {
  660.         $h = $Label{$lab}{name};
  661.     }
  662.     push( @{$Label{$lab}{used}}, $fl );
  663.     } else {
  664.     $h = 'EOS';
  665.     }
  666.     $opcode =~ s/XXX/$h/e;
  667.     Emit( $addr1, $addr2, $negated, $opcode, '', $fl );
  668. }
  669.  
  670. # Change (c command): is special due to range end watching
  671. #
  672. sub Change($$$$$$){
  673.     my( $addr1, $addr2, $negated, $opcode, $arg, $fl ) = @_;
  674.     my $kwd = $negated ? 'unless' : 'if';
  675.     if( defined( $addr2 ) ){
  676.         $addr1 .= $addr2 =~ /^\d+$/ ? "..$addr2" : "...$addr2";
  677.     if( ! $negated ){
  678.         $addr1  = '$icnt = ('.$addr1.')';
  679.         $opcode = 'if( $icnt =~ /E0$/ )' . $opcode;
  680.     }
  681.     } else {
  682.     $addr1 .= ' == $.' if $addr1 =~ /^\d+$/;
  683.     }
  684.     safeHere( \$opcode, \$arg );
  685.     $Code .= "$kwd( $addr1 ){\n  $opcode$arg}\n";
  686.     0;
  687. }
  688.  
  689.  
  690. # Comment (# command): A no-op. Who would've thought that!
  691. #
  692. sub Comment($$$$$$){
  693.     my( $addr1, $addr2, $negated, $opcode, $arg, $fl ) = @_;
  694. ### $Code .= "# $arg\n";
  695.     0;
  696. }
  697.  
  698.  
  699. sub stripRegex($$){
  700.     my( $del, $sref ) = @_;
  701.     my $regex = $del;
  702.     print "stripRegex:$del:$$sref:\n" if $useDEBUG;
  703.     while( $$sref =~ s{^(.*?)(\\*)\Q$del\E(\s*)}{}s ){
  704.         my $sl = $2;
  705.     $regex .= $1.$sl.$del;
  706.     if( length( $sl ) % 2 == 0 ){
  707.         return $regex;
  708.     }
  709.     $regex .= $3;
  710.     }
  711.     undef();
  712. }
  713.  
  714. # stripTrans: take a <del> terminated string from y command
  715. #   honoring and cleaning up of \-escaped <del>'s
  716. #
  717. sub stripTrans($$){
  718.     my( $del, $sref ) = @_;
  719.     my $t = '';
  720.     print "stripTrans:$del:$$sref:\n" if $useDEBUG;
  721.     while( $$sref =~ s{^(.*?)(\\*)\Q$del\E}{}s ){
  722.         my $sl = $2;
  723.     $t .= $1;
  724.     if( length( $sl ) % 2 == 0 ){
  725.         $t .= $sl;
  726.         $t =~ s/\\\\/\\/g;
  727.         return $t;
  728.     }
  729.     chop( $sl );
  730.     $t .= $sl.$del.$3;
  731.     }
  732.     undef();
  733. }
  734.  
  735. # makey - construct Perl y/// from sed y///
  736. #
  737. sub makey($$$){
  738.     my( $fr, $to, $fl ) = @_;
  739.     my $error = 0;
  740.  
  741.     # Ensure that any '-' is up front.
  742.     # Diagnose duplicate contradicting mappings
  743.     my %tr;
  744.     for( my $i = 0; $i < length($fr); $i++ ){
  745.     my $fc = substr($fr,$i,1);
  746.     my $tc = substr($to,$i,1);
  747.     if( exists( $tr{$fc} ) && $tr{$fc} ne $tc ){
  748.         Warn( "ambiguos translation for character `$fc' in `y' command",
  749.           $fl );
  750.         $error++;
  751.     }
  752.     $tr{$fc} = $tc;
  753.     }
  754.     $fr = $to = '';
  755.     if( exists( $tr{'-'} ) ){
  756.     ( $fr, $to ) = ( '-', $tr{'-'} );
  757.     delete( $tr{'-'} );
  758.     } else {
  759.     $fr = $to = '';
  760.     }
  761.     # might just as well sort it...
  762.     for my $fc ( sort keys( %tr ) ){
  763.     $fr .= $fc;
  764.     $to .= $tr{$fc};
  765.     }
  766.     # make embedded delimiters and newlines safe
  767.     $fr =~ s/([{}])/\$1/g;
  768.     $to =~ s/([{}])/\$1/g;
  769.     $fr =~ s/\n/\\n/g;
  770.     $to =~ s/\n/\\n/g;
  771.     return $error ? undef() : "{ y{$fr}{$to}; }";
  772. }
  773.  
  774. ######
  775. # makes - construct Perl s/// from sed s///
  776. #
  777. sub makes($$$$$$$){
  778.     my( $regex, $subst, $path, $global, $print, $nmatch, $fl ) = @_;
  779.  
  780.     # make embedded newlines safe
  781.     $regex =~ s/\n/\\n/g;
  782.     $subst =~ s/\n/\\n/g;
  783.  
  784.     my $code;
  785.     # n-th occurrence
  786.     #
  787.     if( length( $nmatch ) ){
  788.     $code = <<TheEnd;
  789. { \$n = $nmatch;
  790.   while( --\$n && ( \$s = m ${regex}g ) ){}
  791.   \$s = ( substr( \$_, pos() ) =~ s ${regex}${subst}s ) if \$s;
  792.   \$CondReg ||= \$s;
  793. TheEnd
  794.     } else {
  795.         $code = <<TheEnd;
  796. { \$s = s ${regex}${subst}s${global};
  797.   \$CondReg ||= \$s;
  798. TheEnd
  799.     }
  800.     if( $print ){
  801.         $code .= '  print $_, "\n" if $s;'."\n";
  802.     }
  803.     if( defined( $path ) ){
  804.         $wFiles{$path} = '';
  805.     $code .= " _w( '$path' ) if \$s;\n";
  806.         $GenKey{'w'} = 1;
  807.     }
  808.     $code .= "}";
  809. }
  810.  
  811. =head1 BASIC REGULAR EXPRESSIONS
  812.  
  813. A I<Basic Regular Expression> (BRE), as defined in POSIX 1003.2, consists
  814. of I<atoms>, for matching parts of a string, and I<bounds>, specifying
  815. repetitions of a preceding atom.
  816.  
  817. =head2 Atoms
  818.  
  819. The possible atoms of a BRE are: B<.>, matching any single character;
  820. B<^> and B<$>, matching the null string at the beginning or end
  821. of a string, respectively; a I<bracket expressions>, enclosed
  822. in B<[> and B<]> (see below); and any single character with no
  823. other significance (matching that character). A B<\> before one
  824. of: B<.>, B<^>, B<$>, B<[>, B<*>, B<\>, matching the character
  825. after the backslash. A sequence of atoms enclosed in B<\(> and B<\)>
  826. becomes an atom and establishes the target for a I<backreference>,
  827. consisting of the substring that actually matches the enclosed atoms.
  828. Finally, B<\> followed by one of the digits B<0> through B<9> is a
  829. backreference.
  830.  
  831. A B<^> that is not first, or a B<$> that is not last does not have
  832. a special significance and need not be preceded by a backslash to
  833. become literal. The same is true for a B<]>, that does not terminate
  834. a bracket expression.
  835.  
  836. An unescaped backslash cannot be last in a BRE.
  837.  
  838. =head2 Bounds
  839.  
  840. The BRE bounds are: B<*>, specifying 0 or more matches of the preceding
  841. atom; B<\{>I<count>B<\}>, specifying that many repetitions;
  842. B<\{>I<minimum>B<,\}>, giving a lower limit; and
  843. B<\{>I<minimum>B<,>I<maximum>B<\}> finally defines a lower and upper
  844. bound. 
  845.  
  846. A bound appearing as the first item in a BRE is taken literally.
  847.  
  848. =head2 Bracket Expressions
  849.  
  850. A I<bracket expression> is a list of characters, character ranges
  851. and character classes enclosed in B<[> and B<]> and matches any
  852. single character from the represented set of characters.
  853.  
  854. A character range is written as two characters separated by B<-> and
  855. represents all characters (according to the character collating sequence)
  856. that are not less than the first and not greater than the second.
  857. (Ranges are very collating-sequence-dependent, and portable programs
  858. should avoid relying on them.)
  859.  
  860. A character class is one of the class names
  861.  
  862.    alnum     digit     punct
  863.    alpha     graph     space
  864.    blank     lower     upper
  865.    cntrl     print     xdigit
  866.  
  867. enclosed in B<[:> and B<:]> and represents the set of characters
  868. as defined in ctype(3).
  869.  
  870. If the first character after B<[> is B<^>, the sense of matching is
  871. inverted.
  872.  
  873. To include a literal `C<^>', place it anywhere else but first. To
  874. include a literal 'C<]>' place it first or immediately after an
  875. initial B<^>. To include a literal `C<->' make it the first (or
  876. second after B<^>) or last character, or the second endpoint of
  877. a range.
  878.  
  879. The special bracket expression constructs C<[[:E<lt>:]]> and C<[[:E<gt>:]]> 
  880. match the null string at the beginning and end of a word respectively.
  881. (Note that neither is identical to Perl's `\b' atom.)
  882.  
  883. =head2 Additional Atoms
  884.  
  885. Since some sed implementations provide additional regular expression
  886. atoms (not defined in POSIX 1003.2), B<psed> is capable of translating
  887. the following backslash escapes:
  888.  
  889. =over 4
  890.  
  891. =item B<\E<lt>> This is the same as C<[[:E<gt>:]]>.
  892.  
  893. =item B<\E<gt>> This is the same as C<[[:E<lt>:]]>.
  894.  
  895. =item B<\w> This is an abbreviation for C<[[:alnum:]_]>.
  896.  
  897. =item B<\W> This is an abbreviation for C<[^[:alnum:]_]>.
  898.  
  899. =item B<\y> Match the empty string at a word boundary.
  900.  
  901. =item B<\B> Match the empty string between any two either word or non-word characters.
  902.  
  903. =back
  904.  
  905. To enable this feature, the environment variable PSEDEXTBRE must be set
  906. to a string containing the requested characters, e.g.:
  907. C<PSEDEXTBRE='E<lt>E<gt>wW'>.
  908.  
  909. =cut
  910.  
  911. #####
  912. # bre2p - convert BRE to Perl RE
  913. #
  914. sub peek(\$$){
  915.     my( $pref, $ic ) = @_;
  916.     $ic < length($$pref)-1 ? substr( $$pref, $ic+1, 1 ) : '';
  917. }
  918.  
  919. sub bre2p($$$){
  920.     my( $del, $pat, $fl ) = @_;
  921.     my $led = $del;
  922.     $led =~ tr/{([</})]>/;
  923.     $led = '' if $led eq $del;
  924.  
  925.     $pat = substr( $pat, 1, length($pat) - 2 );
  926.     my $res = '';
  927.     my $bracklev = 0;
  928.     my $backref  = 0;
  929.     my $parlev = 0;
  930.     for( my $ic = 0; $ic < length( $pat ); $ic++ ){
  931.         my $c = substr( $pat, $ic, 1 );
  932.         if( $c eq '\\' ){
  933.         ### backslash escapes
  934.             my $nc = peek($pat,$ic);
  935.             if( $nc eq '' ){
  936.                 Warn( "`\\' cannot be last in pattern", $fl );
  937.                 return undef();
  938.             }
  939.         $ic++;
  940.             if( $nc eq $del ){ ## \<pattern del> => \<pattern del>
  941.                 $res .= "\\$del";
  942.  
  943.         } elsif( $nc =~ /([[.*\\n])/ ){
  944.         ## check for \-escaped magics and \n:
  945.         ## \[ \. \* \\ \n stay as they are
  946.                 $res .= '\\'.$nc;
  947.  
  948.             } elsif( $nc eq '(' ){ ## \( => (
  949.                 $parlev++;
  950.                 $res .= '(';
  951.  
  952.             } elsif( $nc eq ')' ){ ## \) => )
  953.                 $parlev--;
  954.         $backref++;
  955.                 if( $parlev < 0 ){
  956.                     Warn( "unmatched `\\)'", $fl );
  957.                     return undef();
  958.                 }
  959.                 $res .= ')';
  960.  
  961.             } elsif( $nc eq '{' ){ ## repetition factor \{<i>[,[<j>]]\}
  962.                 my $endpos = index( $pat, '\\}', $ic );
  963.                 if( $endpos < 0 ){
  964.                     Warn( "unmatched `\\{'", $fl );
  965.                     return undef();
  966.                 }
  967.                 my $rep = substr( $pat, $ic+1, $endpos-($ic+1) );
  968.                 $ic = $endpos + 1;
  969.  
  970.               if( $res =~ /^\^?$/ ){
  971.             $res .= "\\{$rep\}";
  972.                 } elsif( $rep =~ /^(\d+)(,?)(\d*)?$/ ){
  973.                     my $min = $1;
  974.                     my $com = $2 || '';
  975.                     my $max = $3;
  976.                     if( length( $max ) ){
  977.                         if( $max < $min ){
  978.                             Warn( "maximum less than minimum in `\\{$rep\\}'",
  979.                   $fl );
  980.                             return undef();
  981.                         }
  982.                     } else {
  983.                         $max = '';
  984.                     }
  985.             # simplify some
  986.             if( $min == 0 && $max eq '1' ){
  987.             $res .= '?';
  988.             } elsif( $min == 1 && "$com$max" eq ',' ){
  989.             $res .= '+';
  990.             } elsif( $min == 0 && "$com$max" eq ',' ){
  991.             $res .= '*';
  992.             } else {
  993.             $res .= "{$min$com$max}";
  994.             }
  995.                 } else {
  996.                     Warn( "invalid repeat clause `\\{$rep\\}'", $fl );
  997.                     return undef();
  998.                 }
  999.  
  1000.             } elsif( $nc =~ /^[1-9]$/ ){
  1001.         ## \1 .. \9 => \1 .. \9, but check for a following digit
  1002.         if( $nc > $backref ){
  1003.                     Warn( "invalid backreference ($nc)", $fl );
  1004.                     return undef();
  1005.         }
  1006.                 $res .= "\\$nc";
  1007.         if( peek($pat,$ic) =~ /[0-9]/ ){
  1008.             $res .= '(?:)';
  1009.         }
  1010.  
  1011.             } elsif( $useEXTBRE && ( $nc =~ /[$useEXTBRE]/ ) ){
  1012.         ## extensions - at most <>wWyB - not in POSIX
  1013.                 if(      $nc eq '<' ){ ## \< => \b(?=\w), be precise
  1014.                     $res .= '\\b(?<=\\W)';
  1015.                 } elsif( $nc eq '>' ){ ## \> => \b(?=\W), be precise
  1016.                     $res .= '\\b(?=\\W)';
  1017.                 } elsif( $nc eq 'y' ){ ## \y => \b
  1018.                     $res .= '\\b';
  1019.                 } else {               ## \B, \w, \W remain the same
  1020.                     $res .= "\\$nc";
  1021.                 } 
  1022.         } elsif( $nc eq $led ){
  1023.         ## \<closing bracketing-delimiter> - keep '\'
  1024.         $res .= "\\$nc";
  1025.  
  1026.             } else { ## \ <char> => <char> ("as if `\' were not present")
  1027.                 $res .= $nc;
  1028.             }
  1029.  
  1030.         } elsif( $c eq '.' ){ ## . => .
  1031.             $res .= $c;
  1032.  
  1033.     } elsif( $c eq '*' ){ ## * => * but \* if there's nothing preceding it
  1034.         if( $res =~ /^\^?$/ ){
  1035.                 $res .= '\\*';
  1036.             } elsif( substr( $res, -1, 1 ) ne '*' ){
  1037.         $res .= $c;
  1038.         }
  1039.  
  1040.         } elsif( $c eq '[' ){
  1041.         ## parse []: [^...] [^]...] [-...]
  1042.         my $add = '[';
  1043.         if( peek($pat,$ic) eq '^' ){
  1044.         $ic++;
  1045.         $add .= '^';
  1046.         }
  1047.         my $nc = peek($pat,$ic);
  1048.           if( $nc eq ']' || $nc eq '-' ){
  1049.         $add .= $nc;
  1050.                 $ic++;
  1051.         }
  1052.         # check that [ is not trailing
  1053.         if( $ic >= length( $pat ) - 1 ){
  1054.         Warn( "unmatched `['", $fl );
  1055.         return undef();
  1056.         }
  1057.         # look for [:...:] and x-y
  1058.         my $rstr = substr( $pat, $ic+1 );
  1059.         if( $rstr =~ /^((?:\[:\(\w+|[><]\):\]|[^]-](?:-[^]])?)*)/ ){
  1060.              my $cnt = $1;
  1061.         $ic += length( $cnt );
  1062.         $cnt =~ s/([\\\$])/\\$1/g; # `\', `$' are magic in Perl []
  1063.         # try some simplifications
  1064.              my $red = $cnt;
  1065.         if( $red =~ s/0-9// ){
  1066.             $cnt = $red.'\d';
  1067.             if( $red =~ s/A-Z// && $red =~ s/a-z// && $red =~ s/_// ){
  1068.             $cnt = $red.'\w';
  1069.                     }
  1070.         }
  1071.         $add .= $cnt;
  1072.  
  1073.         # POSIX 1003.2 has this (optional) for begin/end word
  1074.         $add = '\\b(?=\\W)'  if $add eq '[[:<:]]';
  1075.         $add = '\\b(?<=\\W)' if $add eq '[[:>:]]';
  1076.  
  1077.         }
  1078.  
  1079.         ## may have a trailing `-' before `]'
  1080.         if( $ic < length($pat) - 1 &&
  1081.                 substr( $pat, $ic+1 ) =~ /^(-?])/ ){
  1082.         $ic += length( $1 );
  1083.         $add .= $1;
  1084.         # another simplification
  1085.         $add =~ s/^\[(\^?)(\\[dw])]$/ $1 eq '^' ? uc($2) : $2 /e;
  1086.         $res .= $add;
  1087.         } else {
  1088.         Warn( "unmatched `['", $fl );
  1089.         return undef();
  1090.         }
  1091.  
  1092.         } elsif( $c eq $led ){ ## unescaped <closing bracketing-delimiter>
  1093.             $res .= "\\$c";
  1094.  
  1095.         } elsif( $c eq ']' ){ ## unmatched ] is not magic
  1096.             $res .= ']';
  1097.  
  1098.         } elsif( $c =~ /[|+?{}()]/ ){ ## not magic in BRE, but in Perl: \-quote
  1099.             $res .= "\\$c";
  1100.  
  1101.         } elsif( $c eq '^' ){ ## not magic unless 1st, but in Perl: \-quote
  1102.             $res .= length( $res ) ? '\\^' : '^';
  1103.  
  1104.         } elsif( $c eq '$' ){ ## not magic unless last, but in Perl: \-quote
  1105.             $res .= $ic == length( $pat ) - 1 ? '$' : '\\$';
  1106.  
  1107.         } else {
  1108.             $res .= $c;
  1109.         }
  1110.     }
  1111.  
  1112.     if( $parlev ){
  1113.        Warn( "unmatched `\\('", $fl );
  1114.        return undef();
  1115.     }
  1116.  
  1117.     # final cleanup: eliminate raw HTs
  1118.     $res =~ s/\t/\\t/g;
  1119.     return $del . $res . ( $led ? $led : $del );
  1120. }
  1121.  
  1122.  
  1123. #####
  1124. # sub2p - convert sed substitution to Perl substitution
  1125. #
  1126. sub sub2p($$$){
  1127.     my( $del, $subst, $fl ) = @_;
  1128.     my $led = $del;
  1129.     $led =~ tr/{([</})]>/;
  1130.     $led = '' if $led eq $del;
  1131.  
  1132.     $subst = substr( $subst, 1, length($subst) - 2 );
  1133.     my $res = '';
  1134.  
  1135.     for( my $ic = 0; $ic < length( $subst ); $ic++ ){
  1136.         my $c = substr( $subst, $ic, 1 );
  1137.         if( $c eq '\\' ){
  1138.         ### backslash escapes
  1139.             my $nc = peek($subst,$ic);
  1140.             if( $nc eq '' ){
  1141.                 Warn( "`\\' cannot be last in substitution", $fl );
  1142.                 return undef();
  1143.             }
  1144.         $ic++;
  1145.         if( $nc =~ /[\\$del$led]/ ){ ## \ and delimiter
  1146.         $res .= '\\' . $nc;
  1147.             } elsif( $nc =~ /[1-9]/ ){ ## \1 - \9 => ${1} - ${9}
  1148.                 $res .= '${' . $nc . '}';
  1149.         } else { ## everything else (includes &): omit \
  1150.         $res .= $nc;
  1151.         }
  1152.         } elsif( $c eq '&' ){ ## & => $&
  1153.             $res .= '$&';
  1154.     } elsif( $c =~ /[\$\@$led]/ ){ ## magic in Perl's substitution string
  1155.         $res .= '\\' . $c;
  1156.         } else {
  1157.         $res .= $c;
  1158.     }
  1159.     }
  1160.  
  1161.     # final cleanup: eliminate raw HTs
  1162.     $res =~ s/\t/\\t/g;
  1163.     return ( $led ? $del : $led ) . $res . ( $led ? $led : $del );
  1164. }
  1165.  
  1166.  
  1167. sub Parse(){
  1168.     my $error = 0;
  1169.     my( $pdef, $pfil, $plin );
  1170.     for( my $icom = 0; $icom < @Commands; $icom++ ){
  1171.     my $cmd = $Commands[$icom];
  1172.     print "Parse:$cmd:\n" if $useDEBUG;
  1173.     $cmd =~ s/^\s+//;
  1174.     next unless length( $cmd );
  1175.     my $scom = $icom;
  1176.     if( exists( $Defined{$icom} ) ){
  1177.         $pdef = $Defined{$icom};
  1178.         if( $pdef =~ /^ #(\d+)/ ){
  1179.         $pfil = 'expression #';
  1180.         $plin = $1;
  1181.         } else {
  1182.         $pfil = "$pdef l.";
  1183.         $plin = 1;
  1184.             }
  1185.         } else {
  1186.         $plin++;
  1187.         }
  1188.         my $fl = "$pfil$plin";
  1189.  
  1190.         # insert command as comment in gnerated code
  1191.     #
  1192.     $Code .= "# $cmd\n" if $doGenerate;
  1193.  
  1194.     # The Address(es)
  1195.     #
  1196.     my( $negated, $naddr, $addr1, $addr2 );
  1197.     $naddr = 0;
  1198.     if(      $cmd =~ s/^(\d+)\s*// ){
  1199.         $addr1 = "$1"; $naddr++;
  1200.     } elsif( $cmd =~ s/^\$\s*// ){
  1201.         $addr1 = 'eofARGV()'; $naddr++;
  1202.     } elsif( $cmd =~ s{^(/)}{} || $cmd =~ s{^\\(.)}{} ){
  1203.         my $del = $1;
  1204.         my $regex = stripRegex( $del, \$cmd );
  1205.         if( defined( $regex ) ){
  1206.         $addr1 = 'm '.bre2p( $del, $regex, $fl ).'s';
  1207.         $naddr++;
  1208.         } else {
  1209.         Warn( "malformed regex, 1st address", $fl );
  1210.         $error++;
  1211.         next;
  1212.         }
  1213.         }
  1214.         if( defined( $addr1 ) && $cmd =~ s/,\s*// ){
  1215.          if(      $cmd =~ s/^(\d+)\s*// ){
  1216.             $addr2 = "$1"; $naddr++;
  1217.         } elsif( $cmd =~ s/^\$\s*// ){
  1218.             $addr2 = 'eofARGV()'; $naddr++;
  1219.         } elsif( $cmd =~ s{^(/)}{} || $cmd =~ s{^\\(.)}{} ){
  1220.         my $del = $1;
  1221.             my $regex = stripRegex( $del, \$cmd );
  1222.         if( defined( $regex ) ){
  1223.             $addr2 = 'm '. bre2p( $del, $regex, $fl ).'s';
  1224.             $naddr++;
  1225.         } else {
  1226.             Warn( "malformed regex, 2nd address", $fl );
  1227.             $error++;
  1228.             next;
  1229.         }
  1230.             } else {
  1231.         Warn( "invalid address after `,'", $fl );
  1232.         $error++;
  1233.         next;
  1234.             }
  1235.         }
  1236.  
  1237.         # address modifier `!'
  1238.         #
  1239.         $negated = $cmd =~ s/^!\s*//;
  1240.     if( defined( $addr1 ) ){
  1241.         print "Parse: addr1=$addr1" if $useDEBUG;
  1242.         if( defined( $addr2 ) ){
  1243.         print ", addr2=$addr2 " if $useDEBUG;
  1244.         # both numeric and addr1 > addr2 => eliminate addr2
  1245.         undef( $addr2 ) if $addr1 =~ /^\d+$/ &&
  1246.                                    $addr2 =~ /^\d+$/ && $addr1 > $addr2;
  1247.         }
  1248.     }
  1249.     print 'negated' if $useDEBUG && $negated;
  1250.     print " command:$cmd\n" if $useDEBUG;
  1251.  
  1252.     # The Command
  1253.     #
  1254.         if( $cmd !~ s/^([:#={}abcdDgGhHilnNpPqrstwxy])\s*// ){
  1255.         my $h = substr( $cmd, 0, 1 );
  1256.          Warn( "unknown command `$h'", $fl );
  1257.         $error++;
  1258.         next;
  1259.     }
  1260.         my $key = $1;
  1261.  
  1262.     my $tabref = $ComTab{$key};
  1263.     $GenKey{$key} = 1;
  1264.     if( $naddr > $tabref->[0] ){
  1265.         Warn( "excess address(es)", $fl );
  1266.         $error++;
  1267.         next;
  1268.     }
  1269.  
  1270.     my $arg = '';
  1271.     if(      $tabref->[1] eq 'str' ){
  1272.         # take remainder - don't care if it is empty
  1273.         $arg = $cmd;
  1274.             $cmd = '';
  1275.  
  1276.     } elsif( $tabref->[1] eq 'txt' ){
  1277.         # multi-line text
  1278.         my $goon = $cmd =~ /(.*)\\$/;
  1279.         if( length( $1 ) ){
  1280.         Warn( "extra characters after command ($cmd)", $fl );
  1281.         $error++;
  1282.         }
  1283.         while( $goon ){
  1284.         $icom++;
  1285.         if( $icom > $#Commands ){
  1286.             Warn( "unexpected end of script", $fl );
  1287.             $error++;
  1288.             last;
  1289.         }
  1290.         $cmd = $Commands[$icom];
  1291.         $Code .= "# $cmd\n" if $doGenerate;
  1292.         $goon = $cmd =~ s/\\$//;
  1293.         $cmd =~ s/\\(.)/$1/g;
  1294.         $arg .= "\n" if length( $arg );
  1295.         $arg .= $cmd;
  1296.         }
  1297.         $arg .= "\n" if length( $arg );
  1298.         $cmd = '';
  1299.  
  1300.     } elsif( $tabref->[1] eq 'sub' ){
  1301.         # s///
  1302.         if( ! length( $cmd ) ){
  1303.         Warn( "`s' command requires argument", $fl );
  1304.         $error++;
  1305.         next;
  1306.         }
  1307.         if( $cmd =~ s{^([^\\\n])}{} ){
  1308.         my $del = $1;
  1309.         my $regex = stripRegex( $del, \$cmd );
  1310.         if( ! defined( $regex ) ){
  1311.             Warn( "malformed regular expression", $fl );
  1312.             $error++;
  1313.             next;
  1314.         }
  1315.         $regex = bre2p( $del, $regex, $fl );
  1316.  
  1317.         # a trailing \ indicates embedded NL (in replacement string)
  1318.         while( $cmd =~ s/(?<!\\)\\$/\n/ ){
  1319.             $icom++;
  1320.             if( $icom > $#Commands ){
  1321.             Warn( "unexpected end of script", $fl );
  1322.             $error++;
  1323.             last;
  1324.             }
  1325.             $cmd .= $Commands[$icom];
  1326.                 $Code .= "# $Commands[$icom]\n" if $doGenerate;
  1327.         }
  1328.  
  1329.         my $subst = stripRegex( $del, \$cmd );
  1330.         if( ! defined( $regex ) ){
  1331.             Warn( "malformed substitution expression", $fl );
  1332.             $error++;
  1333.             next;
  1334.         }
  1335.         $subst = sub2p( $del, $subst, $fl );
  1336.  
  1337.         # parse s/// modifier: g|p|0-9|w <file>
  1338.         my( $global, $nmatch, $print, $write ) =
  1339.           ( '',      '',      0,      undef );
  1340.         while( $cmd =~ s/^([gp0-9])// ){
  1341.             $1 eq 'g' ? ( $global = 'g' ) :
  1342.               $1 eq 'p' ? ( $print  = $1  ) : ( $nmatch .= $1 );
  1343.                 }
  1344.         $write = $1 if $cmd =~ s/w\s*(.*)$//;
  1345.               ### $nmatch =~ s/^(\d)\1*$/$1/; ### may be dangerous?
  1346.         if( $global && length( $nmatch ) || length( $nmatch ) > 1 ){
  1347.             Warn( "conflicting flags `$global$nmatch'", $fl );
  1348.             $error++;
  1349.             next;
  1350.         }
  1351.  
  1352.         $arg = makes( $regex, $subst,
  1353.                   $write, $global, $print, $nmatch, $fl );
  1354.         if( ! defined( $arg ) ){
  1355.             $error++;
  1356.             next;
  1357.         }
  1358.  
  1359.             } else {
  1360.         Warn( "improper delimiter in s command", $fl );
  1361.         $error++;
  1362.         next;
  1363.             }
  1364.  
  1365.     } elsif( $tabref->[1] eq 'tra' ){
  1366.         # y///
  1367.         # a trailing \ indicates embedded newline
  1368.         while( $cmd =~ s/(?<!\\)\\$/\n/ ){
  1369.         $icom++;
  1370.         if( $icom > $#Commands ){
  1371.             Warn( "unexpected end of script", $fl );
  1372.             $error++;
  1373.             last;
  1374.         }
  1375.         $cmd .= $Commands[$icom];
  1376.                 $Code .= "# $Commands[$icom]\n" if $doGenerate;
  1377.         }
  1378.         if( ! length( $cmd ) ){
  1379.         Warn( "`y' command requires argument", $fl );
  1380.         $error++;
  1381.         next;
  1382.         }
  1383.         my $d = substr( $cmd, 0, 1 ); $cmd = substr( $cmd, 1 );
  1384.         if( $d eq '\\' ){
  1385.         Warn( "`\\' not valid as delimiter in `y' command", $fl );
  1386.         $error++;
  1387.         next;
  1388.         }
  1389.         my $fr = stripTrans( $d, \$cmd );
  1390.         if( ! defined( $fr ) || ! length( $cmd ) ){
  1391.         Warn( "malformed `y' command argument", $fl );
  1392.         $error++;
  1393.         next;
  1394.         }
  1395.         my $to = stripTrans( $d, \$cmd );
  1396.         if( ! defined( $to ) ){
  1397.         Warn( "malformed `y' command argument", $fl );
  1398.         $error++;
  1399.         next;
  1400.         }
  1401.         if( length($fr) != length($to) ){
  1402.         Warn( "string lengths in `y' command differ", $fl );
  1403.         $error++;
  1404.         next;
  1405.         }
  1406.         if( ! defined( $arg = makey( $fr, $to, $fl ) ) ){
  1407.         $error++;
  1408.         next;
  1409.         }
  1410.  
  1411.     }
  1412.  
  1413.     # $cmd must be now empty - exception is {
  1414.     if( $cmd !~ /^\s*$/ ){
  1415.         if( $key eq '{' ){
  1416.         # dirty hack to process command on '{' line
  1417.         $Commands[$icom--] = $cmd;
  1418.         } else {
  1419.         Warn( "extra characters after command ($cmd)", $fl );
  1420.         $error++;
  1421.         next;
  1422.         }
  1423.     }
  1424.  
  1425.     # Make Code
  1426.         #
  1427.     if( &{$tabref->[2]}( $addr1, $addr2, $negated,
  1428.                              $tabref->[3], $arg, $fl ) ){
  1429.         $error++;
  1430.     }
  1431.     }
  1432.  
  1433.     while( @BlockStack ){
  1434.     my $bl = pop( @BlockStack );
  1435.     Warn( "start of unterminated `{'", $bl );
  1436.         $error++;
  1437.     }
  1438.  
  1439.     for my $lab ( keys( %Label ) ){
  1440.     if( ! exists( $Label{$lab}{defined} ) ){
  1441.         for my $used ( @{$Label{$lab}{used}} ){
  1442.              Warn( "undefined label `$lab'", $used );
  1443.             $error++;
  1444.         }
  1445.     }
  1446.     }
  1447.  
  1448.     exit( 1 ) if $error;
  1449. }
  1450.  
  1451.  
  1452. ##############
  1453. #### MAIN ####
  1454. ##############
  1455.  
  1456. sub usage(){
  1457.     print STDERR "Usage: sed [-an] command [file...]\n";
  1458.     print STDERR "           [-an] [-e command] [-f script-file] [file...]\n";
  1459. }
  1460.  
  1461. ###################
  1462. # Here we go again...
  1463. #
  1464. my $expr = 0;
  1465. while( @ARGV && $ARGV[0] =~ /^-(.)(.*)$/ ){
  1466.     my $opt = $1;
  1467.     my $arg = $2;
  1468.     shift( @ARGV );
  1469.     if(      $opt eq 'e' ){
  1470.         if( length( $arg ) ){
  1471.         push( @Commands, split( "\n", $arg ) );
  1472.         } elsif( @ARGV ){
  1473.         push( @Commands, shift( @ARGV ) ); 
  1474.         } else {
  1475.             Warn( "option -e requires an argument" );
  1476.             usage();
  1477.             exit( 1 );
  1478.         }
  1479.     $expr++;
  1480.         $Defined{$#Commands} = " #$expr";
  1481.     next;
  1482.     }
  1483.     if( $opt eq 'f' ){
  1484.         my $path;
  1485.         if( length( $arg ) ){
  1486.         $path = $arg;
  1487.         } elsif( @ARGV ){
  1488.         $path = shift( @ARGV ); 
  1489.         } else {
  1490.             Warn( "option -f requires an argument" );
  1491.             usage();
  1492.             exit( 1 );
  1493.         }
  1494.     my $fst = $#Commands + 1;
  1495.         open( SCRIPT, "<$path" ) || die( "$0: $path: could not open ($!)\n" );
  1496.         my $cmd;
  1497.         while( defined( $cmd = <SCRIPT> ) ){
  1498.             chomp( $cmd );
  1499.             push( @Commands, $cmd );
  1500.         }
  1501.         close( SCRIPT );
  1502.     if( $#Commands >= $fst ){
  1503.         $Defined{$fst} = "$path";
  1504.     }
  1505.     next;
  1506.     }
  1507.     if( $opt eq '-' && $arg eq '' ){
  1508.     last;
  1509.     }
  1510.     if( $opt eq 'h' || $opt eq '?' ){
  1511.         usage();
  1512.         exit( 0 );
  1513.     }
  1514.     if( $opt eq 'n' ){
  1515.     $doAutoPrint = 0;
  1516.     } elsif( $opt eq 'a' ){
  1517.     $doOpenWrite = 0;
  1518.     } else {
  1519.         Warn( "illegal option `$opt'" );
  1520.         usage();
  1521.         exit( 1 );
  1522.     }
  1523.     if( length( $arg ) ){
  1524.     unshift( @ARGV, "-$arg" );
  1525.     }
  1526. }
  1527.  
  1528. # A singleton command may be the 1st argument when there are no options.
  1529. #
  1530. if( @Commands == 0 ){
  1531.     if( @ARGV == 0 ){
  1532.         Warn( "no script command given" );
  1533.         usage();
  1534.         exit( 1 );
  1535.     }
  1536.     push( @Commands, split( "\n", shift( @ARGV ) ) );
  1537.     $Defined{0} = ' #1';
  1538. }
  1539.  
  1540. print STDERR "Files: @ARGV\n" if $useDEBUG;
  1541.  
  1542. # generate leading code
  1543. #
  1544. $Func = <<'[TheEnd]';
  1545.  
  1546. # openARGV: open 1st input file
  1547. #
  1548. sub openARGV(){
  1549.     unshift( @ARGV, '-' ) unless @ARGV;
  1550.     my $file = shift( @ARGV );
  1551.     open( ARG, "<$file" )
  1552.     || die( "$0: can't open $file for reading ($!)\n" );
  1553.     $isEOF = 0;
  1554. }
  1555.  
  1556. # getsARGV: Read another input line into argument (default: $_).
  1557. #           Move on to next input file, and reset EOF flag $isEOF.
  1558. sub getsARGV(;\$){
  1559.     my $argref = @_ ? shift() : \$_; 
  1560.     while( $isEOF || ! defined( $$argref = <ARG> ) ){
  1561.     close( ARG );
  1562.     return 0 unless @ARGV;
  1563.     my $file = shift( @ARGV );
  1564.     open( ARG, "<$file" )
  1565.     || die( "$0: can't open $file for reading ($!)\n" );
  1566.     $isEOF = 0;
  1567.     }
  1568.     1;
  1569. }
  1570.  
  1571. # eofARGV: end-of-file test
  1572. #
  1573. sub eofARGV(){
  1574.     return @ARGV == 0 && ( $isEOF = eof( ARG ) );
  1575. }
  1576.  
  1577. # makeHandle: Generates another file handle for some file (given by its path)
  1578. #             to be written due to a w command or an s command's w flag.
  1579. sub makeHandle($){
  1580.     my( $path ) = @_;
  1581.     my $handle;
  1582.     if( ! exists( $wFiles{$path} ) || $wFiles{$path} eq '' ){
  1583.         $handle = $wFiles{$path} = gensym();
  1584.     if( $doOpenWrite ){
  1585.         if( ! open( $handle, ">$path" ) ){
  1586.         die( "$0: can't open $path for writing: ($!)\n" );
  1587.         }
  1588.     }
  1589.     } else {
  1590.         $handle = $wFiles{$path};
  1591.     }
  1592.     return $handle;
  1593. }
  1594.  
  1595. # printQ: Print queued output which is either a string or a reference
  1596. #         to a pathname.
  1597. sub printQ(){
  1598.     for my $q ( @Q ){
  1599.     if( ref( $q ) ){
  1600.             # flush open w files so that reading this file gets it all
  1601.         if( exists( $wFiles{$$q} ) && $wFiles{$$q} ne '' ){
  1602.         open( $wFiles{$$q}, ">>$$q" );
  1603.         }
  1604.             # copy file to stdout: slow, but safe
  1605.         if( open( RF, "<$$q" ) ){
  1606.         while( defined( my $line = <RF> ) ){
  1607.             print $line;
  1608.         }
  1609.         close( RF );
  1610.         }
  1611.     } else {
  1612.         print $q;
  1613.     }
  1614.     }
  1615.     undef( @Q );
  1616. }
  1617.  
  1618. [TheEnd]
  1619.  
  1620. # generate the sed loop
  1621. #
  1622. $Code .= <<'[TheEnd]';
  1623. sub openARGV();
  1624. sub getsARGV(;\$);
  1625. sub eofARGV();
  1626. sub printQ();
  1627.  
  1628. # Run: the sed loop reading input and applying the script
  1629. #
  1630. sub Run(){
  1631.     my( $h, $icnt, $s, $n );
  1632.     # hack (not unbreakable :-/) to avoid // matching an empty string
  1633.     my $z = "\000"; $z =~ /$z/;
  1634.     # Initialize.
  1635.     openARGV();
  1636.     $Hold    = '';
  1637.     $CondReg = 0;
  1638.     $doPrint = $doAutoPrint;
  1639. CYCLE:
  1640.     while( getsARGV() ){
  1641.     chomp();
  1642.     $CondReg = 0;   # cleared on t
  1643. BOS:;
  1644. [TheEnd]
  1645.  
  1646.     # parse - avoid opening files when doing s2p
  1647.     #
  1648.     ( $svOpenWrite, $doOpenWrite ) = (  $doOpenWrite, $svOpenWrite )
  1649.       if $doGenerate;
  1650.     Parse();
  1651.     ( $svOpenWrite, $doOpenWrite ) = (  $doOpenWrite, $svOpenWrite )
  1652.       if $doGenerate;
  1653.  
  1654.     # append trailing code
  1655.     #
  1656.     $Code .= <<'[TheEnd]';
  1657. EOS:    if( $doPrint ){
  1658.             print $_, "\n";
  1659.         } else {
  1660.         $doPrint = $doAutoPrint;
  1661.     }
  1662.         printQ() if @Q;
  1663.     }
  1664.  
  1665.     exit( 0 );
  1666. }
  1667. [TheEnd]
  1668.  
  1669.  
  1670. # append optional functions, prepend prototypes
  1671. #
  1672. my $Proto = "# prototypes\n";
  1673. if( $GenKey{'l'} ){
  1674.     $Proto .= "sub _l();\n";
  1675.     $Func .= <<'[TheEnd]';
  1676. # _l: l command processing
  1677. #
  1678. sub _l(){        
  1679.     my $h = $_;
  1680.     my $mcpl = 70;
  1681.     # transform non printing chars into escape notation
  1682.     $h =~ s/\\/\\\\/g;
  1683.     if( $h =~ /[^[:print:]]/ ){
  1684.     $h =~ s/\a/\\a/g;
  1685.     $h =~ s/\f/\\f/g;
  1686.     $h =~ s/\n/\\n/g;
  1687.     $h =~ s/\t/\\t/g;
  1688.     $h =~ s/\r/\\r/g;
  1689.     $h =~ s/\e/\\e/g;
  1690.         $h =~ s/([^[:print:]])/sprintf("\\%03o", ord($1))/ge;
  1691.     }
  1692.     # split into lines of length $mcpl
  1693.     while( length( $h ) > $mcpl ){
  1694.     my $l = substr( $h, 0, $mcpl-1 );
  1695.     $h = substr( $h, $mcpl );
  1696.     # remove incomplete \-escape from end of line
  1697.     if( $l =~ s/(?<!\\)(\\[0-7]{0,2})$// ){
  1698.         $h = $1 . $h;
  1699.     }
  1700.     print $l, "\\\n";
  1701.     }
  1702.     print "$h\$\n";
  1703. }
  1704.  
  1705. [TheEnd]
  1706. }
  1707.  
  1708. if( $GenKey{'r'} ){
  1709.     $Proto .= "sub _r(\$);\n";
  1710.     $Func .= <<'[TheEnd]';
  1711. # _r: r command processing: Save a reference to the pathname.
  1712. #
  1713. sub _r($){
  1714.     my $path = shift();
  1715.     push( @Q, \$path );
  1716. }
  1717.  
  1718. [TheEnd]
  1719. }
  1720.  
  1721. if( $GenKey{'t'} ){
  1722.     $Proto .= "sub _t();\n";
  1723.     $Func .= <<'[TheEnd]';
  1724. # _t: t command - condition register test/reset
  1725. #
  1726. sub _t(){
  1727.     my $res = $CondReg;
  1728.     $CondReg = 0;
  1729.     $res;
  1730. }
  1731.  
  1732. [TheEnd]
  1733. }
  1734.  
  1735. if( $GenKey{'w'} ){
  1736.     $Proto .= "sub _w(\$);\n";
  1737.     $Func .= <<'[TheEnd]';
  1738. # _w: w command and s command's w flag - write to file 
  1739. #
  1740. sub _w($){
  1741.     my $path   = shift();
  1742.     my $handle = $wFiles{$path};
  1743.     if( ! $doOpenWrite && ! defined( fileno( $handle ) ) ){
  1744.     open( $handle, ">$path" )
  1745.     || die( "$0: $path: cannot open ($!)\n" );
  1746.     }
  1747.     print $handle $_, "\n";
  1748. }
  1749.  
  1750. [TheEnd]
  1751. }
  1752.  
  1753. $Code = $Proto . $Code;
  1754.  
  1755. # magic "#n" - same as -n option
  1756. #
  1757. $doAutoPrint = 0 if substr( $Commands[0], 0, 2 ) eq '#n';
  1758.  
  1759. # eval code - check for errors
  1760. #
  1761. print "Code:\n$Code$Func" if $useDEBUG;
  1762. eval $Code . $Func;
  1763. if( $@ ){
  1764.     print "Code:\n$Code$Func";
  1765.     die( "$0: internal error - generated incorrect Perl code: $@\n" );
  1766. }
  1767.  
  1768. if( $doGenerate ){
  1769.  
  1770.     # write full Perl program
  1771.     #
  1772.  
  1773.     # bang line, declarations, prototypes
  1774.     print <<TheEnd;
  1775. #!$perlpath -w
  1776. eval 'exec $perlpath -S \$0 \${1+"\$@"}'
  1777.   if 0;
  1778. \$0 =~ s/^.*?(\\w+)\[\\.\\w+\]*\$/\$1/;
  1779.  
  1780. use strict;
  1781. use Symbol;
  1782. use vars qw{ \$isEOF \$Hold \%wFiles \@Q \$CondReg
  1783.          \$doAutoPrint \$doOpenWrite \$doPrint };
  1784. \$doAutoPrint = $doAutoPrint;
  1785. \$doOpenWrite = $doOpenWrite;
  1786. TheEnd
  1787.  
  1788.     my $wf = "'" . join( "', '",  keys( %wFiles ) ) . "'";
  1789.     if( $wf ne "''" ){
  1790.     print <<TheEnd;
  1791. sub makeHandle(\$);
  1792. for my \$p ( $wf ){
  1793.    exit( 1 ) unless makeHandle( \$p );
  1794. }
  1795. TheEnd
  1796.    }
  1797.  
  1798.    print $Code;
  1799.    print "Run();\n";
  1800.    print $Func;
  1801.    exit( 0 );
  1802.  
  1803. } else {
  1804.  
  1805.     # execute: make handles (and optionally open) all w files; run!
  1806.     for my $p ( keys( %wFiles ) ){
  1807.         exit( 1 ) unless makeHandle( $p );
  1808.     }
  1809.     Run();
  1810. }
  1811.  
  1812.  
  1813. =head1 ENVIRONMENT
  1814.  
  1815. The environment variable C<PSEDEXTBRE> may be set to extend BREs.
  1816. See L<"Additional Atoms">.
  1817.  
  1818. =head1 DIAGNOSTICS
  1819.  
  1820. =over 4
  1821.  
  1822. =item ambiguos translation for character `%s' in `y' command
  1823.  
  1824. The indicated character appears twice, with different translations.
  1825.  
  1826. =item `[' cannot be last in pattern
  1827.  
  1828. A `[' in a BRE indicates the beginning of a I<bracket expression>.
  1829.  
  1830. =item `\' cannot be last in pattern
  1831.  
  1832. A `\' in a BRE is used to make the subsequent character literal.
  1833.  
  1834. =item `\' cannot be last in substitution
  1835.  
  1836. A `\' in a subsitution string is used to make the subsequent character literal.
  1837.  
  1838. =item conflicting flags `%s'
  1839.  
  1840. In an B<s> command, either the `g' flag and an n-th occurrence flag, or
  1841. multiple n-th occurrence flags are specified. Note that only the digits
  1842. `1' through `9' are permitted.
  1843.  
  1844. =item duplicate label %s (first defined at %s)
  1845.  
  1846. =item excess address(es)
  1847.  
  1848. The command has more than the permitted number of addresses.
  1849.  
  1850. =item extra characters after command (%s)
  1851.  
  1852. =item illegal option `%s'
  1853.  
  1854. =item improper delimiter in s command
  1855.  
  1856. The BRE and substitution may not be delimited with `\' or newline.
  1857.  
  1858. =item invalid address after `,'
  1859.  
  1860. =item invalid backreference (%s)
  1861.  
  1862. The specified backreference number exceeds the number of backreferences
  1863. in the BRE.
  1864.  
  1865. =item invalid repeat clause `\{%s\}'
  1866.  
  1867. The repeat clause does not contain a valid integer value, or pair of
  1868. values.
  1869.  
  1870. =item malformed regex, 1st address
  1871.  
  1872. =item malformed regex, 2nd address
  1873.  
  1874. =item malformed regular expression
  1875.  
  1876. =item malformed substitution expression
  1877.  
  1878. =item malformed `y' command argument
  1879.  
  1880. The first or second string of a B<y> command  is syntactically incorrect.
  1881.  
  1882. =item maximum less than minimum in `\{%s\}'
  1883.  
  1884. =item no script command given
  1885.  
  1886. There must be at least one B<-e> or one B<-f> option specifying a
  1887. script or script file.
  1888.  
  1889. =item `\' not valid as delimiter in `y' command
  1890.  
  1891. =item option -e requires an argument
  1892.  
  1893. =item option -f requires an argument
  1894.  
  1895. =item `s' command requires argument
  1896.  
  1897. =item start of unterminated `{'
  1898.  
  1899. =item string lengths in `y' command differ
  1900.  
  1901. The translation table strings in a B<y> commanf must have equal lengths.
  1902.  
  1903. =item undefined label `%s'
  1904.  
  1905. =item unexpected `}'
  1906.  
  1907. A B<}> command without a preceding B<{> command was encountered.
  1908.  
  1909. =item unexpected end of script
  1910.  
  1911. The end of the script was reached although a text line after a
  1912. B<a>, B<c> or B<i> command indicated another line.
  1913.  
  1914. =item unknown command `%s'
  1915.  
  1916. =item unterminated `['
  1917.  
  1918. A BRE contains an unterminated bracket expression.
  1919.  
  1920. =item unterminated `\('
  1921.  
  1922. A BRE contains an unterminated backreference.
  1923.  
  1924. =item `\{' without closing `\}'
  1925.  
  1926. A BRE contains an unterminated bounds specification.
  1927.  
  1928. =item `\)' without preceding `\('
  1929.  
  1930. =item `y' command requires argument
  1931.  
  1932. =back
  1933.  
  1934. =head1 EXAMPLE
  1935.  
  1936. The basic material for the preceding section was generated by running
  1937. the sed script
  1938.  
  1939.    #no autoprint
  1940.    s/^.*Warn( *"\([^"]*\)".*$/\1/
  1941.    t process
  1942.    b
  1943.    :process
  1944.    s/$!/%s/g
  1945.    s/$[_[:alnum:]]\{1,\}/%s/g
  1946.    s/\\\\/\\/g
  1947.    s/^/=item /
  1948.    p
  1949.  
  1950. on the program's own text, and piping the output into C<sort -u>.
  1951.  
  1952.  
  1953. =head1 SED SCRIPT TRANSLATION
  1954.  
  1955. If this program is invoked with the name F<s2p> it will act as a
  1956. sed-to-Perl translator. After option processing (all other
  1957. arguments are ignored), a Perl program is printed on standard
  1958. output, which will process the input stream (as read from all
  1959. arguments) in the way defined by the sed script and the option setting
  1960. used for the translation.
  1961.  
  1962. =head1 SEE ALSO
  1963.  
  1964. perl(1), re_format(7)
  1965.  
  1966. =head1 BUGS
  1967.  
  1968. The B<l> command will show escape characters (ESC) as `C<\e>', but
  1969. a vertical tab (VT) in octal.
  1970.  
  1971. Trailing spaces are truncated from labels in B<:>, B<t> and B<b> commands.
  1972.  
  1973. The meaning of an empty regular expression (`C<//>'), as defined by B<sed>,
  1974. is "the last pattern used, at run time". This deviates from the Perl
  1975. interpretation, which will re-use the "last last successfully executed
  1976. regular expression". Since keeping track of pattern usage would create
  1977. terribly cluttered code, and differences would only appear in obscure
  1978. context (where other B<sed> implementations appear to deviate, too),
  1979. the Perl semantics was adopted. Note that common usage of this feature,
  1980. such as in C</abc/s//xyz/>, will work as expected.
  1981.  
  1982. Collating elements (of bracket expressions in BREs) are not implemented.
  1983.  
  1984. =head1 STANDARDS
  1985.  
  1986. This B<sed> implementation conforms to the IEEE Std1003.2-1992 ("POSIX.2")
  1987. definition of B<sed>, and is compatible with the I<OpenBSD>
  1988. implementation, except where otherwise noted (see L<"BUGS">).
  1989.  
  1990. =head1 AUTHOR
  1991.  
  1992. This Perl implementation of I<sed> was written by Wolfgang Laun,
  1993. I<Wolfgang.Laun@alcatel.at>.
  1994.  
  1995. =head1 COPYRIGHT and LICENSE
  1996.  
  1997. This program is free and open software. You may use, modify,
  1998. distribute, and sell this program (and any modified variants) in any
  1999. way you wish, provided you do not restrict others from doing the same.
  2000.  
  2001. =cut
  2002.  
  2003.  
  2004. __END__
  2005. :endofperl
  2006.