home *** CD-ROM | disk | FTP | other *** search
/ PC World 2000 February / PCWorld_2000-02_cd.bin / live / usr / lib / perl5 / i386-linux / 5.004 / DynaLoader.pm < prev    next >
Text File  |  1999-02-03  |  23KB  |  694 lines
  1. package DynaLoader;
  2.  
  3. #   And Gandalf said: 'Many folk like to know beforehand what is to
  4. #   be set on the table; but those who have laboured to prepare the
  5. #   feast like to keep their secret; for wonder makes the words of
  6. #   praise louder.'
  7.  
  8. #   (Quote from Tolkien sugested by Anno Siegel.)
  9. #
  10. # See pod text at end of file for documentation.
  11. # See also ext/DynaLoader/README in source tree for other information.
  12. #
  13. # Tim.Bunce@ig.co.uk, August 1994
  14.  
  15. $VERSION = $VERSION = "1.03";    # avoid typo warning
  16.  
  17. require Config;
  18.  
  19. require AutoLoader;
  20. *AUTOLOAD = \&AutoLoader::AUTOLOAD;
  21.  
  22. # The following require can't be removed during maintenance
  23. # releases, sadly, because of the risk of buggy code that does 
  24. # require Carp; Carp::croak "..."; without brackets dying 
  25. # if Carp hasn't been loaded in earlier compile time. :-( 
  26. # We'll let those bugs get found on the development track.
  27. require Carp if $] < 5.00450; 
  28.  
  29.  
  30. # enable debug/trace messages from DynaLoader perl code
  31. $dl_debug = $ENV{PERL_DL_DEBUG} || 0 unless defined $dl_debug;
  32.  
  33. #
  34. # Flags to alter dl_load_file behaviour.  Assigned bits:
  35. #   0x01  make symbols available for linking later dl_load_file's.
  36. #         (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
  37. #         (ignored under VMS; effect is built-in to image linking)
  38. #
  39. # This is called as a class method $module->dl_load_flags.  The
  40. # definition here will be inherited and result on "default" loading
  41. # behaviour unless a sub-class of DynaLoader defines its own version.
  42. #
  43.  
  44. sub dl_load_flags { 0x00 }
  45.  
  46. # 
  47.  
  48. ($dl_dlext, $dlsrc)
  49.     = @Config::Config{'dlext', 'dlsrc'};
  50.  
  51. # Some systems need special handling to expand file specifications
  52. # (VMS support by Charles Bailey <bailey@HMIVAX.HUMGEN.UPENN.EDU>)
  53. # See dl_expandspec() for more details. Should be harmless but
  54. # inefficient to define on systems that don't need it.
  55. $do_expand = $Is_VMS = $^O eq 'VMS';
  56.  
  57. @dl_require_symbols = ();       # names of symbols we need
  58. @dl_resolve_using   = ();       # names of files to link with
  59. @dl_library_path    = ();       # path to look for files
  60. @dl_librefs         = ();       # things we have loaded
  61. @dl_modules         = ();       # Modules we have loaded
  62.  
  63. # This is a fix to support DLD's unfortunate desire to relink -lc
  64. @dl_resolve_using = dl_findfile('-lc') if $dlsrc eq "dl_dld.xs";
  65.  
  66. # Initialise @dl_library_path with the 'standard' library path
  67. # for this platform as determined by Configure
  68. push(@dl_library_path, split(' ',$Config::Config{'libpth'}));
  69.  
  70. # Add to @dl_library_path any extra directories we can gather from
  71. # environment variables. So far LD_LIBRARY_PATH is the only known
  72. # variable used for this purpose. Others may be added later.
  73. push(@dl_library_path, split(/:/, $ENV{LD_LIBRARY_PATH}))
  74.     if $ENV{LD_LIBRARY_PATH};
  75.  
  76.  
  77. # No prizes for guessing why we don't say 'bootstrap DynaLoader;' here.
  78. boot_DynaLoader('DynaLoader') if defined(&boot_DynaLoader);
  79.  
  80.  
  81. if ($dl_debug) {
  82.     print STDERR "DynaLoader.pm loaded (@INC, @dl_library_path)\n";
  83.     print STDERR "DynaLoader not linked into this perl\n"
  84.         unless defined(&boot_DynaLoader);
  85. }
  86.  
  87. 1; # End of main code
  88.  
  89.  
  90. sub croak   { require Carp; Carp::croak(@_)   }
  91.  
  92. # The bootstrap function cannot be autoloaded (without complications)
  93. # so we define it here:
  94.  
  95. sub bootstrap {
  96.     # use local vars to enable $module.bs script to edit values
  97.     local(@args) = @_;
  98.     local($module) = $args[0];
  99.     local(@dirs, $file);
  100.  
  101.     unless ($module) {
  102.     require Carp;
  103.     Carp::confess("Usage: DynaLoader::bootstrap(module)");
  104.     }
  105.  
  106.     # A common error on platforms which don't support dynamic loading.
  107.     # Since it's fatal and potentially confusing we give a detailed message.
  108.     croak("Can't load module $module, dynamic loading not available in this perl.\n".
  109.     "  (You may need to build a new perl executable which either supports\n".
  110.     "  dynamic loading or has the $module module statically linked into it.)\n")
  111.     unless defined(&dl_load_file);
  112.  
  113.     my @modparts = split(/::/,$module);
  114.     my $modfname = $modparts[-1];
  115.  
  116.     # Some systems have restrictions on files names for DLL's etc.
  117.     # mod2fname returns appropriate file base name (typically truncated)
  118.     # It may also edit @modparts if required.
  119.     $modfname = &mod2fname(\@modparts) if defined &mod2fname;
  120.  
  121.     my $modpname = join('/',@modparts);
  122.  
  123.     print STDERR "DynaLoader::bootstrap for $module ",
  124.         "(auto/$modpname/$modfname.$dl_dlext)\n" if $dl_debug;
  125.  
  126.     foreach (@INC) {
  127.     chop($_ = VMS::Filespec::unixpath($_)) if $Is_VMS;
  128.     my $dir = "$_/auto/$modpname";
  129.     next unless -d $dir; # skip over uninteresting directories
  130.  
  131.     # check for common cases to avoid autoload of dl_findfile
  132.     my $try = "$dir/$modfname.$dl_dlext";
  133.     last if $file = ($do_expand) ? dl_expandspec($try) : (-f $try && $try);
  134.  
  135.     # no luck here, save dir for possible later dl_findfile search
  136.     push @dirs, $dir;
  137.     }
  138.     # last resort, let dl_findfile have a go in all known locations
  139.     $file = dl_findfile(map("-L$_",@dirs,@INC), $modfname) unless $file;
  140.  
  141.     croak("Can't locate loadable object for module $module in \@INC (\@INC contains: @INC)")
  142.     unless $file;    # wording similar to error from 'require'
  143.  
  144.     my $bootname = "boot_$module";
  145.     $bootname =~ s/\W/_/g;
  146.     @dl_require_symbols = ($bootname);
  147.  
  148.     # Execute optional '.bootstrap' perl script for this module.
  149.     # The .bs file can be used to configure @dl_resolve_using etc to
  150.     # match the needs of the individual module on this architecture.
  151.     my $bs = $file;
  152.     $bs =~ s/(\.\w+)?$/\.bs/; # look for .bs 'beside' the library
  153.     if (-s $bs) { # only read file if it's not empty
  154.         print STDERR "BS: $bs ($^O, $dlsrc)\n" if $dl_debug;
  155.         eval { do $bs; };
  156.         warn "$bs: $@\n" if $@;
  157.     }
  158.  
  159.     # Many dynamic extension loading problems will appear to come from
  160.     # this section of code: XYZ failed at line 123 of DynaLoader.pm.
  161.     # Often these errors are actually occurring in the initialisation
  162.     # C code of the extension XS file. Perl reports the error as being
  163.     # in this perl code simply because this was the last perl code
  164.     # it executed.
  165.  
  166.     my $libref = dl_load_file($file, $module->dl_load_flags) or
  167.     croak("Can't load '$file' for module $module: ".dl_error()."\n");
  168.  
  169.     push(@dl_librefs,$libref);  # record loaded object
  170.  
  171.     my @unresolved = dl_undef_symbols();
  172.     if (@unresolved) {
  173.     require Carp;
  174.     Carp::carp("Undefined symbols present after loading $file: @unresolved\n");
  175.     }
  176.  
  177.     my $boot_symbol_ref = dl_find_symbol($libref, $bootname) or
  178.          croak("Can't find '$bootname' symbol in $file\n");
  179.  
  180.     my $xs = dl_install_xsub("${module}::bootstrap", $boot_symbol_ref, $file);
  181.  
  182.     push(@dl_modules, $module); # record loaded module
  183.  
  184.     # See comment block above
  185.     &$xs(@args);
  186. }
  187.  
  188.  
  189. #sub _check_file {   # private utility to handle dl_expandspec vs -f tests
  190. #    my($file) = @_;
  191. #    return $file if (!$do_expand && -f $file); # the common case
  192. #    return $file if ( $do_expand && ($file=dl_expandspec($file)));
  193. #    return undef;
  194. #}
  195.  
  196.  
  197. # Let autosplit and the autoloader deal with these functions:
  198. __END__
  199.  
  200.  
  201. sub dl_findfile {
  202.     # Read ext/DynaLoader/DynaLoader.doc for detailed information.
  203.     # This function does not automatically consider the architecture
  204.     # or the perl library auto directories.
  205.     my (@args) = @_;
  206.     my (@dirs,  $dir);   # which directories to search
  207.     my (@found);         # full paths to real files we have found
  208.     my $dl_ext= $Config::Config{'dlext'}; # suffix for perl extensions
  209.     my $dl_so = $Config::Config{'so'};    # suffix for shared libraries
  210.  
  211.     print STDERR "dl_findfile(@args)\n" if $dl_debug;
  212.  
  213.     # accumulate directories but process files as they appear
  214.     arg: foreach(@args) {
  215.         #  Special fast case: full filepath requires no search
  216.         if ($Is_VMS && m%[:>/\]]% && -f $_) {
  217.         push(@found,dl_expandspec(VMS::Filespec::vmsify($_)));
  218.         last arg unless wantarray;
  219.         next;
  220.         }
  221.         elsif (m:/: && -f $_ && !$do_expand) {
  222.         push(@found,$_);
  223.         last arg unless wantarray;
  224.         next;
  225.     }
  226.  
  227.         # Deal with directories first:
  228.         #  Using a -L prefix is the preferred option (faster and more robust)
  229.         if (m:^-L:) { s/^-L//; push(@dirs, $_); next; }
  230.  
  231.         #  Otherwise we try to try to spot directories by a heuristic
  232.         #  (this is a more complicated issue than it first appears)
  233.         if (m:/: && -d $_) {   push(@dirs, $_); next; }
  234.  
  235.         # VMS: we may be using native VMS directry syntax instead of
  236.         # Unix emulation, so check this as well
  237.         if ($Is_VMS && /[:>\]]/ && -d $_) {   push(@dirs, $_); next; }
  238.  
  239.         #  Only files should get this far...
  240.         my(@names, $name);    # what filenames to look for
  241.         if (m:-l: ) {          # convert -lname to appropriate library name
  242.             s/-l//;
  243.             push(@names,"lib$_.$dl_so");
  244.             push(@names,"lib$_.a");
  245.         } else {                # Umm, a bare name. Try various alternatives:
  246.             # these should be ordered with the most likely first
  247.             push(@names,"$_.$dl_ext")    unless m/\.$dl_ext$/o;
  248.             push(@names,"$_.$dl_so")     unless m/\.$dl_so$/o;
  249.             push(@names,"lib$_.$dl_so")  unless m:/:;
  250.             push(@names,"$_.a")          if !m/\.a$/ and $dlsrc eq "dl_dld.xs";
  251.             push(@names, $_);
  252.         }
  253.         foreach $dir (@dirs, @dl_library_path) {
  254.             next unless -d $dir;
  255.             chop($dir = VMS::Filespec::unixpath($dir)) if $Is_VMS;
  256.             foreach $name (@names) {
  257.         my($file) = "$dir/$name";
  258.                 print STDERR " checking in $dir for $name\n" if $dl_debug;
  259.         $file = ($do_expand) ? dl_expandspec($file) : (-f $file && $file);
  260.         #$file = _check_file($file);
  261.         if ($file) {
  262.                     push(@found, $file);
  263.                     next arg; # no need to look any further
  264.                 }
  265.             }
  266.         }
  267.     }
  268.     if ($dl_debug) {
  269.         foreach(@dirs) {
  270.             print STDERR " dl_findfile ignored non-existent directory: $_\n" unless -d $_;
  271.         }
  272.         print STDERR "dl_findfile found: @found\n";
  273.     }
  274.     return $found[0] unless wantarray;
  275.     @found;
  276. }
  277.  
  278.  
  279. sub dl_expandspec {
  280.     my($spec) = @_;
  281.     # Optional function invoked if DynaLoader.pm sets $do_expand.
  282.     # Most systems do not require or use this function.
  283.     # Some systems may implement it in the dl_*.xs file in which case
  284.     # this autoload version will not be called but is harmless.
  285.  
  286.     # This function is designed to deal with systems which treat some
  287.     # 'filenames' in a special way. For example VMS 'Logical Names'
  288.     # (something like unix environment variables - but different).
  289.     # This function should recognise such names and expand them into
  290.     # full file paths.
  291.     # Must return undef if $spec is invalid or file does not exist.
  292.  
  293.     my $file = $spec; # default output to input
  294.  
  295.     if ($Is_VMS) { # dl_expandspec should be defined in dl_vms.xs
  296.     require Carp;
  297.     Carp::croak("dl_expandspec: should be defined in XS file!\n");
  298.     } else {
  299.     return undef unless -f $file;
  300.     }
  301.     print STDERR "dl_expandspec($spec) => $file\n" if $dl_debug;
  302.     $file;
  303. }
  304.  
  305. sub dl_find_symbol_anywhere
  306. {
  307.     my $sym = shift;
  308.     my $libref;
  309.     foreach $libref (@dl_librefs) {
  310.     my $symref = dl_find_symbol($libref,$sym);
  311.     return $symref if $symref;
  312.     }
  313.     return undef;
  314. }
  315.  
  316. =head1 NAME
  317.  
  318. DynaLoader - Dynamically load C libraries into Perl code
  319.  
  320. dl_error(), dl_findfile(), dl_expandspec(), dl_load_file(), dl_find_symbol(), dl_find_symbol_anywhere(), dl_undef_symbols(), dl_install_xsub(), dl_load_flags(), bootstrap() - routines used by DynaLoader modules
  321.  
  322. =head1 SYNOPSIS
  323.  
  324.     package YourPackage;
  325.     require DynaLoader;
  326.     @ISA = qw(... DynaLoader ...);
  327.     bootstrap YourPackage;
  328.  
  329.     # optional method for 'global' loading
  330.     sub dl_load_flags { 0x01 }     
  331.  
  332.  
  333. =head1 DESCRIPTION
  334.  
  335. This document defines a standard generic interface to the dynamic
  336. linking mechanisms available on many platforms.  Its primary purpose is
  337. to implement automatic dynamic loading of Perl modules.
  338.  
  339. This document serves as both a specification for anyone wishing to
  340. implement the DynaLoader for a new platform and as a guide for
  341. anyone wishing to use the DynaLoader directly in an application.
  342.  
  343. The DynaLoader is designed to be a very simple high-level
  344. interface that is sufficiently general to cover the requirements
  345. of SunOS, HP-UX, NeXT, Linux, VMS and other platforms.
  346.  
  347. It is also hoped that the interface will cover the needs of OS/2, NT
  348. etc and also allow pseudo-dynamic linking (using C<ld -A> at runtime).
  349.  
  350. It must be stressed that the DynaLoader, by itself, is practically
  351. useless for accessing non-Perl libraries because it provides almost no
  352. Perl-to-C 'glue'.  There is, for example, no mechanism for calling a C
  353. library function or supplying arguments.  A ExtUtils::DynaLib module
  354. is available from CPAN sites which performs that function for some
  355. common system types.
  356.  
  357. DynaLoader Interface Summary
  358.  
  359.   @dl_library_path
  360.   @dl_resolve_using
  361.   @dl_require_symbols
  362.   $dl_debug
  363.   @dl_librefs
  364.   @dl_modules
  365.                                                   Implemented in:
  366.   bootstrap($modulename)                               Perl
  367.   @filepaths = dl_findfile(@names)                     Perl
  368.   $flags = $modulename->dl_load_flags                  Perl
  369.   $symref  = dl_find_symbol_anywhere($symbol)          Perl
  370.  
  371.   $libref  = dl_load_file($filename, $flags)           C
  372.   $symref  = dl_find_symbol($libref, $symbol)          C
  373.   @symbols = dl_undef_symbols()                        C
  374.   dl_install_xsub($name, $symref [, $filename])        C
  375.   $message = dl_error                                  C
  376.  
  377. =over 4
  378.  
  379. =item @dl_library_path
  380.  
  381. The standard/default list of directories in which dl_findfile() will
  382. search for libraries etc.  Directories are searched in order:
  383. $dl_library_path[0], [1], ... etc
  384.  
  385. @dl_library_path is initialised to hold the list of 'normal' directories
  386. (F</usr/lib>, etc) determined by B<Configure> (C<$Config{'libpth'}>).  This should
  387. ensure portability across a wide range of platforms.
  388.  
  389. @dl_library_path should also be initialised with any other directories
  390. that can be determined from the environment at runtime (such as
  391. LD_LIBRARY_PATH for SunOS).
  392.  
  393. After initialisation @dl_library_path can be manipulated by an
  394. application using push and unshift before calling dl_findfile().
  395. Unshift can be used to add directories to the front of the search order
  396. either to save search time or to override libraries with the same name
  397. in the 'normal' directories.
  398.  
  399. The load function that dl_load_file() calls may require an absolute
  400. pathname.  The dl_findfile() function and @dl_library_path can be
  401. used to search for and return the absolute pathname for the
  402. library/object that you wish to load.
  403.  
  404. =item @dl_resolve_using
  405.  
  406. A list of additional libraries or other shared objects which can be
  407. used to resolve any undefined symbols that might be generated by a
  408. later call to load_file().
  409.  
  410. This is only required on some platforms which do not handle dependent
  411. libraries automatically.  For example the Socket Perl extension
  412. library (F<auto/Socket/Socket.so>) contains references to many socket
  413. functions which need to be resolved when it's loaded.  Most platforms
  414. will automatically know where to find the 'dependent' library (e.g.,
  415. F</usr/lib/libsocket.so>).  A few platforms need to be told the
  416. location of the dependent library explicitly.  Use @dl_resolve_using
  417. for this.
  418.  
  419. Example usage:
  420.  
  421.     @dl_resolve_using = dl_findfile('-lsocket');
  422.  
  423. =item @dl_require_symbols
  424.  
  425. A list of one or more symbol names that are in the library/object file
  426. to be dynamically loaded.  This is only required on some platforms.
  427.  
  428. =item @dl_librefs
  429.  
  430. An array of the handles returned by successful calls to dl_load_file(),
  431. made by bootstrap, in the order in which they were loaded.
  432. Can be used with dl_find_symbol() to look for a symbol in any of
  433. the loaded files.
  434.  
  435. =item @dl_modules
  436.  
  437. An array of module (package) names that have been bootstrap'ed.
  438.  
  439. =item dl_error()
  440.  
  441. Syntax:
  442.  
  443.     $message = dl_error();
  444.  
  445. Error message text from the last failed DynaLoader function.  Note
  446. that, similar to errno in unix, a successful function call does not
  447. reset this message.
  448.  
  449. Implementations should detect the error as soon as it occurs in any of
  450. the other functions and save the corresponding message for later
  451. retrieval.  This will avoid problems on some platforms (such as SunOS)
  452. where the error message is very temporary (e.g., dlerror()).
  453.  
  454. =item $dl_debug
  455.  
  456. Internal debugging messages are enabled when $dl_debug is set true.
  457. Currently setting $dl_debug only affects the Perl side of the
  458. DynaLoader.  These messages should help an application developer to
  459. resolve any DynaLoader usage problems.
  460.  
  461. $dl_debug is set to C<$ENV{'PERL_DL_DEBUG'}> if defined.
  462.  
  463. For the DynaLoader developer/porter there is a similar debugging
  464. variable added to the C code (see dlutils.c) and enabled if Perl was
  465. built with the B<-DDEBUGGING> flag.  This can also be set via the
  466. PERL_DL_DEBUG environment variable.  Set to 1 for minimal information or
  467. higher for more.
  468.  
  469. =item dl_findfile()
  470.  
  471. Syntax:
  472.  
  473.     @filepaths = dl_findfile(@names)
  474.  
  475. Determine the full paths (including file suffix) of one or more
  476. loadable files given their generic names and optionally one or more
  477. directories.  Searches directories in @dl_library_path by default and
  478. returns an empty list if no files were found.
  479.  
  480. Names can be specified in a variety of platform independent forms.  Any
  481. names in the form B<-lname> are converted into F<libname.*>, where F<.*> is
  482. an appropriate suffix for the platform.
  483.  
  484. If a name does not already have a suitable prefix and/or suffix then
  485. the corresponding file will be searched for by trying combinations of
  486. prefix and suffix appropriate to the platform: "$name.o", "lib$name.*"
  487. and "$name".
  488.  
  489. If any directories are included in @names they are searched before
  490. @dl_library_path.  Directories may be specified as B<-Ldir>.  Any other
  491. names are treated as filenames to be searched for.
  492.  
  493. Using arguments of the form C<-Ldir> and C<-lname> is recommended.
  494.  
  495. Example: 
  496.  
  497.     @dl_resolve_using = dl_findfile(qw(-L/usr/5lib -lposix));
  498.  
  499.  
  500. =item dl_expandspec()
  501.  
  502. Syntax:
  503.  
  504.     $filepath = dl_expandspec($spec)
  505.  
  506. Some unusual systems, such as VMS, require special filename handling in
  507. order to deal with symbolic names for files (i.e., VMS's Logical Names).
  508.  
  509. To support these systems a dl_expandspec() function can be implemented
  510. either in the F<dl_*.xs> file or code can be added to the autoloadable
  511. dl_expandspec() function in F<DynaLoader.pm>.  See F<DynaLoader.pm> for
  512. more information.
  513.  
  514. =item dl_load_file()
  515.  
  516. Syntax:
  517.  
  518.     $libref = dl_load_file($filename, $flags)
  519.  
  520. Dynamically load $filename, which must be the path to a shared object
  521. or library.  An opaque 'library reference' is returned as a handle for
  522. the loaded object.  Returns undef on error.
  523.  
  524. The $flags argument to alters dl_load_file behaviour.  
  525. Assigned bits:
  526.  
  527.  0x01  make symbols available for linking later dl_load_file's.
  528.        (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
  529.        (ignored under VMS; this is a normal part of image linking)
  530.  
  531. (On systems that provide a handle for the loaded object such as SunOS
  532. and HPUX, $libref will be that handle.  On other systems $libref will
  533. typically be $filename or a pointer to a buffer containing $filename.
  534. The application should not examine or alter $libref in any way.)
  535.  
  536. This is the function that does the real work.  It should use the
  537. current values of @dl_require_symbols and @dl_resolve_using if required.
  538.  
  539.     SunOS: dlopen($filename)
  540.     HP-UX: shl_load($filename)
  541.     Linux: dld_create_reference(@dl_require_symbols); dld_link($filename)
  542.     NeXT:  rld_load($filename, @dl_resolve_using)
  543.     VMS:   lib$find_image_symbol($filename,$dl_require_symbols[0])
  544.  
  545. (The dlopen() function is also used by Solaris and some versions of
  546. Linux, and is a common choice when providing a "wrapper" on other
  547. mechanisms as is done in the OS/2 port.)
  548.  
  549. =item dl_loadflags()
  550.  
  551. Syntax:
  552.  
  553.     $flags = dl_loadflags $modulename;
  554.  
  555. Designed to be a method call, and to be overridden by a derived class
  556. (i.e. a class which has DynaLoader in its @ISA).  The definition in
  557. DynaLoader itself returns 0, which produces standard behavior from
  558. dl_load_file().
  559.  
  560. =item dl_find_symbol()
  561.  
  562. Syntax:
  563.  
  564.     $symref = dl_find_symbol($libref, $symbol)
  565.  
  566. Return the address of the symbol $symbol or C<undef> if not found.  If the
  567. target system has separate functions to search for symbols of different
  568. types then dl_find_symbol() should search for function symbols first and
  569. then other types.
  570.  
  571. The exact manner in which the address is returned in $symref is not
  572. currently defined.  The only initial requirement is that $symref can
  573. be passed to, and understood by, dl_install_xsub().
  574.  
  575.     SunOS: dlsym($libref, $symbol)
  576.     HP-UX: shl_findsym($libref, $symbol)
  577.     Linux: dld_get_func($symbol) and/or dld_get_symbol($symbol)
  578.     NeXT:  rld_lookup("_$symbol")
  579.     VMS:   lib$find_image_symbol($libref,$symbol)
  580.  
  581.  
  582. =item dl_find_symbol_anywhere()
  583.  
  584. Syntax:
  585.  
  586.     $symref = dl_find_symbol_anywhere($symbol)
  587.  
  588. Applies dl_find_symbol() to the members of @dl_librefs and returns
  589. the first match found.
  590.  
  591. =item dl_undef_symbols()
  592.  
  593. Example
  594.  
  595.     @symbols = dl_undef_symbols()
  596.  
  597. Return a list of symbol names which remain undefined after load_file().
  598. Returns C<()> if not known.  Don't worry if your platform does not provide
  599. a mechanism for this.  Most do not need it and hence do not provide it,
  600. they just return an empty list.
  601.  
  602.  
  603. =item dl_install_xsub()
  604.  
  605. Syntax:
  606.  
  607.     dl_install_xsub($perl_name, $symref [, $filename])
  608.  
  609. Create a new Perl external subroutine named $perl_name using $symref as
  610. a pointer to the function which implements the routine.  This is simply
  611. a direct call to newXSUB().  Returns a reference to the installed
  612. function.
  613.  
  614. The $filename parameter is used by Perl to identify the source file for
  615. the function if required by die(), caller() or the debugger.  If
  616. $filename is not defined then "DynaLoader" will be used.
  617.  
  618.  
  619. =item bootstrap()
  620.  
  621. Syntax:
  622.  
  623. bootstrap($module)
  624.  
  625. This is the normal entry point for automatic dynamic loading in Perl.
  626.  
  627. It performs the following actions:
  628.  
  629. =over 8
  630.  
  631. =item *
  632.  
  633. locates an auto/$module directory by searching @INC
  634.  
  635. =item *
  636.  
  637. uses dl_findfile() to determine the filename to load
  638.  
  639. =item *
  640.  
  641. sets @dl_require_symbols to C<("boot_$module")>
  642.  
  643. =item *
  644.  
  645. executes an F<auto/$module/$module.bs> file if it exists
  646. (typically used to add to @dl_resolve_using any files which
  647. are required to load the module on the current platform)
  648.  
  649. =item *
  650.  
  651. calls dl_load_flags() to determine how to load the file.
  652.  
  653. =item *
  654.  
  655. calls dl_load_file() to load the file
  656.  
  657. =item *
  658.  
  659. calls dl_undef_symbols() and warns if any symbols are undefined
  660.  
  661. =item *
  662.  
  663. calls dl_find_symbol() for "boot_$module"
  664.  
  665. =item *
  666.  
  667. calls dl_install_xsub() to install it as "${module}::bootstrap"
  668.  
  669. =item *
  670.  
  671. calls &{"${module}::bootstrap"} to bootstrap the module (actually
  672. it uses the function reference returned by dl_install_xsub for speed)
  673.  
  674. =back
  675.  
  676. =back
  677.  
  678.  
  679. =head1 AUTHOR
  680.  
  681. Tim Bunce, 11 August 1994.
  682.  
  683. This interface is based on the work and comments of (in no particular
  684. order): Larry Wall, Robert Sanders, Dean Roehrich, Jeff Okamoto, Anno
  685. Siegel, Thomas Neumann, Paul Marquess, Charles Bailey, myself and others.
  686.  
  687. Larry Wall designed the elegant inherited bootstrap mechanism and
  688. implemented the first Perl 5 dynamic loader using it.
  689.  
  690. Solaris global loading added by Nick Ing-Simmons with design/coding
  691. assistance from Tim Bunce, January 1996.
  692.  
  693. =cut
  694.