home *** CD-ROM | disk | FTP | other *** search
/ PC World 2000 December / PCWorld_2000-12_cd.bin / Komunikace / Comanche / comanche.exe / lib / iwidgets2.2.0 / scripts / tabset.itk < prev    next >
Text File  |  1999-02-24  |  83KB  |  2,733 lines
  1. #
  2. # Tabset Widget and the Tab Class
  3. # ----------------------------------------------------------------------
  4. # A Tabset is a widget that contains a set of Tab buttons. 
  5. # It displays these tabs in a row or column depending on it tabpos. 
  6. # When a tab is clicked on, it becomes the only tab in the tab set that 
  7. # is selected. All other tabs are deselected. The Tcl command prefix 
  8. # associated with this tab (through the command tab configure option) 
  9. # is invoked with the tab index number appended to its argument list. 
  10. # This allows the Tabset to control another widget such as a Notebook.
  11. #
  12. # A Tab class is an [incr Tcl] class that displays either an image, 
  13. # bitmap, or label in a graphic object on a canvas. This graphic object 
  14. # can have a wide variety of appearances depending on the options set. 
  15. #
  16. # WISH LIST:
  17. #   This section lists possible future enhancements.
  18. #
  19. #   1) When too many tabs appear, a small scrollbar should appear to
  20. #      move the tabs over.
  21. #
  22. # ----------------------------------------------------------------------
  23. #  AUTHOR: Bill W. Scott                 EMAIL: bscott@spd.dsccc.com
  24. #
  25. #  @(#) $Id: tabset.itk,v 1.1 1998/07/27 18:49:54 stanton Exp $
  26. # ----------------------------------------------------------------------
  27. #            Copyright (c) 1995 DSC Technologies Corporation
  28. # ======================================================================
  29. # Permission to use, copy, modify, distribute and license this software 
  30. # and its documentation for any purpose, and without fee or written 
  31. # agreement with DSC, is hereby granted, provided that the above copyright 
  32. # notice appears in all copies and that both the copyright notice and 
  33. # warranty disclaimer below appear in supporting documentation, and that 
  34. # the names of DSC Technologies Corporation or DSC Communications 
  35. # Corporation not be used in advertising or publicity pertaining to the 
  36. # software without specific, written prior permission.
  37. # 
  38. # DSC DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE, INCLUDING 
  39. # ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, AND NON-
  40. # INFRINGEMENT. THIS SOFTWARE IS PROVIDED ON AN "AS IS" BASIS, AND THE
  41. # AUTHORS AND DISTRIBUTORS HAVE NO OBLIGATION TO PROVIDE MAINTENANCE, 
  42. # SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS. IN NO EVENT SHALL 
  43. # DSC BE LIABLE FOR ANY SPECIAL, INDIRECT OR CONSEQUENTIAL DAMAGES OR 
  44. # ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, 
  45. # WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTUOUS ACTION,
  46. # ARISING OUT OF OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS 
  47. # SOFTWARE.
  48. # ======================================================================
  49.  
  50. #
  51. # Default resources.
  52. #
  53. option add *Tabset.width          0            widgetDefault
  54. option add *Tabset.height         0            widgetDefault
  55. option add *Tabset.equalTabs      true         widgetDefault
  56. option add *Tabset.tabPos         s            widgetDefault
  57. option add *Tabset.raiseSelect    false        widgetDefault
  58. option add *Tabset.start          4            widgetDefault
  59. option add *Tabset.margin         5            widgetDefault
  60. option add *Tabset.tabBorders     true         widgetDefault
  61. option add *Tabset.bevelAmount    0            widgetDefault
  62. option add *Tabset.padX           4            widgetDefault
  63. option add *Tabset.padY           4            widgetDefault
  64. option add *Tabset.gap            overlap      widgetDefault
  65. option add *Tabset.angle          20           widgetDefault
  66. option add *Tabset.font           fixed        widgetDefault
  67. option add *Tabset.state          normal       widgetDefault
  68. option add *Tabset.disabledForeground #a3a3a3  widgetDefault
  69. option add *Tabset.foreground     black        widgetDefault
  70. option add *Tabset.background     #d9d9d9      widgetDefault
  71. option add *Tabset.selectForeground black      widgetDefault
  72. option add *Tabset.selectBackground #ececec    widgetDefault
  73.  
  74. #
  75. # Usual options.
  76. #
  77. itk::usual Tabset {
  78.     keep -backdrop -background -cursor -disabledforeground -font -foreground \
  79.      -selectbackground -selectforeground
  80. }
  81.  
  82. # ------------------------------------------------------------------
  83. #                              TABSET
  84. # ------------------------------------------------------------------
  85. class iwidgets::Tabset {
  86.     inherit itk::Widget
  87.     
  88.     constructor {args} {} 
  89.     destructor {}
  90.     
  91.     itk_option define -width width Width  0 
  92.     itk_option define -equaltabs equalTabs EqualTabs true 
  93.     itk_option define -height height Height  0
  94.     itk_option define -tabpos tabPos TabPos  s
  95.     itk_option define -raiseselect raiseSelect RaiseSelect false
  96.     itk_option define -start start Start 4
  97.     itk_option define -margin margin Margin 5
  98.     itk_option define -tabborders tabBorders TabBorders true
  99.     itk_option define -bevelamount bevelAmount BevelAmount 0
  100.     itk_option define -padx padX PadX 4
  101.     itk_option define -pady padY PadY 4
  102.     itk_option define -gap gap Gap overlap
  103.     itk_option define -angle angle Angle 20
  104.     itk_option define -font font Font fixed
  105.     itk_option define -state state State normal
  106.     itk_option define \
  107.         -disabledforeground disabledForeground DisabledForeground #a3a3a3
  108.     itk_option define -foreground foreground Foreground black
  109.     itk_option define -background background Background #d9d9d9 
  110.     itk_option define -selectforeground selectForeground Background black
  111.     itk_option define -backdrop backdrop Backdrop white 
  112.     itk_option define \
  113.         -selectbackground selectBackground Foreground #ececec
  114.     itk_option define -command command Command {} 
  115.     
  116.     public method configure {args} 
  117.     public method add {args} 
  118.     public method delete {args} 
  119.     public method index {index} 
  120.     public method insert {index args} 
  121.     public method prev {} 
  122.     public method next {} 
  123.     public method select {index} 
  124.     public method tabcget {index args} 
  125.     public method tabconfigure {index args} 
  126.     
  127.     protected method _selectName {tabName} 
  128.     
  129.     private method _createTab {args} 
  130.     private method _deleteTabs {fromTab toTab} 
  131.     private method _index {pathList index select} 
  132.     private method _tabConfigure {args} 
  133.     private method _relayoutTabs {} 
  134.     private method _drawBevelBorder {} 
  135.     private method _calcNextTabOffset {tabName} 
  136.     private method _tabBounds {} 
  137.     private method _recalcCanvasGeom {} 
  138.     private method _canvasReconfigure {width height} 
  139.     private method _startMove {x y} 
  140.     private method _moveTabs {x y} 
  141.     private method _endMove {x y} 
  142.     private method _configRelayout {} 
  143.     
  144.     private variable _width 0          ;# Width of the canvas in screen units
  145.     private variable _height 0         ;# Height of the canvas in screen units
  146.     private variable _selectedTop 0    ;# top edge of tab + a margin
  147.     private variable _deselectedTop 0  ;# top edge of tab + a margin&raiseamt
  148.     private variable _selectedLeft 0   ;# left edge of tab + a margin
  149.     private variable _deselectedLeft 0 ;# left edge of tab + a margin&raiseamt
  150.     private variable _tabs {}          ;# our internal list of tabs
  151.     private variable _currTab -1       ;# numerical index # of selected tab
  152.     private variable _uniqueID 0       ;# used to create unique names
  153.     private variable _cmdStr  {}       ;# holds value of itk_option(-command)
  154.     ;# do not know why I need this!
  155.     private variable _canvasWidth 0    ;# set by canvasReconfigure, is can wid
  156.     private variable _canvasHeight 0   ;# set by canvasReconfigure, is can hgt
  157.     
  158.     private variable _anchorX 0        ;# used by mouse scrolling methods
  159.     private variable _anchorY 0        ;# used by mouse scrolling methods
  160.     
  161.     private variable _margin 0         ;# -margin in screen units
  162.     private variable _start  0         ;# -start in screen units
  163.     private variable _gap overlap      ;# -gap in screen units
  164.     
  165.     private variable _relayout false   ;# flag tripped to tell whether to
  166.                                        ;# relayout tabs after the configure
  167.     private variable _skipRelayout false ;# flag that tells whether to skip
  168.                                        ;# relayouting out the tabs. used by
  169.                                        ;# _endMove.
  170. }
  171.  
  172. #
  173. # Provide a lowercase access method for the Tabset class
  174. #
  175. proc ::iwidgets::tabset {pathName args} {
  176.     uplevel ::iwidgets::Tabset $pathName $args
  177. }
  178.  
  179. # ----------------------------------------------------------------------
  180. #                              CONSTRUCTOR
  181. # ----------------------------------------------------------------------
  182. body iwidgets::Tabset::constructor {args} {
  183.     #
  184.     # Create the canvas that holds the tabs
  185.     #
  186.     itk_component add canvas {
  187.     canvas $itk_interior.canvas -highlightthickness 0
  188.     } {
  189.     keep -cursor -width -height
  190.     }
  191.     pack $itk_component(canvas) -fill both -expand yes -anchor nw
  192.     
  193.     # ... This gives us a chance to redraw our bevel borders, etc when
  194.     # the size of our canvas changes...
  195.     bind $itk_component(canvas) <Configure> \
  196.         [code $this _canvasReconfigure %w %h]
  197.     
  198.     # ... Allow button 2 scrolling as in label widget.
  199.     bind $itk_component(canvas) <2>               \
  200.         [code $this _startMove %x %y]
  201.     bind $itk_component(canvas) <B2-Motion>       \
  202.         [code $this _moveTabs %x %y]
  203.     bind $itk_component(canvas) <ButtonRelease-2> \
  204.         [code $this _endMove %x %y]
  205.     
  206.     # @@@ 
  207.     # @@@ Is there a better way?
  208.     # @@@
  209.     bind $itk_component(hull) <Any-Enter> "focus $itk_component(hull)"
  210.     bind $itk_component(hull) <Tab> [code $this next]
  211.     bind $itk_component(hull) <Shift-Tab> [code $this prev]
  212.     
  213.     eval itk_initialize $args
  214.     
  215.     _configRelayout 
  216.     
  217.     _recalcCanvasGeom
  218.     
  219. }
  220.  
  221. body iwidgets::Tabset::destructor {} {
  222.     foreach tab $_tabs {
  223.     itcl::delete object $tab
  224.     }
  225. }
  226.  
  227. # ----------------------------------------------------------------------
  228. #                              OPTIONS
  229. # ----------------------------------------------------------------------
  230.  
  231. # ----------------------------------------------------------------------
  232. # OPTION -width
  233. #
  234. # Sets the width explicitly for the canvas of the tabset
  235. # ----------------------------------------------------------------------
  236. configbody iwidgets::Tabset::width {
  237.     if {$itk_option(-width) != {}} {
  238.     }
  239.     set _width [winfo pixels $itk_interior $itk_option(-width)]
  240. }
  241.  
  242. # ----------------------------------------------------------------------
  243. # OPTION -equaltabs
  244. #
  245. # If set to true, causes horizontal tabs to be equal in
  246. # in width and vertical tabs to equal in height.
  247. # ----------------------------------------------------------------------
  248. configbody iwidgets::Tabset::equaltabs {
  249.     if {$itk_option(-equaltabs) != {}} {
  250.     set _relayout true
  251.     }
  252. }
  253.  
  254. # ----------------------------------------------------------------------
  255. # OPTION -height
  256. #
  257. # Sets the height explicitly for the canvas of the tabset
  258. # ----------------------------------------------------------------------
  259. configbody iwidgets::Tabset::height {
  260.     set _height [winfo pixels $itk_interior $itk_option(-height)]
  261. }
  262.  
  263. # ----------------------------------------------------------------------
  264. # OPTION -tabpos
  265. #
  266. # Sets the tab position of tabs, n, s, e, w
  267. # ----------------------------------------------------------------------
  268. configbody iwidgets::Tabset::tabpos {
  269.     if {$itk_option(-tabpos) != {}} {
  270.     switch $itk_option(-tabpos) {
  271.         n {
  272.         _tabConfigure -invert true -orient horizontal
  273.         }
  274.         s {
  275.         _tabConfigure -invert false -orient horizontal
  276.         }
  277.         w {
  278.         _tabConfigure -invert false -orient vertical
  279.         }
  280.         e {
  281.         _tabConfigure -invert true -orient vertical
  282.         }
  283.         default {
  284.         error "bad anchor position\
  285.             \"$itk_option(-tabpos)\" must be n, s, e, or w"
  286.         }
  287.     }
  288.     }
  289. }
  290.  
  291. # ----------------------------------------------------------------------
  292. # OPTION -raiseselect
  293. #
  294. # Sets whether to raise selected tabs slightly
  295. # ----------------------------------------------------------------------
  296. configbody iwidgets::Tabset::raiseselect {
  297.     if {$itk_option(-raiseselect) != {}} {
  298.     set _relayout true
  299.     }
  300. }
  301.  
  302. # ----------------------------------------------------------------------
  303. # OPTION -start
  304. #
  305. # Sets the offset to start of tab set
  306. # ----------------------------------------------------------------------
  307. configbody iwidgets::Tabset::start {
  308.     if {$itk_option(-start) != {}} {
  309.     set _start [winfo pixels $itk_interior $itk_option(-start)]
  310.     set _relayout true
  311.     } else {
  312.     set _start 4
  313.     }
  314. }
  315.  
  316. # ----------------------------------------------------------------------
  317. # OPTION -margin
  318. #
  319. # Sets the margin used above n tabs, below s tabs, left of e
  320. # tabs, right of w tabs
  321. # ----------------------------------------------------------------------
  322. configbody iwidgets::Tabset::margin {
  323.     if {$itk_option(-margin) != {}} {
  324.     set _margin [winfo pixels $itk_interior $itk_option(-margin)]
  325.     set _relayout true
  326.     } else {
  327.     set _margin 5
  328.     }
  329. }
  330.  
  331. # ----------------------------------------------------------------------
  332. # OPTION -tabborders
  333. #
  334. # Boolean that specifies whether to draw the borders of
  335. # the unselected tabs (tabs in background)
  336. # ----------------------------------------------------------------------
  337. configbody iwidgets::Tabset::tabborders {
  338.     if {$itk_option(-tabborders) != {}} {
  339.     _tabConfigure -tabborders $itk_option(-tabborders)
  340.     }
  341. }
  342.  
  343. # ----------------------------------------------------------------------
  344. # OPTION -bevelamount
  345. #
  346. # Specifies pixel size of tab corners. 0 means no corners.
  347. # ----------------------------------------------------------------------
  348. configbody iwidgets::Tabset::bevelamount {
  349.     if {$itk_option(-bevelamount) != {}} {
  350.     _tabConfigure -bevelamount $itk_option(-bevelamount)
  351.     }
  352. }
  353.  
  354. # ----------------------------------------------------------------------
  355. # OPTION -padx
  356. #
  357. # Sets the padding in each tab to the left and right of label
  358. # I don't convert for fpixels, since Tab does it for me.
  359. # ----------------------------------------------------------------------
  360. configbody iwidgets::Tabset::padx {
  361.     if {$itk_option(-padx) != {}} {
  362.     _tabConfigure -padx $itk_option(-padx)
  363.     }
  364. }
  365.  
  366. # ----------------------------------------------------------------------
  367. # OPTION -pady
  368. #
  369. # Sets the padding in each tab to the left and right of label
  370. # I don't convert for fpixels, since Tab does it for me.
  371. # ----------------------------------------------------------------------
  372. configbody iwidgets::Tabset::pady {
  373.     if {$itk_option(-pady) != {}} {
  374.     _tabConfigure -pady $itk_option(-pady)
  375.     }
  376. }
  377.  
  378. # ----------------------------------------------------------------------
  379. # OPTION -gap
  380. #
  381. # Sets the amount of spacing between tabs in pixels
  382. # ----------------------------------------------------------------------
  383. configbody iwidgets::Tabset::gap {
  384.     if {$itk_option(-gap) != {}} {
  385.     if {$itk_option(-gap) != "overlap"} {
  386.         set _gap [winfo pixels $itk_interior $itk_option(-gap)]
  387.     } else {
  388.         set _gap overlap
  389.     }
  390.     set _relayout true 
  391.     } else {
  392.     set _gap overlap
  393.     }
  394. }
  395.  
  396. # ----------------------------------------------------------------------
  397. # OPTION -angle
  398. #
  399. # Sets the angle of the tab's sides
  400. # ----------------------------------------------------------------------
  401. configbody iwidgets::Tabset::angle {
  402.     if {$itk_option(-angle) != {}} {
  403.     _tabConfigure -angle $itk_option(-angle)
  404.     }
  405. }
  406.  
  407. # ----------------------------------------------------------------------
  408. # OPTION -font
  409. #
  410. # Sets the font of the tab (SELECTED and UNSELECTED)
  411. # ----------------------------------------------------------------------
  412. configbody iwidgets::Tabset::font {
  413.     if {$itk_option(-font) != {}} {
  414.     _tabConfigure -font $itk_option(-font)
  415.     }
  416. }
  417.  
  418. # ----------------------------------------------------------------------
  419. # OPTION -state
  420. # ----------------------------------------------------------------------
  421. configbody iwidgets::Tabset::state {
  422.     if {$itk_option(-state) != {}} {
  423.     _tabConfigure -state $itk_option(-state)
  424.     }
  425. }
  426.  
  427. # ----------------------------------------------------------------------
  428. # OPTION -disabledforeground
  429. # ----------------------------------------------------------------------
  430. configbody iwidgets::Tabset::disabledforeground {
  431.     if {$itk_option(-disabledforeground) != {}} {
  432.     _tabConfigure \
  433.         -disabledforeground $itk_option(-disabledforeground)
  434.     }
  435. }
  436.  
  437. # ----------------------------------------------------------------------
  438. # OPTION -foreground
  439. #
  440. # Sets the foreground label color of UNSELECTED tabs
  441. # ----------------------------------------------------------------------
  442. configbody iwidgets::Tabset::foreground {
  443.     _tabConfigure -foreground $itk_option(-foreground)
  444. }
  445.  
  446. # ----------------------------------------------------------------------
  447. # OPTION -background
  448. #
  449. # Sets the background color of UNSELECTED tabs
  450. # ----------------------------------------------------------------------
  451. configbody iwidgets::Tabset::background {
  452.     if {$itk_option(-background) != {}} {
  453.     _tabConfigure -background $itk_option(-background)
  454.     } else {
  455.     _tabConfigure -background \
  456.         [$itk_component(canvas) cget -background]
  457.     }
  458. }
  459.  
  460. # ----------------------------------------------------------------------
  461. # OPTION -selectforeground
  462. #
  463. # Sets the foreground label color of SELECTED tabs
  464. # ----------------------------------------------------------------------
  465. configbody iwidgets::Tabset::selectforeground {
  466.     _tabConfigure -selectforeground $itk_option(-selectforeground)
  467. }
  468.  
  469. # ----------------------------------------------------------------------
  470. # OPTION -backdrop
  471. #
  472. # Sets the background color of the Tabset backdrop (behind the tabs)
  473. # ----------------------------------------------------------------------
  474. configbody iwidgets::Tabset::backdrop {
  475.     if {$itk_option(-backdrop) != {}} {
  476.     $itk_component(canvas) configure \
  477.         -background $itk_option(-backdrop)
  478.     }
  479. }
  480.  
  481. # ----------------------------------------------------------------------
  482. # OPTION -selectbackground
  483. #
  484. # Sets the background color of SELECTED tabs
  485. # ----------------------------------------------------------------------
  486. configbody iwidgets::Tabset::selectbackground {
  487.     if {$itk_option(-selectbackground) != {}} {
  488.     } else {
  489.     #set _selectBackground \
  490.         [$itk_component(canvas) cget -background]
  491.     }
  492.     _tabConfigure -selectbackground $itk_option(-selectbackground)
  493. }
  494.  
  495. # ----------------------------------------------------------------------
  496. # OPTION -command
  497. #
  498. # The command to invoke when a tab is hit.
  499. # ----------------------------------------------------------------------
  500. configbody iwidgets::Tabset::command {
  501.     if {$itk_option(-command) != {}} {
  502.     set _cmdStr $itk_option(-command)
  503.     }
  504. }
  505.  
  506. # ----------------------------------------------------------------------
  507. # METHOD: add ?option value...?
  508. #
  509. # Creates a tab and appends it to the list of tabs.
  510. # processes tabconfigure for the tab added.
  511. # ----------------------------------------------------------------------
  512. body iwidgets::Tabset::add {args} {
  513.     set tabName [eval _createTab $args]
  514.     lappend _tabs $tabName
  515.     
  516.     _relayoutTabs
  517.     
  518.     return $tabName
  519. }
  520.  
  521. # ----------------------------------------------------------------------
  522. # METHOD: configure ?option? ?value option value...?
  523. #
  524. # Acts as an addendum to the itk::Widget::configure method.
  525. #
  526. # Checks the _relayout flag to see if after configures are done
  527. # we need to relayout the tabs.
  528. #
  529. # _skipRelayout is set in the MB2 scroll methods, to avoid constant
  530. # relayout of tabs while dragging the mouse.
  531. # ----------------------------------------------------------------------
  532. body iwidgets::Tabset::configure {args} {
  533.     set result [eval itk::Archetype::configure $args]
  534.  
  535.     _configRelayout
  536.  
  537.     return $result
  538. }
  539.  
  540. body iwidgets::Tabset::_configRelayout {} {
  541.     # then relayout tabs if necessary
  542.     if { $_relayout } {
  543.     if { $_skipRelayout } {
  544.     } else {
  545.         _relayoutTabs
  546.     }
  547.     set _relayout false
  548.     }
  549. }
  550.  
  551. # ----------------------------------------------------------------------
  552. # METHOD: delete index1 ?index2?
  553. #
  554. # Deletes a tab or range of tabs from the tabset
  555. # ----------------------------------------------------------------------
  556. body iwidgets::Tabset::delete {args} {
  557.     if { $_tabs == {} } {
  558.     error "can't delete tabs,\
  559.         no tabs in the tabset named $itk_component(hull)"
  560.     }
  561.     
  562.     set len [llength $args]
  563.     switch $len {
  564.     0 {
  565.         error "wrong # args: should be\
  566.             \"$itk_component(hull) delete index1 ?index2?\""
  567.     }
  568.     
  569.     1 {
  570.         set fromTab [index [lindex $args 0]]
  571.         if { $fromTab == -1 } {
  572.         error "bad value for index1:\
  573.             [lindex $args 0] in call to delete"
  574.         }
  575.         set toTab $fromTab
  576.         _deleteTabs $fromTab $toTab
  577.     }
  578.     
  579.     2 {
  580.         set fromTab [index [lindex $args 0]]
  581.         if { $fromTab == -1 } {
  582.         error "bad value for index1:\
  583.             [lindex $args 0] in call to delete"
  584.         }
  585.         set toTab [index [lindex $args 1]]
  586.         
  587.         if { $toTab == -1 } {
  588.         error "bad value for index2:\
  589.             [lindex $args 1] in call to delete"
  590.         }
  591.         _deleteTabs $fromTab $toTab
  592.     }
  593.     
  594.     default {
  595.         error "wrong # args: should be\
  596.             \"$itk_component(hull) delete index1 ?index2?\""
  597.     }
  598.     }
  599. }
  600.  
  601. # ----------------------------------------------------------------------
  602. # METHOD: index index
  603. #
  604. # Given an index identifier returns the numeric index of the tab
  605. # ----------------------------------------------------------------------
  606. body iwidgets::Tabset::index {index} {
  607.     return [_index $_tabs $index $_currTab]
  608. }
  609.  
  610. # ----------------------------------------------------------------------
  611. # METHOD: insert index ?option value...?
  612. #
  613. # Inserts a tab before a index. The before tab may
  614. # be specified as a label or a tab position.
  615. # ----------------------------------------------------------------------
  616. body iwidgets::Tabset::insert {index args} {
  617.     if { $_tabs == {} } {
  618.     error "no tab to insert before,\
  619.         tabset '$itk_component(hull)' is empty"
  620.     }
  621.     
  622.     # get the tab
  623.     set tab [index $index]
  624.     
  625.     # catch bad value for before tab.
  626.     if { $tab < 0 || $tab >= [llength $_tabs] } {
  627.     error "bad value $tab for index:\
  628.         should be between 0 and [expr [llength $_tabs] - 1]"
  629.     }
  630.     
  631.     # create the new tab and get its name...
  632.     set tabName [eval _createTab $args]
  633.     
  634.     # grab the name of the tab currently selected. (to keep in sync)
  635.     set currTabName [lindex $_tabs $_currTab]
  636.     
  637.     # insert tabName before $tab
  638.     set _tabs [linsert $_tabs $tab $tabName]
  639.     
  640.     # keep the _currTab in sync with the insert.
  641.     set _currTab [lsearch -exact $_tabs $currTabName]
  642.     
  643.     _relayoutTabs
  644.     
  645.     return $tabName
  646. }
  647.  
  648. # ----------------------------------------------------------------------
  649. # METHOD: prev
  650. #
  651. # Selects the prev tab. Wraps at first back to last tab.
  652. # ----------------------------------------------------------------------
  653. body iwidgets::Tabset::prev {} {
  654.     if { $_tabs == {} } {
  655.     error "can't goto previous tab,\
  656.         no tabs in the tabset: $itk_component(hull)"
  657.     }
  658.     
  659.     # bump to the previous tab and wrap if necessary
  660.     set prev [expr $_currTab - 1]
  661.     if { $prev < 0 } {
  662.     set prev [expr [llength $_tabs] - 1]
  663.     }
  664.     
  665.     select $prev
  666.     
  667. }
  668.  
  669. # ----------------------------------------------------------------------
  670. # METHOD: next
  671. #
  672. # Selects the next tab. Wraps at last back to first tab.
  673. # ----------------------------------------------------------------------
  674. body iwidgets::Tabset::next {} {
  675.     if { $_tabs == {} } {
  676.     error "can't goto next tab,\
  677.         no tabs in the tabset: $itk_component(hull)"
  678.     }
  679.     
  680.     # bump to the next tab and wrap if necessary
  681.     set next [expr $_currTab + 1]
  682.     if { $next >= [llength $_tabs] } {
  683.     set next 0
  684.     }
  685.     
  686.     select $next
  687. }
  688.  
  689. # ----------------------------------------------------------------------
  690. # METHOD: select index
  691. #
  692. # Select a tab by index
  693. #
  694. # Lowers the last _currTab if it existed.
  695. # Then raises the new one if it exists.
  696. #
  697. # Returns numeric index of selection, -1 if failed.
  698. # -------------------------------------------------------------
  699. body iwidgets::Tabset::select {index} {
  700.     if { $_tabs == {} } {
  701.     error "can't activate a tab,\
  702.         no tabs in the tabset: $itk_component(hull)"
  703.     }
  704.     
  705.     # if there is not current selection just ignore trying this selection
  706.     if { $index == "select" && $_currTab == -1 } {
  707.     return -1
  708.     }
  709.     
  710.     # is selection request in range ? 
  711.     set reqTab [index $index]
  712.     if { $reqTab == -1 } {
  713.     error "bad value $index for index:\
  714.         should be from 0 to [expr [llength $_tabs] - 1]"
  715.     }
  716.     
  717.     # If already selected then ignore and return...
  718.     if { $reqTab == $_currTab } {
  719.     return $reqTab
  720.     }
  721.     
  722.     # ---- Deselect
  723.     if { $_currTab != -1 } {
  724.     set currTabName [lindex $_tabs $_currTab]
  725.     $currTabName deselect
  726.     
  727.     # handle different orientations...
  728.     if { $itk_option(-tabpos) == "n" || $itk_option(-tabpos) == "s"} {
  729.         $currTabName configure -top $_deselectedTop
  730.     } else {
  731.         $currTabName configure -left $_deselectedLeft
  732.     }
  733.     }
  734.     
  735.     # get the stacking order correct...
  736.     foreach tab $_tabs {
  737.     $tab lower
  738.     }
  739.     
  740.     # set this now so that the -command cmd can do an 'index select'
  741.     # to operate on this tab.
  742.     set _currTab $reqTab
  743.     
  744.     # ---- Select
  745.     set reqTabName [lindex $_tabs $reqTab]
  746.     $reqTabName select
  747.     if { $itk_option(-tabpos) == "n" || $itk_option(-tabpos) == "s"} {
  748.     $reqTabName configure -top $_selectedTop
  749.     } else {
  750.     $reqTabName configure -left $_selectedLeft
  751.     }
  752.     
  753.     set _currTab $reqTab
  754.     
  755.     # invoke any user command string, appended with tab index number
  756.     if { $_cmdStr != {} } {
  757.     set newCmd $_cmdStr
  758.     eval [lappend newCmd $reqTab]
  759.     }
  760.     
  761.     return $reqTab
  762. }
  763.  
  764. # ----------------------------------------------------------------------
  765. # METHOD: tabcget index ?option? 
  766. #
  767. # Returns the value for the option setting of the tab at index $index.
  768. # ----------------------------------------------------------------------
  769. body iwidgets::Tabset::tabcget {index args} {
  770.     return [lindex [eval tabconfigure $index $args] 2]
  771. }
  772.  
  773. # ----------------------------------------------------------------------
  774. # METHOD: tabconfigure index ?option? ?value option value?
  775. #
  776. # tabconfigure index : returns configuration list
  777. # tabconfigure index -option : returns option values
  778. # tabconfigure index ?option value option value ...? sets options
  779. #   and returns empty string.
  780. #
  781. # Performs configure on a given tab denoted by index.
  782. #
  783. # Index may be a tab number or a pattern matching the label
  784. # associated with a tab.
  785. # ----------------------------------------------------------------------
  786. body iwidgets::Tabset::tabconfigure {index args} {
  787.     # convert index to numeric
  788.     set tab [index $index]
  789.     
  790.     if { $tab == -1 } {
  791.     error "bad index value:\
  792.         $index for $itk_component(hull) tabconfigure"
  793.     }
  794.     
  795.     set tabName [lindex $_tabs $tab]
  796.     
  797.     set len [llength $args]
  798.     switch $len {
  799.     0 {
  800.         return [eval $tabName configure]
  801.     }
  802.     1 {
  803.         return [eval $tabName configure $args]
  804.     }
  805.     default {
  806.         eval $tabName configure $args
  807.         _relayoutTabs
  808.         select select
  809.     }
  810.     }
  811.     return ""
  812. }
  813.  
  814. # ----------------------------------------------------------------------
  815. # PROTECTED METHOD: _selectName
  816. #
  817. # internal method to allow selection by internal tab name 
  818. # rather than index. This is used by the bind methods
  819. # ----------------------------------------------------------------------
  820. body iwidgets::Tabset::_selectName {tabName} {
  821.     # if the tab is disabled, then ignore this selection...
  822.     if { [$tabName cget -state] == "disabled" } {
  823.     return
  824.     }
  825.     
  826.     set tab [lsearch -exact $_tabs $tabName]
  827.     select $tab
  828. }
  829.  
  830. # ----------------------------------------------------------------------
  831. # PRIVATE METHOD: _createTab
  832. #
  833. # Creates a tab, using unique tab naming, propagates background
  834. # and keeps unique id up to date.
  835. # ----------------------------------------------------------------------
  836. body iwidgets::Tabset::_createTab {args} {
  837.     #
  838.     # create an internal name for the tab: tab0, tab1, etc.
  839.     # these are one-up numbers they do not 
  840.     # correspond to the position the tab is located in.
  841.     #
  842.     set tabName $this-tab$_uniqueID
  843.     
  844.     switch $itk_option(-tabpos) {
  845.     n {
  846.         set invert true
  847.         set orient horizontal
  848.         set x 0
  849.         set y [expr $_margin + 1]
  850.     }
  851.     s {
  852.         set invert false
  853.         set orient horizontal
  854.         set x 0
  855.         set y 0
  856.     }
  857.     w {
  858.         set invert false
  859.         set orient vertical
  860.         set x 0 
  861.         set y 0
  862.     }
  863.     e {
  864.         set invert true
  865.         set orient vertical
  866.         set x [expr $_margin + 1]
  867.         set y 0
  868.     }
  869.     default {
  870.         error "bad anchor position\
  871.             \"$itk_option(-tabpos)\" must be n, s, e, or w"
  872.     }
  873.     }
  874.     
  875.     eval iwidgets::Tab $tabName $itk_component(canvas) \
  876.         -left             $x \
  877.         -top              $y \
  878.         -font             [list $itk_option(-font)] \
  879.         -background       $itk_option(-background) \
  880.         -foreground       $itk_option(-foreground) \
  881.         -selectforeground $itk_option(-selectforeground) \
  882.         -disabledforeground $itk_option(-disabledforeground) \
  883.         -selectbackground $itk_option(-selectbackground) \
  884.         -angle            $itk_option(-angle) \
  885.         -padx             $itk_option(-padx) \
  886.         -pady             $itk_option(-pady) \
  887.         -bevelamount      $itk_option(-bevelamount) \
  888.         -state            $itk_option(-state) \
  889.         -tabborders       $itk_option(-tabborders) \
  890.         -invert           $invert \
  891.         -orient           $orient \
  892.         $args
  893.     
  894.     $tabName lower
  895.     
  896.     $itk_component(canvas) \
  897.         bind $tabName <Button-1> [code $this _selectName $tabName]
  898.     
  899.     incr _uniqueID
  900.     
  901.     return $tabName
  902. }
  903.  
  904. # ----------------------------------------------------------------------
  905. # PRIVATE METHOD: _deleteTabs
  906. #
  907. # Deletes tabs from $fromTab to $toTab.
  908. #
  909. # Operates in two passes, destroys all the widgets
  910. # Then removes the pathName from the tab list
  911. #
  912. # Also keeps the current selection in bounds.
  913. # ----------------------------------------------------------------------
  914. body iwidgets::Tabset::_deleteTabs {fromTab toTab} {
  915.     for { set tab $fromTab } { $tab <= $toTab } { incr tab } {
  916.     set tabName [lindex $_tabs $tab]
  917.     
  918.     # unbind Button-1 from this window name
  919.     $itk_component(canvas) bind $tabName <Button-1> {}
  920.     
  921.     # Destroy the Tab class...
  922.     itcl::delete object $tabName 
  923.     }
  924.     
  925.     # physically remove the tab
  926.     set _tabs [lreplace $_tabs $fromTab $toTab]
  927.     
  928.     # If we deleted a selected tab set our selection to none
  929.     if { $_currTab >= $fromTab && $_currTab <= $toTab } {
  930.     set _currTab -1
  931.     _drawBevelBorder
  932.     }
  933.     
  934.     # make sure _currTab stays in sync with new numbering...
  935.     if { $_tabs == {} } {
  936.     # if deleted only remaining tab,
  937.     # reset current tab to undefined
  938.     set _currTab -1
  939.     
  940.     # or if the current tab was the last tab, it needs come back
  941.     } elseif { $_currTab >= [llength $_tabs] } {
  942.     incr _currTab -1
  943.     if { $_currTab < 0 } {
  944.         # but only to zero
  945.         set _currTab 0
  946.     }
  947.     }
  948.     
  949.     _relayoutTabs
  950. }
  951.  
  952. # ----------------------------------------------------------------------
  953. # PRIVATE METHOD: _index
  954. #
  955. # pathList : list of path names to search thru if index is a label
  956. # index    : either number, 'select', 'end', or pattern
  957. # select   : current selection
  958. #
  959. # _index takes takes the value $index converts it to
  960. # a numeric identifier. If the value is not already
  961. # an integer it looks it up in the $pathList array.
  962. # If it fails it returns -1
  963. # ----------------------------------------------------------------------
  964. body iwidgets::Tabset::_index {pathList index select} {
  965.     switch $index {
  966.     select {
  967.         set number $select
  968.     }
  969.     end {
  970.         set number [expr [llength $pathList] -1]
  971.     }
  972.     default {
  973.         # is it an number already?
  974.         if { [regexp {^[0-9]+$} $index] } {
  975.         set number $index
  976.         if { $number < 0 || $number >= [llength $pathList] } {
  977.             set number -1
  978.         }
  979.         
  980.         # otherwise it is a label
  981.         } else {
  982.         # look thru the pathList of pathNames and
  983.         # get each label and compare with index.
  984.         # if we get a match then set number to postion in $pathList
  985.         # and break out.
  986.         # otherwise number is still -1
  987.         set i 0
  988.         set number -1
  989.         foreach pathName $pathList {
  990.             set label [$pathName cget -label]
  991.             if { $label == $index } {
  992.             set number $i
  993.             break
  994.             }
  995.             incr i
  996.         }
  997.         }
  998.     }
  999.     }
  1000.     
  1001.     return $number
  1002. }
  1003.  
  1004. # ----------------------------------------------------------------------
  1005. # PRIVATE METHOD: _tabConfigure
  1006. # ----------------------------------------------------------------------
  1007. body iwidgets::Tabset::_tabConfigure {args} {
  1008.     foreach tab $_tabs {
  1009.     eval $tab configure $args
  1010.     }
  1011.     
  1012.     set _relayout true
  1013.     
  1014.     if { $_tabs != {} } {
  1015.     select select
  1016.     }
  1017. }
  1018.  
  1019. # ----------------------------------------------------------------------
  1020. # PRIVATE METHOD: _relayoutTabs
  1021. # 
  1022. # relays out the tabs with correct spacing...
  1023. # ----------------------------------------------------------------------
  1024. body iwidgets::Tabset::_relayoutTabs {} {
  1025.     if { [llength $_tabs] == 0 } {
  1026.     return
  1027.     }
  1028.     
  1029.     # get the max width for fixed width tabs...
  1030.     set maxWidth 0
  1031.     foreach tab $_tabs {
  1032.     set width [$tab labelwidth]
  1033.     if { $width > $maxWidth } {
  1034.         set maxWidth $width
  1035.     }
  1036.     }
  1037.     
  1038.     # get the max height for fixed height tabs...
  1039.     set maxHeight 0
  1040.     foreach tab $_tabs {
  1041.     set height [$tab labelheight]
  1042.     if { $height > $maxHeight } {
  1043.         set maxHeight $height
  1044.     }
  1045.     }
  1046.     
  1047.     # get curr tab's name
  1048.     set currTabName [lindex $_tabs $_currTab]
  1049.     
  1050.     # Start with our margin offset in pixels...
  1051.     set tabStart $_start
  1052.     
  1053.     if { $itk_option(-raiseselect) } {
  1054.     set raiseAmt 2
  1055.     } else {
  1056.     set raiseAmt 0
  1057.     }
  1058.     
  1059.     #
  1060.     # Depending on the tab layout: n, s, e, or w place the tabs
  1061.     # according to orientation, raise, margins, etc.
  1062.     #
  1063.     switch $itk_option(-tabpos) {
  1064.     n {
  1065.         set _selectedTop [expr $_margin + 1]
  1066.         set _deselectedTop [expr $_selectedTop + $raiseAmt]
  1067.         
  1068.         if { $itk_option(-equaltabs) } {
  1069.         set tabWidth $maxWidth
  1070.         } else {
  1071.         set tabWidth 0
  1072.         }
  1073.         
  1074.         foreach tab $_tabs {
  1075.         if { $tab == $currTabName } {
  1076.             $tab configure -left $tabStart -top $_selectedTop \
  1077.                 -height $maxHeight -width $tabWidth -anchor c
  1078.         } else {
  1079.             $tab configure -left $tabStart -top $_deselectedTop \
  1080.                 -height $maxHeight -width $tabWidth -anchor c
  1081.         }
  1082.         set tabStart [expr $tabStart + [_calcNextTabOffset $tab]]
  1083.         }
  1084.         
  1085.     }
  1086.     s {
  1087.         set _selectedTop 0
  1088.         set _deselectedTop [expr $_selectedTop - $raiseAmt]
  1089.         
  1090.         if { $itk_option(-equaltabs) } {
  1091.         set tabWidth $maxWidth
  1092.         } else {
  1093.         set tabWidth 0
  1094.         }
  1095.         
  1096.         foreach tab $_tabs {
  1097.         if { $tab == $currTabName } {
  1098.             $tab configure -left $tabStart -top $_selectedTop \
  1099.                 -height $maxHeight -width $tabWidth -anchor c
  1100.         } else {
  1101.             $tab configure -left $tabStart -top $_deselectedTop \
  1102.                 -height $maxHeight -width $tabWidth -anchor c
  1103.         }
  1104.         set tabStart [expr $tabStart + [_calcNextTabOffset $tab]]
  1105.         }
  1106.         
  1107.     }
  1108.     w {
  1109.         set _selectedLeft [expr $_margin + 1]
  1110.         set _deselectedLeft [expr $_selectedLeft + $raiseAmt]
  1111.         
  1112.         if { $itk_option(-equaltabs) } {
  1113.         set tabHeight $maxHeight
  1114.         } else {
  1115.         set tabHeight 0
  1116.         }
  1117.         
  1118.         foreach tab $_tabs {
  1119.         # selected
  1120.         if { $tab == $currTabName } {
  1121.             $tab configure -top $tabStart -left $_selectedLeft \
  1122.                 -height $tabHeight -width $maxWidth -anchor e
  1123.             # deselected
  1124.         } else {
  1125.             $tab configure -top $tabStart -left $_deselectedLeft \
  1126.                 -height $tabHeight -width $maxWidth -anchor e
  1127.         }
  1128.         set tabStart [expr $tabStart + [_calcNextTabOffset $tab]]
  1129.         }
  1130.         
  1131.     }
  1132.     e {
  1133.         set _selectedLeft 0
  1134.         set _deselectedLeft [expr $_selectedLeft - $raiseAmt]
  1135.         
  1136.         if { $itk_option(-equaltabs) } {
  1137.         set tabHeight $maxHeight
  1138.         } else {
  1139.         set tabHeight 0
  1140.         }
  1141.         
  1142.         foreach tab $_tabs {
  1143.         # selected
  1144.         if { $tab == $currTabName } {
  1145.             $tab configure -top $tabStart -left $_selectedLeft \
  1146.                 -height $tabHeight -width $maxWidth -anchor w
  1147.             # deselected
  1148.         } else {
  1149.             $tab configure -top $tabStart -left $_deselectedLeft \
  1150.                 -height $tabHeight -width $maxWidth -anchor w
  1151.         }
  1152.         set tabStart [expr $tabStart + [_calcNextTabOffset $tab]]
  1153.         }
  1154.         
  1155.     }
  1156.     default {
  1157.         error "bad anchor position\
  1158.             \"$itk_option(-tabpos)\" must be n, s, e, or w"
  1159.     }
  1160.     }
  1161.     
  1162.     # put border on & calc our new canvas size...
  1163.     _drawBevelBorder
  1164.     _recalcCanvasGeom
  1165.     
  1166. }
  1167.  
  1168. # ----------------------------------------------------------------------
  1169. # PRIVATE METHOD: _drawBevelBorder
  1170. # 
  1171. # draws the bevel border along tab edge (below selected tab)
  1172. # ----------------------------------------------------------------------
  1173. body iwidgets::Tabset::_drawBevelBorder {} {
  1174.     $itk_component(canvas) delete bevelBorder
  1175.     
  1176.     switch $itk_option(-tabpos) {
  1177.     n {
  1178.         $itk_component(canvas) create line \
  1179.             0 [expr $_canvasHeight - 1] \
  1180.             $_canvasWidth [expr $_canvasHeight - 1] \
  1181.             -fill [iwidgets::colors::topShadow $itk_option(-selectbackground)] \
  1182.             -tags bevelBorder
  1183.         $itk_component(canvas) create line \
  1184.             0 $_canvasHeight \
  1185.             $_canvasWidth $_canvasHeight \
  1186.             -fill [iwidgets::colors::topShadow $itk_option(-selectbackground)] \
  1187.             -tags bevelBorder
  1188.     }
  1189.     s {
  1190.         $itk_component(canvas) create line \
  1191.             0 0 \
  1192.             $_canvasWidth 0 \
  1193.             -fill [iwidgets::colors::bottomShadow $itk_option(-selectbackground)] \
  1194.             -tags bevelBorder
  1195.         $itk_component(canvas) create line \
  1196.             0 1 \
  1197.             $_canvasWidth 1 \
  1198.             -fill black \
  1199.             -tags bevelBorder
  1200.     }
  1201.     w {
  1202.         $itk_component(canvas) create line \
  1203.             $_canvasWidth 0 \
  1204.             $_canvasWidth [expr $_canvasHeight - 1] \
  1205.             -fill [iwidgets::colors::topShadow $itk_option(-selectbackground)] \
  1206.             -tags bevelBorder
  1207.         $itk_component(canvas) create line \
  1208.             [expr $_canvasWidth - 1] 0 \
  1209.             [expr $_canvasWidth - 1] [expr $_canvasHeight - 1] \
  1210.             -fill [iwidgets::colors::topShadow $itk_option(-selectbackground)] \
  1211.             -tags bevelBorder
  1212.         
  1213.     }
  1214.     e {
  1215.         $itk_component(canvas) create line \
  1216.             0 0 \
  1217.             0 [expr $_canvasHeight - 1] \
  1218.             -fill black \
  1219.             -tags bevelBorder
  1220.         $itk_component(canvas) create line \
  1221.             1 0 \
  1222.             1 [expr $_canvasHeight - 1] \
  1223.             -fill [iwidgets::colors::bottomShadow $itk_option(-selectbackground)] \
  1224.             -tags bevelBorder
  1225.         
  1226.     }
  1227.     }
  1228.     
  1229.     $itk_component(canvas) raise bevelBorder
  1230.     if { $_currTab != -1 } {
  1231.     set currTabName [lindex $_tabs $_currTab]
  1232.     $currTabName raise
  1233.     }
  1234. }
  1235.  
  1236. # ----------------------------------------------------------------------
  1237. # PRIVATE METHOD: _calcNextTabOffset
  1238. # 
  1239. # given $tabName, determines the offset in pixels to place
  1240. # the next tab's start edge at.
  1241. # ----------------------------------------------------------------------
  1242. body iwidgets::Tabset::_calcNextTabOffset {tabName} {
  1243.     if { $_gap == "overlap" } {
  1244.     return [$tabName offset]
  1245.     } else {
  1246.     return [expr [$tabName majordim] + $_gap]
  1247.     }
  1248. }
  1249.  
  1250. # ----------------------------------------------------------------------
  1251. # PRIVATE METHOD: _tabBounds
  1252. # 
  1253. # calculates the bounding box that will completely enclose 
  1254. # all the tabs.
  1255. # ----------------------------------------------------------------------
  1256. body iwidgets::Tabset::_tabBounds {} {
  1257.     set bbox { 100000 100000 -10000 -10000 }
  1258.     foreach tab $_tabs {
  1259.     set tabBBox [$tab bbox]
  1260.     # if this left is less use it
  1261.     if { [lindex $tabBBox 0] < [lindex $bbox 0] } {
  1262.         set bbox [lreplace $bbox 0 0 [lindex $tabBBox 0]]
  1263.     }
  1264.     # if this top is greater use it
  1265.     if { [lindex $tabBBox 1] < [lindex $bbox 1] } {
  1266.         set bbox [lreplace $bbox 1 1 [lindex $tabBBox 1]]
  1267.     }
  1268.     # if this right is less use it
  1269.     if { [lindex $tabBBox 2] > [lindex $bbox 2] } {
  1270.         set bbox [lreplace $bbox 2 2 [lindex $tabBBox 2]]
  1271.     }
  1272.     # if this bottom is greater use it
  1273.     if { [lindex $tabBBox 3] > [lindex $bbox 3] } {
  1274.         set bbox [lreplace $bbox 3 3 [lindex $tabBBox 3]]
  1275.     }
  1276.     
  1277.     }
  1278.     return $bbox
  1279. }
  1280.  
  1281. # ----------------------------------------------------------------------
  1282. # PRIVATE METHOD: _recalcCanvasGeom
  1283. # 
  1284. # Based on size of tabs, recalculates the canvas geometry that
  1285. # will hold the tabs.
  1286. # ----------------------------------------------------------------------
  1287. body iwidgets::Tabset::_recalcCanvasGeom {} {
  1288.     if { [llength $_tabs] == 0 } {
  1289.     return
  1290.     }
  1291.     
  1292.     set bbox [_tabBounds]
  1293.     
  1294.     set width [lindex [_tabBounds] 2]
  1295.     set height [lindex [_tabBounds] 3]
  1296.     
  1297.     # now we have the dimensions of all the tabs in the canvas.
  1298.     
  1299.     
  1300.     switch $itk_option(-tabpos) {
  1301.     n {
  1302.         # height already includes margin
  1303.         $itk_component(canvas) configure \
  1304.             -width $width \
  1305.             -height $height
  1306.     }
  1307.     s {
  1308.         $itk_component(canvas) configure \
  1309.             -width $width \
  1310.             -height [expr $height + $_margin]
  1311.     }
  1312.     w {
  1313.         # width already includes margin
  1314.         $itk_component(canvas) configure \
  1315.             -width $width \
  1316.             -height [expr $height + 1]
  1317.     }
  1318.     e {
  1319.         $itk_component(canvas) configure \
  1320.             -width [expr $width + $_margin] \
  1321.             -height [expr $height + 1]
  1322.     }
  1323.     default {
  1324.     }
  1325.     }
  1326. }
  1327.  
  1328. # ----------------------------------------------------------------------
  1329. # PRIVATE METHOD: _canvasReconfigure
  1330. # 
  1331. # Bound to the reconfigure notify event of a canvas, this 
  1332. # method resets canvas's correct width (since we are fill x)
  1333. # and redraws the beveled edge border.
  1334. # will hold the tabs.
  1335. # ----------------------------------------------------------------------
  1336. body iwidgets::Tabset::_canvasReconfigure {width height} {
  1337.     set _canvasWidth $width
  1338.     set _canvasHeight $height
  1339.     
  1340.     if { [llength $_tabs] > 0 } {
  1341.     _drawBevelBorder
  1342.     }
  1343. }
  1344.  
  1345. # ----------------------------------------------------------------------
  1346. # PRIVATE METHOD: _startMove
  1347. # 
  1348. # This method is bound to the MB2 down in the canvas area of the
  1349. # tab set. This starts animated scrolling of the tabs along their
  1350. # major axis.
  1351. # ----------------------------------------------------------------------
  1352. body iwidgets::Tabset::_startMove {x y} {
  1353.     if { $itk_option(-tabpos) == "n" || $itk_option(-tabpos) == "s" } {
  1354.     set _anchorX $x
  1355.     } else {
  1356.     set _anchorY $y
  1357.     }
  1358. }
  1359.  
  1360. # ----------------------------------------------------------------------
  1361. # PRIVATE METHOD: _moveTabs
  1362. # 
  1363. # This method is bound to the MB2 motion in the canvas area of the
  1364. # tab set. This causes the tabset to move with the mouse.
  1365. # ----------------------------------------------------------------------
  1366. body iwidgets::Tabset::_moveTabs {x y} {
  1367.     if { $itk_option(-tabpos) == "n" || $itk_option(-tabpos) == "s" } {
  1368.     set startX [expr $_start + $x - $_anchorX]
  1369.     foreach tab $_tabs {
  1370.         $tab configure -left $startX 
  1371.         set startX [expr $startX + [_calcNextTabOffset $tab]]
  1372.     }
  1373.     } else {
  1374.     set startY [expr $_start + $y - $_anchorY]
  1375.     foreach tab $_tabs {
  1376.         $tab configure -top $startY 
  1377.         set startY [expr $startY + [_calcNextTabOffset $tab]]
  1378.     }
  1379.     }
  1380. }
  1381.  
  1382. # ----------------------------------------------------------------------
  1383. # PRIVATE METHOD: _endMove
  1384. # 
  1385. # This method is bound to the MB2 release in the canvas area of the
  1386. # tab set. This causes the tabset to end moving tabs.
  1387. # ----------------------------------------------------------------------
  1388. body iwidgets::Tabset::_endMove {x y} {
  1389.     if { $itk_option(-tabpos) == "n" || $itk_option(-tabpos) == "s" } {
  1390.     set startX [expr $_start + $x - $_anchorX]
  1391.     set _skipRelayout true
  1392.     configure -start $startX
  1393.     set _skipRelayout false
  1394.     } else {
  1395.     set startY [expr $_start + $y - $_anchorY]
  1396.     set _skipRelayout true
  1397.     configure -start $startY
  1398.     set _skipRelayout false
  1399.     }
  1400. }
  1401.  
  1402.  
  1403. #==============================================================
  1404. # CLASS: Tab
  1405. #==============================================================
  1406.  
  1407. class iwidgets::Tab {
  1408.     constructor {args} {}
  1409.     
  1410.     destructor {}
  1411.     
  1412.     public variable bevelamount 0 {}
  1413.     public variable state normal {}
  1414.     public variable height 0 {}
  1415.     public variable width 0 {}
  1416.     public variable anchor c {}
  1417.     public variable left 0 {}
  1418.     public variable top 0 {}
  1419.     public variable image {} {}
  1420.     public variable bitmap {} {}
  1421.     public variable label {} {}
  1422.     public variable padx 4 {}
  1423.     public variable pady 4 {}
  1424.     public variable selectbackground "gray70" {}
  1425.     public variable selectforeground "black" {}
  1426.     public variable disabledforeground "gray" {}
  1427.     public variable background "white" {}
  1428.     public variable foreground "black" {}
  1429.     public variable orient vertical {}
  1430.     public variable invert false {}
  1431.     public variable angle 20 {}
  1432.     public variable font \
  1433.        "-adobe-helvetica-bold-r-normal--34-240-100-100-p-182-iso8859-1" {}
  1434.     public variable tabborders true {}
  1435.     
  1436.     public method configure {args} 
  1437.     public method bbox  {} 
  1438.     public method deselect {} 
  1439.     public method lower {} 
  1440.     public method majordim  {} 
  1441.     public method minordim  {} 
  1442.     public method offset  {} 
  1443.     public method raise {} 
  1444.     public method select {}
  1445.     public method labelheight {}
  1446.     public method labelwidth {} 
  1447.     
  1448.     private method _makeTab {} 
  1449.     private method _createLabel {canvas tagList} 
  1450.     private method _makeEastTab {canvas} 
  1451.     private method _makeWestTab {canvas} 
  1452.     private method _makeNorthTab {canvas}
  1453.     private method _makeSouthTab {canvas}
  1454.     private method _calcLabelDim {labelItem}
  1455.     private method _itk_config  {args} @itcl-builtin-configure 
  1456.     private method _selectNoRaise {}
  1457.     private method _deselectNoLower {}
  1458.     
  1459.     private variable   _selected false
  1460.     private variable   _padX 0
  1461.     private variable   _padY 0
  1462.     
  1463.     private variable   _canvas
  1464.     
  1465.     # these are in pixels
  1466.     private variable   _left 0
  1467.     private variable   _width 0
  1468.     private variable   _height 0
  1469.     private variable   _oldLeft 0
  1470.     private variable   _top 0
  1471.     private variable   _oldTop 0
  1472.     
  1473.     private variable   _right
  1474.     private variable   _bottom
  1475.     
  1476.     private variable   _offset
  1477.     private variable   _majorDim
  1478.     private variable   _minorDim
  1479.     
  1480.     private variable   _darkShadow
  1481.     private variable   _lightShadow
  1482.     
  1483.     # 
  1484.     # graphic components that make up a tab
  1485.     #
  1486.     private variable   _gRegion
  1487.     private variable   _gLabel
  1488.     private variable   _gLightOutline {}
  1489.     private variable   _gBlackOutline {}
  1490.     private variable   _gTopLine
  1491.     private variable   _gTopLineShadow
  1492.     private variable   _gLightShadow
  1493.     private variable   _gDarkShadow
  1494.     
  1495.     private variable   _labelWidth 0
  1496.     private variable   _labelHeight 0
  1497.     
  1498.     private variable   _labelXOrigin 0
  1499.     private variable   _labelYOrigin 0
  1500.     
  1501.     private variable   _just left
  1502.     
  1503.     private variable   _configTripped true
  1504.     
  1505.     common _tan
  1506.     
  1507.     set _tan(0)  0.0
  1508.     set _tan(1)  0.0175
  1509.     set _tan(2)  0.0349
  1510.     set _tan(3)  0.0524
  1511.     set _tan(4)  0.0699
  1512.     set _tan(5)  0.0875
  1513.     set _tan(6)  0.1051
  1514.     set _tan(7)  0.1228
  1515.     set _tan(8)  0.1405
  1516.     set _tan(9)  0.1584
  1517.     set _tan(10) 0.1763
  1518.     set _tan(11) 0.1944
  1519.     set _tan(12) 0.2126
  1520.     set _tan(13) 0.2309
  1521.     set _tan(14) 0.2493
  1522.     set _tan(15) 0.2679
  1523.     set _tan(16) 0.2867
  1524.     set _tan(17) 0.3057
  1525.     set _tan(18) 0.3249
  1526.     set _tan(19) 0.3443
  1527.     set _tan(20) 0.3640
  1528.     set _tan(21) 0.3839
  1529.     set _tan(22) 0.4040
  1530.     set _tan(23) 0.4245
  1531.     set _tan(24) 0.4452
  1532.     set _tan(25) 0.4663
  1533.     set _tan(26) 0.4877
  1534.     set _tan(27) 0.5095
  1535.     set _tan(28) 0.5317
  1536.     set _tan(29) 0.5543
  1537.     set _tan(30) 0.5774
  1538.     set _tan(31) 0.6009
  1539.     set _tan(32) 0.6294
  1540.     set _tan(33) 0.6494
  1541.     set _tan(34) 0.6745
  1542.     set _tan(35) 0.7002
  1543.     set _tan(36) 0.7265
  1544.     set _tan(37) 0.7536
  1545.     set _tan(38) 0.7813
  1546.     set _tan(39) 0.8098
  1547.     set _tan(40) 0.8391
  1548.     set _tan(41) 0.8693
  1549.     set _tan(42) 0.9004
  1550.     set _tan(43) 0.9325
  1551.     set _tan(44) 0.9657
  1552.     set _tan(45) 1.0
  1553. }
  1554.  
  1555. # ----------------------------------------------------------------------
  1556. #                              CONSTRUCTOR
  1557. # ----------------------------------------------------------------------
  1558. body iwidgets::Tab::constructor {args} {
  1559.     
  1560.     set _canvas [lindex $args 0]
  1561.     set args [lrange $args 1 [llength $args]]
  1562.     
  1563.     set _darkShadow  [iwidgets::colors::bottomShadow $selectbackground]
  1564.     set _lightShadow [iwidgets::colors::topShadow $selectbackground]
  1565.     
  1566.     if { $args != "" } {
  1567.     eval configure $args
  1568.     }
  1569. }
  1570.  
  1571. # ----------------------------------------------------------------------
  1572. #                              DESTRUCTOR
  1573. # ----------------------------------------------------------------------
  1574. body iwidgets::Tab::destructor {} {
  1575.     if { [winfo exists $_canvas] } {
  1576.     $_canvas delete $this
  1577.     }
  1578. }
  1579.  
  1580. # ----------------------------------------------------------------------
  1581. #                              OPTIONS
  1582. # ----------------------------------------------------------------------
  1583. #
  1584. # Note, we trip _configTripped for every option that requires the tab
  1585. # to be remade.
  1586. #
  1587. # ----------------------------------------------------------------------
  1588. # OPTION -bevelamount
  1589. #
  1590. # Specifies the size of tab corners. A value of 0 with angle set 
  1591. # to 0 results in square tabs. A bevelAmount of 4, means that the 
  1592. # tab will be drawn with angled corners that cut in 4 pixels from 
  1593. # the edge of the tab. The default is 0.
  1594. # ----------------------------------------------------------------------
  1595. configbody iwidgets::Tab::bevelamount { 
  1596. }
  1597.  
  1598. # ----------------------------------------------------------------------
  1599. # OPTION -state
  1600. #
  1601. # sets the active state of the tab. specifying normal allows 
  1602. # the tab to be selectable. Specifying disabled disables the tab, 
  1603. # causing its image, bitmap, or label to be drawn with the 
  1604. # disabledForeground color.
  1605. # ----------------------------------------------------------------------
  1606. configbody iwidgets::Tab::state { 
  1607. }
  1608.  
  1609. # ----------------------------------------------------------------------
  1610. # OPTION -height
  1611. #
  1612. # the height of the tab. if 0, uses the font label height.
  1613. # ----------------------------------------------------------------------
  1614. configbody iwidgets::Tab::height {
  1615.     set _height [winfo pixels $_canvas $height]
  1616.     set _configTripped true
  1617. }
  1618.  
  1619. # ----------------------------------------------------------------------
  1620. # OPTION -width
  1621. #
  1622. # The width of the tab. If 0, uses the font label width.
  1623. # ----------------------------------------------------------------------
  1624. configbody iwidgets::Tab::width {
  1625.     set _width [winfo pixels $_canvas $width]
  1626.     set _configTripped true
  1627. }
  1628.  
  1629. # ----------------------------------------------------------------------
  1630. # OPTION -anchor
  1631. #
  1632. # Where the text in the tab will be anchored: n,nw,ne,s,sw,se,e,w,center
  1633. # ----------------------------------------------------------------------
  1634. configbody iwidgets::Tab::anchor { 
  1635. }
  1636.  
  1637. # ----------------------------------------------------------------------
  1638. # OPTION -left
  1639. #
  1640. # Specifies the left edge of the tab's bounding box. This value 
  1641. # may have any of the forms acceptable to Tk_GetPixels.
  1642. # ----------------------------------------------------------------------
  1643. configbody iwidgets::Tab::left {
  1644.     
  1645.     # get into pixels
  1646.     set _left [winfo pixels $_canvas $left]
  1647.     
  1648.     # move by offset from last setting
  1649.     $_canvas move $this [expr $_left - $_oldLeft] 0
  1650.     
  1651.     # update old for next time
  1652.     set _oldLeft $_left
  1653. }
  1654.  
  1655. # ----------------------------------------------------------------------
  1656. # OPTION -top
  1657. #
  1658. # Specifies the topedge of the tab's bounding box. This value may 
  1659. # have any of the forms acceptable to Tk_GetPixels.
  1660. # ----------------------------------------------------------------------
  1661. configbody iwidgets::Tab::top {
  1662.     
  1663.     # get into pixels
  1664.     set _top [winfo pixels $_canvas $top]
  1665.     
  1666.     # move by offset from last setting
  1667.     $_canvas move $this 0 [expr $_top - $_oldTop]
  1668.     
  1669.     # update old for next time
  1670.     set _oldTop $_top
  1671. }
  1672.  
  1673. # ----------------------------------------------------------------------
  1674. # OPTION -image
  1675. #
  1676. # Specifies the imageto display in the tab. 
  1677. # Images are created with the image create command. 
  1678. # ----------------------------------------------------------------------
  1679. configbody iwidgets::Tab::image { 
  1680.     set _configTripped true
  1681. }
  1682.  
  1683. # ----------------------------------------------------------------------
  1684. # OPTION -bitmap
  1685. #
  1686. # If bitmap is an empty string, specifies the bitmap to display in 
  1687. # the tab. Bitmap may be of any of the forms accepted by Tk_GetBitmap. 
  1688. # ----------------------------------------------------------------------
  1689. configbody iwidgets::Tab::bitmap { 
  1690.     set _configTripped true
  1691. }
  1692.  
  1693. # ----------------------------------------------------------------------
  1694. # OPTION -label
  1695. #
  1696. # If image is an empty string and bitmap is an empty string, 
  1697. # it specifies a text string to be placed in the tab's label. 
  1698. # This label serves as an additional identifier used to reference 
  1699. # the tab. Label may be used for the index value in widget commands.
  1700. # ----------------------------------------------------------------------
  1701. configbody iwidgets::Tab::label { 
  1702.     set _configTripped true
  1703. }
  1704.  
  1705. # ----------------------------------------------------------------------
  1706. # OPTION -padx
  1707. #
  1708. # Horizontal padding around the label (text, image, or bitmap).
  1709. # ----------------------------------------------------------------------
  1710. configbody iwidgets::Tab::padx {
  1711.     set _configTripped true
  1712.     set _padX [winfo pixels $_canvas $padx]
  1713. }
  1714.  
  1715. # ----------------------------------------------------------------------
  1716. # OPTION -pady
  1717. #
  1718. # Vertical padding around the label (text, image, or bitmap).
  1719. # ----------------------------------------------------------------------
  1720. configbody iwidgets::Tab::pady {
  1721.     set _configTripped true
  1722.     set _padY [winfo pixels $_canvas $pady]
  1723. }
  1724.  
  1725. # ----------------------------------------------------------------------
  1726. # OPTION -selectbackground
  1727. # ----------------------------------------------------------------------
  1728. configbody iwidgets::Tab::selectbackground {
  1729.     set _darkShadow  [iwidgets::colors::bottomShadow $selectbackground]
  1730.     set _lightShadow [iwidgets::colors::topShadow $selectbackground]
  1731.     
  1732.     if { $_selected } {
  1733.     _selectNoRaise
  1734.     } else {
  1735.     _deselectNoLower
  1736.     }
  1737. }
  1738.  
  1739. # ----------------------------------------------------------------------
  1740. # OPTION -selectforeground
  1741. #
  1742. # Foreground of tab when selected
  1743. # ----------------------------------------------------------------------
  1744. configbody iwidgets::Tab::selectforeground { 
  1745.     if { $_selected } {
  1746.     _selectNoRaise
  1747.     } else {
  1748.     _deselectNoLower
  1749.     }
  1750. }
  1751.  
  1752. # ----------------------------------------------------------------------
  1753. # OPTION -disabledforeground
  1754. #
  1755. # Background of tab when -state is disabled
  1756. # ----------------------------------------------------------------------
  1757. configbody iwidgets::Tab::disabledforeground { 
  1758.     if { $_selected } {
  1759.     _selectNoRaise
  1760.     } else {
  1761.     _deselectNoLower
  1762.     }
  1763. }
  1764.  
  1765. # ----------------------------------------------------------------------
  1766. # OPTION -background
  1767. #
  1768. # Normal background of tab.
  1769. # ----------------------------------------------------------------------
  1770. configbody iwidgets::Tab::background { 
  1771.     
  1772.     if { $_selected } {
  1773.     _selectNoRaise
  1774.     } else {
  1775.     _deselectNoLower
  1776.     }
  1777.     
  1778. }
  1779.  
  1780. # ----------------------------------------------------------------------
  1781. # OPTION -foreground
  1782. #
  1783. # Foreground of tabs when in normal unselected state
  1784. # ----------------------------------------------------------------------
  1785. configbody iwidgets::Tab::foreground { 
  1786.     if { $_selected } {
  1787.     _selectNoRaise
  1788.     } else {
  1789.     _deselectNoLower
  1790.     }
  1791. }
  1792.  
  1793. # ----------------------------------------------------------------------
  1794. # OPTION -orient
  1795. #
  1796. # Specifies the orientation of the tab. Orient can be either 
  1797. # horizontal or vertical. 
  1798. # ----------------------------------------------------------------------
  1799. configbody iwidgets::Tab::orient { 
  1800.     set _configTripped true
  1801. }
  1802.  
  1803. # ----------------------------------------------------------------------
  1804. # OPTION -invert
  1805. #
  1806. # Specifies the direction to draw the tab. If invert is true, 
  1807. # it draws horizontal tabs upside down and vertical tabs opening 
  1808. # to the left (pointing right). The value may have any of the 
  1809. # forms accepted by the Tcl_GetBoolean, such as true, 
  1810. # false, 0, 1, yes, or no.
  1811. # ----------------------------------------------------------------------
  1812. configbody iwidgets::Tab::invert { 
  1813.     set _configTripped true
  1814. }
  1815.  
  1816. # ----------------------------------------------------------------------
  1817. # OPTION -angle
  1818. #
  1819. # Specifes the angle of slope from the inner edge to the outer edge 
  1820. # of the tab. An angle of 0 specifies square tabs. Valid ranges are 
  1821. # 0 to 45 degrees inclusive. Default is 15 degrees. If this option 
  1822. # is specified as an empty string (the default), then the angle 
  1823. # option for the overall Tabset is used.
  1824. # ----------------------------------------------------------------------
  1825. configbody iwidgets::Tab::angle {
  1826.     if {$angle < 0 || $angle > 45 } {
  1827.     error "bad angle: must be between 0 and 45"
  1828.     }
  1829.     set _configTripped true
  1830. }
  1831.  
  1832. # ----------------------------------------------------------------------
  1833. # OPTION -font
  1834. #
  1835. # Font for tab text.
  1836. # ----------------------------------------------------------------------
  1837. configbody iwidgets::Tab::font { 
  1838. }
  1839.  
  1840.  
  1841. # ----------------------------------------------------------------------
  1842. # OPTION -tabborders
  1843. #
  1844. # Specifies whether to draw the borders of a deselected tab. 
  1845. # Specifying true (the default) draws these borders, 
  1846. # specifying false disables this drawing. If the tab is in 
  1847. # its selected state this option has no effect. 
  1848. # The value may have any of the forms accepted by the 
  1849. # Tcl_GetBoolean, such as true, false, 0, 1, yes, or no.
  1850. # ----------------------------------------------------------------------
  1851. configbody iwidgets::Tab::tabborders { 
  1852.     set _configTripped true
  1853. }
  1854.  
  1855. # ----------------------------------------------------------------------
  1856. # METHOD: configure ?option value?
  1857. #
  1858. # Configures the Tab, checks a configTripped flag to see if the tab
  1859. # needs to be remade. We take the easy way since it is so inexpensive
  1860. # to delete canvas items and remake them.
  1861. # ----------------------------------------------------------------------
  1862. body iwidgets::Tab::configure {args} {
  1863.     set len [llength $args]
  1864.     
  1865.     switch $len {
  1866.     0 {
  1867.         set result [_itk_config]
  1868.         return $result
  1869.     }
  1870.     1 {
  1871.         set result [eval _itk_config $args]
  1872.         return $result
  1873.     }
  1874.     default {
  1875.         eval _itk_config $args
  1876.         if { $_configTripped } {
  1877.         _makeTab 
  1878.         set _configTripped false
  1879.         }
  1880.         return ""
  1881.     }
  1882.     }
  1883. }
  1884.  
  1885. # ----------------------------------------------------------------------
  1886. # METHOD: bbox
  1887. #
  1888. # Returns the bounding box of the tab
  1889. # ----------------------------------------------------------------------
  1890. body iwidgets::Tab::bbox {} {
  1891.     return [lappend bbox $_left $_top $_right $_bottom]
  1892. }
  1893. # ----------------------------------------------------------------------
  1894. # METHOD: deselect
  1895. #
  1896. # Causes the given tab to be drawn as deselected and lowered
  1897. # ----------------------------------------------------------------------
  1898. body iwidgets::Tab::deselect {} {
  1899.     $_canvas lower $this
  1900.     _deselectNoLower
  1901. }
  1902.  
  1903. # ----------------------------------------------------------------------
  1904. # METHOD: lower
  1905. #
  1906. # Lowers the tab below all others in the canvas.
  1907. #
  1908. # This is used as our tag name on the canvas.
  1909. # ----------------------------------------------------------------------
  1910. body iwidgets::Tab::lower {} {
  1911.     $_canvas lower $this
  1912. }
  1913.  
  1914. # ----------------------------------------------------------------------
  1915. # METHOD: majordim
  1916. #
  1917. # Returns the width for horizontal tabs and the height for
  1918. # vertical tabs.
  1919. # ----------------------------------------------------------------------
  1920. body iwidgets::Tab::majordim {} {
  1921.     return $_majorDim  
  1922. }
  1923.  
  1924. # ----------------------------------------------------------------------
  1925. # METHOD: minordim
  1926. #
  1927. # Returns the height for horizontal tabs and the width for
  1928. # vertical tabs.
  1929. # ----------------------------------------------------------------------
  1930. body iwidgets::Tab::minordim {} {
  1931.     return $_minorDim  
  1932. }
  1933.  
  1934. # ----------------------------------------------------------------------
  1935. # METHOD: offset
  1936. #
  1937. # Returns the width less the angle offset. This allows a 
  1938. # geometry manager to ask where to place a sibling tab.
  1939. # ----------------------------------------------------------------------
  1940. body iwidgets::Tab::offset {} {
  1941.     return $_offset  
  1942. }
  1943.  
  1944. # ----------------------------------------------------------------------
  1945. # METHOD: raise
  1946. #
  1947. # Raises the tab above all others in the canvas.
  1948. #
  1949. # This is used as our tag name on the canvas.
  1950. # ----------------------------------------------------------------------
  1951. body iwidgets::Tab::raise {} {
  1952.     $_canvas raise $this
  1953. }
  1954.  
  1955. # ----------------------------------------------------------------------
  1956. # METHOD: select
  1957. #
  1958. # Causes the given tab to be drawn as selected. 3d shadows are
  1959. # turned on and top line and top line shadow are drawn in sel
  1960. # bg color to hide them.
  1961. # ----------------------------------------------------------------------
  1962. body iwidgets::Tab::select {} {
  1963.     $_canvas raise $this
  1964.     _selectNoRaise
  1965. }
  1966.  
  1967. # ----------------------------------------------------------------------
  1968. # METHOD: labelheight
  1969. #
  1970. # Returns the height of the tab's label in its current font.
  1971. # ----------------------------------------------------------------------
  1972. body iwidgets::Tab::labelheight {} {
  1973.     if {$_gLabel != 0} {
  1974.     set labelBBox [$_canvas bbox $_gLabel]
  1975.     set labelHeight [expr [lindex $labelBBox 3] - [lindex $labelBBox 1]]
  1976.     } else {
  1977.     set labelHeight 0
  1978.     }
  1979.     return $labelHeight
  1980. }
  1981.  
  1982. # ----------------------------------------------------------------------
  1983. # METHOD: labelwidth
  1984. #
  1985. # Returns the width of the tab's label in its current font.
  1986. # ----------------------------------------------------------------------
  1987. body iwidgets::Tab::labelwidth {} {
  1988.     if {$_gLabel != 0} {
  1989.     set labelBBox [$_canvas bbox $_gLabel]
  1990.     set labelWidth [expr [lindex $labelBBox 2] - [lindex $labelBBox 0]]
  1991.     } else {
  1992.     set labelWidth 0
  1993.     }
  1994.     return $labelWidth
  1995. }
  1996.  
  1997. # ----------------------------------------------------------------------
  1998. # PRIVATE METHOD: _selectNoRaise
  1999. #
  2000. # Draws tab as selected without raising it.
  2001. # ----------------------------------------------------------------------
  2002. body iwidgets::Tab::_selectNoRaise {} {
  2003.     if { ! [info exists _gRegion] } {
  2004.     return
  2005.     }
  2006.     
  2007.     $_canvas itemconfigure $_gRegion -fill $selectbackground
  2008.     $_canvas itemconfigure $_gTopLine -fill $selectbackground
  2009.     $_canvas itemconfigure $_gTopLineShadow -fill $selectbackground
  2010.     $_canvas itemconfigure $_gLightShadow -fill $_lightShadow
  2011.     $_canvas itemconfigure $_gDarkShadow -fill $_darkShadow
  2012.     
  2013.     if { $_gLightOutline != {} } {
  2014.     $_canvas itemconfigure $_gLightOutline -fill $_lightShadow
  2015.     }
  2016.     if { $_gBlackOutline != {} } {
  2017.     $_canvas itemconfigure $_gBlackOutline -fill black
  2018.     }
  2019.     
  2020.     if { $state == "normal" } {
  2021.     if { $image != {}} {
  2022.         # do nothing for now
  2023.     } elseif { $bitmap != {}} {
  2024.         $_canvas itemconfigure $_gLabel \
  2025.             -foreground $selectforeground \
  2026.             -background $selectbackground 
  2027.     } else {
  2028.         $_canvas itemconfigure $_gLabel -fill $selectforeground
  2029.     }
  2030.     } else {
  2031.     if { $image != {}} {
  2032.         # do nothing for now
  2033.     } elseif { $bitmap != {}} {
  2034.         $_canvas itemconfigure $_gLabel \
  2035.             -foreground $disabledforeground \
  2036.             -background $selectbackground 
  2037.     } else {
  2038.         $_canvas itemconfigure $_gLabel -fill $disabledforeground
  2039.     }
  2040.     }
  2041.     
  2042.     set _selected true
  2043. }
  2044.  
  2045. # ----------------------------------------------------------------------
  2046. # PRIVATE METHOD: _deselectNoLower
  2047. #
  2048. # Causes the given tab to be drawn as deselected. 3d shadows are
  2049. # removed and top line and top line shadow are drawn in visible
  2050. # colors to reveal them.
  2051. # ----------------------------------------------------------------------
  2052. body iwidgets::Tab::_deselectNoLower {} {
  2053.     if { ! [info exists _gRegion] } {
  2054.     return
  2055.     }
  2056.     
  2057.     $_canvas itemconfigure $_gRegion -fill $background
  2058.     $_canvas itemconfigure $_gTopLine -fill black
  2059.     $_canvas itemconfigure $_gTopLineShadow -fill $_darkShadow
  2060.     $_canvas itemconfigure $_gLightShadow -fill $background
  2061.     $_canvas itemconfigure $_gDarkShadow -fill $background
  2062.     
  2063.     if { $tabborders } {
  2064.     if { $_gLightOutline != {} } {
  2065.         $_canvas itemconfigure $_gLightOutline -fill $_lightShadow
  2066.     }
  2067.     if { $_gBlackOutline != {} } {
  2068.         $_canvas itemconfigure $_gBlackOutline -fill black
  2069.     }
  2070.     } else {
  2071.     if { $_gLightOutline != {} } {
  2072.         $_canvas itemconfigure $_gLightOutline -fill $background
  2073.     }
  2074.     if { $_gBlackOutline != {} } {
  2075.         $_canvas itemconfigure $_gBlackOutline -fill $background
  2076.     }
  2077.     }
  2078.     
  2079.     
  2080.     if { $state == "normal" } {
  2081.     if { $image != {}} {
  2082.         # do nothing for now
  2083.     } elseif { $bitmap != {}} {
  2084.         $_canvas itemconfigure $_gLabel \
  2085.             -foreground $foreground \
  2086.             -background $background 
  2087.     } else {
  2088.         $_canvas itemconfigure $_gLabel -fill $foreground
  2089.     }
  2090.     } else {
  2091.     if { $image != {}} {
  2092.         # do nothing for now
  2093.     } elseif { $bitmap != {}} {
  2094.         $_canvas itemconfigure $_gLabel \
  2095.             -foreground $disabledforeground \
  2096.             -background $background 
  2097.     } else {
  2098.         $_canvas itemconfigure $_gLabel -fill $disabledforeground
  2099.     }
  2100.     }
  2101.     
  2102.     set _selected false
  2103. }
  2104.  
  2105. # ----------------------------------------------------------------------
  2106. # PRIVATE METHOD: _makeTab
  2107. # ----------------------------------------------------------------------
  2108. body iwidgets::Tab::_makeTab {} {
  2109.     if { $orient == "horizontal" } {
  2110.     if { $invert } {
  2111.         _makeNorthTab $_canvas
  2112.     } else {
  2113.         _makeSouthTab $_canvas
  2114.     }
  2115.     } elseif { $orient == "vertical" } {
  2116.     if { $invert } {
  2117.         _makeEastTab $_canvas
  2118.     } else {
  2119.         _makeWestTab $_canvas
  2120.     }
  2121.     } else {
  2122.     error "bad value for option -orient"
  2123.     }
  2124. }
  2125.  
  2126. # ----------------------------------------------------------------------
  2127. # PRIVATE METHOD: _createLabel
  2128. #
  2129. # Creates the label for the tab. Can be either a text label
  2130. # or a bitmap label.
  2131. # ----------------------------------------------------------------------
  2132. body iwidgets::Tab::_createLabel {canvas tagList} {
  2133.     if { $image != {}} {
  2134.     set _gLabel [$canvas create image \
  2135.         0 0 \
  2136.         -image $image \
  2137.         -anchor nw \
  2138.         -tags $tagList \
  2139.         ]
  2140.     } elseif { $bitmap != {}} {
  2141.     set _gLabel [$canvas create bitmap \
  2142.         0 0 \
  2143.         -bitmap $bitmap \
  2144.         -anchor nw \
  2145.         -tags $tagList \
  2146.         ]
  2147.     } else {
  2148.     set _gLabel [$canvas create text \
  2149.         0 0 \
  2150.         -text $label \
  2151.         -font $font \
  2152.         -anchor nw \
  2153.         -tags $tagList \
  2154.         ]
  2155.     }
  2156. }
  2157.  
  2158. # ----------------------------------------------------------------------
  2159. # PRIVATE METHOD: _makeEastTab
  2160. #
  2161. # Makes a tab that hangs to the east and opens to the west.
  2162. # ----------------------------------------------------------------------
  2163. body iwidgets::Tab::_makeEastTab {canvas} {
  2164.     $canvas delete $this
  2165.     set _gLightOutline {}
  2166.     set _gBlackOutline {}
  2167.     
  2168.     lappend tagList $this TAB
  2169.     
  2170.     _createLabel $canvas $tagList
  2171.     
  2172.     _calcLabelDim $_gLabel
  2173.     
  2174.     
  2175.     set right  [expr $_left + $_labelWidth]
  2176.     # now have _left, _top, right...
  2177.     
  2178.     # Turn off calculating angle tabs on Vertical orientations
  2179.     #set angleOffset [expr $_labelHeight * $_tan($angle)]
  2180.     set angleOffset 0
  2181.     
  2182.     set outerTop $_top
  2183.     set outerBottom \
  2184.         [expr $outerTop + $angleOffset + $_labelHeight + $angleOffset]
  2185.     set innerTop [expr $outerTop + $angleOffset]
  2186.     set innerBottom [expr $outerTop + $angleOffset + $_labelHeight]
  2187.     
  2188.     # now have _left, _top, right, outerTop, innerTop,
  2189.     # innerBottom, outerBottom, width, height
  2190.     
  2191.     set bottom $innerBottom
  2192.     # tab area... gets filled either white or selected
  2193.     # done
  2194.     set _gRegion [$canvas create polygon \
  2195.         $_left $outerTop \
  2196.         [expr $right - $bevelamount] $innerTop \
  2197.         $right [expr $innerTop + $bevelamount] \
  2198.         $right [expr $innerBottom - $bevelamount] \
  2199.         [expr $right - $bevelamount] $innerBottom \
  2200.         $_left $outerBottom \
  2201.         $_left $outerTop \
  2202.         -tags $tagList  \
  2203.         ]
  2204.     
  2205.     # lighter shadow (left edge)
  2206.     set _gLightShadow [$canvas create line \
  2207.         [expr $_left - 3] [expr $outerTop + 1] \
  2208.         [expr $right - $bevelamount] [expr $innerTop + 1] \
  2209.         -tags $tagList \
  2210.         ]
  2211.     
  2212.     # darker shadow (bottom and right edges)
  2213.     set _gDarkShadow [$canvas create line \
  2214.         [expr $right - $bevelamount] [expr $innerTop + 1] \
  2215.         [expr $right - 1] [expr $innerTop + $bevelamount] \
  2216.         [expr $right - 1] [expr $innerBottom - $bevelamount] \
  2217.         [expr $right - $bevelamount] [expr $innerBottom - 1] \
  2218.         [expr $_left - 3] [expr $outerBottom - 1] \
  2219.         -tags $tagList \
  2220.         ]
  2221.     
  2222.     # outline of tab
  2223.     set _gLightOutline [$canvas create line \
  2224.         $_left $outerTop \
  2225.         [expr $right - $bevelamount] $innerTop \
  2226.         -tags $tagList \
  2227.         ]
  2228.     # outline of tab
  2229.     set _gBlackOutline [$canvas create line \
  2230.         [expr $right - $bevelamount] $innerTop \
  2231.         $right [expr $innerTop + $bevelamount] \
  2232.         $right [expr $innerBottom - $bevelamount] \
  2233.         [expr $right - $bevelamount] $innerBottom \
  2234.         $_left $outerBottom \
  2235.         $_left $outerTop \
  2236.         -tags $tagList \
  2237.         ]
  2238.     
  2239.     # line closest to the edge
  2240.     set _gTopLineShadow [$canvas create line \
  2241.         $_left $outerTop \
  2242.         $_left $outerBottom \
  2243.         -tags $tagList \
  2244.         ]
  2245.     
  2246.     # next line down
  2247.     set _gTopLine [$canvas create line \
  2248.         [expr $_left + 1] [expr $outerTop + 2] \
  2249.         [expr $_left + 1] [expr $outerBottom - 1] \
  2250.         -tags $tagList  \
  2251.         ]
  2252.     
  2253.     $canvas coords $_gLabel [expr $_left + $_labelXOrigin] \
  2254.         [expr $innerTop + $_labelYOrigin]
  2255.     
  2256.     if { $image != {} || $bitmap != {} } {
  2257.     $canvas itemconfigure $_gLabel -anchor $anchor
  2258.     } else {
  2259.     $canvas itemconfigure $_gLabel -anchor $anchor -justify $_just
  2260.     }
  2261.     
  2262.     $canvas raise $_gLabel $_gRegion
  2263.     
  2264.     
  2265.     set _offset    [expr $innerBottom - $outerTop]
  2266.     # height
  2267.     set _majorDim  [expr $outerBottom - $outerTop]
  2268.     # width
  2269.     set _minorDim [expr $right - $_left]
  2270.     
  2271.     set _right   $right 
  2272.     set _bottom  $outerBottom
  2273.     
  2274.     # draw in correct state...
  2275.     if { $_selected } {
  2276.     select
  2277.     } else {
  2278.     deselect
  2279.     }
  2280. }
  2281.  
  2282. # ----------------------------------------------------------------------
  2283. # PRIVATE METHOD: _makeWestTab
  2284. #
  2285. # Makes a tab that hangs to the west and opens to the east.
  2286. # ----------------------------------------------------------------------
  2287. body iwidgets::Tab::_makeWestTab {canvas} {
  2288.     $canvas delete $this
  2289.     set _gLightOutline {}
  2290.     set _gBlackOutline {}
  2291.     
  2292.     lappend tagList $this TAB
  2293.     
  2294.     _createLabel $canvas $tagList
  2295.     _calcLabelDim $_gLabel
  2296.     
  2297.     set right  [expr $_left + $_labelWidth]
  2298.     # now have _left, _top, right...
  2299.     
  2300.     # Turn off calculating angle tabs on Vertical orientations
  2301.     #set angleOffset [expr $_labelHeight * $_tan($angle)]
  2302.     set angleOffset 0
  2303.     
  2304.     set outerTop $_top
  2305.     set outerBottom \
  2306.         [expr $outerTop + $angleOffset + $_labelHeight + $angleOffset]
  2307.     set innerTop [expr $outerTop + $angleOffset]
  2308.     set innerBottom [expr $outerTop + $angleOffset + $_labelHeight]
  2309.     
  2310.     # now have _left, _top, right, outerTop, innerTop,
  2311.     # innerBottom, outerBottom, width, height
  2312.     
  2313.     # tab area... gets filled either white or selected
  2314.     # done
  2315.     set _gRegion [$canvas create polygon \
  2316.         $right $outerTop \
  2317.         [expr $_left + $bevelamount] $innerTop \
  2318.         $_left [expr $innerTop + $bevelamount] \
  2319.         $_left [expr $innerBottom - $bevelamount]\
  2320.         [expr $_left + $bevelamount] $innerBottom \
  2321.         $right $outerBottom \
  2322.         $right $outerTop \
  2323.         -tags $tagList  \
  2324.         ]
  2325.     # lighter shadow (left edge)
  2326.     set _gLightShadow [$canvas create line \
  2327.         $right [expr $outerTop+1] \
  2328.         [expr $_left + $bevelamount] [expr $innerTop + 1] \
  2329.         [expr $_left + 1] [expr $innerTop + $bevelamount] \
  2330.         [expr $_left + 1] [expr $innerBottom - $bevelamount] \
  2331.         -tags $tagList \
  2332.         ]
  2333.     
  2334.     # darker shadow (bottom and right edges)
  2335.     set _gDarkShadow [$canvas create line \
  2336.         [expr $_left + 1] [expr $innerBottom - $bevelamount] \
  2337.         [expr $_left + $bevelamount] [expr $innerBottom - 1] \
  2338.         $right [expr $outerBottom - 1] \
  2339.         -tags $tagList \
  2340.         ]
  2341.     
  2342.     # outline of tab -- lighter top left sides
  2343.     set _gLightOutline [$canvas create line \
  2344.         $right $outerTop \
  2345.         [expr $_left + $bevelamount] $innerTop \
  2346.         $_left [expr $innerTop + $bevelamount] \
  2347.         $_left [expr $innerBottom - $bevelamount]\
  2348.         -tags $tagList \
  2349.         ]
  2350.     # outline of tab -- darker bottom side
  2351.     set _gBlackOutline [$canvas create line \
  2352.         $_left [expr $innerBottom - $bevelamount]\
  2353.         [expr $_left + $bevelamount] $innerBottom \
  2354.         $right $outerBottom \
  2355.         $right $outerTop \
  2356.         -tags $tagList \
  2357.         ]
  2358.     
  2359.     # top of tab
  2360.     set _gTopLine [$canvas create line \
  2361.         [expr $right + 1] $outerTop \
  2362.         [expr $right + 1] $outerBottom \
  2363.         -tags $tagList  \
  2364.         ]
  2365.     
  2366.     # line below top of tab
  2367.     set _gTopLineShadow [$canvas create line \
  2368.         $right $outerTop \
  2369.         $right $outerBottom \
  2370.         -tags $tagList \
  2371.         ]
  2372.     
  2373.     $canvas coords $_gLabel [expr $_left + $_labelXOrigin] \
  2374.         [expr $innerTop + $_labelYOrigin]
  2375.     if { $image != {} || $bitmap != {} } {
  2376.     $canvas itemconfigure $_gLabel -anchor $anchor 
  2377.     } else {
  2378.     $canvas itemconfigure $_gLabel -anchor $anchor -justify $_just
  2379.     }
  2380.     
  2381.     $canvas raise $_gLabel $_gRegion
  2382.     
  2383.     
  2384.     set _offset    [expr $innerBottom - $outerTop]
  2385.     # height
  2386.     set _majorDim  [expr $outerBottom - $outerTop]
  2387.     # width
  2388.     set _minorDim [expr $right - $_left]
  2389.     
  2390.     set _right   $right 
  2391.     set _bottom  $outerBottom
  2392.     
  2393.     # draw in correct state...
  2394.     if { $_selected } {
  2395.     select
  2396.     } else {
  2397.     deselect
  2398.     }
  2399.     
  2400. }
  2401.  
  2402. # ----------------------------------------------------------------------
  2403. # PRIVATE METHOD: _makeNorthTab
  2404. #
  2405. # Makes a tab that hangs to the north and opens to the south.
  2406. # ----------------------------------------------------------------------
  2407. body iwidgets::Tab::_makeNorthTab {canvas} {
  2408.     $canvas delete $this
  2409.     set _gLightOutline {}
  2410.     set _gBlackOutline {}
  2411.     
  2412.     lappend tagList $this TAB
  2413.     
  2414.     _createLabel $canvas $tagList
  2415.     
  2416.     # first get the label width and height
  2417.     _calcLabelDim $_gLabel
  2418.     
  2419.     set bottom [expr $_top + $_labelHeight]
  2420.     
  2421.     set angleOffset [expr $_labelHeight * $_tan($angle)]
  2422.     
  2423.     set outerLeft $_left
  2424.     set outerRight \
  2425.         [expr $outerLeft + $angleOffset + $_labelWidth + $angleOffset]
  2426.     set innerLeft [expr $outerLeft + $angleOffset]
  2427.     set innerRight [expr $outerLeft + $angleOffset + $_labelWidth]
  2428.     
  2429.     # tab area... gets filled either white or selected
  2430.     set _gRegion [$canvas create polygon \
  2431.         $outerLeft [expr $bottom + 3]  \
  2432.         $innerLeft [expr $_top + $bevelamount] \
  2433.         [expr $innerLeft +  $bevelamount] $_top \
  2434.         [expr $innerRight - $bevelamount] $_top \
  2435.         $innerRight [expr $_top + $bevelamount]\
  2436.         $outerRight [expr $bottom + 3] \
  2437.         $outerLeft [expr $bottom + 3] \
  2438.         -tags $tagList  \
  2439.         ]
  2440.     
  2441.     # lighter shadow (left edge)
  2442.     set _gLightShadow [$canvas create line \
  2443.         [expr $outerLeft + 1] [expr $bottom + 3]  \
  2444.         [expr $innerLeft + 1] [expr $_top + $bevelamount] \
  2445.         [expr $innerLeft + $bevelamount] [expr $_top + 1]\
  2446.         [expr $innerRight - $bevelamount] [expr $_top + 1]\
  2447.         -tags $tagList \
  2448.         ]
  2449.     
  2450.     # darker shadow (bottom and right edges)
  2451.     set _gDarkShadow [$canvas create line \
  2452.         [expr $innerRight - $bevelamount] [expr $_top + 1]\
  2453.         [expr $innerRight - 1] [expr $_top + $bevelamount]\
  2454.         [expr $outerRight - 1] [expr $bottom + 3]\
  2455.         -tags $tagList \
  2456.         ]
  2457.     
  2458.     set _gLightOutline [$canvas create line \
  2459.         $outerLeft [expr $bottom + 3]  \
  2460.         $innerLeft [expr $_top + $bevelamount] \
  2461.         [expr $innerLeft +  $bevelamount] $_top \
  2462.         [expr $innerRight - $bevelamount] $_top \
  2463.         -tags $tagList \
  2464.         ]
  2465.     
  2466.     set _gBlackOutline [$canvas create line \
  2467.         [expr $innerRight - $bevelamount] $_top \
  2468.         $innerRight [expr $_top + $bevelamount]\
  2469.         $outerRight [expr $bottom + 3] \
  2470.         $outerLeft [expr $bottom + 3] \
  2471.         -tags $tagList \
  2472.         ]
  2473.     
  2474.     # top of tab... to make it closed off
  2475.     set _gTopLine [$canvas create line \
  2476.         0 0 0 0\
  2477.         -tags $tagList  \
  2478.         ]
  2479.     #[expr $outerLeft + 2] [expr $_top + 1] \
  2480.         [expr $outerRight - 2] [expr $_top + 1]
  2481.     
  2482.     # top of tab... to make it closed off
  2483.     set _gTopLineShadow [$canvas create line \
  2484.         0 0 0 0 \
  2485.         -tags $tagList \
  2486.         ]
  2487.     #$outerLeft $_top \
  2488.         $outerRight $_top 
  2489.     
  2490.     $canvas coords $_gLabel [expr $innerLeft + $_labelXOrigin] \
  2491.         [expr $_top + $_labelYOrigin]
  2492.     
  2493.     if { $image != {} || $bitmap != {} } {
  2494.     $canvas itemconfigure $_gLabel -anchor $anchor 
  2495.     } else {
  2496.     $canvas itemconfigure $_gLabel -anchor $anchor -justify $_just
  2497.     }
  2498.     
  2499.     $canvas raise $_gLabel $_gRegion
  2500.     
  2501.     
  2502.     set _offset    [expr $innerRight - $outerLeft]
  2503.     # width
  2504.     set _majorDim  [expr $outerRight - $outerLeft]
  2505.     # height
  2506.     set _minorDim [expr $bottom - $_top]
  2507.     
  2508.     set _right     $outerRight
  2509.     set _bottom    $bottom
  2510.     
  2511.     # draw in correct state...
  2512.     if { $_selected } {
  2513.     select
  2514.     } else {
  2515.     deselect
  2516.     }
  2517. }
  2518.  
  2519. # ----------------------------------------------------------------------
  2520. # PRIVATE METHOD: _makeSouthTab
  2521. #
  2522. # Makes a tab that hangs to the south and opens to the north.
  2523. # ----------------------------------------------------------------------
  2524. body iwidgets::Tab::_makeSouthTab {canvas} {
  2525.     $canvas delete $this
  2526.     set _gLightOutline {}
  2527.     set _gBlackOutline {}
  2528.     
  2529.     lappend tagList $this TAB
  2530.     
  2531.     _createLabel $canvas $tagList
  2532.     
  2533.     # first get the label width and height
  2534.     _calcLabelDim $_gLabel
  2535.     
  2536.     set bottom [expr $_top + $_labelHeight]
  2537.     
  2538.     set angleOffset [expr $_labelHeight * $_tan($angle)]
  2539.     
  2540.     set outerLeft $_left
  2541.     set outerRight \
  2542.         [expr $outerLeft + $angleOffset + $_labelWidth + $angleOffset]
  2543.     set innerLeft [expr $outerLeft + $angleOffset]
  2544.     set innerRight [expr $outerLeft + $angleOffset + $_labelWidth]
  2545.     
  2546.     # tab area... gets filled either white or selected
  2547.     set _gRegion [$canvas create polygon \
  2548.         $outerLeft [expr $_top + 1] \
  2549.         $innerLeft [expr $bottom  - $bevelamount]\
  2550.         [expr $innerLeft + $bevelamount] $bottom \
  2551.         [expr $innerRight - $bevelamount] $bottom \
  2552.         $innerRight [expr $bottom - $bevelamount]\
  2553.         $outerRight [expr $_top + 1] \
  2554.         $outerLeft [expr $_top + 1] \
  2555.         -tags $tagList  \
  2556.         ]
  2557.     
  2558.     
  2559.     # lighter shadow (left edge)
  2560.     set _gLightShadow [$canvas create line \
  2561.         [expr $outerLeft+1] $_top \
  2562.         [expr $innerLeft+1] [expr $bottom-$bevelamount] \
  2563.         -tags $tagList \
  2564.         ]
  2565.     
  2566.     # darker shadow (bottom and right edges)
  2567.     set _gDarkShadow [$canvas create line \
  2568.         [expr $innerLeft+1] [expr $bottom-$bevelamount] \
  2569.         [expr $innerLeft+$bevelamount] [expr $bottom-1] \
  2570.         [expr $innerRight-$bevelamount] [expr $bottom-1] \
  2571.         [expr $innerRight-1] [expr $bottom-$bevelamount] \
  2572.         [expr $outerRight-1] [expr $_top + 1] \
  2573.         -tags $tagList \
  2574.         ]
  2575.     # outline of tab
  2576.     set _gBlackOutline [$canvas create line \
  2577.         $outerLeft [expr $_top + 1] \
  2578.         $innerLeft [expr $bottom  -$bevelamount]\
  2579.         [expr $innerLeft + $bevelamount] $bottom \
  2580.         [expr $innerRight - $bevelamount] $bottom \
  2581.         $innerRight [expr $bottom - $bevelamount]\
  2582.         $outerRight [expr $_top + 1] \
  2583.         -tags $tagList \
  2584.         ]
  2585.     
  2586.     # top of tab... to make it closed off
  2587.     set _gTopLine [$canvas create line \
  2588.         $outerLeft [expr $_top + 1] \
  2589.         $outerRight [expr $_top + 1] \
  2590.         -tags $tagList  \
  2591.         ]
  2592.     
  2593.     # top of tab... to make it closed off
  2594.     set _gTopLineShadow [$canvas create line \
  2595.         $outerLeft $_top \
  2596.         $outerRight $_top \
  2597.         -tags $tagList \
  2598.         ]
  2599.     
  2600.     #$canvas coords $_gLabel [expr $innerLeft + $_padX + 2] \
  2601.         [expr $_top + $_padY]
  2602.     $canvas coords $_gLabel [expr $innerLeft + $_labelXOrigin] \
  2603.         [expr $_top + $_labelYOrigin]
  2604.     
  2605.     if { $image != {} || $bitmap != {} } {
  2606.     $canvas itemconfigure $_gLabel -anchor $anchor 
  2607.     } else {
  2608.     $canvas itemconfigure $_gLabel -anchor $anchor -justify $_just
  2609.     }
  2610.     $canvas raise $_gLabel $_gRegion
  2611.     
  2612.     
  2613.     set _offset    [expr $innerRight - $outerLeft]
  2614.     
  2615.     # width
  2616.     set _majorDim  [expr $outerRight - $outerLeft]
  2617.     
  2618.     # height
  2619.     set _minorDim [expr $bottom - $_top]
  2620.     
  2621.     set _right     $outerRight
  2622.     set _bottom    $bottom
  2623.     
  2624.     # draw in correct state...
  2625.     if { $_selected } {
  2626.     select
  2627.     } else {
  2628.     deselect
  2629.     }
  2630. }
  2631.  
  2632. # ----------------------------------------------------------------------
  2633. # PRIVATE METHOD: _calcLabelDim
  2634. #
  2635. # Calculate the width and height of the label bbox of labelItem
  2636. # can be either text or bitmap (in future also an image)
  2637. #
  2638. # There are two ways to calculate the label bbox.
  2639. #
  2640. # First, if the $_width and/or $_height is specified, we will use
  2641. # it to determine that dimension(s) width and/or height. For 
  2642. # a width/height of 0 we use the labels bbox to
  2643. # give us a base width/height.
  2644. # Then we add in the padx/pady to determine final bounds.
  2645. #
  2646. # Uses the following option or option derived variables:
  2647. #    -padx     ($_padX - converted to pixels)
  2648. #    -pady     ($_padY - converted to pixels)
  2649. #    -anchor   ($anchor)
  2650. #    -width    ($_width) This is the width for inside tab (label area)
  2651. #    -height   ($_height) This is the width for inside tab (label area)
  2652. #
  2653. # Side Effects:
  2654. #    _labelWidth will be set
  2655. #    _labelHeight will be set
  2656. #    _labelXOrigin will be set
  2657. #    _labelYOrigin will be set
  2658. # ----------------------------------------------------------------------
  2659. body iwidgets::Tab::_calcLabelDim {labelItem} {
  2660.     # ... calculate the label width and height
  2661.     set labelBBox [$_canvas bbox $labelItem]
  2662.     
  2663.     if { $_width > 0 } {
  2664.     set _labelWidth [expr $_width + ($_padX * 2)]
  2665.     } else {
  2666.     set _labelWidth [expr \
  2667.         ([lindex $labelBBox 2] - [lindex $labelBBox 0]) + ($_padX * 2)]
  2668.     }
  2669.     
  2670.     if { $_height > 0 } {
  2671.     set _labelHeight [expr $_height + ($_padY * 2)]
  2672.     } else {
  2673.     set _labelHeight [expr \
  2674.         ([lindex $labelBBox 3] - [lindex $labelBBox 1]) + ($_padY * 2)]
  2675.     }
  2676.     
  2677.     # ... calculate the label anchor point
  2678.     set centerX [expr $_labelWidth/2.0]
  2679.     set centerY [expr $_labelHeight/2.0 - 1]
  2680.     
  2681.     switch $anchor {
  2682.     n {
  2683.         set _labelXOrigin $centerX
  2684.         set _labelYOrigin $_padY
  2685.         set _just center
  2686.     }
  2687.     s {
  2688.         set _labelXOrigin $centerX
  2689.         set _labelYOrigin [expr $_labelHeight - $_padY]
  2690.         set _just center
  2691.     }
  2692.     e {
  2693.         set _labelXOrigin [expr $_labelWidth - $_padX - 1]
  2694.         set _labelYOrigin $centerY
  2695.         set _just right
  2696.     }
  2697.     w {
  2698.         set _labelXOrigin [expr $_padX + 2]
  2699.         set _labelYOrigin $centerY
  2700.         set _just left
  2701.     }
  2702.     c {
  2703.         set _labelXOrigin $centerX
  2704.         set _labelYOrigin $centerY
  2705.         set _just center
  2706.     }
  2707.     ne {
  2708.         set _labelXOrigin [expr $_labelWidth - $_padX - 1]
  2709.         set _labelYOrigin $_padY
  2710.         set _just right
  2711.     }
  2712.     nw {
  2713.         set _labelXOrigin [expr $_padX + 2]
  2714.         set _labelYOrigin $_padY
  2715.         set _just left
  2716.     }
  2717.     se {
  2718.         set _labelXOrigin [expr $_labelWidth - $_padX - 1]
  2719.         set _labelYOrigin [expr $_labelHeight - $_padY]
  2720.         set _just right
  2721.     }
  2722.     sw {
  2723.         set _labelXOrigin [expr $_padX + 2]
  2724.         set _labelYOrigin [expr $_labelHeight - $_padY]
  2725.         set _just left
  2726.     }
  2727.     default {
  2728.         error "bad anchor position: \
  2729.             \"$tabpos\" must be n, ne, nw, s, sw, se, e, w, or center"
  2730.     }
  2731.     }
  2732. }
  2733.