home *** CD-ROM | disk | FTP | other *** search
/ PC World 2001 January / PCWorld_2001-01_cd.bin / Software / Topware / xmlspy / xmlspy35.exe / Main / gra_ent.txt < prev    next >
Encoding:
Text File  |  2000-11-20  |  3.4 KB  |  43 lines
  1. extParsedEnt    ::=    xmlDecl? content                                                    >External Parsed Entity
  2. xmlDecl$        ::=    '<?xml' versionInfo? encodingDecl S? '?>'                            >XML Declaration (<?xml...?>)
  3. versionInfo$    ::= S 'version' Eq ( ( '"' VersionNum '"' ) | ( "'" VersionNum "'" ) )    >Version Info (version="1.0")
  4. VersionNum        ::= ([a-zA-Z0-9_.:] | '-')+                                                >Version Number (1.0)
  5. encodingDecl$    ::= S 'encoding' Eq ( ( '"' EncName '"' ) | ( "'" EncName "'" ) )        >Encoding Declaration (encoding="...")
  6. EncName            ::= [A-Za-z] ([A-Za-z0-9._] | '-')*                                        >Encoding Name (UTF-8, ISO-8859-1, etc)
  7. content$        ::=    ( element | cdSect | pi | comment | TextData | S? )*                >Element Content (Element | CData | Processing Instruction | Comment | Text Data | Whitespace)
  8. element            ::= emptyElemTag | realElemTag                                            >Element (<Element>...)
  9. realElemTag$    ::= sTag content eTag { ElementName = ElementNameEnd }                    >Element (<Element>...)
  10. sTag            ::=    '<' ElementName (S attribute)* S? '>'                                >Element Start Tag (<Element>)
  11. attribute$        ::=    AttName Eq attQValue                                                >Attribute (attribute="value")
  12. Eq!                ::=    S? '=' S?                                                            >Equal sign ('=')
  13. eTag            ::= '</' ElementNameEnd S? '>'                                            >Element End Tag (</Element>)
  14. TextData        ::= S* ( CharNoWhite | Reference ) ( CharData | Reference )*            >Text Data
  15. emptyElemTag$    ::= '<' ElementName (S attribute)* S? '/>'                                >Empty Element (<Element/>)
  16. ElementName        ::= Name                                                                >Element Name
  17. ElementNameEnd    ::= Name                                                                >closing element name
  18. Reference        ::= EntityRef | CharRef                                                    >Reference (Entity-Reference | Character-Reference)
  19. CharRef            ::= ('&#' [0-9]+ ';') | ('&#x' [0-9a-fA-F]+ ';')                        >Character-Reference (Ù or ê)
  20. EntityRef        ::= '&' Name ';'                                                        >Entity-Reference (&Entity;)
  21. S!                ::=    (#x20 | #x09 | #x0D | #x0A)+                                        >Whitespace (Blank, Tab, CR, LF)
  22. AttName            ::=    Name                                                                >Attribute Name
  23. Name            ::= (Letter | '_' | ':') (NameChar)*                                    >Name ( (Letter | '_' | ':') (Name-Character)* )
  24. NameChar        ::= Letter | Digit | '.' | '-' | '_' | ':'                                >Name-Character (Letter | Digit | '.' | '-' | '_' | ':')
  25. attQValue        ::=    ('"' AttValue1 '"') | ("'" AttValue2 "'")                            >Quoted Attribute Value ("value" | 'value')
  26. AttValue1        ::= ([^<&"] | Reference)*                                                >Attribute Value
  27. AttValue2        ::= ([^<&'] | Reference)*                                                >Attribute Value
  28. CharData        ::=    [^<&]* / ']]>'                                                        >Character Data
  29. CharNoWhite!    ::=    [^< #x09#x0D#x0A]                                                >Character (may not contain Whitespaces)
  30. comment            ::=    '<!--' CommentText '-->'                                            >Comment (<!-- Text -->)
  31. CommentText        ::= (CharNoDash | ('-' CharNoDash))*                                    >Comment Text (may not contain '--')
  32. CharNoDash!        ::=    #x09 | #x0A | #x0D | [#x20-#x2C] | [#x2E-#xFF]                        >Character (no dash)
  33. pi$                ::= '<?' PITarget (S PIData)? '?>'                                        >Processing Instruction (<?pi...?>)
  34. PITarget        ::= Name - 'xml'                                                        >Processing Instruction Name (may not be 'xml')
  35. PIData            ::=    Char* / '?>'                                                        >Processing Instruction Data
  36. Char!            ::=    #x09 | #x0A | #x0D | [#x20-#xFF]                                    >Character
  37. cdSect            ::=    CDStart CData? CDEnd                                                >CData Section (<![CDATA[...]]>)
  38. CDStart!        ::=    '<![CDATA['                                                            >'<!CDATA['
  39. CData            ::=    Char* / ']]>'                                                        >Character Data
  40. CDEnd!            ::=    ']]>'                                                                >']]>'
  41. Digit!            ::=    [#x30-#x39]                                                            >Digit ([0-9])
  42. Letter!            ::=    [#x41-#x5A] | [#x61-#x7A] | [#xC0-#xD6] | [#xD8-#xF6] | [#xF8-#xFF]    >Letter ([a-zA-Z], etc)
  43.