home *** CD-ROM | disk | FTP | other *** search
/ PC World 2000 December / PCWorld_2000-12_cd.bin / Komunikace / Comanche / comanche.exe / lib / iwidgets2.2.0 / scripts / combobox.itk < prev    next >
Text File  |  1999-02-24  |  37KB  |  1,138 lines
  1. #
  2. # Combobox
  3. # ----------------------------------------------------------------------
  4. # Implements a Combobox widget. A Combobox has 2 basic styles: simple and
  5. # dropdown. Dropdowns display an entry field with an arrow button to the 
  6. # right of it. When the arrow button is pressed a selectable list of items 
  7. # is popped up. A simple Combobox displays an entry field and a listbox 
  8. # just beneath it which is always displayed. In both types, if the user 
  9. # selects an item in the listbox, the contents of the entry field are 
  10. # replaced with the text from the selected item. If the Combobox is 
  11. # editable, the user can type in the entry field and when <Return> is pressed
  12. # the item will be inserted into the list.
  13. #
  14. # WISH LIST:
  15. #   This section lists possible future enhancements.  
  16. #
  17. #     Combobox 1.x:
  18. #         - convert bindings to bindtags.
  19. #         - determine clean way to have a state for listbox/canvas.
  20. #         - add completion functionality when typing in the entry.
  21. #         - add grab option: global, local, none.
  22. #
  23. # ----------------------------------------------------------------------
  24. #  AUTHOR: John S. Sigler               EMAIL: jsigler@spd.dsccc.com
  25. #                                              sigler@onramp.net
  26. #  @(#) $Id: combobox.itk,v 1.1 1998/07/27 18:49:23 stanton Exp $
  27. # ----------------------------------------------------------------------
  28. #                   Copyright (c) 1995  John S. Sigler
  29. # ======================================================================
  30. # Permission is hereby granted, without written agreement and without
  31. # license or royalty fees, to use, copy, modify, and distribute this
  32. # software and its documentation for any purpose, provided that the
  33. # above copyright notice and the following two paragraphs appear in
  34. # all copies of this software.
  35. # 
  36. # IN NO EVENT SHALL THE COPYRIGHT HOLDER BE LIABLE TO ANY PARTY FOR
  37. # DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES 
  38. # ARISING OUT OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN 
  39. # IF THE COPYRIGHT HOLDER HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH 
  40. # DAMAGE.
  41. #
  42. # THE COPYRIGHT HOLDER SPECIFICALLY DISCLAIMS ANY WARRANTIES, INCLUDING, 
  43. # BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND 
  44. # FITNESS FOR A PARTICULAR PURPOSE.  THE SOFTWARE PROVIDED HEREUNDER IS
  45. # ON AN "AS IS" BASIS, AND THE COPYRIGHT HOLDER HAS NO OBLIGATION TO
  46. # PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS.
  47. # ======================================================================
  48.  
  49. #
  50. # Default resources.
  51. #
  52. option add *Combobox.borderWidth 2 widgetDefault
  53. option add *Combobox.labelPos w widgetDefault
  54. option add *Combobox.listHeight 150 widgetDefault
  55. option add *Combobox.hscrollMode dynamic widgetDefault
  56. option add *Combobox.vscrollMode dynamic widgetDefault
  57.  
  58. #
  59. # Usual options.
  60. #
  61. itk::usual Combobox {
  62.     keep -background -borderwidth -cursor -foreground -highlightcolor \
  63.      -highlightthickness -insertbackground -insertborderwidth \
  64.      -insertofftime -insertontime -insertwidth -labelfont -popupcursor \
  65.      -selectbackground -selectborderwidth -selectforeground \
  66.      -textbackground -textfont
  67. }
  68.  
  69. # ------------------------------------------------------------------
  70. #                            COMBOBOX
  71. # ------------------------------------------------------------------
  72. class iwidgets::Combobox {
  73.     inherit iwidgets::Entryfield
  74.     
  75.     constructor {args} {}
  76.     destructor {}
  77.  
  78.     itk_option define -autoclear autoClear AutoClear true
  79.     itk_option define -arrowrelief arrowRelief Relief raised
  80.     itk_option define -dropdown dropdown Dropdown true
  81.     itk_option define -editable editable Editable true
  82.     itk_option define -fliparrow flipArrow FlipArrow false
  83.     itk_option define -items items Items ""
  84.     itk_option define -labelpos labelPos Position w
  85.     itk_option define -listheight listHeight Height 150
  86.     itk_option define -margin margin Margin 1
  87.     itk_option define -popupcursor popupCursor Cursor arrow
  88.     itk_option define -selectioncommand selectionCommand SelectionCommand {}
  89.     itk_option define -unique unique Unique true
  90.  
  91.     public method clear {{component all}}
  92.     public method curselection {}
  93.     public method delete {component first {last {}}}
  94.     public method get {{index {}}}
  95.     public method getcurselection {}
  96.     public method insert {component index args}
  97.     public method invoke {}
  98.     public method justify {direction}
  99.     public method see {index}
  100.     public method selection {option first {last {}}}
  101.     public method size {}
  102.     public method sort {{mode ascending}}
  103.     public method xview {args}
  104.     public method yview {args}
  105.  
  106.     protected method _addToList {}
  107.     protected method _createComponents {}
  108.     protected method _deleteList {first {last {}}}
  109.     protected method _deleteText {first {last {}}}
  110.     protected method _doLayout {{when later}}
  111.     protected method _drawArrow {{mode normal}}
  112.     protected method _dropdownBtnRelease {{window {}} {x 1} {y 1}}
  113.     protected method _ignoreNextBtnRelease {ignore}
  114.     protected method _insertText {index string}
  115.     protected method _next {}
  116.     protected method _packArrow {labelpos}
  117.     protected method _packComponents {{when later}}
  118.     protected method _positionList {}
  119.     protected method _postList {}
  120.     protected method _previous {}
  121.     protected method _resizeArrow {}
  122.     protected method _selectCmd {}
  123.     protected method _toggleList {}
  124.     protected method _unpostList {}
  125.     protected method _commonBindings {}
  126.     protected method _dropdownBindings {}
  127.     protected method _simpleBindings {}
  128.     protected method _listShowing {{val ""}}
  129.  
  130.     private method _slbListbox {}
  131.  
  132.     private   variable _currItem {};           ;# current selected item.
  133.     private   variable _ignoreRelease true     ;# next button release ignored.
  134.     private   variable _isPosted false;        ;# is the dropdown popped up.
  135.     private   variable _repacking {}    ;# non-null => _packComponents pending.
  136.     private   common _listShowing
  137. }    
  138.  
  139. #
  140. # Provide a lowercase access method for the Combobox class.
  141. # 
  142. proc ::iwidgets::combobox {pathName args} {
  143.     uplevel ::iwidgets::Combobox $pathName $args
  144. }
  145.  
  146. # ------------------------------------------------------------------
  147. #                       CONSTRUCTOR
  148. # ------------------------------------------------------------------
  149. body iwidgets::Combobox::constructor {args} {
  150.     set _listShowing($this) 0
  151.  
  152.     # combobox is different as all components are created 
  153.     # after determining what the dropdown style is...
  154.  
  155.     # configure args
  156.     eval itk_initialize $args
  157.     
  158.     # create components that are dependent on options 
  159.     # (Scrolledlistbox, arrow button) and pack them.
  160.     _doLayout
  161. }
  162.     
  163. # ------------------------------------------------------------------
  164. #                          DESTRUCTOR
  165. # ------------------------------------------------------------------
  166. body iwidgets::Combobox::destructor {} {
  167.     # catch any repacking that may be waiting for idle time
  168.     if {$_repacking != ""} {
  169.     after cancel $_repacking
  170.     }
  171. }
  172.     
  173. # ================================================================
  174. #                           OPTIONS
  175. # ================================================================
  176.  
  177. # --------------------------------------------------------------------
  178. # OPTION:  -autoclear
  179. #
  180. # Specifies wheather or not to clear the entry field as items are
  181. # added to the list.  The default is true.
  182. # --------------------------------------------------------------------
  183. configbody iwidgets::Combobox::autoclear {}
  184.  
  185. # --------------------------------------------------------------------
  186. # OPTION:  -arrowrelief
  187. #
  188. # Relief style used on the arrow button.
  189. # --------------------------------------------------------------------
  190. configbody iwidgets::Combobox::arrowrelief {}
  191.  
  192. # --------------------------------------------------------------------
  193. # OPTION:  -dropdown  
  194. #
  195. # Boolean which determines the Combobox style: dropdown or simple.
  196. # Because the two style's lists reside in different toplevel widgets
  197. # this is more complicated than it should be.
  198. # --------------------------------------------------------------------
  199. configbody iwidgets::Combobox::dropdown {
  200.     if {$itk_option(-dropdown)} {
  201.     if {[winfo exists $itk_interior.list]} {
  202.         destroy $itk_component(list)
  203.         _doLayout
  204.     }
  205.     } else {
  206.     if {[winfo exists $itk_interior.popup.list]} {
  207.         destroy $itk_component(margin)
  208.         destroy $itk_component(arrowBtn)
  209.         destroy $itk_component(popup)  ;# this deletes the list too
  210.         _doLayout
  211.     }
  212.     }
  213. }
  214.  
  215. # --------------------------------------------------------------------
  216. # OPTION: -editable  
  217. #
  218. # Boolean which allows/disallows user input to the entry field area.
  219. # --------------------------------------------------------------------
  220. configbody iwidgets::Combobox::editable {
  221.     if {$itk_option(-editable)} {
  222.     configure -state normal -command [code $this _addToList]
  223.     bind $itk_component(entry) <1> ""
  224.     } else {
  225.     configure -state disabled
  226.     bind $itk_component(entry) <1> [code $this _toggleList]
  227.     }
  228. }
  229.  
  230. # --------------------------------------------------------------------
  231. # OPTION: -fliparrow
  232. #
  233. # Boolean which causes dropdown comboboxes to have their arrow point
  234. # up when the listbox is displayed.
  235. # --------------------------------------------------------------------
  236. configbody iwidgets::Combobox::fliparrow {
  237.     # boolean error check
  238.     if {$itk_option(-fliparrow)} {
  239.     }
  240. }
  241.  
  242. # --------------------------------------------------------------------
  243. # OPTION: -items  
  244. #
  245. # Set/get the current list of items in the listbox.
  246. # --------------------------------------------------------------------
  247. configbody iwidgets::Combobox::items {
  248.     # clear out what was in entry field before
  249.     if {$itk_option(-autoclear)} {
  250.     delete entry 0 end
  251.     }
  252.  
  253.     if {[winfo exists $itk_interior.popup.list]} {
  254.     _drawArrow normal
  255.     }
  256. }
  257.  
  258. # --------------------------------------------------------------------
  259. # OPTION: -labelpos
  260. #
  261. # Labelpos. Overrides the labelpos of the labeledwidget. This doesn't
  262. # work as positionalLabel seems to get called after this routine is called!
  263. # --------------------------------------------------------------------
  264. configbody iwidgets::Combobox::labelpos {
  265.     iwidgets::Labeledwidget::_positionLabel 
  266.  
  267.     switch -- $itk_option(-labelpos) {
  268.     e -
  269.     w {
  270.         pack configure $itk_component(label) -anchor n
  271.     }
  272.     }
  273. }
  274.  
  275. # --------------------------------------------------------------------
  276. # OPTION: -listheight  
  277. #
  278. # Listbox height in pixels. (Need to integrate the scrolledlistbox
  279. # -visibleitems option here - at least for simple listbox.)
  280. # --------------------------------------------------------------------
  281. configbody iwidgets::Combobox::listheight {}
  282.  
  283. # --------------------------------------------------------------------
  284. # OPTION:  -margin
  285. #
  286. # Spacer between the entry field and arrow button of dropdown style
  287. # Comboboxes.
  288. # --------------------------------------------------------------------
  289. configbody iwidgets::Combobox::margin {}
  290.  
  291. # --------------------------------------------------------------------
  292. # OPTION:  -popupcursor
  293. #
  294. # Set the cursor for the popup list.
  295. # --------------------------------------------------------------------
  296. configbody iwidgets::Combobox::popupcursor {}
  297.  
  298. # --------------------------------------------------------------------
  299. # OPTION:  -selectioncommand
  300. #
  301. # Defines the proc to be called when an item is selected in the list.
  302. # --------------------------------------------------------------------
  303. configbody iwidgets::Combobox::selectioncommand {}
  304.  
  305. # --------------------------------------------------------------------
  306. # OPTION: -unique  
  307. #
  308. # Boolean which disallows/allows adding duplicate items to the listbox.
  309. # --------------------------------------------------------------------
  310. configbody iwidgets::Combobox::unique {
  311.     # boolean error check
  312.     if {$itk_option(-unique)} {
  313.     }
  314. }
  315.  
  316. # =================================================================
  317. #                            METHODS
  318. # =================================================================
  319.  
  320. # ------------------------------------------------------
  321. #  PUBLIC METHOD: clear ?component?
  322. #
  323. #  Remove all elements from the listbox, all contents
  324. #  from the entry component, or both (if all).
  325. #
  326. # ------------------------------------------------------
  327. body iwidgets::Combobox::clear {{component all}} {
  328.     switch -- $component {
  329.     entry {
  330.         iwidgets::Entryfield::clear
  331.     }
  332.     list {
  333.         delete list 0 end
  334.     }
  335.     all {
  336.         delete list 0 end
  337.         iwidgets::Entryfield::clear
  338.     }
  339.     default {
  340.         error "bad Combobox component \"$component\": must be entry, list,\
  341. or all."
  342.     }
  343.     }
  344.     return
  345. }
  346.  
  347. # ------------------------------------------------------
  348. # PUBLIC METHOD: curselection
  349. #
  350. # Return the current selection index.
  351. #
  352. # ------------------------------------------------------
  353. body iwidgets::Combobox::curselection {} {
  354.     return [$itk_component(list) curselection]
  355. }
  356.  
  357. # ------------------------------------------------------
  358. # PUBLIC METHOD: delete component first ?last?
  359. #
  360. # Delete an item or items from the listbox OR delete
  361. # text from the entry field. First argument determines
  362. # which component deletion occurs in - valid values are
  363. # entry or list.
  364. #
  365. # ------------------------------------------------------
  366. body iwidgets::Combobox::delete {component first {last {}}} {
  367.     switch -- $component {
  368.     entry {
  369.         iwidgets::Entryfield::delete $first $last
  370.     }
  371.     list {
  372.         _deleteList $first $last
  373.     }
  374.     default {
  375.            error "bad Combobox component \"$component\": must be entry or list."
  376.     }
  377.     }
  378. }
  379.  
  380. # ------------------------------------------------------
  381. # PUBLIC METHOD: get ?index?
  382. #
  383. #
  384. # Retrieve entry contents if no args OR use args as list 
  385. # index and retrieve list item at index .
  386. #
  387. # ------------------------------------------------------
  388. body iwidgets::Combobox::get {{index {}}} {
  389.     # no args means to get the current text in the entry field area
  390.     if {$index == {}} {
  391.     iwidgets::Entryfield::get
  392.     } else {
  393.     eval $itk_component(list) get $index
  394.     }
  395. }
  396.  
  397. # ------------------------------------------------------
  398. # PUBLIC METHOD: getcurselection
  399. #
  400. # Return currently selected item in the listbox. Shortcut
  401. # version of get curselection command combination.
  402. #
  403. # ------------------------------------------------------
  404. body iwidgets::Combobox::getcurselection {} {
  405.     return [$itk_component(list) getcurselection]
  406. }
  407.  
  408. # ------------------------------------------------------------------
  409. # PUBLIC METHOD: ivoke
  410. #
  411. # Pops up or down a dropdown combobox.
  412. # 
  413. # ------------------------------------------------------------------
  414. body iwidgets::Combobox::invoke {} {
  415.     if {$itk_option(-dropdown)} {
  416.     return [_toggleList]
  417.     }
  418.     return 
  419. }
  420.  
  421. # ------------------------------------------------------------
  422. # PUBLIC METHOD: insert comonent index string ?string ...?
  423. #
  424. # Insert an item into the listbox OR text into the entry area.
  425. # Valid component names are entry or list.
  426. #
  427. # ------------------------------------------------------------
  428. body iwidgets::Combobox::insert {component index args} {
  429.     if {$args == {}} {
  430.     error "no value given for parameter \"string\" in function\
  431. \"Combobox::insert\""
  432.     } 
  433.  
  434.     switch -- $component {
  435.     entry {
  436.         if { [llength $args] > 1} {
  437.         error "called function \"Combobox::insert entry\" with too\
  438. many arguments"
  439.         } else {
  440.         eval iwidgets::Entryfield::insert $index $args
  441.         }
  442.     }
  443.     list {
  444.         configure -items [eval linsert {$itk_option(-items)} $index $args]
  445.     }
  446.     default {
  447.            error "bad Combobox component \"$component\": must be entry or list."
  448.     }
  449.     }
  450. }
  451.  
  452. # ------------------------------------------------------
  453. # PUBLIC METHOD: justify direction
  454. #
  455. # Wrapper for justifying the listbox items in one of
  456. # 4 directions:  top, bottom, left, or right.
  457. #
  458. # ------------------------------------------------------
  459. body iwidgets::Combobox::justify {direction} {
  460.     return [$itk_component(list) justify $direction]
  461. }
  462.  
  463. # ------------------------------------------------------------------
  464. # PUBLIC METHOD: see index
  465. #
  466. # Adjusts the view such that the element given by index is visible.
  467. # ------------------------------------------------------------------
  468. body iwidgets::Combobox::see {index} {
  469.     return [$itk_component(list) see $index]
  470. }
  471.  
  472. # ------------------------------------------------------------------
  473. # PUBLIC METHOD: selection option first ?last?
  474. #
  475. # Adjusts the selection within the listbox and changes the contents
  476. # of the entry component to be the value of the selected list item.
  477. # ------------------------------------------------------------------
  478. body iwidgets::Combobox::selection {option first {last {}}} {
  479.     # thin wrap
  480.     set rtn [eval $itk_component(list) selection $option $first $last]
  481.     set _currItem $first
  482.  
  483.     # combobox additions
  484.     set theText [getcurselection]
  485.     if {$theText != [$itk_component(entry) get]} {
  486.     clear entry
  487.     if {$theText != ""} {
  488.         insert entry 0 $theText
  489.     }
  490.     }
  491.     return $rtn
  492. }
  493.  
  494. # ------------------------------------------------------------------
  495. # PUBLIC METHOD: size 
  496. #
  497. # Returns a decimal string indicating the total number of elements 
  498. # in the listbox.
  499. # ------------------------------------------------------------------
  500. body iwidgets::Combobox::size {} {
  501.     return [$itk_component(list) size]
  502. }
  503.  
  504. # ------------------------------------------------------
  505. # PUBLIC METHOD: sort ?mode?
  506. #
  507. # Sort the current list in either "ascending" or "descending" order.
  508. #
  509. #   jss: how should i handle selected items?
  510. #
  511. # ------------------------------------------------------
  512. body iwidgets::Combobox::sort {{mode ascending}} {
  513.     return [$itk_component(list) sort $mode]
  514. }
  515.  
  516.  
  517. # ------------------------------------------------------------------
  518. # PUBLIC METHOD: xview ?arg arg ...?
  519. #
  520. # Change or query the vertical position of the text in the list box.
  521. # ------------------------------------------------------------------
  522. body iwidgets::Combobox::xview {args} {
  523.     return [eval $itk_component(list) xview $args]
  524. }
  525.  
  526. # ------------------------------------------------------------------
  527. # PUBLIC METHOD: yview ?arg arg ...?
  528. #
  529. # Change or query the horizontal position of the text in the list box.
  530. # ------------------------------------------------------------------
  531. body iwidgets::Combobox::yview {args} {
  532.     return [eval $itk_component(list) yview $args]
  533. }
  534.  
  535. # ------------------------------------------------------
  536. # PROTECTED METHOD: _addToList
  537. #
  538. # Add the current item in the entry to the listbox.
  539. #
  540. # ------------------------------------------------------
  541. body iwidgets::Combobox::_addToList {} {
  542.     set input [get]
  543.     if {$input != ""} {
  544.     if {$itk_option(-unique)} {
  545.         # if item is already in list, select it and exit
  546.         set item [lsearch -exact $itk_option(-items) $input]
  547.         if {$item != -1} {
  548.         selection clear 0 end
  549.         if {$item != {}} {
  550.             selection set $item $item
  551.             set _currItem $item
  552.         }
  553.         return
  554.         }
  555.     }
  556.     # add the item to end of list and clear the text area
  557.     insert list end $input
  558.  
  559.     if {$itk_option(-autoclear)} {
  560.         delete entry 0 end
  561.     }
  562.     }
  563. }
  564.  
  565. # ------------------------------------------------------
  566. # PROTECTED METHOD:   _createComponents
  567. #
  568. # Create deferred combobox components and add bindings.
  569. #
  570. # ------------------------------------------------------
  571. body iwidgets::Combobox::_createComponents {} {
  572.     if {$itk_option(-dropdown)} {
  573.     # --- build a dropdown combobox ---
  574.  
  575.     # make the arrow and margin childsite's be on the right hand side
  576.     configure -childsitepos e
  577.  
  578.     # add spacer between arrow and the entry component
  579.     itk_component add margin {
  580.         frame $itk_interior.margin -width $itk_option(-margin)
  581.     } {
  582.         rename -width -margin margin Margin
  583.     }
  584.     
  585.     # arrow button to popup the list
  586.     itk_component add arrowBtn {
  587.         canvas $itk_interior.arrowBtn -borderwidth 2 \
  588.         -width 16 -height 16
  589.     } {
  590.         keep -background -borderwidth -cursor  \
  591.         -highlightcolor -highlightthickness
  592.         rename -relief -arrowrelief arrowRelief Relief
  593.         rename -highlightbackground -background background Background
  594.     }
  595.     
  596.     # popup list container
  597.     itk_component add popup {
  598.         toplevel $itk_interior.popup
  599.     } {
  600.         keep -background -cursor
  601.     }
  602.     wm withdraw $itk_interior.popup
  603.     wm overrideredirect $itk_interior.popup 1
  604.     
  605.     # the listbox
  606.     itk_component add list {
  607.         iwidgets::Scrolledlistbox $itk_interior.popup.list -exportselection no \
  608.         -vscrollmode dynamic -hscrollmode dynamic 
  609.     } {
  610.         keep -background -borderwidth -cursor -foreground \
  611.         -highlightcolor -highlightthickness \
  612.         -hscrollmode -items -selectbackground \
  613.         -selectborderwidth -selectforeground -textbackground \
  614.         -textfont -vscrollmode
  615.         rename -height -listheight listHeight Height
  616.         rename -cursor -popupcursor popupCursor Cursor
  617.     }
  618.     # mode specific bindings
  619.     _dropdownBindings
  620.  
  621.     # Ugly hack to avoid tk buglet revealed in _dropdownBtnRelease where 
  622.     # relief is used but not set in scrollbar.tcl. 
  623.     global tkPriv
  624.     set tkPriv(relief) raise
  625.  
  626.     } else {
  627.     # --- build a simple combobox ---
  628.     configure -childsitepos s
  629.     itk_component add list {
  630.         iwidgets::Scrolledlistbox $itk_interior.list -exportselection no \
  631.         -vscrollmode dynamic -hscrollmode dynamic 
  632.     } {
  633.         keep -background -borderwidth -cursor -foreground \
  634.         -highlightcolor -highlightthickness \
  635.         -hscrollmode -items -selectbackground \
  636.         -selectborderwidth -selectforeground -textbackground \
  637.         -textfont -visibleitems -vscrollmode 
  638.         rename -height -listheight listHeight Height
  639.     }
  640.     # add mode specific bindings
  641.     _simpleBindings
  642.     }
  643.  
  644.     # popup cursor applies only to the list within the combobox
  645.     configure -popupcursor $itk_option(-popupcursor)
  646.  
  647.     # add mode independent bindings
  648.     _commonBindings
  649. }
  650.  
  651. # ------------------------------------------------------
  652. # PROTECTED METHOD: _deleteList first ?last?
  653. #
  654. # Delete an item or items from the listbox. Called via 
  655. # "delete list args".
  656. #
  657. # ------------------------------------------------------
  658. body iwidgets::Combobox::_deleteList {first {last {}}} {
  659.  
  660.     if {$last == {}} {
  661.     set last $first
  662.     }
  663.     configure -items [eval lreplace {$itk_option(-items)} $first $last]
  664.  
  665.     # remove the item if it is no longer in the list
  666.     set text [$this get]
  667.     if {$text != ""} {
  668.     set index [lsearch -exact $itk_option(-items) $text ]
  669.     if {$index == -1} {
  670.         clear entry
  671.     }
  672.     }
  673.     return
  674. }
  675.  
  676. # ------------------------------------------------------
  677. # PROTECTED METHOD: _deleteText first ?last?
  678. #
  679. # Renamed Entryfield delete method. Called via "delete entry args".
  680. #
  681. # ------------------------------------------------------
  682. body iwidgets::Combobox::_deleteText {first {last {}}} {
  683.     $itk_component(entry) configure -state normal 
  684.     set rtrn [delete $first $last]
  685.     if {$itk_option(-editable)} {
  686.     } else {
  687.     $itk_component(entry) configure -state disabled
  688.     }
  689.     return $rtrn
  690. }
  691.  
  692. # ------------------------------------------------------
  693. # PROTECTED METHOD:   _doLayout ?when?
  694. #
  695. # Call methods to create and pack the Combobox components.
  696. #
  697. # ------------------------------------------------------
  698. body iwidgets::Combobox::_doLayout {{when later}} {
  699.     _createComponents
  700.     _packComponents $when
  701. }
  702.  
  703.  
  704. # ------------------------------------------------------
  705. # PROTECTED METHOD:   _drawArrow ?mode?
  706. #
  707. # Draw the arrow button. Determines packing according to
  708. # -labelpos.
  709. #
  710. # ------------------------------------------------------
  711. body iwidgets::Combobox::_drawArrow {{mode normal}} {
  712.     set flip false
  713.     switch -- $mode {
  714.     normal {
  715.         set fg [cget -foreground]
  716.         $itk_component(arrowBtn) configure -relief $itk_option(-arrowrelief)
  717.         bind $itk_component(arrowBtn) <1> [code $this _toggleList]
  718.         if {$_isPosted} {
  719.         if {$itk_option(-fliparrow)} {
  720.             set flip true
  721.         }
  722.         }
  723.     }
  724.     disabled {
  725.         set fg grey65
  726.         $itk_component(arrowBtn) configure -relief $itk_option(-arrowrelief)
  727.         bind $itk_component(arrowBtn) <1> ""
  728.     }
  729.     depressed {
  730.         set fg [cget -foreground]
  731.         $itk_component(arrowBtn) configure -relief sunken
  732. #        update
  733.     }
  734.     }
  735.  
  736.     # undraw the old arrow polygon
  737.     $itk_component(arrowBtn) delete arrow
  738.  
  739.     # draw new arrow
  740.     set bw [expr ([$itk_component(arrowBtn) cget -borderwidth] + \
  741.               [$itk_component(arrowBtn) cget -highlightthickness]) / 2]
  742.     set h [expr [$itk_component(arrowBtn) cget -height] + (2*$bw)]
  743.     set w [expr [$itk_component(arrowBtn) cget -width] + (2*$bw)]
  744.  
  745.     if {$flip} {
  746.     $itk_component(arrowBtn) create polygon \
  747.         [expr .25*$w+$bw] [expr .75*$h+$bw] \
  748.         [expr .75*$w+$bw] [expr .75*$h+$bw] \
  749.         [expr .5*$w+$bw] [expr .25*$h+$bw-1] -fill $fg -tag arrow
  750.     } else {
  751.     $itk_component(arrowBtn) create polygon \
  752.         [expr .25*$w+$bw] [expr .25*$h+$bw] \
  753.         [expr .75*$w+$bw] [expr .25*$h+$bw] \
  754.         [expr .5*$w+$bw] [expr .75*$h+$bw] \
  755.         -fill $fg -tag arrow
  756.     }
  757. }
  758.  
  759. # ------------------------------------------------------
  760. # PROTECTED METHOD: _dropdownBtnRelease window x y
  761. #
  762. # Event handler for button releases while a dropdown list
  763. # is posted.
  764. #
  765. # ------------------------------------------------------
  766. body iwidgets::Combobox::_dropdownBtnRelease {{window {}} {x 1} {y 1}} {
  767.  
  768.     # if it's a scrollbar then ignore the release
  769.     if {($window == [$itk_component(list) component vertsb]) ||
  770.     ($window == [$itk_component(list) component horizsb])} {
  771.     return
  772.     }
  773.  
  774.     # 1st release allows list to stay up unless we are in listbox
  775.     if {$_ignoreRelease} {
  776.     _ignoreNextBtnRelease false
  777.     return
  778.     }
  779.     
  780.     # should I use just the listbox or also include the scrollbars
  781.     if {($x >= 0) && ($x < [winfo width [_slbListbox]]) && 
  782.     ($y >= 0) && ($y < [winfo height [_slbListbox]])} {
  783.     _selectCmd
  784.     }
  785.     
  786.     _unpostList
  787. }
  788.  
  789. # ------------------------------------------------------
  790. # PROTECTED METHOD: _ignoreNextBtnRelease ignore
  791. #
  792. # Set private variable _ignoreRelease. If this variable
  793. # is true then the next button release will not remove
  794. # a dropdown list.
  795. #
  796. # ------------------------------------------------------
  797. body iwidgets::Combobox::_ignoreNextBtnRelease {ignore} {
  798.     set _ignoreRelease $ignore
  799. }
  800.  
  801. # ------------------------------------------------------
  802. # PROTECTED METHOD:   _next
  803. #
  804. # Select the next item in the list.
  805. #
  806. # ------------------------------------------------------
  807. body iwidgets::Combobox::_next {} {
  808.     if {[$this size] <= 1} {
  809.     return
  810.     }
  811.     set i [$this curselection]
  812.     if {($i == {}) || ($i == [expr [$this size]-1]) } {
  813.     set i 0
  814.     } else {
  815.     incr i
  816.     }
  817.     $this selection clear 0 end
  818.     $this selection set $i $i
  819.     $this see $i
  820.     set _currItem $i
  821. }
  822.  
  823. # ------------------------------------------------------
  824. # PROTECTED METHOD:   _packArrow labelpos
  825. #
  826. # Pack the arrowbutton according to the label position.
  827. #
  828. # ------------------------------------------------------
  829. body iwidgets::Combobox::_packArrow {labelpos} {
  830.     pack $itk_component(arrowBtn) -side right -anchor center
  831. }
  832.  
  833. # ------------------------------------------------------
  834. # PROTECTED METHOD:   _packComponents ?when?
  835. #
  836. # Pack the components of the combobox and add bindings.
  837. #
  838. # ------------------------------------------------------
  839. body iwidgets::Combobox::_packComponents {{when later}} {
  840.     if {$when == "later"} {
  841.     if {$_repacking == ""} {
  842.         set _repacking [after idle [code $this _packComponents now]]
  843.         return
  844.     }
  845.     } elseif {$when != "now"} {
  846.     error "bad option \"$when\": should be now or later"
  847.     }
  848.  
  849.     if {$itk_option(-dropdown)} {
  850.     pack $itk_component(margin) -side left
  851.     pack configure $itk_component(list) -expand yes -fill both
  852.     _resizeArrow
  853.     pack $itk_component(arrowBtn) -side right
  854.     } else {
  855.     # size and pack list hack
  856.     set w [winfo reqwidth $itk_component(hull)]
  857.     $itk_component(list) configure -width $w
  858.     pack configure $itk_component(entry) -fill x -side top -expand no
  859.     pack configure $itk_component(efchildsite) -side top \
  860.         -after $itk_component(entry) -fill both -expand yes
  861.     pack configure $itk_component(list) -side top -fill both -expand yes
  862.     }
  863.     
  864.     set _repacking ""
  865. }
  866.  
  867. # ------------------------------------------------------
  868. # PROTECTED METHOD:   _positionList
  869. #
  870. # Determine the position (geometry) for the popped up list
  871. # and map it to the screen.
  872. #
  873. # ------------------------------------------------------
  874. body iwidgets::Combobox::_positionList {} {
  875.  
  876.     set x [winfo rootx $itk_component(entry) ]
  877.     set y [expr [winfo rooty $itk_component(entry) ] + \
  878.            [winfo height $itk_component(entry) ]]
  879.     set w [winfo width $itk_component(entry) ]
  880.     set h [winfo height [_slbListbox] ]
  881.     set sh [winfo screenheight .]
  882.  
  883.     if {([expr $y+$h] > $sh) && ($y > [expr $sh/2])} {
  884.     set y [expr [winfo rooty $itk_component(entry) ] - $h]
  885.     }
  886.     
  887.     $itk_component(list) configure -width $w
  888.     wm geometry $itk_component(popup) +$x+$y
  889. }
  890.  
  891. # ------------------------------------------------------
  892. # PROTECTED METHOD:   _postList
  893. #
  894. # Pop up the list in a dropdown style Combobox.
  895. #
  896. # ------------------------------------------------------
  897. body iwidgets::Combobox::_postList {} {
  898.  
  899.     if {[$itk_component(list) size] == ""} {
  900.     return
  901.     }
  902.  
  903.     set _isPosted true
  904.     _drawArrow depressed      ;# sad button
  905.     _positionList
  906.  
  907.     # map window and do a grab
  908.     wm deiconify $itk_component(popup)
  909.     _listShowing -wait
  910.     grab -global $itk_component(popup) 
  911.     raise $itk_component(popup)
  912.     focus $itk_component(popup)
  913.  
  914.     _drawArrow normal
  915.     set _ignoreRelease true
  916. }
  917.  
  918. # ------------------------------------------------------
  919. # PROTECTED METHOD:    _previous
  920. #
  921. # Select the previous item in the list. Wraps at front
  922. # and end of list. 
  923. #
  924. # ------------------------------------------------------
  925. body iwidgets::Combobox::_previous {} {
  926.     if {[$this size] <= 1} {
  927.     return
  928.     }
  929.     set i [$this curselection]
  930.     if {$i == "" || $i == 0} {
  931.     set i [expr [$this size] - 1]
  932.     } else {
  933.     incr i -1
  934.     }
  935.     $this selection clear 0 end
  936.     $this selection set $i $i
  937.     $this see $i
  938.     set _currItem $i
  939. }
  940.  
  941. # ------------------------------------------------------
  942. # PROTECTED METHOD:   _resizeArrow
  943. #
  944. # Recalculate the arrow button size and then redraw it.
  945. #
  946. # ------------------------------------------------------
  947. body iwidgets::Combobox::_resizeArrow {} {
  948.     set bw [expr [$itk_component(arrowBtn) cget -borderwidth]+ \
  949.         [$itk_component(arrowBtn) cget -highlightthickness]]
  950.     set newHeight [expr [winfo reqheight $itk_component(entry) ]-(2*$bw)]
  951.     $itk_component(arrowBtn) configure -width $newHeight -height $newHeight
  952.     _drawArrow
  953. }
  954.  
  955. # ------------------------------------------------------
  956. # PROTECTED METHOD:   _selectCmd
  957. #
  958. # Called when list item is selected to insert new text 
  959. # in entry, and call user -command callback if defined.
  960. #
  961. # ------------------------------------------------------
  962. body iwidgets::Combobox::_selectCmd {} {
  963.     $itk_component(entry) configure -state normal
  964.     
  965.     set _currItem [$itk_component(list) curselection]
  966.     set item [$itk_component(list) getcurselection]
  967.     clear entry
  968.     $itk_component(entry) insert 0 $item
  969.     if {$itk_option(-editable)} {
  970.     } else {
  971.     $itk_component(entry) configure -state disabled
  972.     }
  973.  
  974.     # execute user command
  975.     if {$itk_option(-selectioncommand) != ""} {
  976.     uplevel #0 $itk_option(-selectioncommand)
  977.     }
  978. }
  979.  
  980. # ------------------------------------------------------
  981. # PROTECTED METHOD:  _toggleList
  982. #
  983. # Post or unpost the dropdown listbox (toggle).
  984. #
  985. # ------------------------------------------------------
  986. body iwidgets::Combobox::_toggleList {} {
  987.     if {[winfo ismapped $itk_component(popup)] } {
  988.     _unpostList
  989.     } else {
  990.     _postList
  991.     }
  992. }
  993.  
  994. # ------------------------------------------------------
  995. # PROTECTED METHOD:   _unpostList
  996. #
  997. # Unmap the listbox (pop it down).
  998. #
  999. # ------------------------------------------------------
  1000. body iwidgets::Combobox::_unpostList {} {
  1001.     # Determine if event occured in the scrolledlistbox and, if it did, 
  1002.     # don't unpost it. (A selection in the list unposts it correctly and 
  1003.     # in the scrollbar we don't want to unpost it.)
  1004.     set x [winfo x $itk_component(list)]
  1005.     set y [winfo y $itk_component(list)]
  1006.     set w [winfo width $itk_component(list)]
  1007.     set h [winfo height $itk_component(list)]
  1008.  
  1009.     wm withdraw $itk_component(popup)
  1010.     grab release $itk_component(popup)    
  1011.     
  1012.     set _isPosted false
  1013.     _drawArrow normal
  1014.     
  1015.     $itk_component(list) selection clear 0 end
  1016.     if {$_currItem != {}} {
  1017.     $itk_component(list) selection set $_currItem $_currItem
  1018.     $itk_component(list) activate $_currItem
  1019.     }
  1020.  
  1021.     if {$itk_option(-editable)} {
  1022.     $itk_component(entry) configure -state normal
  1023.     } else {
  1024.     $itk_component(entry) configure -state disabled
  1025.     }
  1026. }
  1027.  
  1028. # ------------------------------------------------------
  1029. # PROTECTED METHOD:   _commonBindings
  1030. #
  1031. # Bindings that are used by both simple and dropdown
  1032. # style Comboboxes.
  1033. #
  1034. # ------------------------------------------------------
  1035. body iwidgets::Combobox::_commonBindings {} {
  1036.     bind $itk_component(entry) <Down>       [code $this _next]
  1037.     bind $itk_component(entry) <Up>         [code $this _previous]
  1038.     bind $itk_component(entry) <Control-n>  [code $this _next]
  1039.     bind $itk_component(entry) <Control-p>  [code $this _previous]
  1040.     bind [_slbListbox]         <Control-n>  [code $this _next]
  1041.     bind [_slbListbox]         <Control-p>  [code $this _previous]
  1042. }
  1043.  
  1044.  
  1045. # ------------------------------------------------------
  1046. # PROTECTED METHOD: _dropdownBindings
  1047. #
  1048. # Bindings used only by the dropdown type Combobox.
  1049. #
  1050. # ------------------------------------------------------
  1051. body iwidgets::Combobox::_dropdownBindings {} {
  1052.     bind $itk_component(popup)  <Escape> [code $this _unpostList]
  1053.     bind $itk_component(popup)  <space>  \
  1054.     "[code $this _selectCmd]; [code $this _unpostList]"
  1055.     bind $itk_component(popup)  <Return> \
  1056.     "[code $this _selectCmd]; [code $this _unpostList]"
  1057.     bind $itk_component(popup)  <ButtonRelease-1> \
  1058.     [code $this _dropdownBtnRelease %W %x %y]
  1059.  
  1060.     bind $itk_component(list)  <Map> \
  1061.     [code $this _listShowing 1]
  1062.     bind $itk_component(list)  <Unmap> \
  1063.     [code $this _listShowing 0]
  1064.  
  1065.     # once in the listbox, we drop on the next release (unless in scrollbar)
  1066.     bind [_slbListbox]   <Enter>   \
  1067.     [code $this _ignoreNextBtnRelease false]
  1068.  
  1069.     bind $itk_component(arrowBtn) <Configure>  [code $this _drawArrow]
  1070.     bind $itk_component(arrowBtn) <3>          [code $this _next]
  1071.     bind $itk_component(arrowBtn) <Shift-3>    [code $this _previous]
  1072.     bind $itk_component(arrowBtn) <Down>       [code $this _next]
  1073.     bind $itk_component(arrowBtn) <Up>         [code $this _previous]
  1074.     bind $itk_component(arrowBtn) <Control-n>  [code $this _next]
  1075.     bind $itk_component(arrowBtn) <Control-p>  [code $this _previous]
  1076.     bind $itk_component(arrowBtn) <Shift-Down> [code $this _toggleList]
  1077.     bind $itk_component(arrowBtn) <Shift-Up>   [code $this _toggleList]
  1078.     bind $itk_component(arrowBtn) <Return>     [code $this _toggleList]
  1079.     bind $itk_component(arrowBtn) <space>      [code $this _toggleList]
  1080.  
  1081.     bind $itk_component(entry)    <Configure>  [code $this _resizeArrow]
  1082.     bind $itk_component(entry)    <Shift-Down> [code $this _toggleList]
  1083.     bind $itk_component(entry)    <Shift-Up>   [code $this _toggleList]
  1084. }
  1085.  
  1086. # ------------------------------------------------------
  1087. # PROTECTED METHOD: _simpleBindings
  1088. #
  1089. # Bindings used only by the simple type Comboboxes.
  1090. #
  1091. # ------------------------------------------------------
  1092. body iwidgets::Combobox::_simpleBindings {} {
  1093.     bind [_slbListbox]         <ButtonRelease-1> [code $this _selectCmd]
  1094.     bind [_slbListbox]         <space>     [code $this _selectCmd]
  1095.     bind [_slbListbox]         <Return>    [code $this _selectCmd]
  1096.     bind $itk_component(entry) <Escape>     ""
  1097.     bind $itk_component(entry) <Shift-Down> ""
  1098.     bind $itk_component(entry) <Shift-Up>   ""
  1099.     bind $itk_component(entry) <Configure>  ""
  1100. }
  1101.  
  1102. # ------------------------------------------------------
  1103. # PROTECTED METHOD: _listShowing ?val?
  1104. #
  1105. # Used instead of "tkwait visibility" to make sure that
  1106. # the dropdown list is visible.  Whenever the list gets
  1107. # mapped or unmapped, this method is called to keep
  1108. # track of it.  When it is called with the value "-wait",
  1109. # it waits for the list to be mapped.
  1110. # ------------------------------------------------------
  1111. body iwidgets::Combobox::_listShowing {{val ""}} {
  1112.     if {$val == ""} {
  1113.         return $_listShowing($this)
  1114.     } elseif {$val == "-wait"} {
  1115.         while {!$_listShowing($this)} {
  1116.             tkwait variable [scope _listShowing($this)]
  1117.         }
  1118.         return
  1119.     }
  1120.     set _listShowing($this) $val
  1121. }
  1122.  
  1123. # ------------------------------------------------------
  1124. # PRIVATE METHOD:    _slbListbox
  1125. #
  1126. # Access the tk listbox window out of the scrolledlistbox.
  1127. #
  1128. # ------------------------------------------------------
  1129. body iwidgets::Combobox::_slbListbox {} {
  1130.     return [$itk_component(list) component listbox]
  1131. }
  1132.  
  1133. # ... emacs mode recognition ...
  1134. # Local Variables:
  1135. # mode: tcl
  1136. # End:
  1137.  
  1138.