home *** CD-ROM | disk | FTP | other *** search
/ PC World 2000 December / PCWorld_2000-12_cd.bin / Komunikace / Comanche / comanche.exe / lib / iwidgets2.2.0 / scripts / panedwindow.itk < prev    next >
Text File  |  1999-02-24  |  30KB  |  911 lines
  1. #
  2. # Panedwindow
  3. # ----------------------------------------------------------------------
  4. # Implements a multiple paned window widget capable of orienting the panes
  5. # either vertically or horizontally.  Each pane is itself a frame acting
  6. # as a child site for other widgets.  The border separating each pane 
  7. # contains a sash which allows user positioning of the panes relative to
  8. # one another.  
  9. #
  10. # WISH LIST:
  11. #   This section lists possible future enhancements.  
  12. #
  13. #   1) Add an option to support squeezable panes.  Say you had more than
  14. #      two panes and you start to move the bottom one up, currently
  15. #      the sash movement is stopped when the minimum of the above pane
  16. #      is reached.  It be nice if movement could continue if any of
  17. #      the upper panes still has room, until all the upper panes
  18. #      are at minimum.  This is just an example which must be greatly
  19. #      generalized to be useful.
  20. #
  21. # ----------------------------------------------------------------------
  22. #  AUTHOR: Mark L. Ulferts               EMAIL: mulferts@spd.dsccc.com
  23. #
  24. #  @(#) $Id: panedwindow.itk,v 1.1 1998/07/27 18:49:44 stanton Exp $
  25. # ----------------------------------------------------------------------
  26. #            Copyright (c) 1995 DSC Technologies Corporation
  27. # ======================================================================
  28. # Permission to use, copy, modify, distribute and license this software 
  29. # and its documentation for any purpose, and without fee or written 
  30. # agreement with DSC, is hereby granted, provided that the above copyright 
  31. # notice appears in all copies and that both the copyright notice and 
  32. # warranty disclaimer below appear in supporting documentation, and that 
  33. # the names of DSC Technologies Corporation or DSC Communications 
  34. # Corporation not be used in advertising or publicity pertaining to the 
  35. # software without specific, written prior permission.
  36. # 
  37. # DSC DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE, INCLUDING 
  38. # ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, AND NON-
  39. # INFRINGEMENT. THIS SOFTWARE IS PROVIDED ON AN "AS IS" BASIS, AND THE
  40. # AUTHORS AND DISTRIBUTORS HAVE NO OBLIGATION TO PROVIDE MAINTENANCE, 
  41. # SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS. IN NO EVENT SHALL 
  42. # DSC BE LIABLE FOR ANY SPECIAL, INDIRECT OR CONSEQUENTIAL DAMAGES OR 
  43. # ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, 
  44. # WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTUOUS ACTION,
  45. # ARISING OUT OF OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS 
  46. # SOFTWARE.
  47. # ======================================================================
  48.  
  49. #
  50. # Default resources.
  51. #
  52. option add *Panedwindow.orient horizontal widgetDefault
  53. option add *Panedwindow.sashBorderWidth 2 widgetDefault
  54. option add *Panedwindow.sashCursor crosshair widgetDefault
  55. option add *Panedwindow.sashIndent -10 widgetDefault
  56. option add *Panedwindow.sashHeight 10 widgetDefault
  57. option add *Panedwindow.sashWidth 10 widgetDefault
  58. option add *Panedwindow.thickness 3 widgetDefault
  59. option add *Panedwindow.width 10 widgetDefault
  60. option add *Panedwindow.height 10 widgetDefault
  61.  
  62. #
  63. # Usual options.
  64. #
  65. itk::usual Panedwindow {
  66.     keep -background -cursor -sashcursor
  67. }
  68.  
  69. # ------------------------------------------------------------------
  70. #                            PANEDWINDOW
  71. # ------------------------------------------------------------------
  72. class iwidgets::Panedwindow {
  73.     inherit itk::Widget
  74.  
  75.     constructor {args} {}
  76.  
  77.     itk_option define -orient orient Orient horizontal 
  78.     itk_option define -sashborderwidth sashBorderWidth SashBorderWidth 2
  79.     itk_option define -sashcursor sashCursor SashCursor crosshair
  80.     itk_option define -sashwidth sashWidth SashWidth 10
  81.     itk_option define -sashheight sashHeight SashHeight 10
  82.     itk_option define -thickness thickness Thickness 3
  83.     itk_option define -sashindent sashIndent SashIndent -10
  84.  
  85.     public method index {index} 
  86.     public method childsite {args} 
  87.     public method fraction {percentage1 percentage2 args} 
  88.     public method add {tag args} 
  89.     public method insert {index tag args} 
  90.     public method delete {index} 
  91.     public method hide {index}    
  92.     public method show {index} 
  93.     public method paneconfigure {index args} 
  94.     public method reset {} 
  95.  
  96.     protected method _pwConfigureEventHandler {width height} 
  97.     protected method _startGrip {where num} 
  98.     protected method _endGrip {where num} 
  99.     protected method _configGrip {where num} 
  100.     protected method _handleGrip {where num} 
  101.     protected method _moveSash {where num} 
  102.  
  103.     private method _setFracArray {} 
  104.     private method _setActivePanes {} 
  105.     private method _calcFraction {where num} 
  106.     private method _makeSashes {} 
  107.     private method _placeSash {i} 
  108.     private method _placePanes {{start 0} {end end}} 
  109.     
  110.     private variable _initialized 0    ;# Denotes initialized state.
  111.     private variable _panes {}         ;# List of panes.
  112.     private variable _activePanes {}   ;# List of active panes.
  113.     private variable _sashes {}        ;# List of sashes.
  114.     private variable _separators {}    ;# List of separators.
  115.     private variable _frac             ;# Array of fraction percentages.
  116.     private variable _lowerlimit       ;# Margin distance above/left of sash.
  117.     private variable _upperlimit       ;# Margin distance below/right of sash.
  118.     private variable _dimension        ;# Width/Height at start of drag.
  119.     private variable _sashloc          ;# Array of dist of sash from above/left.
  120.     private variable _pixels           ;# Array of dist of sash from above/left.
  121.     private variable _minheight        ;# Array of min heights for panes.
  122.     private variable _minsashmoved     ;# Lowest sash moved during dragging.
  123.     private variable _maxsashmoved     ;# Highest sash moved during dragging.
  124.     private variable _dragging 0       ;# Boolean for dragging enabled.
  125.     private variable _movecount 0      ;# Kludge counter to get sashes to
  126.                                        ;# display without calling update 
  127.                                        ;# idletasks too often.
  128.     private variable _width 0          ;# hull's width.
  129.     private variable _height 0         ;# hull's height.
  130.     private variable _unique -1         ;# Unique number for pane names.
  131. }
  132.  
  133. #
  134. # Provide a lowercased access method for the Panedwindow class.
  135. # 
  136. proc ::iwidgets::panedwindow {pathName args} {
  137.     uplevel ::iwidgets::Panedwindow $pathName $args
  138. }
  139.  
  140. # ------------------------------------------------------------------
  141. #                        CONSTRUCTOR
  142. # ------------------------------------------------------------------
  143. body iwidgets::Panedwindow::constructor {args} {
  144.     itk_option add hull.width hull.height
  145.  
  146.     pack propagate $itk_component(hull) no
  147.     
  148.     #
  149.     # Add binding for the configure event.
  150.     #
  151.     bind pw-config-$this <Configure> [code $this _pwConfigureEventHandler %w %h]
  152.     bindtags $itk_component(hull) \
  153.         [linsert [bindtags $itk_component(hull)] 0 pw-config-$this]
  154.     
  155.     eval itk_initialize $args
  156. }
  157.  
  158. # ------------------------------------------------------------------
  159. #                             OPTIONS
  160. # ------------------------------------------------------------------
  161.  
  162. # ------------------------------------------------------------------
  163. # OPTION: -orient
  164. #
  165. # Specifies the orientation of the sashes.  Once the paned window
  166. # has been mapped, set the sash bindings and place the panes.
  167. # ------------------------------------------------------------------
  168. configbody iwidgets::Panedwindow::orient {
  169.     if {$_initialized} {
  170.     switch $itk_option(-orient) {
  171.         vertical {
  172.         for {set i 1} {$i < [llength $_panes]} {incr i} {
  173.             bind $itk_component(sash$i) <Button-1> \
  174.                 [code $this _startGrip %x $i]
  175.             bind $itk_component(sash$i) <B1-Motion> \
  176.                 [code $this _handleGrip %x $i]
  177.             bind $itk_component(sash$i) <B1-ButtonRelease-1> \
  178.                 [code $this _endGrip %x $i]
  179.             bind $itk_component(sash$i) <Configure> \
  180.                 [code $this _configGrip %x $i]
  181.         }
  182.         
  183.         _setFracArray
  184.         _makeSashes
  185.         _placePanes
  186.         }
  187.         
  188.         horizontal {
  189.         for {set i 1} {$i < [llength $_panes]} {incr i} {
  190.             bind $itk_component(sash$i) <Button-1> \
  191.                 [code $this _startGrip %y $i]
  192.             bind $itk_component(sash$i) <B1-Motion> \
  193.                 [code $this _handleGrip %y $i]
  194.             bind $itk_component(sash$i) <B1-ButtonRelease-1> \
  195.                 [code $this _endGrip %y $i]
  196.             bind $itk_component(sash$i) <Configure> \
  197.                 [code $this _configGrip %y $i]
  198.         }
  199.         
  200.         _setFracArray
  201.         _makeSashes
  202.         _placePanes
  203.         }
  204.         
  205.         default {
  206.         error "bad orientation option \"$itk_option(-orient)\":\
  207.             should be horizontal or vertical"
  208.         }
  209.     }
  210.     }
  211. }
  212.  
  213. # ------------------------------------------------------------------
  214. # OPTION: -sashborderwidth
  215. #
  216. # Specifies a non-negative value indicating the width of the 3-D
  217. # border to draw around the outside of the sash.
  218. # ------------------------------------------------------------------
  219. configbody iwidgets::Panedwindow::sashborderwidth {
  220.     set pixels [winfo pixels $itk_component(hull) \
  221.         $itk_option(-sashborderwidth)]
  222.     set itk_option(-sashborderwidth) $pixels
  223.     
  224.     if {$_initialized} {
  225.     for {set i 1} {$i < [llength $_panes]} {incr i} {
  226.         $itk_component(sash$i) configure \
  227.             -borderwidth $itk_option(-sashborderwidth)
  228.     }
  229.     }
  230. }
  231.  
  232. # ------------------------------------------------------------------
  233. # OPTION: -sashcursor
  234. #
  235. # Specifies the type of cursor to be used when over the sash.
  236. # ------------------------------------------------------------------
  237. configbody iwidgets::Panedwindow::sashcursor {
  238.     if {$_initialized} {
  239.     for {set i 1} {$i < [llength $_panes]} {incr i} {
  240.         $itk_component(sash$i) configure \
  241.             -cursor $itk_option(-sashcursor)
  242.     }
  243.     }
  244. }
  245.  
  246. # ------------------------------------------------------------------
  247. # OPTION: -sashwidth
  248. #
  249. # Specifies the width of the sash.
  250. # ------------------------------------------------------------------
  251. configbody iwidgets::Panedwindow::sashwidth {
  252.     set pixels [winfo pixels $itk_component(hull) \
  253.         $itk_option(-sashwidth)]
  254.     set itk_option(-sashwidth) $pixels
  255.     
  256.     if {$_initialized} {
  257.     for {set i 1} {$i < [llength $_panes]} {incr i} {
  258.         $itk_component(sash$i) configure \
  259.             -width $itk_option(-sashwidth)
  260.     }
  261.     }
  262. }
  263.  
  264. # ------------------------------------------------------------------
  265. # OPTION: -sashheight
  266. #
  267. # Specifies the height of the sash,
  268. # ------------------------------------------------------------------
  269. configbody iwidgets::Panedwindow::sashheight {
  270.     set pixels [winfo pixels $itk_component(hull) \
  271.         $itk_option(-sashheight)]
  272.     set itk_option(-sashheight) $pixels
  273.     
  274.     if {$_initialized} {
  275.     for {set i 1} {$i < [llength $_panes]} {incr i} {
  276.         $itk_component(sash$i) configure \
  277.             -height $itk_option(-sashheight)
  278.     }
  279.     }
  280. }
  281.  
  282. # ------------------------------------------------------------------
  283. # OPTION: -thickness
  284. #
  285. # Specifies the thickness of the separators.  It sets the width and
  286. # height of the separator to the thickness value and the borderwidth
  287. # to half the thickness.
  288. # ------------------------------------------------------------------
  289. configbody iwidgets::Panedwindow::thickness {
  290.     set pixels [winfo pixels $itk_component(hull) \
  291.         $itk_option(-thickness)]
  292.     set itk_option(-thickness) $pixels
  293.     
  294.     if {$_initialized} {
  295.     for {set i 1} {$i < [llength $_panes]} {incr i} {
  296.         $itk_component(separator$i) configure \
  297.             -height $itk_option(-thickness)
  298.         $itk_component(separator$i) configure \
  299.             -width $itk_option(-thickness)
  300.         $itk_component(separator$i) configure \
  301.             -borderwidth [expr $itk_option(-thickness) / 2]
  302.     }
  303.     
  304.     for {set i 1} {$i < [llength $_panes]} {incr i} {
  305.         _placeSash $i
  306.     }
  307.     }
  308. }
  309.  
  310. # ------------------------------------------------------------------
  311. # OPTION: -sashindent
  312. #
  313. # Specifies the placement of the sash along the panes.  A positive
  314. # value causes the sash to be offset from the near (left/top) side
  315. # of the pane, and a negative value causes the sash to be offset from
  316. # the far (right/bottom) side.  If the offset is greater than the 
  317. # width, then the sash is placed flush against the side.  
  318. # ------------------------------------------------------------------
  319. configbody iwidgets::Panedwindow::sashindent {
  320.     set pixels [winfo pixels $itk_component(hull) \
  321.         $itk_option(-sashindent)]
  322.     set itk_option(-sashindent) $pixels
  323.     
  324.     if {$_initialized} {
  325.     for {set i 1} {$i < [llength $_panes]} {incr i} {
  326.         _placeSash $i
  327.     }
  328.     }
  329. }
  330.  
  331. # ------------------------------------------------------------------
  332. #                            METHODS
  333. # ------------------------------------------------------------------
  334.  
  335. # ------------------------------------------------------------------
  336. # METHOD: index index
  337. #
  338. # Searches the panes in the paned window for the one with the 
  339. # requested tag, numerical index, or keyword "end".  Returns the pane's 
  340. # numerical index if found, otherwise error.
  341. # ------------------------------------------------------------------    
  342. body iwidgets::Panedwindow::index {index} {
  343.     if {[llength $_panes] > 0} {
  344.     if {[regexp {(^[0-9]+$)} $index]} {
  345.         if {$index < [llength $_panes]} {
  346.         return $index
  347.         } else {
  348.         error "Panedwindow index \"$index\" is out of range"
  349.         }
  350.         
  351.     } elseif {$index == "end"} {
  352.         return [expr [llength $_panes] - 1]
  353.         
  354.     } else {
  355.         if {[set idx [lsearch $_panes $index]] != -1} {
  356.         return $idx
  357.         }
  358.         
  359.         error "bad Panedwindow index \"$index\": must be number, end,\
  360.             or pattern"
  361.     }
  362.     
  363.     } else {
  364.     error "Panedwindow \"$itk_component(hull)\" has no panes"
  365.     }
  366. }
  367.  
  368. # ------------------------------------------------------------------
  369. # METHOD: childsite ?index?
  370. #
  371. # Given an index return the specifc childsite path name.  Invoked 
  372. # without an index return a list of all the child site panes.  The 
  373. # list is ordered from the near side (left/top).
  374. # ------------------------------------------------------------------
  375. body iwidgets::Panedwindow::childsite {args} {
  376.     if {! $_initialized} {
  377.     set _initialized 1
  378.     reset
  379.     }
  380.  
  381.     if {[llength $args] == 0} {
  382.     set children {}
  383.     
  384.     foreach pane $_panes {
  385.         lappend children [$itk_component($pane) childSite]
  386.     }
  387.     
  388.     return $children
  389.     
  390.     } else {
  391.     set index [index [lindex $args 0]]
  392.     return [$itk_component([lindex $_panes $index]) childSite]
  393.     }
  394. }
  395.  
  396. # ------------------------------------------------------------------
  397. # METHOD: fraction percentage percentage ?percentage ...?
  398. #
  399. # Sets the visible percentage of the panes.  Specifies a list of
  400. # percentages which are applied to the currently visible panes from 
  401. # the near side (left/top).  The number of percentages must be equal 
  402. # to the current number of visible (mapped) panes and add up to 100.
  403. # ------------------------------------------------------------------
  404. body iwidgets::Panedwindow::fraction {percentage1 percentage2 args} {
  405.     set args [linsert $args 0 $percentage1 $percentage2]
  406.     
  407.     if {[llength $args] == [llength $_activePanes]} {
  408.     set sum 0
  409.     
  410.     for {set i 0} {$i < [llength $args]} {incr i} {
  411.         set sum [expr $sum + [lindex $args $i]]
  412.     }
  413.     
  414.     if {$sum == 100} {
  415.         set perc 0.0
  416.         
  417.         for {set i 0} {$i < [llength $_activePanes]} {incr i} {
  418.         set _frac($i) $perc
  419.         set perc [expr $perc + [expr [lindex $args $i] / 100.0]]
  420.         }
  421.         
  422.         set _frac($i) 1.0
  423.         
  424.         if {[winfo ismapped $itk_component(hull)]} {
  425.         _placePanes
  426.         }
  427.         
  428.     } else {
  429.         error "bad fraction arguments \"$args\": they should add\
  430.             up to 100"
  431.     }
  432.     
  433.     } else {
  434.     error "wrong # args: should be \"$itk_component(hull)\
  435.         fraction percentage percentage ?percentage ...?\",\
  436.         where the number of percentages is\
  437.         [llength $_activePanes] and equal 100"
  438.     }
  439. }
  440.  
  441. # ------------------------------------------------------------------
  442. # METHOD: add tag ?option value option value ...?
  443. #
  444. # Add a new pane to the paned window to the far (right/bottom) side.
  445. # The method takes additional options which are passed on to the 
  446. # pane constructor.  These include -margin, and -minimum.  The path 
  447. # of the pane is returned.
  448. # ------------------------------------------------------------------
  449. body iwidgets::Panedwindow::add {tag args} {
  450.     #
  451.     # Create panes.
  452.     #
  453.     itk_component add $tag {
  454.     eval iwidgets::Pane $itk_interior.pane[incr _unique] $args
  455.     } {
  456.     keep -background -cursor
  457.     }
  458.     
  459.     lappend _panes $tag
  460.     lappend _activePanes $tag
  461.     
  462.     reset
  463.     
  464.     return $itk_component($tag)
  465. }
  466.  
  467. # ------------------------------------------------------------------
  468. # METHOD: insert index tag ?option value option value ...?
  469. #
  470. # Insert the specified pane in the paned window just before the one 
  471. # given by index.  Any additional options which are passed on to the 
  472. # pane constructor.  These include -margin, -minimum.  The path of 
  473. # the pane is returned.
  474. # ------------------------------------------------------------------
  475. body iwidgets::Panedwindow::insert {index tag args} {
  476.     #
  477.     # Create panes.
  478.     #
  479.     itk_component add $tag {
  480.     eval iwidgets::Pane $itk_interior.pane[incr _unique] $args
  481.     } {
  482.     keep -background -cursor
  483.     }
  484.     
  485.     set index [index $index]
  486.     set _panes [linsert $_panes $index $tag]
  487.     lappend _activePanes $tag
  488.     
  489.     reset
  490.     
  491.     return $itk_component($tag)
  492. }
  493.  
  494. # ------------------------------------------------------------------
  495. # METHOD: delete index
  496. #
  497. # Delete the specified pane.
  498. # ------------------------------------------------------------------
  499. body iwidgets::Panedwindow::delete {index} {
  500.     set index [index $index]
  501.     set tag [lindex $_panes $index]
  502.     
  503.     destroy $itk_component($tag)
  504.     
  505.     set _panes [lreplace $_panes $index $index]
  506.     
  507.     reset
  508. }
  509.  
  510. # ------------------------------------------------------------------
  511. # METHOD: hide index
  512. #
  513. # Remove the specified pane from the paned window. 
  514. # ------------------------------------------------------------------
  515. body iwidgets::Panedwindow::hide {index} {
  516.     set index [index $index]
  517.     set tag [lindex $_panes $index]
  518.     
  519.     if {[set idx [lsearch -exact $_activePanes $tag]] != -1} {
  520.     set _activePanes [lreplace $_activePanes $idx $idx]
  521.     }
  522.     
  523.     reset
  524. }   
  525.  
  526. # ------------------------------------------------------------------
  527. # METHOD: show index
  528. #
  529. # Display the specified pane in the paned window.
  530. # ------------------------------------------------------------------
  531. body iwidgets::Panedwindow::show {index} {
  532.     set index [index $index]
  533.     set tag [lindex $_panes $index]
  534.     
  535.     if {[lsearch -exact $_activePanes $tag] == -1} {
  536.     lappend _activePanes $tag
  537.     }
  538.     
  539.     reset
  540. }   
  541.  
  542. # ------------------------------------------------------------------
  543. # METHOD: paneconfigure index ?option? ?value option value ...?
  544. #
  545. # Configure a specified pane.  This method allows configuration of
  546. # panes from the Panedwindow level.  The options may have any of the 
  547. # values accepted by the add method.
  548. # ------------------------------------------------------------------
  549. body iwidgets::Panedwindow::paneconfigure {index args} {
  550.     set index [index $index]
  551.     set tag [lindex $_panes $index]
  552.     
  553.     return [uplevel $itk_component($tag) configure $args]
  554. }
  555.  
  556. # ------------------------------------------------------------------
  557. # METHOD: reset
  558. #
  559. # Redisplay the panes based on the default percentages of the panes.
  560. # ------------------------------------------------------------------
  561. body iwidgets::Panedwindow::reset {} {
  562.     if {$_initialized && [llength $_panes]} {
  563.     _setActivePanes
  564.     _setFracArray
  565.     
  566.     _makeSashes
  567.     _placePanes
  568.     }
  569. }
  570.  
  571. # ------------------------------------------------------------------
  572. # PROTECTED METHOD: _pwConfigureEventHandler
  573. #
  574. # Performs operations necessary following a configure event.  This
  575. # includes placing the panes.
  576. # ------------------------------------------------------------------
  577. body iwidgets::Panedwindow::_pwConfigureEventHandler {width height} {
  578.     set _width $width
  579.     set _height $height
  580.     if {$_initialized} {
  581.     _placePanes
  582.     } else {
  583.     set _initialized 1
  584.     reset
  585.     }
  586. }
  587.  
  588. # ------------------------------------------------------------------
  589. # PROTECTED METHOD: _startGrip where num
  590. #
  591. # Starts the sash drag and drop operation.  At the start of the drag
  592. # operation all the information is known as for the upper and lower
  593. # limits for sash movement.  The calculation is made at this time and
  594. # stored in protected variables for later access during the drag
  595. # handling routines.
  596. # ------------------------------------------------------------------
  597. body iwidgets::Panedwindow::_startGrip {where num} {
  598.     if {$itk_option(-orient) == "horizontal"} {
  599.       set _dimension $_height
  600.     } else {
  601.       set _dimension $_width
  602.     }
  603.     
  604.     set _minsashmoved $num
  605.     set _maxsashmoved $num
  606.     set totMinHeight 0
  607.     set cnt [llength $_activePanes]
  608.     set _sashloc(0) 0
  609.     set _pixels($cnt) [expr int($_dimension)]
  610.     for {set i 0} {$i < $cnt} {incr i} {
  611.       set _pixels($i) [expr int($_frac($i) * $_dimension)]
  612.       set margaft [$itk_component([lindex $_activePanes $i]) cget -margin]
  613.       set minaft [$itk_component([lindex $_activePanes $i]) cget -minimum]
  614.       set _minheight($i) [expr $minaft + (2 * $margaft)]
  615.       incr totMinHeight $_minheight($i)
  616.     }
  617.     set _dragging [expr $_dimension > $totMinHeight]
  618.  
  619.     grab  $itk_component(sash$num)
  620.     raise $itk_component(separator$num)
  621.     raise $itk_component(sash$num)
  622.     
  623.     $itk_component(sash$num) configure -relief sunken
  624. }
  625.  
  626. # ------------------------------------------------------------------
  627. # PROTECTED METHOD: _endGrip where num
  628. #
  629. # Ends the sash drag and drop operation.
  630. # ------------------------------------------------------------------
  631. body iwidgets::Panedwindow::_endGrip {where num} {
  632.     $itk_component(sash$num) configure -relief raised
  633.     grab release $itk_component(sash$num)
  634.     if {$_dragging} {
  635.       _calcFraction [expr $_sashloc($num) + $where] $num
  636.       _placePanes [expr $_minsashmoved - 1] $_maxsashmoved
  637.       set _dragging 0
  638.     }
  639. }
  640.  
  641. # ------------------------------------------------------------------
  642. # PROTECTED METHOD: _configGrip where num
  643. #
  644. # Configure  action for sash.
  645. # ------------------------------------------------------------------
  646. body iwidgets::Panedwindow::_configGrip {where num} {
  647.    set _sashloc($num) $where
  648. }
  649.  
  650. # ------------------------------------------------------------------
  651. # PROTECTED METHOD: _handleGrip where num
  652. #
  653. # Motion action for sash.
  654. # ------------------------------------------------------------------
  655. body iwidgets::Panedwindow::_handleGrip {where num} {
  656.  if {$_dragging} {
  657.   _moveSash [expr $where + $_sashloc($num)] $num
  658.   incr _movecount
  659.   if {$_movecount>4} {
  660.     set _movecount 0
  661.     update idletasks
  662.   }
  663.  }
  664. }
  665.  
  666. # ------------------------------------------------------------------
  667. # PROTECTED METHOD: _moveSash where num
  668. #
  669. # Move the sash to the absolute pixel location
  670. # ------------------------------------------------------------------
  671. body iwidgets::Panedwindow::_moveSash {where num} {
  672.   set _minsashmoved [expr ($_minsashmoved<$num)?$_minsashmoved:$num]
  673.   set _maxsashmoved [expr ($_maxsashmoved>$num)?$_maxsashmoved:$num]
  674.   set oldfrac $_frac($num)
  675.   _calcFraction $where $num
  676.   if {$_frac($num)!=$oldfrac} { _placeSash $num }
  677. }
  678.  
  679. # ------------------------------------------------------------------
  680. # PRIVATE METHOD: _setFracArray
  681. #
  682. # Calculates the percentages for the fraction array which lists the
  683. # percentages for each pane.
  684. # ------------------------------------------------------------------
  685. body iwidgets::Panedwindow::_setFracArray {} {
  686.     if {[llength [array names _frac]] != [expr [llength $_activePanes] + 1]} {
  687.     set perc 0.0
  688.     set percIncr [expr 1.0 / [llength $_activePanes]]
  689.     
  690.     for {set i 0} {$i < [llength $_activePanes]} {incr i} {
  691.         set _frac($i) $perc
  692.         set perc [expr $perc + $percIncr]
  693.     }
  694.     
  695.     set _frac($i) 1.0
  696.     }
  697. }
  698.  
  699. # ------------------------------------------------------------------
  700. # PRIVATE METHOD: _setActivePanes
  701. #
  702. # Resets the active pane list.
  703. # ------------------------------------------------------------------
  704. body iwidgets::Panedwindow::_setActivePanes {} {
  705.     set _prevActivePanes $_activePanes
  706.  
  707.     set _activePanes {}
  708.     
  709.     foreach pane $_panes {
  710.     if {[lsearch -exact $_prevActivePanes $pane] != -1} {
  711.         lappend _activePanes $pane
  712.     }
  713.     }
  714. }
  715.  
  716. # ------------------------------------------------------------------
  717. # PRIVATE METHOD: _calcFraction where num
  718. #
  719. # Determines the fraction for the sash.  Make sure the fraction does
  720. # not go past the minimum for the pane on each side of the separator.
  721. # ------------------------------------------------------------------
  722. body iwidgets::Panedwindow::_calcFraction {where num} {
  723.     
  724.     set _lowerlimit \
  725.         [expr $_pixels([expr $num - 1]) + $_minheight([expr $num - 1])]
  726.     set _upperlimit \
  727.         [expr $_pixels([expr $num + 1]) - $_minheight($num)]
  728.     
  729.     set dir [expr $where - $_pixels($num)]
  730.  
  731.     if {$where < $_lowerlimit && $dir <= 0} {
  732.      if {$num == 1} {
  733.       set _pixels($num) $_lowerlimit
  734.      } {
  735.       _moveSash [expr $where - $_minheight([expr $num - 1])] [expr $num -1]
  736.       set _pixels($num) \
  737.          [expr $_pixels([expr $num - 1]) + $_minheight([expr $num - 1])]
  738.      }
  739.     } elseif {$where > $_upperlimit && $dir >= 0} {
  740.      if {[expr $num + 1] == [llength $_activePanes]} {
  741.       set _pixels($num) $_upperlimit
  742.      } {
  743.       _moveSash [expr $where + $_minheight($num)] [expr $num +1]
  744.       set _pixels($num) \
  745.          [expr $_pixels([expr $num + 1]) - $_minheight($num)]
  746.      }
  747.     } else {
  748.       set _pixels($num) $where
  749.     }
  750.     set _frac($num) [expr $_pixels($num).0 / $_dimension]
  751. }
  752.  
  753. # ------------------------------------------------------------------
  754. # PRIVATE METHOD: _makeSashes
  755. #
  756. # Removes any previous sashes and separators and creates new one.
  757. # ------------------------------------------------------------------
  758. body iwidgets::Panedwindow::_makeSashes {} {
  759.     #
  760.     # Remove any existing sashes and separators.
  761.     #
  762.     foreach sash $_sashes {
  763.     destroy $itk_component($sash)
  764.     }
  765.     
  766.     foreach separator $_separators {
  767.     destroy $itk_component($separator)
  768.     }
  769.     
  770.     set _sashes {}
  771.     set _separators {}
  772.     
  773.     #
  774.     # Create one less separator and sash than the number of panes.  
  775.     #
  776.     for {set id 1} {$id < [llength $_activePanes]} {incr id} {
  777.     itk_component add sash$id {
  778.         frame $itk_interior.sash$id -relief raised \
  779.             -borderwidth $itk_option(-sashborderwidth) \
  780.             -cursor $itk_option(-sashcursor) \
  781.             -width $itk_option(-sashwidth) \
  782.             -height $itk_option(-sashheight)
  783.     } {
  784.         keep -background
  785.     }
  786.     
  787.     lappend _sashes sash$id
  788.     
  789.     switch $itk_option(-orient) {
  790.         vertical {
  791.         bind $itk_component(sash$id) <Button-1> \
  792.             [code $this _startGrip %x $id]
  793.         bind $itk_component(sash$id) <B1-Motion> \
  794.             [code $this _handleGrip %x $id]
  795.         bind $itk_component(sash$id) <B1-ButtonRelease-1> \
  796.             [code $this _endGrip %x $id]
  797.         bind $itk_component(sash$id) <Configure> \
  798.                 [code $this _configGrip %x $id]
  799.         }
  800.         
  801.         horizontal {
  802.         bind $itk_component(sash$id) <Button-1> \
  803.             [code $this _startGrip %y $id]
  804.         bind $itk_component(sash$id) <B1-Motion> \
  805.             [code $this _handleGrip %y $id]
  806.         bind $itk_component(sash$id) <B1-ButtonRelease-1> \
  807.             [code $this _endGrip %y $id]
  808.         bind $itk_component(sash$id) <Configure> \
  809.                 [code $this _configGrip %y $id]
  810.         }
  811.     }
  812.     
  813.     itk_component add separator$id {
  814.         frame $itk_interior.separator$id -relief sunken \
  815.             -height $itk_option(-thickness) \
  816.             -width $itk_option(-thickness) \
  817.             -borderwidth [expr $itk_option(-thickness) / 2]
  818.     } {
  819.         keep -background -cursor
  820.     }
  821.     
  822.     lappend _separators separator$id
  823.     }
  824. }
  825.  
  826. # ------------------------------------------------------------------
  827. # PRIVATE METHOD: _placeSash i
  828. #
  829. # Places the position of the sash and separator.
  830. # ------------------------------------------------------------------
  831. body iwidgets::Panedwindow::_placeSash {i} {
  832.     
  833.     if {$itk_option(-orient) == "horizontal"} {
  834.     place $itk_component(separator$i) -in $itk_component(hull) \
  835.         -x 0 -relwidth 1 -rely $_frac($i) -anchor w \
  836.         -height $itk_option(-thickness)
  837.     
  838.     if {$itk_option(-sashindent) < 0} {
  839.         set sashPos [expr $_width + $itk_option(-sashindent)]
  840.         set sashAnchor e
  841.     } else {
  842.         set sashPos $itk_option(-sashindent)
  843.         set sashAnchor w
  844.     }
  845.     
  846.     place $itk_component(sash$i) -in $itk_component(hull) \
  847.         -x $sashPos -rely $_frac($i) -anchor $sashAnchor
  848.     
  849.     } else {
  850.     place $itk_component(separator$i) -in $itk_component(hull) \
  851.         -y 0 -relheight 1 -relx $_frac($i) -anchor n \
  852.         -width $itk_option(-thickness)
  853.     
  854.     if {$itk_option(-sashindent) < 0} {
  855.         set sashPos [expr $_height + $itk_option(-sashindent)]
  856.         set sashAnchor s
  857.     } else {
  858.         set sashPos $itk_option(-sashindent)
  859.         set sashAnchor n
  860.     }
  861.     
  862.     place $itk_component(sash$i) -in $itk_component(hull) \
  863.         -y $sashPos -relx $_frac($i) -anchor $sashAnchor
  864.     }
  865. }
  866.  
  867. # ------------------------------------------------------------------
  868. # PRIVATE METHOD: _placePanes
  869. #
  870. # Resets the panes of the window following movement of the sash.
  871. # ------------------------------------------------------------------
  872. body iwidgets::Panedwindow::_placePanes {{start 0} {end end}} {
  873.      if {$end=="end"} { set end [expr [llength $_activePanes] - 1] }
  874.      set _updatePanes [lrange $_activePanes $start $end]
  875.      if {$_updatePanes == $_activePanes} {
  876.        set _forgetPanes $_panes
  877.      } {
  878.        set _forgetPanes $_updatePanes
  879.      }
  880.     foreach pane $_forgetPanes {
  881.     place forget $itk_component($pane)
  882.     }
  883.    
  884.     
  885.     if {$itk_option(-orient) == "horizontal"} {
  886.     set i $start
  887.     foreach pane $_updatePanes {
  888.         place $itk_component($pane) -in $itk_component(hull) \
  889.             -x 0 -rely $_frac($i) -relwidth 1 \
  890.             -relheight [expr $_frac([expr $i + 1]) - $_frac($i)]
  891.         incr i
  892.     }
  893.     
  894.     } else {
  895.     set i $start
  896.     foreach pane $_updatePanes {
  897.         place $itk_component($pane) -in $itk_component(hull) \
  898.             -y 0 -relx $_frac($i) -relheight 1 \
  899.             -relwidth [expr $_frac([expr $i + 1]) - $_frac($i)]
  900.         incr i
  901.     }
  902.     
  903.     }
  904.  
  905.     for {set i [expr $start+1]} {$i <= $end} {incr i} {
  906.         _placeSash $i
  907.         raise $itk_component(separator$i)
  908.         raise $itk_component(sash$i)
  909.     }
  910. }
  911.