home *** CD-ROM | disk | FTP | other *** search
/ PC World Komputer 1996 September / PCWK996.iso / polskie / orhmet / dfdisk / rlibc / h_ldiv.asm < prev    next >
Assembly Source File  |  1995-09-24  |  6KB  |  198 lines
  1. ;[]-----------------------------------------------------------------[]
  2. ;|      H_LDIV.ASM -- long division routine                          |
  3. ;[]-----------------------------------------------------------------[]
  4.  
  5. ;
  6. ;       C/C++ Run Time Library - Version 5.0
  7. ; 
  8. ;       Copyright (c) 1987, 1992 by Borland International
  9. ;       All Rights Reserved.
  10. ; 
  11.  
  12.         INCLUDE RULES.ASI
  13.  
  14. _TEXT   segment public byte 'CODE'
  15.         assume  cs:_TEXT
  16.         public  LDIV@
  17.         public  F_LDIV@
  18.         public  N_LDIV@
  19.         public  LUDIV@
  20.         public  F_LUDIV@
  21.         public  N_LUDIV@
  22.         public  LMOD@
  23.         public  F_LMOD@
  24.         public  N_LMOD@
  25.         public  LUMOD@
  26.         public  F_LUMOD@
  27.         public  N_LUMOD@
  28.  
  29. N_LDIV@:
  30.         pop     cx                      ;fix up far return
  31.         push    cs
  32.         push    cx
  33. LDIV@:
  34. F_LDIV@:
  35.         xor     cx,cx                   ; signed divide
  36.         jmp     short common
  37.  
  38. N_LUDIV@:
  39.         pop     cx                      ;fix up far return
  40.         push    cs
  41.         push    cx
  42. LUDIV@:
  43. F_LUDIV@:
  44.         mov     cx,1                    ; unsigned divide
  45.         jmp     short common
  46.  
  47. N_LMOD@:
  48.         pop     cx                      ;fix up far return
  49.         push    cs
  50.         push    cx
  51. LMOD@:
  52. F_LMOD@:
  53.         mov     cx,2                    ; signed remainder
  54.         jmp     short   common
  55.  
  56. N_LUMOD@:
  57.         pop     cx                      ;fix up far return
  58.         push    cs
  59.         push    cx
  60. LUMOD@:
  61. F_LUMOD@:
  62.         mov     cx,3                    ; unsigned remainder
  63.  
  64. ;
  65. ;       di now contains a two bit control value.  The low order
  66. ;       bit (test mask of 1) is on if the operation is unsigned,
  67. ;       signed otherwise.  The next bit (test mask of 2) is on if
  68. ;       the operation returns the remainder, quotient otherwise.
  69. ;
  70. common:
  71.         push    bp
  72.         push    si
  73.         push    di
  74.         mov     bp,sp                   ; set up frame
  75.         mov     di,cx
  76. ;
  77. ;       dividend is pushed last, therefore the first in the args
  78. ;       divisor next.
  79. ;
  80.         mov     ax,10[bp]               ; get the first low word
  81.         mov     dx,12[bp]               ; get the first high word
  82.         mov     bx,14[bp]               ; get the second low word
  83.         mov     cx,16[bp]               ; get the second high word
  84.  
  85.         or      cx,cx
  86.         jnz     slow@ldiv               ; both high words are zero
  87.  
  88.         or      dx,dx
  89.         jz      quick@ldiv
  90.  
  91.         or      bx,bx
  92.         jz      quick@ldiv              ; if cx:bx == 0 force a zero divide
  93.                                         ; we don't expect this to actually
  94.                                         ; work
  95.  
  96. slow@ldiv:
  97.  
  98.         test    di,1                    ; signed divide?
  99.         jnz     positive                ; no: skip
  100. ;
  101. ;               Signed division should be done.  Convert negative
  102. ;               values to positive and do an unsigned division.
  103. ;               Store the sign value in the next higher bit of
  104. ;               di (test mask of 4).  Thus when we are done, testing
  105. ;               that bit will determine the sign of the result.
  106. ;
  107.         or      dx,dx                   ; test sign of dividend
  108.         jns     onepos
  109.         neg     dx
  110.         neg     ax
  111.         sbb     dx,0                    ; negate dividend
  112.         or      di,0Ch
  113. onepos:
  114.         or      cx,cx                   ; test sign of divisor
  115.         jns     positive
  116.         neg     cx
  117.         neg     bx
  118.         sbb     cx,0                    ; negate divisor
  119.         xor     di,4
  120. positive:
  121.         mov     bp,cx
  122.         mov     cx,32                   ; shift counter
  123.         push    di                      ; save the flags
  124. ;
  125. ;       Now the stack looks something like this:
  126. ;
  127. ;               16[bp]: divisor (high word)
  128. ;               14[bp]: divisor (low word)
  129. ;               12[bp]: dividend (high word)
  130. ;               10[bp]: dividend (low word)
  131. ;                8[bp]: return CS
  132. ;                6[bp]: return IP
  133. ;                4[bp]: previous BP
  134. ;                2[bp]: previous SI
  135. ;                 [bp]: previous DI
  136. ;               -2[bp]: control bits
  137. ;                       01 - Unsigned divide
  138. ;                       02 - Remainder wanted
  139. ;                       04 - Negative quotient
  140. ;                       08 - Negative remainder
  141. ;
  142.         xor     di,di                   ; fake a 64 bit dividend
  143.         xor     si,si                   ;
  144. xloop:
  145.         shl     ax,1                    ; shift dividend left one bit
  146.         rcl     dx,1
  147.         rcl     si,1
  148.         rcl     di,1
  149.         cmp     di,bp                   ; dividend larger?
  150.         jb      nosub
  151.         ja      subtract
  152.         cmp     si,bx                   ; maybe
  153.         jb      nosub
  154. subtract:
  155.         sub     si,bx
  156.         sbb     di,bp                   ; subtract the divisor
  157.         inc     ax                      ; build quotient
  158. nosub:
  159.         loop    xloop
  160. ;
  161. ;       When done with the loop the four register value look like:
  162. ;
  163. ;       |     di     |     si     |     dx     |     ax     |
  164. ;       |        remainder        |         quotient        |
  165. ;
  166.         pop     bx                      ; get control bits
  167.         test    bx,2                    ; remainder?
  168.         jz      usequo
  169.         mov     ax,si
  170.         mov     dx,di                   ; use remainder
  171.         shr     bx,1                    ; shift in the remainder sign bit
  172. usequo:
  173.         test    bx,4                    ; needs negative
  174.         jz      finish
  175.         neg     dx
  176.         neg     ax
  177.         sbb     dx,0                    ; negate
  178. finish:
  179.         pop     di
  180.         pop     si
  181.         pop     bp
  182.         retf    8
  183.  
  184. quick@ldiv:
  185.         div     bx                      ; unsigned divide
  186.                                         ; DX = remainder AX = quotient
  187.         test    di,2                    ; want remainder?
  188.         jz      quick@quo
  189.         xchg    ax,dx
  190.  
  191. quick@quo:
  192.  
  193.         xor     dx,dx
  194.         jmp     short finish
  195.  
  196. _TEXT   ends
  197.         end
  198.