home *** CD-ROM | disk | FTP | other *** search
/ PC World 2000 December / PCWorld_2000-12_cd.bin / Komunikace / Comanche / comanche.exe / lib / iwidgets2.2.0 / scripts / notebook.itk < prev    next >
Text File  |  1999-02-24  |  30KB  |  918 lines
  1. #
  2. # Notebook Widget
  3. # ----------------------------------------------------------------------
  4. # The Notebook command creates a new window (given by the pathName 
  5. # argument) and makes it into a Notebook widget. Additional options, 
  6. # described above may be specified on the command line or in the 
  7. # option database to configure aspects of the Notebook such as its 
  8. # colors, font, and text. The Notebook command returns its pathName 
  9. # argument. At the time this command is invoked, there must not exist 
  10. # a window named pathName, but path Name's parent must exist.
  11. # 
  12. # A Notebook is a widget that contains a set of pages. It displays one 
  13. # page from the set as the selected page. When a page is selected, the 
  14. # page's contents are displayed in the page area. When first created a 
  15. # Notebook has no pages. Pages may be added or deleted using widget commands 
  16. # described below.
  17. # 
  18. # A special option may be provided to the Notebook. The -auto option 
  19. # specifies whether the Nptebook will automatically handle the unpacking 
  20. # and packing of pages when pages are selected. A value of true signifies 
  21. # that the notebook will automatically manage it. This is the default 
  22. # value. A value of false signifies the notebook will not perform automatic 
  23. # switching of pages.
  24. #
  25. # WISH LIST:
  26. #   This section lists possible future enhancements.
  27. #
  28. # ----------------------------------------------------------------------
  29. #  AUTHOR: Bill W. Scott                 EMAIL: bscott@spd.dsccc.com
  30. #
  31. #  @(#) $Id: notebook.itk,v 1.1 1998/07/27 18:49:39 stanton Exp $
  32. # ----------------------------------------------------------------------
  33. #            Copyright (c) 1995 DSC Technologies Corporation
  34. # ======================================================================
  35. # Permission to use, copy, modify, distribute and license this software 
  36. # and its documentation for any purpose, and without fee or written 
  37. # agreement with DSC, is hereby granted, provided that the above copyright 
  38. # notice appears in all copies and that both the copyright notice and 
  39. # warranty disclaimer below appear in supporting documentation, and that 
  40. # the names of DSC Technologies Corporation or DSC Communications 
  41. # Corporation not be used in advertising or publicity pertaining to the 
  42. # software without specific, written prior permission.
  43. # 
  44. # DSC DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE, INCLUDING 
  45. # ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, AND NON-
  46. # INFRINGEMENT. THIS SOFTWARE IS PROVIDED ON AN "AS IS" BASIS, AND THE
  47. # AUTHORS AND DISTRIBUTORS HAVE NO OBLIGATION TO PROVIDE MAINTENANCE, 
  48. # SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS. IN NO EVENT SHALL 
  49. # DSC BE LIABLE FOR ANY SPECIAL, INDIRECT OR CONSEQUENTIAL DAMAGES OR 
  50. # ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, 
  51. # WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTUOUS ACTION,
  52. # ARISING OUT OF OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS 
  53. # SOFTWARE.
  54. # ======================================================================
  55.  
  56. #
  57. # Default resources.
  58. #
  59. option add *Notebook.background          #d9d9d9      widgetDefault
  60. option add *Notebook.auto                true         widgetDefault
  61.  
  62. #
  63. # Usual options.
  64. #
  65. itk::usual Notebook {
  66.     keep -background -cursor
  67. }
  68.  
  69. # ------------------------------------------------------------------
  70. #                            NOTEBOOK
  71. # ------------------------------------------------------------------
  72. class iwidgets::Notebook {
  73.     inherit itk::Widget
  74.     
  75.     constructor {args} {}
  76.     
  77.     itk_option define -background background Background #d9d9d9 
  78.     itk_option define -auto auto Auto true 
  79.     itk_option define -scrollcommand scrollCommand ScrollCommand {}
  80.     
  81.     public method add { args }
  82.     public method childsite { args }
  83.     public method delete { args } 
  84.     public method index { index } 
  85.     public method insert { args } 
  86.     public method prev { } 
  87.     public method next { } 
  88.     public method pageconfigure { args } 
  89.     public method select { index } 
  90.     public method view { args } 
  91.     
  92.     private method _childSites { } 
  93.     private method _scrollCommand { } 
  94.     private method _index { pathList index select} 
  95.     private method _createPage { args } 
  96.     private method _deletePages { fromPage toPage } 
  97.     private method _configurePages { args } 
  98.     private method _tabCommand { } 
  99.     
  100.     private variable _currPage -1  ;# numerical index of current page selected
  101.     private variable _pages {}     ;# list of Page components
  102.     private variable _uniqueID 0   ;# one-up number for unique page numbering
  103.     
  104. }
  105.  
  106. #
  107. # Provide a lowercase access method for the Notebook class
  108. #
  109. proc ::iwidgets::notebook {pathName args} {
  110.     uplevel ::iwidgets::Notebook $pathName $args
  111. }
  112.  
  113. # ------------------------------------------------------------------
  114. #                      CONSTRUCTOR
  115. # ------------------------------------------------------------------
  116. body iwidgets::Notebook::constructor {args}  {
  117.     #
  118.     # Create the outermost frame to maintain geometry.
  119.     #
  120.     itk_component add cs {
  121.     frame $itk_interior.cs 
  122.     } {
  123.     keep -cursor -background -width -height
  124.     }
  125.     pack $itk_component(cs) -fill both -expand yes
  126.     pack propagate $itk_component(cs) no
  127.     
  128.     eval itk_initialize $args
  129.     
  130.     # force bg of all pages to reflect Notebook's background.
  131.     _configurePages -background $itk_option(-background)
  132. }
  133.  
  134. # ------------------------------------------------------------------
  135. #                      OPTIONS
  136. # ------------------------------------------------------------------
  137. # ------------------------------------------------------------------
  138. # OPTION -background
  139. #
  140. # Sets the bg color of all the pages in the Notebook.
  141. # ------------------------------------------------------------------
  142. configbody iwidgets::Notebook::background {
  143.     if {$itk_option(-background) != {}} {
  144.     _configurePages -background $itk_option(-background)
  145.     }
  146. }
  147.  
  148. # ------------------------------------------------------------------
  149. # OPTION -auto
  150. #
  151. # Determines whether pages are automatically unpacked and
  152. # packed when pages get selected.
  153. # ------------------------------------------------------------------
  154. configbody iwidgets::Notebook::auto {
  155.     if {$itk_option(-auto) != {}} {
  156.     }
  157. }
  158.  
  159. # ------------------------------------------------------------------
  160. # OPTION -scrollcommand
  161. #
  162. # Command string to be invoked when the notebook 
  163. # has any changes to its current page, or number of pages.
  164. # 
  165. # typically for scrollbars.
  166. # ------------------------------------------------------------------
  167. configbody iwidgets::Notebook::scrollcommand {
  168.     if {$itk_option(-scrollcommand) != {}} {
  169.     _scrollCommand
  170.     }
  171. }
  172.  
  173. # ------------------------------------------------------------------
  174. # METHOD: add add ?<option> <value>...?
  175. # 
  176. # Creates a page and appends it to the list of pages.
  177. # processes pageconfigure for the page added.
  178. # ------------------------------------------------------------------
  179. body iwidgets::Notebook::add { args } {
  180.     # The args list should be an even # of params, if not then
  181.     # prob missing value for last item in args list. Signal error.
  182.     set len [llength $args]
  183.     if { [expr $len % 2] } {
  184.     error "value for \"[lindex $args [expr $len - 1]]\" missing"
  185.     }
  186.     
  187.     # add a Page component
  188.     set pathName [eval _createPage $args]
  189.     lappend _pages $pathName
  190.     
  191.     # update scroller
  192.     _scrollCommand 
  193.     
  194.     # return childsite for the Page component
  195.     return [eval $pathName childsite]
  196. }
  197.  
  198. # ------------------------------------------------------------------
  199. # METHOD: childsite ?<index>?
  200. #
  201. # If index is supplied, returns the child site widget corresponding 
  202. # to the page index.  If called with no arguments, returns a list 
  203. # of all child sites
  204. # ------------------------------------------------------------------
  205. body iwidgets::Notebook::childsite { args } {
  206.     set len [llength $args]
  207.     
  208.     switch $len {
  209.     0 {
  210.         # ... called with no arguments, return a list
  211.         if { [llength $args] == 0 } {
  212.         return [_childSites]
  213.         }
  214.     }
  215.     1 {
  216.         set index [lindex $args 0]
  217.         # ... otherwise, return child site for the index given
  218.         # empty notebook
  219.         if { $_pages == {} } {
  220.         error "can't get childsite,\
  221.             no pages in the notebook \"$itk_component(hull)\""
  222.         }
  223.         
  224.         set index [_index $_pages $index $_currPage]
  225.         
  226.         # index out of range
  227.         if { $index < 0 || $index >= [llength $_pages] } {
  228.         error "bad Notebook page index in childsite method:\
  229.             should be between 0 and [expr [llength $_pages] - 1]"
  230.         }
  231.         
  232.         set pathName [lindex $_pages $index]
  233.         
  234.         set cs [eval $pathName childsite]
  235.         return $cs
  236.     }
  237.     default {
  238.         # ... too many parameters passed
  239.         error "wrong # args: should be\
  240.             \"$itk_component(hull) childsite ?index?\""
  241.     }
  242.     }
  243. }
  244.  
  245. # ------------------------------------------------------------------
  246. # METHOD: delete <index1> ?<index2>?
  247. # 
  248. # Deletes a page or range of pages from the notebook
  249. # ------------------------------------------------------------------
  250. body iwidgets::Notebook::delete { args } {
  251.     # empty notebook
  252.     if { $_pages == {} } {
  253.     error "can't delete page, no pages in the notebook\
  254.         \"$itk_component(hull)\""
  255.     }
  256.     
  257.     set len [llength $args]
  258.     switch -- $len {
  259.     1 {
  260.         set fromPage [_index $_pages [lindex $args 0] $_currPage]
  261.         
  262.         if { $fromPage < 0 || $fromPage >= [llength $_pages] } {
  263.         error "bad Notebook page index in delete method:\
  264.             should be between 0 and [expr [llength $_pages] - 1]"
  265.         }
  266.         
  267.         set toPage $fromPage
  268.         _deletePages $fromPage $toPage
  269.     }
  270.     
  271.     2 {
  272.         set fromPage [_index $_pages [lindex $args 0] $_currPage]
  273.         
  274.         if { $fromPage < 0 || $fromPage >= [llength $_pages] } {
  275.         error "bad Notebook page index1 in delete method:\
  276.             should be between 0 and [expr [llength $_pages] - 1]"
  277.         }
  278.         
  279.         set toPage [_index $_pages [lindex $args 1] $_currPage]
  280.         
  281.         if { $toPage < 0 || $toPage >= [llength $_pages] } {
  282.         error "bad Notebook page index2 in delete method:\
  283.             should be between 0 and [expr [llength $_pages] - 1]"
  284.         error "bad Notebook page index2"
  285.         }
  286.         
  287.         if { $fromPage > $toPage } {
  288.         error "bad Notebook page index1 in delete method:\
  289.             index1 is greater than index2"
  290.         }
  291.         
  292.         _deletePages $fromPage $toPage
  293.         
  294.     }
  295.     
  296.     default {
  297.         # ... too few/many parameters passed
  298.         error "wrong # args: should be\
  299.             \"$itk_component(hull) delete index1 ?index2?\""
  300.     }
  301.     }
  302. }
  303.  
  304. # ------------------------------------------------------------------
  305. # METHOD: index <index>
  306. #
  307. # Given an index identifier returns the numeric index of the page
  308. # ------------------------------------------------------------------
  309. body iwidgets::Notebook::index {index} {
  310.     set number [_index $_pages $index $_currPage]
  311.     if { $number < 0 || $number >= [llength $_pages] } {
  312.     error "bad Notebook page index in index method:\
  313.         should be between 0 and [expr [llength $_pages] - 1]"
  314.     }
  315.     return $number
  316. }
  317.  
  318. # ------------------------------------------------------------------
  319. # METHOD: insert <index> ?<option> <value>...?
  320. #
  321. # Inserts a page before a index. The before page may
  322. # be specified as a label or a page position. 
  323. # ------------------------------------------------------------------
  324. body iwidgets::Notebook::insert { args } {
  325.     # ... Error: no args passed
  326.     set len [llength $args]
  327.     if { $len == 0 } {
  328.     error "wrong # args: should be\
  329.         \"$itk_component(hull) insert index ?option value?\""
  330.     }
  331.     
  332.     # ... set up index and args 
  333.     set index [lindex $args 0]
  334.     set args [lrange $args 1 $len]
  335.     
  336.     # ... Error: unmatched option value pair (len is odd)
  337.     # The args list should be an even # of params, if not then
  338.     # prob missing value for last item in args list. Signal error.
  339.     set len [llength $args]
  340.     if { [expr $len % 2] } {
  341.     error "value for \"[lindex $args [expr $len - 1]]\" missing"
  342.     }
  343.     
  344.     # ... Error: catch notebook empty
  345.     if { $_pages == {} } {
  346.     error "can't insert page, no pages in the notebook\
  347.         \"$itk_component(hull)\""
  348.     }
  349.     
  350.     # ok, get the page
  351.     set page [_index $_pages $index $_currPage]
  352.     
  353.     # ... Error: catch bad value for before page.
  354.     if { $page < 0 || $page >= [llength $_pages] } {
  355.     error "bad Notebook page index in insert method:\
  356.         should be between 0 and [expr [llength $_pages] - 1]"
  357.     }
  358.     
  359.     # ... Start the business of inserting
  360.     # create the new page and get its path name...
  361.     set pathName [eval _createPage $args]
  362.     
  363.     # grab the name of the page currently selected. (to keep in sync)
  364.     set currPathName [lindex $_pages $_currPage]
  365.     
  366.     # insert pathName before $page
  367.     set _pages [linsert $_pages $page $pathName]
  368.     
  369.     # keep the _currPage in sync with the insert.
  370.     set _currPage [lsearch -exact $_pages $currPathName]
  371.     
  372.     # give scrollcommand chance to update
  373.     _scrollCommand 
  374.     
  375.     # give them child site back...
  376.     return [eval $pathName childsite]
  377. }
  378.  
  379. # ------------------------------------------------------------------
  380. # METHOD: prev
  381. #
  382. # Selects the previous page. Wraps at first back to last page.
  383. # ------------------------------------------------------------------
  384. body iwidgets::Notebook::prev { } {
  385.     # catch empty notebook
  386.     if { $_pages == {} } {
  387.     error "can't move to previous page,\
  388.         no pages in the notebook \"$itk_component(hull)\""
  389.     }
  390.     
  391.     # bump to the previous page and wrap if necessary
  392.     set prev [expr $_currPage - 1]
  393.     if { $prev < 0 } {
  394.     set prev [expr [llength $_pages] - 1]
  395.     }
  396.     
  397.     select $prev
  398.     
  399.     return $prev
  400. }
  401.  
  402. # ------------------------------------------------------------------
  403. # METHOD: next
  404. #
  405. # Selects the next page. Wraps at last back to first page.
  406. # ------------------------------------------------------------------
  407. body iwidgets::Notebook::next { } {
  408.     # catch empty notebook
  409.     if { $_pages == {} } {
  410.     error "can't move to next page,\
  411.         no pages in the notebook \"$itk_component(hull)\""
  412.     }
  413.     
  414.     # bump to the next page and wrap if necessary
  415.     set next [expr $_currPage + 1]
  416.     if { $next >= [llength $_pages] } {
  417.     set next 0
  418.     }
  419.     
  420.     select $next
  421.     
  422.     return $next
  423. }
  424.  
  425. # ------------------------------------------------------------------
  426. # METHOD: pageconfigure <index> ?<option> <value>...?
  427. #
  428. # Performs configure on a given page denoted by index.  Index may 
  429. # be a page number or a pattern matching the label associated with 
  430. # a page.
  431. # ------------------------------------------------------------------
  432. body iwidgets::Notebook::pageconfigure { args } {
  433.     # ... Error: no args passed
  434.     set len [llength $args]
  435.     if { $len == 0 } {
  436.     error "wrong # args: should be\
  437.         \"$itk_component(hull) pageconfigure index ?option value?\""
  438.     }
  439.     
  440.     # ... set up index and args 
  441.     set index [lindex $args 0]
  442.     set args [lrange $args 1 $len]
  443.     
  444.     set page [_index $_pages $index $_currPage]
  445.     
  446.     # ... Error: page out of range
  447.     if { $page < 0 || $page >= [llength $_pages] } {
  448.     error "bad Notebook page index in pageconfigure method:\
  449.         should be between 0 and [expr [llength $_pages] - 1]"
  450.     }
  451.     
  452.     # Configure the page component
  453.     set pathName [lindex $_pages $page]
  454.     return [eval $pathName configure $args]
  455. }
  456.  
  457. # ------------------------------------------------------------------
  458. # METHOD: select <index>
  459. #
  460. # Select a page by index.  Hide the last _currPage if it existed.
  461. # Then show the new one if it exists.  Returns the currently 
  462. # selected page or -1 if tried to do a select select when there is 
  463. # no selection.
  464. # ------------------------------------------------------------------
  465. body iwidgets::Notebook::select { index } {
  466.     global page$itk_component(hull)
  467.     
  468.     # ... Error: empty notebook
  469.     if { $_pages == {} } {
  470.     error "can't select page $index,\
  471.         no pages in the notebook \"$itk_component(hull)\""
  472.     }
  473.     
  474.     # if there is not current selection just ignore trying this selection
  475.     if { $index == "select" && $_currPage == -1 } {
  476.     return -1
  477.     }
  478.     
  479.     set reqPage [_index $_pages $index $_currPage]
  480.     
  481.     if { $reqPage < 0 || $reqPage >= [llength $_pages] } {
  482.     error "bad Notebook page index in select method:\
  483.         should be between 0 and [expr [llength $_pages] - 1]"
  484.     }
  485.     
  486.     # if we already have this page selected, then ignore selection.
  487.     if { $reqPage == $_currPage } {
  488.     return $_currPage
  489.     }
  490.     
  491.     # if we are handling packing and unpacking the unpack if we can
  492.     if { $itk_option(-auto) } {
  493.     # if there is a current page packed, then unpack it
  494.     if { $_currPage != -1 } {
  495.         set currPathName [lindex $_pages $_currPage]
  496.         pack forget $currPathName
  497.     }
  498.     }
  499.     
  500.     # set this now so that the -command cmd can do an 'index select'
  501.     # to operate on this page.
  502.     set _currPage $reqPage
  503.     
  504.     # invoke the command for this page
  505.     set cmd [lindex [pageconfigure $index -command] 4]
  506.     eval $cmd
  507.     
  508.     # give scrollcommand chance to update
  509.     _scrollCommand 
  510.     
  511.     # if we are handling packing and unpacking the pack if we can
  512.     if { $itk_option(-auto) } {
  513.     set reqPathName [lindex $_pages $reqPage]
  514.     pack $reqPathName -anchor nw -fill both -expand yes
  515.     }
  516.     
  517.     return $_currPage
  518. }
  519.  
  520.  
  521. # ------------------------------------------------------------------
  522. # METHOD: view
  523. #
  524. # Return the current page
  525. #
  526. #      view <index>
  527. #
  528. # Selects the page denoted by index to be current page
  529. #
  530. #         view 'moveto' <fraction>
  531. #
  532. # Selects the page by using fraction amount
  533. #
  534. #      view 'scroll' <num> <what>
  535. #
  536. # Selects the page by using num as indicator of next or    previous
  537. # ------------------------------------------------------------------
  538. body iwidgets::Notebook::view { args } {
  539.     set len [llength $args]
  540.     switch -- $len {
  541.     0 {
  542.         # Return current page
  543.         return $_currPage
  544.     }
  545.     1 {
  546.         # Select by index
  547.         select [lindex $args 0]
  548.     }
  549.     2 {
  550.         # Select using moveto
  551.         set arg [lindex $args 0]
  552.         if { $arg == "moveto" } {
  553.         set fraction [lindex $args 1]
  554.         if { [catch { set page \
  555.             [expr round($fraction/(1.0/[llength $_pages]))]}]} {
  556.             error "expected floating-point number \
  557.                 but got \"$fraction\""
  558.         }
  559.         if { $page == [llength $_pages] } {
  560.             incr page -1
  561.         }
  562.         
  563.         if { $page >= 0 && $page < [llength $_pages] } {
  564.             select $page
  565.         }
  566.         } else {
  567.         error "expected \"moveto\" but got $arg"
  568.         }
  569.     }
  570.     3 {
  571.         # Select using scroll keyword
  572.         set arg [lindex $args 0]
  573.         if { $arg == "scroll" } {
  574.         set amount [lindex $args 1]
  575.         # check for integer value
  576.         if { ! [regexp {^[-]*[0-9]*$} $amount] } {
  577.             error "expected integer but got \"$amount\""
  578.         }
  579.         set page [expr $_currPage + $amount]
  580.         if { $page >= 0 && $page < [llength $_pages] } {
  581.             select $page
  582.         }
  583.         
  584.         } else {
  585.         error "expected \"scroll\" but got $arg"
  586.         }
  587.     }
  588.     default {
  589.         set arg [lindex $args 0]
  590.         if { $arg == "moveto" } {
  591.         error "wrong # args: should be\
  592.             \"$itk_component(hull) view moveto fraction\""
  593.         } elseif { $arg == "scroll" } {
  594.         error "wrong # args: should be\
  595.             \"$itk_component(hull) view scroll units|pages\""
  596.         } else {
  597.         error "wrong # args: should be\
  598.             \"$itk_component(hull) view index\""
  599.         }
  600.     }
  601.     }
  602. }
  603.  
  604. # ------------------------------------------------------------------
  605. # PRIVATE METHOD: _childSites
  606. #
  607. # Returns a list of child sites for all pages in the notebook.
  608. # ------------------------------------------------------------------
  609. body iwidgets::Notebook::_childSites { } {
  610.     # empty notebook
  611.     if { $_pages == {} } {
  612.     error "can't get childsite list,\
  613.         no pages in the notebook \"$itk_component(hull)\""
  614.     }
  615.     
  616.     set csList {}
  617.     
  618.     foreach pathName $_pages { 
  619.     lappend csList [eval $pathName childsite]
  620.     }
  621.     
  622.     return $csList
  623. }
  624.  
  625. # ------------------------------------------------------------------
  626. # PRIVATE METHOD: _scrollCommand
  627. #
  628. # If there is a -scrollcommand set up, then call the tcl command
  629. # and suffix onto it the standard 4 numbers scrollbars get.
  630. #
  631. # Invoke the scrollcommand, this is like the y/xscrollcommand
  632. # it is designed to talk to scrollbars and the the
  633. # tabset also knows how to obey scrollbar protocol.
  634. # ------------------------------------------------------------------
  635. body iwidgets::Notebook::_scrollCommand { } {
  636.     if { $itk_option(-scrollcommand) != {} && $_currPage != -1 }  {
  637.     set relTop [expr ($_currPage*1.0) / [llength $_pages]]
  638.     set relBottom [expr (($_currPage+1)*1.0) / [llength $_pages]]
  639.     set scrollCommand "$itk_option(-scrollcommand) $relTop $relBottom"
  640.     
  641.     uplevel #0 $scrollCommand
  642.     }
  643. }
  644.  
  645. # ------------------------------------------------------------------
  646. # PRIVATE METHOD: _index
  647. #
  648. # pathList : list of path names to search thru if index is a label
  649. # index    : either number, 'select', 'end', or pattern
  650. # select   : current selection
  651. #
  652. # _index takes takes the value $index converts it to
  653. # a numeric identifier. If the value is not already
  654. # an integer it looks it up in the $pathList array.
  655. # If it fails it returns -1
  656. # ------------------------------------------------------------------
  657. body iwidgets::Notebook::_index { pathList index select} {
  658.     switch -- $index {
  659.     select {
  660.         set number $select
  661.     }
  662.     end {
  663.         set number [expr [llength $pathList] -1]
  664.     }
  665.     default {
  666.         # is it a number already?
  667.         if { [regexp {^[0-9]+$} $index] } {
  668.         set number $index
  669.         if { $number < 0 || $number >= [llength $pathList] } {
  670.             set number -1
  671.         }
  672.         
  673.         # otherwise it is a label
  674.         } else {
  675.         # look thru the pathList of pathNames and 
  676.         # get each label and compare with index.
  677.         # if we get a match then set number to postion in $pathList
  678.         # and break out.
  679.         # otherwise number is still -1
  680.         set i 0
  681.         set number -1
  682.         foreach pathName $pathList {
  683.             set label [lindex [$pathName configure -label] 4]
  684.             if { [string match $index $label] } {
  685.             set number $i
  686.             break
  687.             }
  688.             incr i
  689.         }
  690.         }
  691.     }
  692.     }
  693.     
  694.     return $number
  695. }
  696.  
  697. # ------------------------------------------------------------------
  698. # PRIVATE METHOD: _createPage
  699. #
  700. # Creates a page, using unique page naming, propagates background
  701. # and keeps unique id up to date.
  702. # ------------------------------------------------------------------
  703. body iwidgets::Notebook::_createPage { args } {
  704.     #
  705.     # create an internal name for the page: .n.cs.page0, .n.cs.page1, etc.
  706.     #
  707.     set pathName $itk_component(cs).page$_uniqueID
  708.     
  709.     eval iwidgets::Page $pathName -background $itk_option(-background) $args
  710.     
  711.     incr _uniqueID
  712.     return $pathName
  713.     
  714. }
  715.  
  716. # ------------------------------------------------------------------
  717. # PRIVATE METHOD: _deletePages
  718. #
  719. # Deletes pages from $fromPage to $toPage.
  720. #
  721. # Operates in two passes, destroys all the widgets
  722. # Then removes the pathName from the page list
  723. #
  724. # Also keeps the current selection in bounds.
  725. # ------------------------------------------------------------------
  726. body iwidgets::Notebook::_deletePages { fromPage toPage } {
  727.     for { set page $fromPage } { $page <= $toPage } { incr page } {
  728.     # kill the widget
  729.     set pathName [lindex $_pages $page]
  730.     destroy $pathName
  731.     }
  732.     
  733.     # physically remove the page
  734.     set _pages [lreplace $_pages $fromPage $toPage]
  735.     
  736.     # If we deleted a selected page set our selection to none
  737.     if { $_currPage >= $fromPage && $_currPage <= $toPage } {
  738.     set $_currPage -1
  739.     }
  740.     
  741.     # make sure _currPage stays in sync with new numbering...
  742.     if { $_pages == {} } {
  743.     # if deleted only remaining page,
  744.     # reset current page to undefined
  745.     set _currPage -1
  746.     
  747.     # or if the current page was the last page, it needs come back
  748.     } elseif { $_currPage >= [llength $_pages] } {
  749.     incr _currPage -1
  750.     if { $_currPage < 0 } {
  751.         # but only to zero
  752.         set _currPage 0
  753.     }
  754.     }
  755.     
  756.     # give scrollcommand chance to update
  757.     _scrollCommand 
  758. }
  759.  
  760. # ------------------------------------------------------------------
  761. # PRIVATE METHOD: _configurePages
  762. #
  763. # Does the pageconfigure method on each page in the notebook
  764. # ------------------------------------------------------------------
  765. body iwidgets::Notebook::_configurePages { args } {
  766.     # make sure we have pages
  767.     if { [catch {set _pages}] } {
  768.     return
  769.     }
  770.     
  771.     # go thru all pages and pageconfigure them.
  772.     foreach pathName $_pages {
  773.     eval "$pathName configure $args"
  774.     }
  775. }
  776.  
  777. # ------------------------------------------------------------------
  778. # PRIVATE METHOD: _tabCommand
  779. #
  780. # Calls the command that was passed in through the 
  781. # $itk_option(-tabcommand) argument.
  782. #
  783. # This method is up for debate... do we need the -tabcommand option?
  784. # ------------------------------------------------------------------
  785. body iwidgets::Notebook::_tabCommand { } {
  786.     global page$itk_component(hull)
  787.     
  788.     if { $itk_option(-tabcommand) != {} } {
  789.     set newTabCmdStr $itk_option(-tabcommand)
  790.     lappend newTabCmdStr [set page$itk_component(hull)]
  791.     
  792.     #eval $newTabCmdStr
  793.     uplevel #0 $newTabCmdStr
  794.     }
  795. }
  796.     
  797. #
  798. # Page widget
  799. # ------------------------------------------------------------------
  800. #
  801. # The Page command creates a new window (given by the pathName argument) 
  802. # and makes it into a Page widget. Additional options, described above 
  803. # may be specified on the com mand line or in the option database to 
  804. # configure aspects of the Page such as its back ground, cursor, and 
  805. # geometry. The Page command returns its pathName argument. At the time 
  806. # this command is invoked, there must not exist a window named pathName, 
  807. # but path Name's parent must exist.
  808. # 
  809. # A Page is a frame that holds a child site. It is nothing more than a 
  810. # frame widget with some intelligence built in. Its primary purpose is 
  811. # to support the Notebook's concept of a page. It allows another widget 
  812. # like the Notebook to treat a page as a single object. The Page has an 
  813. # associated label and knows how to return its child site.
  814. #
  815. # ------------------------------------------------------------------
  816. #  AUTHOR: Bill W. Scott                 EMAIL: bscott@spd.dsccc.com
  817. #
  818. # ------------------------------------------------------------------
  819. #               Copyright (c) 1995  DSC Communications Corp.
  820. # ======================================================================
  821. # Permission is hereby granted, without written agreement and without
  822. # license or royalty fees, to use, copy, modify, and distribute this
  823. # software and its documentation for any purpose, provided that the
  824. # above copyright notice and the following two paragraphs appear in
  825. # all copies of this software.
  826. #
  827. # IN NO EVENT SHALL THE COPYRIGHT HOLDER BE LIABLE TO ANY PARTY FOR
  828. # DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES
  829. # ARISING OUT OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN
  830. # IF THE COPYRIGHT HOLDER HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH
  831. # DAMAGE.
  832. #
  833. # THE COPYRIGHT HOLDER SPECIFICALLY DISCLAIMS ANY WARRANTIES, INCLUDING,
  834. # BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND
  835. # FITNESS FOR A PARTICULAR PURPOSE.  THE SOFTWARE PROVIDED HEREUNDER IS
  836. # ON AN "AS IS" BASIS, AND THE COPYRIGHT HOLDER HAS NO OBLIGATION TO
  837. # PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS.
  838. # ======================================================================
  839. #
  840. # Option database default resources:
  841. #
  842. option add *Page.disabledForeground #a3a3a3     widgetDefault
  843. option add *Page.label              {}       widgetDefault
  844. option add *Page.command            {}       widgetDefault
  845.  
  846. class iwidgets::Page {
  847.     inherit itk::Widget
  848.     
  849.     constructor {args} {}
  850.     
  851.     itk_option define \
  852.         -disabledforeground disabledForeground DisabledForeground #a3a3a3 
  853.     itk_option define -label label Label {} 
  854.     itk_option define -command command Command {}
  855.     
  856.     public method childsite { } 
  857. }
  858.  
  859. # ------------------------------------------------------------------
  860. #                          CONSTRUCTOR
  861. # ------------------------------------------------------------------
  862. body iwidgets::Page::constructor {args} {
  863.     #
  864.     # Create the outermost frame to maintain geometry.
  865.     #
  866.     itk_component add cs {
  867.     frame $itk_interior.cs 
  868.     } {
  869.     keep -cursor -background -width -height
  870.     }
  871.     pack $itk_component(cs) -fill both -expand yes 
  872.     pack propagate $itk_component(cs) no
  873.     
  874.     eval itk_initialize $args
  875. }
  876.  
  877. # ------------------------------------------------------------------
  878. #                            OPTIONS
  879. # ------------------------------------------------------------------
  880. # ------------------------------------------------------------------
  881. # OPTION -disabledforeground
  882. #
  883. # Sets the disabledForeground color of this page
  884. # ------------------------------------------------------------------
  885. configbody iwidgets::Page::disabledforeground {
  886. }
  887.  
  888. # ------------------------------------------------------------------
  889. # OPTION -label
  890. #
  891. # Sets the label of this page.  The label is a string identifier 
  892. # for this page.
  893. # ------------------------------------------------------------------
  894. configbody iwidgets::Page::label {
  895. }
  896.  
  897. # ------------------------------------------------------------------
  898. # OPTION -command
  899. #
  900. # The Tcl Command to associate with this page.
  901. # ------------------------------------------------------------------
  902. configbody iwidgets::Page::command {
  903. }
  904.  
  905. # ------------------------------------------------------------------
  906. #                            METHODS
  907. # ------------------------------------------------------------------
  908.  
  909. # ------------------------------------------------------------------
  910. # METHOD: childsite
  911. #
  912. # Returns the child site widget of this page
  913. # ------------------------------------------------------------------
  914. body iwidgets::Page::childsite { } {
  915.     return $itk_component(cs)
  916. }
  917.  
  918.