home *** CD-ROM | disk | FTP | other *** search
/ PC World 2000 May / PCWorld_2000-05_cd.bin / Software / TemaCD / povray / povwin3.exe / %MAINDIR% / scenes / advanced / skyvase.pov < prev    next >
Encoding:
Text File  |  2000-04-06  |  2.7 KB  |  114 lines
  1. // Persistence Of Vision raytracer version 3.1 sample file.
  2. // File by Dan Farmer
  3. //
  4. // NOTE: This image has traditionally been used as the standard
  5. // benchmark file.  At the time of POV-Ray 1.0, this scene rendered
  6. // in about the same time as the average of all of the standard scene
  7. // files.  Be cautious of making changes that will unfairly affect
  8. // benchmarks.  Please log all changes to this file below.
  9. // ===============
  10. // Change history
  11. // ===============
  12. // POV-Ray 3.0 changes:
  13. // DMF 1995 - Commented out bounding object.
  14. // DMF 1995 - Added max_trace_level 20 for use with ADC
  15. //            (reached level 13 of 20 on a 160x100 -a render)
  16. // DCB 1998 - Changed syntax to 3.1 compatable
  17. // ===============
  18.  
  19.  
  20. global_settings { assumed_gamma 2.2 max_trace_level 20 }
  21.  
  22. #include "shapes.inc"
  23. #include "shapes2.inc"
  24. #include "colors.inc"
  25. #include "textures.inc"
  26.  
  27. #declare DMF_Hyperboloid = quadric {  /* Like Hyperboloid_Y, but more curvy */
  28.    <1.0, -1.0,  1.0>,
  29.    <0.0,  0.0,  0.0>,
  30.    <0.0,  0.0,  0.0>,
  31.    -0.5
  32. }
  33.  
  34. camera {
  35.    location <0.0, 28.0, -200.0>
  36.    direction <0.0, 0.0, 2.0>
  37.    up  <0.0, 1.0, 0.0>
  38.    right <4/3, 0.0, 0.0>
  39.    look_at <0.0, -12.0, 0.0>
  40. }
  41.  
  42. /* Light behind viewer postion (pseudo-ambient light) */
  43. light_source { <100.0, 500.0, -500.0> colour White }
  44.  
  45. union {
  46.    union {
  47.       intersection {
  48.          plane { y, 0.7 }
  49.          object { DMF_Hyperboloid scale <0.75, 1.25, 0.75> }
  50.          object { DMF_Hyperboloid scale <0.70, 1.25, 0.70> inverse }
  51.          plane { y, -1.0 inverse }
  52.       }
  53.       sphere { <0, 0, 0>, 1 scale <1.6, 0.75, 1.6 > translate <0, -1.15, 0> }
  54.  
  55.       scale <20, 25, 20>
  56.  
  57.       pigment {
  58.          Bright_Blue_Sky
  59.          turbulence 0.3
  60.          quick_color Blue
  61.          scale <8.0, 4.0, 4.0>
  62.          rotate 15*z
  63.       }
  64.       finish {
  65.          ambient 0.1
  66.          diffuse 0.75
  67.          phong 1
  68.          phong_size 100
  69.          reflection 0.35
  70.       }
  71.    }
  72.  
  73.    sphere {  /* Gold ridge around sphere portion of vase*/
  74.       <0, 0, 0>, 1
  75.       scale <1.6, 0.75, 1.6>
  76.       translate -7*y
  77.       scale <20.5, 4.0, 20.5>
  78.  
  79.       finish { Metal }
  80.       pigment { OldGold }
  81.    }
  82. }
  83.  
  84. /* Stand for the vase */
  85. object { Hexagon
  86.    rotate -90.0*z             /* Stand it on end (vertical)*/
  87.    rotate -45*y               /* Turn it to a pleasing angle */
  88.    scale <40, 25, 40>
  89.    translate -70*y
  90.  
  91.    pigment {
  92.       Sapphire_Agate
  93.       quick_color Red
  94.       scale 10.0
  95.    }
  96.    finish {
  97.       ambient 0.2
  98.       diffuse 0.75
  99.       reflection 0.85
  100.    }
  101. }
  102.  
  103. union {
  104.    plane { z, 50  rotate -45*y }
  105.    plane { z, 50  rotate +45*y }
  106.    hollow on
  107.    pigment { DimGray }
  108.    finish {
  109.       ambient 0.2
  110.       diffuse 0.75
  111.       reflection 0.5
  112.    }
  113. }
  114.