home *** CD-ROM | disk | FTP | other *** search
/ PC World 2000 December / PCWorld_2000-12_cd.bin / Komunikace / Comanche / comanche.exe / lib / iwidgets2.2.0 / scripts / buttonbox.itk next >
Text File  |  1999-02-24  |  18KB  |  567 lines
  1. #
  2. # Buttonbox
  3. # ----------------------------------------------------------------------
  4. # Manages a framed area with Motif style buttons.  The button box can 
  5. # be configured either horizontally or vertically.  
  6. #
  7. # ----------------------------------------------------------------------
  8. #  AUTHOR: Mark L. Ulferts               EMAIL: mulferts@spd.dsccc.com
  9. #          Bret A. Schuhmacher           EMAIL: bas@wn.com
  10. #
  11. #  @(#) $Id: buttonbox.itk,v 1.1 1998/07/27 18:49:21 stanton Exp $
  12. # ----------------------------------------------------------------------
  13. #            Copyright (c) 1995 DSC Technologies Corporation
  14. # ======================================================================
  15. # Permission to use, copy, modify, distribute and license this software 
  16. # and its documentation for any purpose, and without fee or written 
  17. # agreement with DSC, is hereby granted, provided that the above copyright 
  18. # notice appears in all copies and that both the copyright notice and 
  19. # warranty disclaimer below appear in supporting documentation, and that 
  20. # the names of DSC Technologies Corporation or DSC Communications 
  21. # Corporation not be used in advertising or publicity pertaining to the 
  22. # software without specific, written prior permission.
  23. # 
  24. # DSC DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE, INCLUDING 
  25. # ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, AND NON-
  26. # INFRINGEMENT. THIS SOFTWARE IS PROVIDED ON AN "AS IS" BASIS, AND THE
  27. # AUTHORS AND DISTRIBUTORS HAVE NO OBLIGATION TO PROVIDE MAINTENANCE, 
  28. # SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS. IN NO EVENT SHALL 
  29. # DSC BE LIABLE FOR ANY SPECIAL, INDIRECT OR CONSEQUENTIAL DAMAGES OR 
  30. # ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, 
  31. # WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTUOUS ACTION,
  32. # ARISING OUT OF OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS 
  33. # SOFTWARE.
  34. # ======================================================================
  35.  
  36. #
  37. # Default resources,
  38. #
  39. option add *Buttonbox.padX 5 widgetDefault
  40. option add *Buttonbox.padY 5 widgetDefault
  41. option add *Buttonbox.orient horizontal widgetDefault
  42.  
  43. #
  44. # Usual options.
  45. #
  46. itk::usual Buttonbox {
  47.     keep -background -cursor -foreground
  48. }
  49.  
  50. # ------------------------------------------------------------------
  51. #                            BUTTONBOX
  52. # ------------------------------------------------------------------
  53. class iwidgets::Buttonbox {
  54.     inherit itk::Widget
  55.  
  56.     constructor {args} {}
  57.     destructor {}
  58.  
  59.     itk_option define -pady padY Pad 5
  60.     itk_option define -padx padX Pad 5
  61.     itk_option define -orient orient Orient "horizontal"
  62.     itk_option define -foreground foreground Foreground black
  63.     
  64.     public method index {args}
  65.     public method add {args}
  66.     public method insert {args}
  67.     public method delete {args}
  68.     public method default {args}
  69.     public method hide {args}
  70.     public method show {args}
  71.     public method invoke {args}
  72.     public method buttonconfigure {args}
  73.  
  74.     private method _positionButtons {}
  75.     private method _setBoxSize {{when later}}
  76.     private method _getMaxWidth {}
  77.     private method _getMaxHeight {}
  78.  
  79.     private variable _resizeFlag {}         ;# Flag for resize needed.
  80.     private variable _buttonList {}         ;# List of all buttons in box.
  81.     private variable _displayList {}        ;# List of displayed buttons.
  82. }
  83.  
  84. namespace eval iwidgets::Buttonbox {
  85.     #
  86.     # Set up some class level bindings for map and configure events.
  87.     #
  88.     bind bbox-map <Map> [code %W _setBoxSize]
  89.     bind bbox-config <Configure> [code %W _positionButtons]
  90. }
  91.  
  92. #
  93. # Provide a lowercased access method for the Buttonbox class.
  94. # 
  95. proc ::iwidgets::buttonbox {pathName args} {
  96.     uplevel ::iwidgets::Buttonbox $pathName $args
  97. }
  98.     
  99. # ------------------------------------------------------------------
  100. #                        CONSTRUCTOR
  101. # ------------------------------------------------------------------
  102. body iwidgets::Buttonbox::constructor {args} {
  103.     # 
  104.     # Add Configure bindings for geometry management.  
  105.     #
  106.     bindtags $itk_component(hull) \
  107.         [linsert [bindtags $itk_component(hull)] 0 bbox-map]
  108.     bindtags $itk_component(hull) \
  109.         [linsert [bindtags $itk_component(hull)] 1 bbox-config]
  110.     
  111.     pack propagate $itk_component(hull) no
  112.     
  113.     #
  114.     # Explicitly handle configs that may have been ignored earlier.
  115.     #
  116.     eval itk_initialize $args
  117. }
  118.  
  119. # ------------------------------------------------------------------
  120. #                           DESTRUCTOR
  121. # ------------------------------------------------------------------
  122. body iwidgets::Buttonbox::destructor {} {
  123.     if {$_resizeFlag != ""} {after cancel $_resizeFlag}
  124. }
  125.  
  126. # ------------------------------------------------------------------
  127. #                             OPTIONS
  128. # ------------------------------------------------------------------
  129.  
  130. # ------------------------------------------------------------------
  131. # OPTION: -pady
  132. #
  133. # Pad the y space between the button box frame and the hull.
  134. # ------------------------------------------------------------------
  135. configbody iwidgets::Buttonbox::pady {
  136.     _setBoxSize
  137. }
  138.  
  139. # ------------------------------------------------------------------
  140. # OPTION: -padx
  141. #
  142. # Pad the x space between the button box frame and the hull.
  143. # ------------------------------------------------------------------
  144. configbody iwidgets::Buttonbox::padx {
  145.     _setBoxSize
  146. }
  147.  
  148. # ------------------------------------------------------------------
  149. # OPTION: -orient
  150. #
  151. # Position buttons either horizontally or vertically.
  152. # ------------------------------------------------------------------
  153. configbody iwidgets::Buttonbox::orient {
  154.     switch $itk_option(-orient) {
  155.     "horizontal" -
  156.     "vertical" {
  157.         _setBoxSize
  158.     }
  159.     
  160.     default {
  161.         error "bad orientation option \"$itk_option(-orient)\",\
  162.             should be either horizontal or vertical"
  163.     }
  164.     }
  165. }
  166.  
  167. # ------------------------------------------------------------------
  168. #                            METHODS
  169. # ------------------------------------------------------------------
  170.  
  171. # ------------------------------------------------------------------
  172. # METHOD: index index
  173. #
  174. # Searches the buttons in the box for the one with the requested tag,
  175. # numerical index, keyword "end" or "default".  Returns the button's 
  176. # tag if found, otherwise error.
  177. # ------------------------------------------------------------------    
  178. body iwidgets::Buttonbox::index {index} {
  179.     if {[llength $_buttonList] > 0} {
  180.     if {[regexp {(^[0-9]+$)} $index]} {
  181.         if {$index < [llength $_buttonList]} {
  182.         return $index
  183.         } else {
  184.         error "Buttonbox index \"$index\" is out of range"
  185.         }
  186.         
  187.     } elseif {$index == "end"} {
  188.         return [expr [llength $_buttonList] - 1]
  189.         
  190.     } elseif {$index == "default"} {
  191.         foreach knownButton $_buttonList {
  192.         if {[$itk_component($knownButton) cget -defaultring]} {
  193.             return [lsearch -exact $_buttonList $knownButton]
  194.         }
  195.         }
  196.         
  197.         error "Buttonbox \"$itk_component(hull)\" has no default"
  198.         
  199.     } else {
  200.         if {[set idx [lsearch $_buttonList $index]] != -1} {
  201.         return $idx
  202.         }
  203.         
  204.         error "bad Buttonbox index \"$index\": must be number, end,\
  205.             default, or pattern"
  206.     }
  207.     
  208.     } else {
  209.     error "Buttonbox \"$itk_component(hull)\" has no buttons"
  210.     }
  211. }
  212.  
  213. # ------------------------------------------------------------------
  214. # METHOD: add tag ?option value option value ...?
  215. #
  216. # Add the specified button to the button box.  All PushButton options
  217. # are allowed.  New buttons are added to the list of buttons and the 
  218. # list of displayed buttons.  The PushButton path name is returned.
  219. # ------------------------------------------------------------------
  220. body iwidgets::Buttonbox::add {tag args} {
  221.     itk_component add $tag {
  222.     iwidgets::Pushbutton $itk_component(hull).#auto
  223.     } {
  224.     keep -disabledforeground -highlightthickness -borderwidth \
  225.         -font -highlightcolor -background \
  226.         -foreground -activebackground -cursor -activeforeground 
  227.     rename -highlightbackground -background background Background
  228.     }
  229.     
  230.     if {$args != ""} {
  231.     uplevel $itk_component($tag) configure $args
  232.     }
  233.     
  234.     lappend _buttonList $tag
  235.     lappend _displayList $tag
  236.     
  237.     _setBoxSize
  238. }
  239.  
  240. # ------------------------------------------------------------------
  241. # METHOD: insert index tag ?option value option value ...?
  242. #
  243. # Insert the specified button in the button box just before the one 
  244. # given by index.  All PushButton options are allowed.  New buttons 
  245. # are added to the list of buttons and the list of displayed buttons.
  246. # The PushButton path name is returned.
  247. # ------------------------------------------------------------------
  248. body iwidgets::Buttonbox::insert {index tag args} {
  249.     itk_component add $tag {
  250.     iwidgets::Pushbutton $itk_component(hull).#auto
  251.     } {
  252.     keep -disabledforeground -highlightthickness -borderwidth \
  253.         -font -highlightcolor -background \
  254.         -foreground -activebackground -cursor -activeforeground 
  255.     rename -highlightbackground -background background Background
  256.     }
  257.     
  258.     if {$args != ""} {
  259.     uplevel $itk_component($tag) configure $args
  260.     }
  261.     
  262.     set index [index $index]
  263.     set _buttonList [linsert $_buttonList $index $tag]
  264.     set _displayList [linsert $_displayList $index $tag]
  265.     
  266.     _setBoxSize
  267. }
  268.  
  269. # ------------------------------------------------------------------
  270. # METHOD: delete index
  271. #
  272. # Delete the specified button from the button box.
  273. # ------------------------------------------------------------------
  274. body iwidgets::Buttonbox::delete {index} {
  275.     set index [index $index]
  276.     set tag [lindex $_buttonList $index]
  277.     
  278.     destroy $itk_component($tag)
  279.     
  280.     set _buttonList [lreplace $_buttonList $index $index]
  281.     
  282.     if {[set dind [lsearch $_displayList $tag]] != -1} {
  283.     set _displayList [lreplace $_displayList $dind $dind]
  284.     }
  285.     
  286.     _setBoxSize
  287.     update idletasks
  288. }
  289.  
  290. # ------------------------------------------------------------------
  291. # METHOD: default index
  292. #
  293. # Sets the default to the push button given by index.
  294. # ------------------------------------------------------------------
  295. body iwidgets::Buttonbox::default {index} {
  296.     set index [index $index]
  297.     
  298.     set defbtn [lindex $_buttonList $index]
  299.     
  300.     foreach knownButton $_displayList {
  301.     if {$knownButton == $defbtn} {
  302.         $itk_component($knownButton) configure -defaultring yes
  303.     } else {
  304.         $itk_component($knownButton) configure -defaultring no
  305.     }
  306.     }
  307. }
  308.  
  309. # ------------------------------------------------------------------
  310. # METHOD: hide index
  311. #
  312. # Hide the push button given by index.  This doesn't remove the button 
  313. # permanently from the display list, just inhibits its display.
  314. # ------------------------------------------------------------------
  315. body iwidgets::Buttonbox::hide {index} {
  316.     set index [index $index]
  317.     set tag [lindex $_buttonList $index]
  318.     
  319.     if {[set dind [lsearch $_displayList $tag]] != -1} {
  320.     place forget $itk_component($tag)
  321.     set _displayList [lreplace $_displayList $dind $dind] 
  322.     
  323.     _setBoxSize
  324.     }
  325. }
  326.  
  327. # ------------------------------------------------------------------
  328. # METHOD: show index
  329. #
  330. # Displays a previously hidden push button given by index.  Check if 
  331. # the button is already in the display list.  If not then add it back 
  332. # at it's original location and redisplay.
  333. # ------------------------------------------------------------------
  334. body iwidgets::Buttonbox::show {index} {
  335.     set index [index $index]
  336.     set tag [lindex $_buttonList $index]
  337.     
  338.     if {[lsearch $_displayList $tag] == -1} {
  339.     set _displayList [linsert $_displayList $index $tag]
  340.     
  341.     _setBoxSize
  342.     }
  343. }
  344.  
  345. # ------------------------------------------------------------------
  346. # METHOD: invoke ?index?
  347. #
  348. # Invoke the command associated with a push button.  If no arguments
  349. # are given then the default button is invoked, otherwise the argument
  350. # is expected to be a button index.
  351. # ------------------------------------------------------------------
  352. body iwidgets::Buttonbox::invoke {args} {
  353.     if {[llength $args] == 0} {
  354.     $itk_component([lindex $_buttonList [index default]]) invoke
  355.     
  356.     } else {
  357.     $itk_component([lindex $_buttonList [index [lindex $args 0]]]) \
  358.         invoke
  359.     }
  360. }
  361.  
  362. # ------------------------------------------------------------------
  363. # METHOD: buttonconfigure index ?option? ?value option value ...?
  364. #
  365. # Configure a push button given by index.  This method allows 
  366. # configuration of pushbuttons from the Buttonbox level.  The options
  367. # may have any of the values accepted by the add method.
  368. # ------------------------------------------------------------------
  369. body iwidgets::Buttonbox::buttonconfigure {index args} {
  370.     set tag [lindex $_buttonList [index $index]]
  371.     
  372.     set retstr [uplevel $itk_component($tag) configure $args]
  373.     
  374.     _setBoxSize
  375.     
  376.     return $retstr
  377. }
  378.  
  379. # -----------------------------------------------------------------
  380. # PRIVATE METHOD: _getMaxWidth
  381. #
  382. # Returns the required width of the largest button.
  383. # -----------------------------------------------------------------
  384. body iwidgets::Buttonbox::_getMaxWidth {} {
  385.     set max 0
  386.     
  387.     foreach tag $_displayList {
  388.     set w [winfo reqwidth $itk_component($tag)]
  389.     
  390.     if {$w > $max} {
  391.         set max $w
  392.     }
  393.     }
  394.     
  395.     return $max
  396. }
  397.  
  398. # -----------------------------------------------------------------
  399. # PRIVATE METHOD: _getMaxHeight
  400. #
  401. # Returns the required height of the largest button.
  402. # -----------------------------------------------------------------
  403. body iwidgets::Buttonbox::_getMaxHeight {} {
  404.     set max 0
  405.     
  406.     foreach tag $_displayList {
  407.     set h [winfo reqheight $itk_component($tag)]
  408.     
  409.     if {$h > $max} {
  410.         set max $h
  411.     }
  412.     }
  413.     
  414.     return $max
  415. }
  416.  
  417. # ------------------------------------------------------------------
  418. # METHOD: _setBoxSize ?when?
  419. #
  420. # Sets the proper size of the frame surrounding all the buttons.
  421. # If "when" is "now", the change is applied immediately.  If it is 
  422. # "later" or it is not specified, then the change is applied later, 
  423. # when the application is idle.
  424. # ------------------------------------------------------------------
  425. body iwidgets::Buttonbox::_setBoxSize {{when later}} {
  426.     if {[winfo ismapped $itk_component(hull)]} {
  427.     if {$when == "later"} {
  428.         if {$_resizeFlag == ""} {
  429.         set _resizeFlag [after idle [code $this _setBoxSize now]]
  430.         }
  431.         return
  432.     } elseif {$when != "now"} {
  433.         error "bad option \"$when\": should be now or later"
  434.     }
  435.  
  436.     set _resizeFlag ""
  437.  
  438.     set numBtns [llength $_displayList]
  439.     
  440.     if {$itk_option(-orient) == "horizontal"} {
  441.         set minw [expr $numBtns * [_getMaxWidth] \
  442.             + ($numBtns+1) * $itk_option(-padx)]
  443.         set minh [expr [_getMaxHeight] + 2 * $itk_option(-pady)]
  444.         
  445.     } else {
  446.         set minw [expr [_getMaxWidth] + 2 * $itk_option(-padx)]
  447.         set minh [expr $numBtns * [_getMaxHeight] \
  448.             + ($numBtns+1) * $itk_option(-pady)]
  449.     }
  450.     
  451.     #
  452.     # Remove the configure event bindings on the hull while we adjust the
  453.     # width/height and re-position the buttons.  Once we're through, we'll
  454.     # update and reinstall them.  This prevents double calls to position
  455.     # the buttons.
  456.     #
  457.     set tags [bindtags $itk_component(hull)]
  458.     if {[set i [lsearch $tags bbox-config]] != -1} {
  459.         set tags [lreplace $tags $i $i]
  460.         bindtags $itk_component(hull) $tags
  461.     }
  462.     
  463.     component hull configure -width $minw -height $minh
  464.     
  465.     update idletasks
  466.         
  467.     _positionButtons
  468.     
  469.     bindtags $itk_component(hull) [linsert $tags 0 bbox-config]
  470.     }
  471. }
  472.     
  473. # ------------------------------------------------------------------
  474. # METHOD: _positionButtons
  475. # 
  476. # This method is responsible setting the width/height of all the 
  477. # displayed buttons to the same value and for placing all the buttons
  478. # in equidistant locations.
  479. # ------------------------------------------------------------------
  480. body iwidgets::Buttonbox::_positionButtons {} {
  481.     set bf $itk_component(hull)
  482.     set numBtns [llength $_displayList]
  483.     
  484.     # 
  485.     # First, determine the common width and height for all the 
  486.     # displayed buttons.
  487.     #
  488.     if {$numBtns > 0} {
  489.     set bfWidth [winfo width $itk_component(hull)]
  490.     set bfHeight [winfo height $itk_component(hull)]
  491.     
  492.     if {$bfWidth >= [winfo reqwidth $itk_component(hull)]} {
  493.         set _btnWidth [_getMaxWidth] 
  494.         
  495.     } else {
  496.         if {$itk_option(-orient) == "horizontal"} {
  497.         set _btnWidth [expr $bfWidth / $numBtns]
  498.         } else {
  499.         set _btnWidth $bfWidth
  500.         }
  501.     }        
  502.     
  503.     if {$bfHeight >= [winfo reqheight $itk_component(hull)]} {
  504.         set _btnHeight [_getMaxHeight]
  505.         
  506.     } else {
  507.         if {$itk_option(-orient) == "vertical"} {
  508.         set _btnHeight [expr $bfHeight / $numBtns]
  509.         } else {
  510.         set _btnHeight $bfHeight
  511.         }
  512.     }        
  513.     }
  514.     
  515.     #
  516.     # Place the buttons at the proper locations.
  517.     #
  518.     if {$numBtns > 0} {
  519.     if {$itk_option(-orient) == "horizontal"} {
  520.         set leftover [expr [winfo width $bf] \
  521.             - 2 * $itk_option(-padx) - $_btnWidth * $numBtns]
  522.         
  523.         if {$numBtns > 0} {
  524.         set offset [expr $leftover / ($numBtns + 1)]
  525.         } else {
  526.         set offset 0
  527.         }
  528.         if {$offset < 0} {set offset 0}
  529.         
  530.         set xDist [expr $itk_option(-padx) + $offset]
  531.         set incrAmount [expr $_btnWidth + $offset]
  532.         
  533.         foreach button $_displayList {
  534.         place $itk_component($button) -anchor w \
  535.             -x $xDist -rely .5 -y 0 -relx 0 \
  536.             -width $_btnWidth -height $_btnHeight
  537.         
  538.         set xDist [expr $xDist + $incrAmount]
  539.         }
  540.         
  541.     } else {
  542.         set leftover [expr [winfo height $bf] \
  543.             - 2 * $itk_option(-pady) - $_btnHeight * $numBtns]
  544.         
  545.         if {$numBtns > 0} {
  546.         set offset [expr $leftover / ($numBtns + 1)]
  547.         } else {
  548.         set offset 0
  549.         }
  550.         if {$offset < 0} {set offset 0}
  551.         
  552.         set yDist [expr $itk_option(-pady) + $offset]
  553.         set incrAmount [expr $_btnHeight + $offset]
  554.         
  555.         foreach button $_displayList {
  556.         place $itk_component($button) -anchor n \
  557.             -y $yDist -relx .5 -x 0 -rely 0 \
  558.             -width $_btnWidth -height $_btnHeight
  559.         
  560.         set yDist [expr $yDist + $incrAmount]
  561.         }
  562.     }
  563.     }
  564. }
  565.  
  566.  
  567.